avoid repetition of post list table code

[~bandali/bndl.org] / haunt.scm

(use-modules (haunt asset)
             (haunt builder blog)
             (haunt builder atom)
             (haunt builder assets)
             (haunt builder rss)
             (haunt html)
             (haunt page)
             (haunt post)
             (haunt reader commonmark)
             (haunt site)
             (haunt utils)
             (ice-9 match)
             (srfi srfi-19))

(define my-scheme 'https)
(define my-domain "bandali.eu.org")
(define my-url
  (string-append (symbol->string my-scheme) "://" my-domain))
(define my-tag-prefix "tags")
(define my-date-format "~B ~e, ~Y")

(define (stylesheet name)
  `(link (@ (rel "stylesheet")
            (href ,(string-append "/" name ".css")))))

(define* (aa content #:optional (uri content) . title)
  `(a (@ (href ,uri) (title ,(apply string-append title))) ,content))

(define* (base-layout site body #:key title copy license-page?)
  `((doctype "html")
    (html
     (head
      (meta (@ (charset "utf-8")))
      (title ,(if title (string-append title " — " (site-title site))
                  "Amin Bandali’s Personal Site"))
      ,(stylesheet "reset")
      ,(stylesheet "style"))
     (body
      (main ,body)
      (footer
       (p "Copyright © "
          ,(if copy copy "2016–2019")
          " Amin Bandali.  See "
          ,(if license-page? "the above"
               (aa "license.html" "/license.html"))
          " for license conditions.  Please copy and share."))))))

(define* (tag-uri prefix tag #:optional (ext ".html"))
  "Return a URI relative to the site's root for a page listing entries
in PREFIX that are tagged with TAG."
  (string-append "/" my-tag-prefix "/" tag ext))

(define* (tag-pages #:key
                    (theme bandali-theme)
                    (prefix "")
                    (filter posts/reverse-chronological))
  "Return a builder procedure that renders a list page for every tag
used in a post.  All arguments are optional:

PREFIX: The directory in which to write the posts
FILTER: The procedure called to manipulate the posts list before rendering"
  (lambda (site posts)
    (define (tag-list tag posts all-posts)
      (define (render-list title posts prefix)
        (let ((body ((theme-collection-template theme)
                     site title posts prefix all-posts tag)))
          ((theme-layout theme) site title body)))
      (make-page (tag-uri my-tag-prefix tag)
                 (render-list (string-append "Notes tagged ‘" tag "’")
                              (filter posts)
                              prefix)
                 sxml->html))
    (let ((tag-groups (posts/group-by-tag posts)))
      (map (match-lambda
             ((tag . tagged-posts) (tag-list tag tagged-posts posts)))
           tag-groups))))

(define (tag-links posts)
  "Generate an alphabetically sorted list of links to tagged posts.
The link text consists of the tag name and the number of tagged posts
in parentheses."
  `(ul (@ (class "tag-list"))
       ,(map (match-lambda
               ((tag . posts)
                `(li
                  ,(aa (string-append tag
                                      " ("
                                      (number->string (length posts))
                                      ")")
                       (tag-uri my-tag-prefix tag)))))
             ;; sort by tag
             (sort (posts/group-by-tag posts)
                   (lambda (a b) (string<? (car a) (car b)))))))

(register-metadata-parser! 'updated string->date*)

(define (intersperse lst delim)
  "Return the elements of LST delimited by DELIM, such that the
resulting list is of an odd length and every second element is DELIM."
  (if (<= (length lst) 1)
      lst
      (cons* (car lst)
             delim
             (intersperse (cdr lst) delim))))

(define (my-post-template post)
  `((header
     (h1 ,(post-ref post 'title))
     (address "By " ,(aa (post-ref post 'author) "/")
              " <" ,(post-ref post 'email) ">")
     (p (@ (class "date"))
        "Published "
        ,(date->string (post-date post) my-date-format))
     ,(if (post-ref post 'updated)
          `(p (@ (class "updated"))
              "Updated "
              ,(date->string (post-ref post 'updated)
                             my-date-format)) '())
     ,(if (post-ref post 'tags)
          `(p (@ (class "tags"))
              "Tagged "
              ,@(intersperse
                 (map (lambda (tag)
                        (aa tag (tag-uri my-tag-prefix tag)))
                      (post-ref post 'tags))
                 ", "))
          '()))
    ,(post-sxml post)
    (p (@ (class "muted inbox"))
       "Have a question or comment?  Start a discussion in my "
       ,(aa "public inbox" "https://lists.sr.ht/~bandali/public-inbox")
       " by sending an email to "
       ,(aa "~bandali/public-inbox@lists.sr.ht"
            "mailto:~bandali/public-inbox@lists.sr.ht")
       (small
        " [" ,(aa "mailing list etiquette"
                  "https://man.sr.ht/lists.sr.ht/etiquette.md") "]")
       ".")))

(define* (post-uri site post #:optional prefix)
  (string-append (or prefix "") "/"
                 (site-post-slug site post) ".html"))

(define* (post-list-table site posts #:optional prefix)
  `((table
     (@ (class "post-list"))
     (tbody
      ,@(map
         (lambda (post)
           `(tr
             (td ,(aa (post-ref post 'title)
                      (post-uri site post prefix)))
             (td (small ,(date->string (post-date post)
                                       my-date-format)))))
         posts)))))

(define* (my-collection-template site title posts prefix
                                 #:optional all-posts tag)
  `((h2 ,title
        ,(if tag
             (aa `(img (@ (class "feed-icon-h2")
                          (src "/icon-16px.png")
                          (alt "subscribe to atom feed")))
                 (tag-uri my-tag-prefix tag ".xml"))
             '()))
    ,(post-list-table site posts prefix)
    (h2 "Tags")
    ,(tag-links (or all-posts posts))
    ,(if tag
         '(a (@ (href "/notes.html"))
             "← all notes")
         '())))

(define bandali-theme
  (theme #:name "bandali"
         #:layout
         (lambda (site title body)
           (base-layout site body
                        #:title title))
         #:post-template my-post-template
         #:collection-template my-collection-template))

(define* (static-page title file-name body copy #:key license?)
  (lambda (site posts)
    (make-page file-name
               (base-layout site body #:title title #:copy copy
                            #:license-page? license?)
               sxml->html)))

(define (index-material site posts)
  `((h1 (@ (style "font-size: 0;"))
        "Amin Bandali")
    (p (@ (style "margin-top: 0;"))
       "Hi, I’m "
       ,(aa "Amin Bandali" "images/bandali-with-rms.jpg"
            "photo of bandali with rms wearing a "
            "“pay cash don’t be tracked” pin")
       ".  I’m a graduate student at "
       ,(aa "WatForm" "https://watform.uwaterloo.ca")
       " at University of Waterloo, supervised by "
       ,(aa "Dr. Nancy Day" "https://cs.uwaterloo.ca/~nday/")
       ".  The main goal of my research is improving "
       (strong "software and systems reliability")
       " through application of " (em "formal methods") ".")
    (p "My research at WatForm focuses on formal logic, model "
       "checking, and verification.  I’m also interested in "
       "programming languages, theorem provers, and their "
       "type systems.  You may wish to view my academic "
       ,(aa "curriculum vitae" "bandali-cv.html") ".")
    (p (@ (class "notice"))
       (strong "SE 212 students: ")
       "see " ,(aa "here" "se212-f19/") " for slides and other "
       "material from the tutorials.")
    (p "On the side, I dabble in "
       ,(aa "Lean" "https://leanprover.github.io") " and enjoy "
       ,(aa "hacking" "https://stallman.org/articles/on-hacking.html")
       " on "
       ,(aa "Elisp"
            "https://www.gnu.org/software/emacs/manual/elisp.html")
       ".  I’m a " ,(aa "Free Software"
                        "https://www.gnu.org/philosophy/free-sw.html")
       " activist, a GNU "
       ,(aa "maintainer" "https://www.gnu.org/people/#bandali")
       " and "
       ,(aa "webmaster"
            "https://www.gnu.org/people/webmeisters.html#bandali")
       ", and an " ,(aa "associate member"
                        "https://www.fsf.org/associate/")
       " of the " ,(aa "FSF" "https:///www.fsf.org"
                       "Free Software Foundation")
       ".  I co-host the " ,(aa "Emacs.el" "https://emacsel.com")
       " podcast with " ,(aa "Daniel Gopar" "https://www.pygopar.com")
       ", and organize " ,(aa "EmacsConf" "https://emacsconf.org")
       " with help from many wonderful people.  I am also a member of"
       " the Systems Committee for the "
       ,(aa "CSC" "https://csclub.uwaterloo.ca"
            "Computer Science Club of the University of Waterloo")
       ".")
    (p "See my " ,(aa "contact" "contact.html") " page for how to "
       "best reach me.")
    (h2 (@ (id "papers")) "Papers")
    (dl
     (dt "A Comparison of the Declarative Modelling Languages B, DASH,
          and TLA" (sup "+")
          (small
           " [ " ,(aa "pdf" "papers/modre2018-declarative.pdf") " | "
           ,(aa "bib" "papers/modre2018-declarative.bib") " ]"))
     (dd "Ali Abbassi, "
         ,(aa "Amin Bandali" my-url) ", "
         ,(aa "Nancy A. Day" "https://cs.uwaterloo.ca/~nday/") ", "
         "Jose Serna"
         (br)
         (em "2018 IEEE 8th International Model-Driven Requirements"
             " Engineering Workshop (MoDRE)")
         (br)
         "Copyright © 2018 IEEE.  All Rights Reserved.  Sadly."))
    (h2 (@ (id "talks")) "Talks")
    (dl
     (dt
      "The Magic of Specifications and Type Systems"
      (small
       " [ "
       ,(aa "slides" "talks/cucsc-2017-slides.pdf"
            "presented at the Canadian Undergraduate Computer Science"
            " Conference 2017,\n"
            "University of Toronto, Canada, June 15–17, 2017")
       " | "
       ,(aa "poster" "talks/eecs4080-poster.pdf"
            "presented at the Lassonde Undergraduate Summer Student"
            " Research Conference,\n"
            "York University, Toronto, Canada, August 15, 2017")
       " ]"))
     (dd ,(aa "Amin Bandali" my-url) ", "
         ,(aa "Simon Hudon" "https://github.com/cipher1024") ", "
         ,(aa "Jonathan S. Ostroff"
              "http://www.cse.yorku.ca/~jonathan/")))
    (h2 (@ (id "projects")) "Projects")
    (p "Below are a number of free software projects I have worked "
       "on:")
    (dl
     (dt ,(aa "george-mode" "https://git.sr.ht/~bandali/george-mode"))
     (dd "Emacs major mode for editing George files")
     (dt ,(aa "alloy-catalyst"
              "https://git.uwaterloo.ca/bandali/alloy-catalyst"))
     (dd "Framework for performance analysis of Alloy models")
     (dt ,(aa "unitb-web" "https://github.com/unitb/unitb-web"))
     (dd "Web interface for Unit-B")
     (dt ,(aa "tex2png-hs" "https://github.com/unitb/tex2png-hs"))
     (dd "Library and CLI for converting TeX and LaTeX to PNG "
         "images"))
    (h2 (@ (id "notes")) "Notes")
    (p "Here are notes about a variety of topics and issues I care "
       "about.  They’re also available via "
       ,(aa `((img (@ (class "feed-icon")
                      (src "/icon-12px.png")
                      (alt "subscribe to atom feed")))
              "Atom")
            "notes.atom")
       " and "
       ,(aa `((img (@ (class "feed-icon")
                      (src "/icon-12px.png")
                      (alt "subscribe to rss feed")))
              "RSS") "notes.rss") " feeds.")
    ,(post-list-table site posts)))

(define (index-page site posts)
  (make-page
   "index.html"
   (base-layout site (index-material site posts))
   sxml->html))

(define license-page
  (static-page
   "Licensing Information"
   "license.html"
   `((h1 "License information for "
         ,(aa my-domain my-url))
     (p "I strongly believe in "
        ,(aa "free culture"
             "https://questioncopyright.org/what_is_free_culture")
        " and that all creative works everywhere should be "
        ,(aa "free" "https://freedomdefined.org/Definition") ".")
     (p "Unless otherwise noted material on this site is licensed "
        "under the GNU General Public License as published by the "
        "Free Software Foundation, either version 3 of the License, "
        "or (at your option) any later version.  A copy of the "
        "license is included at " ,(aa "gpl-3.0.html") ".")
     (p "Some resources on free software and licenses:")
     (ul
      (li ,(aa "What is free software?"
               "https://www.gnu.org/philosophy/free-sw.html"))
      (li ,(aa "Various Licenses and Comments about Them"
               "https://www.gnu.org/licenses/license-list.html"))
      (li ,(aa "Proprietary Software Is Often Malware"
               "https://www.gnu.org/proprietary/proprietary.html"))))
      "2019"
      #:license? #t))

(define contact-page
  (static-page
   "Contact Information"
   "contact.html"
   `((h1 "Contact information")
     (p "Email is by far my preferred method of communication.  I may"
        " be contacted at any of the following addresses (choose the"
        " most closely related):")
     (ul
      (li "bandali@gnu.org")
      (li "bandali@uwaterloo.ca")
      (li "bandali@csclub.uwaterloo.ca"))
     (p "If you want to send me GPG-encrypted mail, you can use my "
        ,(aa "public key" "bandali-pubkey.txt") " with the"
        " fingerprint "
        (code "BE62 7373 8E61 6D6D 1B3A  08E8 A21A 0202 4881 6103")
        ".")
     (table
      (tbody
       (tr
        (td "IRC")
        (td "bandali on " ,(aa "freenode" "https://freenode.net") ", "
            ,(aa "moznet" "https://wiki.mozilla.org/IRC") ", and "
            ,(aa "oftc" "https://www.oftc.net")))
       (tr
        (td "XMPP")
        (td ,(aa "bandali@member.fsf.org"
                 "xmpp:bandali@member.fsf.org")))
       (tr
        (td "Matrix")
        (td ,(aa "@bandali:matrix.org"
                 "https://matrix.to/#/@bandali:matrix.org")))
       (tr
        (td "Fediverse")
        (td ,(aa "@bandali@pleroma.site"
                 "https://pleroma.site/bandali")))))
     (h2 "Elsewhere")
     (p "You may also find me at a few other places online.  Stricken"
        " through accounts are those I don’t use anymore, unless"
        " absolutely necessary.")
     (ul
      (li ,(aa "bandali" "https://libreplanet.org/wiki/User:Bandali")
          " on LibrePlanet")
      (li ,(aa "bandali" "https://emacsconf.org/bandali")
          " on EmacsConf")
      (li ,(aa "bandali" "https://savannah.gnu.org/users/bandali")
          " on Savannah")
      (li ,(aa "bandali" "https://git.sr.ht/~bandali")
          " on Sourcehut")
      (li ,(aa "bandali" "https://lobste.rs/u/bandali")
          " on Lobsters")
      (li ,(aa "bandali" "https://hackage.haskell.org/user/bandali")
          " on Hackage")
      (li ,(aa "bandali" "https://gitlab.com/bandali")
          " on GitLab")
      (li ,(aa "bandali"
               "https://news.ycombinator.com/user?id=bandali")
          " on HN")
      (li ,(aa "bandali" "https://www.reddit.com/u/bandali")
          " on reddit")
      (li (del ,(aa "bandali0" "https://github.com/bandali0")
               " on GitHub"))
      (li (del ,(aa "bandali0" "https://twitter.com/bandali0")
               " on Twitter"))))
   "2019"))

(define cv-page
  (static-page
   "Curriculum vitae"
   "bandali-cv.html"
   `((h1 "Curriculum vitae (" ,(aa "PDF" "bandali-cv.pdf") ")")
     (table
      (tbody
       (tr
        (td "Site")
        (td ,(aa my-domain my-url)))
       (tr
        (td "Email")
        (td "bandali@uwaterloo.ca"))
       (tr
        (td "Phone")
        (td "available upon request via email"))))
     (h2 "Education")
     (h3 "Master of Mathematics (Computer Science) | 2018–present")
     (p "University of Waterloo, Canada")
     (p "Supervised by Dr. Nancy Day | GPA: 3.7/4.0 | "
        "Expected completion: April 2020")
     (p "Research focusing on formal logic, model checking, and "
        "verification.")
     (h3 "B.Sc. Honours Computer Science | 2013–2017")
     (p "York University, Toronto, Canada")
     (p "GPA: 7.84/9.0")
     (p "Relevant courses: System Specification & Refinement, "
        "Software Requirements Eng., Software Design, "
        "Operating Systems, Computational Complexity, "
        "Design & Analysis of Algorithms.")
     (p "Finished first year (2013-14) at " (em "Carleton University")
        " with a GPA of 11.0/12.0, then transferred to "
        (em "York University") " in Fall 2014.")
     (h2 "Publications")
     (p "Listed on my " ,(aa "homepage" "/#papers"))
     (h2 "Work & Research Experience")
     (h3 "Cheriton School of Computer Science, University of Waterloo"
         " | 2018–present")
     (p "Instructional Apprentice, Teaching Assistant, "
        "Research Assistant")
     (ul
      (li (abbr (@ (title "Logic and Computation")) "SE 212") ": "
          (abbr (@ (title "Instructional Apprentice")) "IA") " in "
          "Fall 2019, "
          (abbr (@ (title "Teaching Assistant")) "TA") " in "
          "Fall 2018")
      (li (abbr (@ (title ,(string-append
                            "Software Requirements Specification and "
                            "Analysis"))) "SE 463")
          ": TA in Summer 2019 and 2018")
      (li (abbr (@ (title ,(string-append
                            "Elementary Algorithm Design and "
                            "Data Abstraction"))) "CS 136")
          ": TA in Winter 2018"))
     (h3 (abbr (@ (title
                   ,(string-append
                     "Electrical Engineering & Computer Science")))
               "EECS")
         " Department, York University | Fall 2017")
     (p "Teaching Assistant")
     (p (abbr (@ (title "Net-Centric Introduction to Computing"))
              "EECS 1012")
        ": TA in Fall 2017"))
   "2019"))

(define se212-f19-page
  (static-page
   "SE 212 Material"
   "se212-f19/index.html"
   `((h1 "Material from SE 212 tutorials")
     (p "This page contains slides and other material from "
        ,(aa "SE 212 tutorials"
             "https://www.student.cs.uwaterloo.ca/~se212/times.html")
        " held by me in Fall 2019. "
        (del "If you have any questions, concerns, or suggestions "
             "about the presented material, please email me at "
             "bandali@uwaterloo.ca or come see me during my "
             ,(aa "Friday office hours"
                  "https://www.student.cs.uwaterloo.ca/~se212/personnel.html")
             "."))
     (ul
      (li "Tutorial 1:"
          (ul
           (li ,(aa "TUT 101 slides" "se212-t01-101.pdf"))
           (li ,(aa "TUT 102 slides" "se212-t01-102.pdf"))
           (li ,(aa "Org beamer sources" "se212-t01.org"))))
      (li "Tutorial 2:"
          (ul
           (li ,(aa "Homework 2 q04d solution"
                    "se212-h02q04d-soln.grg"))))
      (li "Tutorial 3: —")
      (li "Tutorial 4: —")
      (li "Tutorial 5:"
          (ul
           (li ,(aa "Slides" "se212-t05.pdf"))
           (li ,(aa "Org beamer sources" "se212-t05.org"))))
      (li "Tutorial 6: —")
      (li "Tutorial 7: worked through questions 1–5 of Homework 7")
      (li "Tutorial 8: —")
      (li "Tutorial 9: —")
      (li "Tutorial 10: worked through questions 1–10 of "
          "Homework 10")))
   "2019"))

(module-define!
 (resolve-module '(haunt builder blog))
 'render-post
 (lambda (theme site post)
   (let ((title (post-ref post 'title))
         (body ((theme-post-template theme) post))
         (copy (post-ref post 'copyright)))
     (base-layout site body #:title title #:copy copy))))

(site #:title "Amin Bandali"
      ;; TODO: uncomment after new haunt release
      ;; #:scheme my-scheme
      #:domain my-domain
      #:default-metadata
      '((author . "Amin Bandali")
        (email  . "bandali@gnu.org")
        (domain . my-domain))
      #:readers (list commonmark-reader)
      #:builders (list (blog #:theme bandali-theme
                             #:collections
                             `(("Notes" "notes.html"
                                ,posts/reverse-chronological)))
                       (tag-pages)
                       index-page
                       (atom-feed
                        #:file-name "notes.atom")
                       (atom-feeds-by-tag
                        #:prefix my-tag-prefix)
                       (rss-feed
                        #:file-name "notes.rss")
                       contact-page
                       cv-page
                       license-page
                       se212-f19-page
                       (static-directory "static" "")))