(use-modules (haunt asset)
             (haunt builder blog)
             (haunt builder atom)
             (haunt builder assets)
             (haunt builder rss)
             (haunt html)
             (haunt page)
             (haunt post)
             (haunt reader commonmark)
             (haunt site)
             (haunt utils)
             (ice-9 match)
             (srfi srfi-19))

(define (stylesheet name)
  `(link (@ (rel "stylesheet")
            (href ,(string-append "/" name ".css")))))

(define* (base-layout site body #:key title)
  `((doctype "html")
    (html
     (head
      (meta (@ (charset "utf-8")))
      (title ,(if title (string-append title " — " (site-title site))
                  "Amin Bandali’s Personal Site"))
      ,(stylesheet "reset")
      ,(stylesheet "style"))
     (body
      (main ,body)
      (footer
       (p
        "Copyright 2016–2019 Amin Bandali.  See "
        (a (@ (href "license.html")) "license.html")
        " for license conditions. Please copy and share."))))))

(define my-date-format "~B ~d, ~Y")

(define (my-post-template post)
  `((header
     (h1 ,(post-ref post 'title))
     (address "By "
              (a (@ (href "/"))
                 ,(post-ref post 'author))
              " <" ,(post-ref post 'email) ">")
     (p (@ (class "date"))
        ,(date->string (post-date post) my-date-format)))
    ,(post-sxml post)
    (p (@ (class "muted inbox"))
       "Have a question or comment?  Start a discussion in my "
       (a (@ (href "https://lists.sr.ht/~bandali/public-inbox"))
          "public inbox")
       " by sending an email to "
       (a (@ (href "mailto:~bandali/public-inbox@lists.sr.ht"))
          "~bandali/public-inbox@lists.sr.ht")
       (small
        " ["
        (a (@ (href "https://man.sr.ht/lists.sr.ht/etiquette.md"))
           "mailing list etiquette")
        "]")
       ".")))

(define (my-collection-template site title posts prefix)
  (define (post-uri post)
    (string-append (or prefix "") "/"
                   (site-post-slug site post) ".html"))

  `((h3 ,title)
    (ul
     ,@(map (lambda (post)
              `(li
                (a (@ (href ,(post-uri post)))
                   ,(post-ref post 'title))
                " — " ,(date->string (post-date post) my-date-format)))
            posts))))

(define bandali-theme
  (theme #:name "bandali"
         #:layout
         (lambda (site title body)
           (base-layout site body
                        #:title title))
         #:post-template my-post-template
         #:collection-template my-collection-template))

(define (static-page title file-name body)
  (lambda (site posts)
    (make-page file-name
               (with-layout bandali-theme site title body)
               sxml->html)))

(define (index-material site posts)
  `(div
    (h1 (@ (style "font-size: 0;"))
        "Amin Bandali")
    (p (@ (style "margin-top: 0;"))
       "Hi, I’m "
       (a (@ (href "images/bandali-with-rms.jpg")
             (title ,(string-append
                      "photo of bandali with rms wearing a "
                      "“pay cash don’t be tracked” pin")))
          "Amin Bandali")
       ".  I’m a graduate student at "
       (a (@ (href "https://watform.uwaterloo.ca"))
          "WatForm")
       " at University of Waterloo, supervised by "
       (a (@ (href "https://cs.uwaterloo.ca/~nday/"))
          "Dr. Nancy Day")
       ".  The main goal of my research is improving "
       (strong "software and systems reliability")
       " through application of " (em "formal methods") ".")
    (p "My research at WatForm focuses on formal logic, model "
       "checking, and verification.  I’m also interested in "
       "programming languages, theorem provers, and their "
       "type systems.  You may wish to view my academic "
       (a (@ (href "bandali-cv.html")) "curriculum vitae") ".")
    (p (@ (class "notice"))
       (strong "SE 212 students: ")
       "see " (a (@ (href "se212-f19/")) "here") " for slides and "
       "other material from the tutorials.")
    (p "On the side, I dabble in "
       (a (@ (href "https://leanprover.github.io")) "Lean")
       " and enjoy "
       (a (@ (href "https://stallman.org/articles/on-hacking.html"))
          "hacking")
       " on "
       (a (@ (href "https://www.gnu.org/software/emacs/manual/elisp.html"))
          "Elisp")
       ".  I’m a "
       (a (@ (href "https://www.gnu.org/philosophy/free-sw.html"))
          "Free Software")
       " activist, a GNU "
       (a (@ (href "https://www.gnu.org/people/#bandali"))
          "maintainer")
       " and "
       (a (@ (href "https://www.gnu.org/people/webmeisters.html#bandali"))
          "webmaster")
       ", and an "
       (a (@ (href "https://www.fsf.org/associate/"))
          "associate member")
       " of the " (a (@ (href "https:///www.fsf.org")
                        (title "Free Software Foundation")) "FSF")
       ".  I co-host the "
       (a (@ (href "https://emacsel.com")) "Emacs.el")
       " podcast with "
       (a (@ (href "https://www.pygopar.com")) "Daniel Gopar")
       ", and organize "
       (a (@ (href "https://emacsconf.org")) "EmacsConf") " with help"
       " from many wonderful people.  I am also a member of the"
       " Systems Committee for the "
       (a (@ (href "https://csclub.uwaterloo.ca")
             (title ,(string-append
                      "Computer Science Club of the "
                      "University of Waterloo"))) "CSC")
       ".")
    (p "See my " (a (@ (href "contact.html")) "contact") " page for "
       "how to best reach me.")
    (h2 (@ (id "papers")) "Papers")
    (dl
     (dt "A Comparison of the Declarative Modelling Languages B, DASH,
          and TLA" (sup "+")
          (small
           " [ "
           (a (@ (href "papers/modre2018-declarative.pdf")) "pdf")
           " | "
           (a (@ (href "papers/modre2018-declarative.bib")) "bib")
           " ]"))
     (dd "Ali Abbassi, "
         (a (@ (href "https://bandali.eu.org")) "Amin Bandali") ", "
         (a (@ (href "https://cs.uwaterloo.ca/~nday/"))
            "Nancy A. Day")
         ", and Jose Serna"
         (br)
         (em "2018 IEEE 8th International Model-Driven Requirements"
             " Engineering Workshop (MoDRE)")
         (br)
         "Copyright © 2018 IEEE.  All Rights Reserved.  Sadly."))
    (h2 (@ (id "talks")) "Talks")
    (dl
     (dt
      "The Magic of Specifications and Type Systems"
      (span (@ (class "plinks"))
            " [ "
            (a (@ (href "talks/cucsc-2017-slides.pdf")
                  (title ,(string-append
                           "presented at the Canadian Undergraduate"
                           " Computer Science Conference 2017,\n"
                           "University of Toronto, Canada,"
                           "June 15–17, 2017")))
                  "slides")
               " | "
               (a (@ (href "talks/eecs4080-poster.pdf")
                     (title ,(string-append
                           "presented at the Lassonde Undergraduate"
                           " Summer Student Research Conference,\n"
                           "York University, Toronto, Canada,"
                           "August 15, 2017")))
                  "poster")
               " ]"))
     (dd (a (@ (href "https://bandali.eu.org")) "Amin Bandali") ", "
         (a (@ (href "https://github.com/cipher1024"))
            "Simon Hudon")
         ", "
         (a (@ (href "http://www.cse.yorku.ca/~jonathan/"))
            "Jonathan S. Ostroff")))
    (h2 (@ (id "projects")) "Projects")
    (p "Below are a number of free software projects I have worked "
       "on:")
    (dl
     (dt (a (@ (href "https://git.sr.ht/~bandali/george-mode"))
            "george-mode"))
     (dd "Emacs major mode for editing George files")
     (dt (a (@ (href "https://git.uwaterloo.ca/bandali/alloy-catalyst"))
            "alloy-catalyst"))
     (dd "Framework for performance analysis of Alloy models")
     (dt (a (@ (href "https://github.com/unitb/unitb-web"))
            "unitb-web"))
     (dd "Web interface for Unit-B")
     (dt (a (@ (href "https://github.com/unitb/tex2png-hs"))
            "tex2png-hs"))
     (dd "Library and CLI for converting TeX and LaTeX to PNG "
         "images"))
    (h2 (@ (id "notes")) "Notes")
    (table
     (@ (class "post-list"))
     (tbody
     ,@(map
        (lambda (post)
          (define (post-uri post)
            (string-append "/"
                           (site-post-slug site post) ".html"))
          `(tr
            (td (a (@ (href ,(post-uri post)))
                   ,(post-ref post 'title)))
            (td (@ (style "font-size: 0.875em;"))
             ,(date->string (post-date post) my-date-format))))
        (take-up-to 10 (posts/reverse-chronological posts)))))))

(define (index-page site posts)
  (make-page
   "index.html"
   (base-layout site (index-material site posts))
   sxml->html))

(define license-page
  (static-page
   "Licensing Information"
   "license.html"
   `((h1 "License information for bandali.eu.org")
     (p "I strongly believe in "
        (a (@ (href "https://questioncopyright.org/what_is_free_culture"))
           "free culture")
        " and that all creative works everywhere should be "
        (a (@ (href "https://freedomdefined.org/Definition")) "free"
           "."))
     (p "Unless otherwise noted material on this site is licensed "
        "under the GNU General Public License as published by the "
        "Free Software Foundation, either version 3 of the License, "
        "or (at your option) any later version.  A copy of the "
        "license is included at "
        (a (@ (href "gpl-3.0.html")) "gpl-3.0.html") ".")
     (p "Some resources on free software and licenses:")
     (ul
      (li (a (@ (href "https://www.gnu.org/philosophy/free-sw.html"))
             "What is free software?"))
      (li (a (@ (href "https://www.gnu.org/licenses/license-list.html"))
             "Various Licenses and Comments about Them"))
      (li (a (@ (href "https://www.gnu.org/proprietary/proprietary.html"))
             "Proprietary Software Is Often Malware"))))))

(define my-domain "bandali.eu.org")

(site #:title "Amin Bandali"
      #:domain my-domain
      #:default-metadata
      '((author . "Amin Bandali")
        (email  . "bandali@gnu.org")
        (domain . my-domain))
      #:readers (list commonmark-reader)
      #:builders (list (blog #:theme bandali-theme
                             #:collections
                             `(("Notes" "notes.html"
                                ,posts/reverse-chronological)))
                       index-page
                       (atom-feed
                        #:file-name "feed.atom")
                       (atom-feeds-by-tag
                        #:prefix "tags")
                       (rss-feed
                        #:file-name "feed.rss")
                       license-page
                       (static-directory "static" "")))