git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 ** Packages
 569
 570 The packages in this section are absolutely essential to my everyday
 571 workflow, and they play key roles in how I do my computing. They
 572 immensely enhance the Emacs experience for me; both using Emacs, and
 573 customizing it.
 574
 575 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 576
 577 #+begin_src emacs-lisp
 578 (use-package auto-compile
 579   :demand t
 580   :config
 581   (auto-compile-on-load-mode)
 582   (auto-compile-on-save-mode)
 583   (setq auto-compile-display-buffer               nil
 584         auto-compile-mode-line-counter            t
 585         auto-compile-source-recreate-deletes-dest t
 586         auto-compile-toggle-deletes-nonlib-dest   t
 587         auto-compile-update-autoloads             t)
 588   (add-hook 'auto-compile-inhibit-compile-hook
 589             'auto-compile-inhibit-compile-detached-git-head))
 590 #+end_src
 591
 592 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 593
 594 #+begin_quote
 595 Roll your own modal mode
 596 #+end_quote
 597
 598 #+begin_src emacs-lisp
 599 (use-package ryo-modal
 600   :commands ryo-modal-mode
 601   :bind ("M-m" . ryo-modal-mode)
 602   :after which-key
 603   :config
 604   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 605   (ryo-modal-keys
 606    ("," ryo-modal-repeat)
 607    ("b" backward-char)
 608    ("n" next-line)
 609    ("p" previous-line)
 610    ("f" forward-char)
 611    ("a" move-beginning-of-line)
 612    ("e" move-end-of-line)
 613    ("SPC" (("b b" ibuffer-list-buffers)
 614            ("b k" kill-this-buffer)
 615            ("b o" other-window)
 616            ("b s" save-buffer)
 617            ("q q" save-buffers-kill-terminal)))
 618    ("d" (("w" kill-word)
 619          ("d" kill-whole-line)
 620          ("b" backward-kill-word)))
 621    ("c" (("w" kill-word :exit t)
 622          ("c" kill-whole-line :exit t))))
 623
 624   (ryo-modal-keys
 625    ;; First argyment to ryo-modal-keys may be a list of keywords.
 626    ;; These keywords will be applied to all keybindings.
 627    (:norepeat t)
 628    ("0" "M-0")
 629    ("1" "M-1")
 630    ("2" "M-2")
 631    ("3" "M-3")
 632    ("4" "M-4")
 633    ("5" "M-5")
 634    ("6" "M-6")
 635    ("7" "M-7")
 636    ("8" "M-8")
 637    ("9" "M-9"))
 638   :hook ((text-mode . ryo-modal-mode)
 639          (prog-mode . ryo-modal-mode)))
 640 #+end_src
 641
 642 *** [[https://orgmode.org/][Org mode]]
 643
 644 #+begin_quote
 645 Org mode is for keeping notes, maintaining TODO lists, planning
 646 projects, and authoring documents with a fast and effective plain-text
 647 system.
 648 #+end_quote
 649
 650 In short, my favourite way of life.
 651
 652 #+begin_src emacs-lisp
 653 (use-package org
 654   :ryo ("SPC b t" org-babel-tangle)
 655   :config
 656   (setq org-src-tab-acts-natively t
 657         org-src-preserve-indentation nil
 658         org-edit-src-content-indentation 0
 659         org-html-divs '((preamble  "header" "preamble")
 660                         (content   "main"   "content")
 661                         (postamble "footer" "postamble"))
 662         org-html-doctype "html5"
 663         org-html-html5-fancy t
 664         org-html-postamble nil)
 665   :hook (org-mode . org-indent-mode))
 666 (use-package htmlize
 667   :after org)
 668 (use-package org-notmuch
 669   :after (:any org notmuch))
 670 #+end_src
 671
 672 *** [[https://magit.vc/][Magit]]
 673
 674 #+begin_quote
 675 It's Magit! A Git porcelain inside Emacs.
 676 #+end_quote
 677
 678 Not just how I do git, but /the/ way to do git.
 679
 680 #+begin_src emacs-lisp
 681 (use-package magit
 682   :ryo ("SPC" (("g s" magit-status)))
 683   :defer t
 684   :bind (("s-g"     . magit-status)
 685          ("C-x g"   . magit-status)
 686          ("C-x M-g" . magit-dispatch-popup))
 687   :config
 688   (magit-add-section-hook 'magit-status-sections-hook
 689                           'magit-insert-modules
 690                           'magit-insert-stashes
 691                           'append))
 692 #+end_src
 693
 694 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 695
 696 #+begin_quote
 697 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 698 an overview, and more. Oh, man!
 699 #+end_quote
 700
 701 There's no way I could top that, so I won't attempt to.
 702
 703 **** Ivy
 704
 705 #+begin_src emacs-lisp
 706 (use-package ivy
 707   :defer 1
 708   :bind
 709   (:map ivy-minibuffer-map
 710         ([escape] . keyboard-escape-quit)
 711         ;; ("C-j"    . ivy-next-line)
 712         ;; ("C-k"    . ivy-previous-line)
 713         ([S-up]   . ivy-previous-history-element)
 714         ([S-down] . ivy-next-history-element)
 715         ("DEL"    . ivy-backward-delete-char))
 716   :ryo ("SPC ," ivy-switch-buffer)
 717   :config
 718   (setq ivy-wrap t)
 719   (ivy-mode 1))
 720 #+end_src
 721
 722 **** Swiper
 723
 724 #+begin_src emacs-lisp
 725 (use-package swiper
 726   :ryo
 727   ("SPC /" swiper)
 728   ("s" swiper)
 729   :bind (([remap isearch-forward]  . swiper)
 730          ([remap isearch-backward] . swiper)))
 731 #+end_src
 732
 733 **** Counsel
 734
 735 #+begin_src emacs-lisp
 736 (use-package counsel
 737   :defer 1
 738   :ryo
 739   ("SPC" (("f r" counsel-recentf)
 740           ("SPC" counsel-M-x)
 741           ("."   counsel-find-file)))
 742   :bind (([remap execute-extended-command] . counsel-M-x)
 743          ([remap find-file] . counsel-find-file)
 744          ("s-r"     . counsel-recentf)
 745          :map minibuffer-local-map
 746          ("C-r" . counsel-minibuffer-history))
 747   :config
 748   (counsel-mode 1)
 749   (defalias 'locate #'counsel-locate))
 750 #+end_src
 751
 752 * Borg's =layer/essentials=
 753
 754 TODO: break this giant source block down into individual org sections.
 755
 756 #+begin_src emacs-lisp
 757 (use-package dash
 758   :config (dash-enable-font-lock))
 759
 760 (use-package diff-hl
 761   :config
 762   (setq diff-hl-draw-borders nil)
 763   (global-diff-hl-mode)
 764   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 765
 766 (use-package dired
 767   :defer t
 768   :config (setq dired-listing-switches "-alh"))
 769
 770 (use-package eldoc
 771   :when (version< "25" emacs-version)
 772   :config (global-eldoc-mode))
 773
 774 (use-package help
 775   :defer t
 776   :config (temp-buffer-resize-mode))
 777
 778 (progn ;    `isearch'
 779   (setq isearch-allow-scroll t))
 780
 781 (use-package lisp-mode
 782   :config
 783   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 784   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 785   (defun indent-spaces-mode ()
 786     (setq indent-tabs-mode nil))
 787   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 788
 789 (use-package man
 790   :defer t
 791   :config (setq Man-width 80))
 792
 793 (use-package paren
 794   :config (show-paren-mode))
 795
 796 (use-package prog-mode
 797   :config (global-prettify-symbols-mode)
 798   (defun indicate-buffer-boundaries-left ()
 799     (setq indicate-buffer-boundaries 'left))
 800   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 801
 802 (use-package recentf
 803   :demand t
 804   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 805
 806 (use-package savehist
 807   :config (savehist-mode))
 808
 809 (use-package saveplace
 810   :when (version< "25" emacs-version)
 811   :config (save-place-mode))
 812
 813 (use-package simple
 814   :config (column-number-mode))
 815
 816 (progn ;    `text-mode'
 817   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 818
 819 (use-package tramp
 820   :defer t
 821   :config
 822   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 823   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 824   (add-to-list 'tramp-default-proxies-alist
 825                (list (regexp-quote (system-name)) nil nil)))
 826
 827 (use-package undo-tree
 828   :ryo
 829   ("/" undo-tree-undo)
 830   ("_" undo-tree-redo)
 831   :config
 832   (global-undo-tree-mode)
 833   (setq undo-tree-mode-lighter ""))
 834 #+end_src
 835
 836 * Editing
 837
 838 ** Company
 839
 840 #+begin_src emacs-lisp
 841 (use-package company
 842   :defer 5
 843   :bind
 844   (:map company-active-map
 845         ([tab] . company-complete-common-or-cycle))
 846   :custom
 847   (company-idle-delay 0.3)
 848   (company-minimum-prefix-length 1)
 849   (company-selection-wrap-around t)
 850   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 851   :config
 852   (global-company-mode t))
 853 #+end_src
 854
 855 * Syntax and spell checking
 856 #+begin_src emacs-lisp
 857 (use-package flycheck
 858   :hook (prog-mode . flycheck-mode)
 859   :config
 860   ;; Use the load-path from running Emacs when checking elisp files
 861   (setq flycheck-emacs-lisp-load-path 'inherit)
 862
 863   ;; Only flycheck when I actually save the buffer
 864   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 865 #+end_src
 866 * Programming modes
 867
 868 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 869
 870 #+begin_src emacs-lisp
 871 (use-package alloy-mode
 872   :config (setq alloy-basic-offset 2))
 873 #+end_src
 874
 875 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 876
 877 #+begin_src emacs-lisp
 878 (use-package proof-site  ; Proof General
 879   :load-path "lib/proof-site/generic/")
 880 #+end_src
 881
 882 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 883
 884 #+begin_src emacs-lisp
 885 (use-package lean-mode
 886   :bind (:map lean-mode-map
 887               ("S-SPC" . company-complete)))
 888 #+end_src
 889
 890 ** Haskell
 891
 892 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 893
 894 #+begin_src emacs-lisp
 895 (use-package haskell-mode
 896   :config
 897   (setq haskell-indentation-layout-offset 4
 898         haskell-indentation-left-offset 4
 899         flycheck-checker 'haskell-hlint
 900         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 901 #+end_src
 902
 903 *** [[https://github.com/jyp/dante][dante]]
 904
 905 #+begin_src emacs-lisp
 906 (use-package dante
 907   :after haskell-mode
 908   :commands dante-mode
 909   :hook (haskell-mode . dante-mode))
 910 #+end_src
 911
 912 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 913
 914 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 915 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 916
 917 #+begin_src emacs-lisp
 918 (use-package hlint-refactor
 919   :bind (:map hlint-refactor-mode-map
 920               ("C-c l b" . hlint-refactor-refactor-buffer)
 921               ("C-c l r" . hlint-refactor-refactor-at-point))
 922   :hook (haskell-mode . hlint-refactor-mode))
 923 #+end_src
 924
 925 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 926
 927 #+begin_src emacs-lisp
 928 (use-package flycheck-haskell)
 929 #+end_src
 930
 931 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 932 :PROPERTIES:
 933 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 934 :END:
 935
 936 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 937 instead.
 938
 939 #+begin_src emacs-lisp :tangle no
 940 ;;; hs-lint.el --- minor mode for HLint code checking
 941
 942 ;; Copyright 2009 (C) Alex Ott
 943 ;;
 944 ;; Author: Alex Ott <alexott@gmail.com>
 945 ;; Keywords: haskell, lint, HLint
 946 ;; Requirements:
 947 ;; Status: distributed under terms of GPL2 or above
 948
 949 ;; Typical message from HLint looks like:
 950 ;;
 951 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 952 ;; Found:
 953 ;;   count1 p l = length (filter p l)
 954 ;; Why not:
 955 ;;   count1 p = length . filter p
 956
 957
 958 (require 'compile)
 959
 960 (defgroup hs-lint nil
 961   "Run HLint as inferior of Emacs, parse error messages."
 962   :group 'tools
 963   :group 'haskell)
 964
 965 (defcustom hs-lint-command "hlint"
 966   "The default hs-lint command for \\[hlint]."
 967   :type 'string
 968   :group 'hs-lint)
 969
 970 (defcustom hs-lint-save-files t
 971   "Save modified files when run HLint or no (ask user)"
 972   :type 'boolean
 973   :group 'hs-lint)
 974
 975 (defcustom hs-lint-replace-with-suggestions nil
 976   "Replace user's code with suggested replacements"
 977   :type 'boolean
 978   :group 'hs-lint)
 979
 980 (defcustom hs-lint-replace-without-ask nil
 981   "Replace user's code with suggested replacements automatically"
 982   :type 'boolean
 983   :group 'hs-lint)
 984
 985 (defun hs-lint-process-setup ()
 986   "Setup compilation variables and buffer for `hlint'."
 987   (run-hooks 'hs-lint-setup-hook))
 988
 989 ;; regex for replace suggestions
 990 ;;
 991 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 992 ;; Found:
 993 ;; \s +\(.*\)
 994 ;; Why not:
 995 ;; \s +\(.*\)
 996
 997 (defvar hs-lint-regex
 998   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
 999   "Regex for HLint messages")
1000
1001 (defun make-short-string (str maxlen)
1002   (if (< (length str) maxlen)
1003       str
1004     (concat (substring str 0 (- maxlen 3)) "...")))
1005
1006 (defun hs-lint-replace-suggestions ()
1007   "Perform actual replacement of suggestions"
1008   (goto-char (point-min))
1009   (while (re-search-forward hs-lint-regex nil t)
1010     (let* ((fname (match-string 1))
1011           (fline (string-to-number (match-string 2)))
1012           (old-code (match-string 4))
1013           (new-code (match-string 5))
1014           (msg (concat "Replace '" (make-short-string old-code 30)
1015                        "' with '" (make-short-string new-code 30) "'"))
1016           (bline 0)
1017           (eline 0)
1018           (spos 0)
1019           (new-old-code ""))
1020       (save-excursion
1021         (switch-to-buffer (get-file-buffer fname))
1022         (goto-char (point-min))
1023         (forward-line (1- fline))
1024         (beginning-of-line)
1025         (setf bline (point))
1026         (when (or hs-lint-replace-without-ask
1027                   (yes-or-no-p msg))
1028           (end-of-line)
1029           (setf eline (point))
1030           (beginning-of-line)
1031           (setf old-code (regexp-quote old-code))
1032           (while (string-match "\\\\ " old-code spos)
1033             (setf new-old-code (concat new-old-code
1034                                  (substring old-code spos (match-beginning 0))
1035                                  "\\ *"))
1036             (setf spos (match-end 0)))
1037           (setf new-old-code (concat new-old-code (substring old-code spos)))
1038           (remove-text-properties bline eline '(composition nil))
1039           (when (re-search-forward new-old-code eline t)
1040             (replace-match new-code nil t)))))))
1041
1042 (defun hs-lint-finish-hook (buf msg)
1043   "Function, that is executed at the end of HLint execution"
1044   (if hs-lint-replace-with-suggestions
1045       (hs-lint-replace-suggestions)
1046       (next-error 1 t)))
1047
1048 (define-compilation-mode hs-lint-mode "HLint"
1049   "Mode for check Haskell source code."
1050   (set (make-local-variable 'compilation-process-setup-function)
1051        'hs-lint-process-setup)
1052   (set (make-local-variable 'compilation-disable-input) t)
1053   (set (make-local-variable 'compilation-scroll-output) nil)
1054   (set (make-local-variable 'compilation-finish-functions)
1055        (list 'hs-lint-finish-hook))
1056   )
1057
1058 (defun hs-lint ()
1059   "Run HLint for current buffer with haskell source"
1060   (interactive)
1061   (save-some-buffers hs-lint-save-files)
1062   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1063                      'hs-lint-mode))
1064
1065 (provide 'hs-lint)
1066 ;;; hs-lint.el ends here
1067 #+end_src
1068
1069 #+begin_src emacs-lisp :tangle no
1070 (use-package hs-lint
1071   :load-path "lisp/"
1072   :bind (:map haskell-mode-map
1073               ("C-c l l" . hs-lint)))
1074 #+end_src
1075 * Emacs Enhancements
1076
1077 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1078
1079 #+begin_quote
1080 Emacs package that displays available keybindings in popup
1081 #+end_quote
1082
1083 #+begin_src emacs-lisp
1084 (use-package which-key
1085   :defer 1
1086   :config (which-key-mode))
1087 #+end_src
1088
1089 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1090
1091 #+begin_src emacs-lisp
1092 (use-package doom-modeline
1093   :demand t
1094   :config (setq doom-modeline-height 32)
1095   :hook (after-init . doom-modeline-init))
1096 #+end_src
1097
1098 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1099
1100 #+begin_src emacs-lisp :tangle no
1101 (use-package tao-theme
1102   :demand t
1103   :config (load-theme 'tao-yang t))
1104 #+end_src
1105
1106 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1107
1108 #+begin_src emacs-lisp
1109 (load-theme 'eink t)
1110 #+end_src
1111
1112 * Email
1113 ** [[https://notmuchmail.org][notmuch]]
1114
1115 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1116
1117 #+begin_src emacs-lisp
1118 (defun ab/notmuch ()
1119   "Delete other windows, then launch `notmuch'."
1120   (interactive)
1121   (require 'notmuch)
1122   (delete-other-windows)
1123   (notmuch))
1124
1125 ;; (map!
1126 ;;  :leader
1127 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1128 ;;  (:desc "search" :prefix "/"
1129 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1130 #+end_src
1131
1132 #+begin_src emacs-lisp
1133 (defvar ab-maildir "~/mail")
1134
1135 (use-package sendmail
1136   ;; :ensure nil
1137   :config
1138   (setq sendmail-program "/usr/bin/msmtp"
1139         mail-specify-envelope-from t
1140         mail-envelope-from 'header))
1141
1142 (use-package message
1143   ;; :ensure nil
1144   :config
1145   (setq message-kill-buffer-on-exit t
1146         message-send-mail-function 'message-send-mail-with-sendmail
1147         message-sendmail-envelope-from 'header
1148         message-directory "drafts"
1149         message-user-fqdn "aminb.org")
1150   (add-hook 'message-mode-hook
1151             (lambda () (setq fill-column 65
1152                         message-fill-column 65)))
1153   (add-hook 'message-mode-hook
1154             #'flyspell-mode)
1155   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1156   ;; TODO: is there a way to only run this when replying and not composing?
1157   ;; (add-hook 'notmuch-message-mode-hook
1158   ;;           (lambda () (progn
1159   ;;                   (newline)
1160   ;;                   (newline)
1161   ;;                   (forward-line -1)
1162   ;;                   (forward-line -1))))
1163   ;; (add-hook 'message-setup-hook
1164   ;;           #'mml-secure-message-sign-pgpmime)
1165   )
1166
1167 (after! mml-sec
1168   (setq mml-secure-openpgp-encrypt-to-self t
1169         mml-secure-openpgp-sign-with-sender t))
1170
1171 (use-package notmuch
1172   :ryo ("SPC m" ab/notmuch)
1173   :config
1174   (setq notmuch-hello-sections
1175         '(notmuch-hello-insert-header
1176           notmuch-hello-insert-saved-searches
1177           ;; notmuch-hello-insert-search
1178           notmuch-hello-insert-alltags)
1179         notmuch-search-oldest-first nil
1180         notmuch-show-all-tags-list t
1181         notmuch-message-headers  ; see bug follow-up above
1182         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1183         notmuch-hello-thousands-separator ","
1184         notmuch-fcc-dirs
1185         '(("amin@aminb.org"            . "amin/Sent")
1186           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1187           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1188           ("aminb@gnu.org"             . "gnu/Sent")
1189           (".*"                        . "sent"))
1190         notmuch-search-result-format
1191         '(("date" . "%12s ")
1192           ("count" . "%-7s ")
1193           ("authors" . "%-40s ")
1194           ("subject" . "%s ")
1195           ("tags" . "(%s)")))
1196   ;; (add-hook 'visual-fill-column-mode-hook
1197   ;;           (lambda ()
1198   ;;             (when (string= major-mode 'notmuch-message-mode)
1199   ;;               (setq visual-fill-column-width 70))))
1200   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1201   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1202   ;;             :override #'kill-this-buffer)
1203   :bind
1204   (:map notmuch-hello-mode-map
1205         ("g" . notmuch-poll-and-refresh-this-buffer)
1206         ("i" . (lambda ()
1207                  "Search for `inbox' tagged messages"
1208                  (interactive)
1209                  (notmuch-hello-search "tag:inbox")))
1210         ("u" . (lambda ()
1211                  "Search for `unread' tagged messages"
1212                  (interactive)
1213                  (notmuch-hello-search "tag:unread")))
1214         ("l" . (lambda ()
1215                  "Search for `latest tagged messages"
1216                  (interactive)
1217                  (notmuch-hello-search "tag:latest")))
1218         ("M" . (lambda ()
1219                  "Compose new mail and prompt for sender"
1220                  (interactive)
1221                  (let ((current-prefix-arg t))
1222                    (call-interactively #'notmuch-mua-new-mail)))))
1223   (:map notmuch-search-mode-map
1224         ("g" . notmuch-poll-and-refresh-this-buffer)
1225         ("k" . (lambda ()
1226                  "Mark message read"
1227                  (interactive)
1228                  (notmuch-search-tag '("-unread"))
1229                  ;; (notmuch-search-archive-thread)
1230                  (notmuch-search-next-thread)))
1231         ("u" . (lambda ()
1232                  "Mark message unread"
1233                  (interactive)
1234                  (notmuch-search-tag '("+unread"))
1235                  (notmuch-search-next-thread)))
1236         ("K" . (lambda ()
1237                  "Mark message deleted"
1238                  (interactive)
1239                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1240                  (notmuch-search-archive-thread)))
1241         ("S" . (lambda ()
1242                  "Mark message as spam"
1243                  (interactive)
1244                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1245                  (notmuch-search-archive-thread))))
1246   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1247         ("S" . (lambda ()
1248                  "Mark message as spam"
1249                  (interactive)
1250                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1251                  (notmuch-tree-archive-thread))))
1252 )
1253
1254 ;; (use-package counsel-notmuch
1255 ;;   :commands counsel-notmuch)
1256
1257 (after! notmuch-crypto
1258   (setq notmuch-crypto-process-mime t))
1259
1260 ;; (after! evil
1261 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1262 ;;         '((notmuch-hello-mode . emacs)
1263 ;;           (notmuch-search-mode . emacs)
1264 ;;           (notmuch-tree-mode . emacs))))
1265
1266 (after! recentf
1267   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1268 #+end_src
1269
1270 ** supercite
1271
1272 #+begin_src emacs-lisp :tangle no
1273 (use-package supercite
1274   :commands sc-cite-original
1275   :init
1276   (add-hook 'mail-citation-hook 'sc-cite-original)
1277
1278   (defun sc-remove-existing-signature ()
1279     (save-excursion
1280       (goto-char (region-beginning))
1281       (when (re-search-forward message-signature-separator (region-end) t)
1282         (delete-region (match-beginning 0) (region-end)))))
1283
1284   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1285
1286   (defun sc-remove-if-not-mailing-list ()
1287     (unless (assoc "list-id" sc-mail-info)
1288       (setq attribution sc-default-attribution
1289             citation (concat sc-citation-delimiter
1290                              sc-citation-separator))))
1291
1292   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1293
1294   :config
1295   (defun sc-fill-if-different (&optional prefix)
1296     "Fill the region bounded by `sc-fill-begin' and point.
1297 Only fill if optional PREFIX is different than
1298 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1299 fill region.  If PREFIX is not supplied, initialize fill
1300 variables.  This is useful for a regi `begin' frame-entry."
1301     (if (not prefix)
1302         (setq sc-fill-line-prefix ""
1303               sc-fill-begin (line-beginning-position))
1304       (if (and sc-auto-fill-region-p
1305                (not (string= prefix sc-fill-line-prefix)))
1306           (let ((fill-prefix sc-fill-line-prefix))
1307             (unless (or (string= fill-prefix "")
1308                         (save-excursion
1309                           (goto-char sc-fill-begin)
1310                           (or (looking-at ">+  +")
1311                               (< (length
1312                                   (buffer-substring (point)
1313                                                     (line-end-position)))
1314                                  65))))
1315               (fill-region sc-fill-begin (line-beginning-position)))
1316             (setq sc-fill-line-prefix prefix
1317                   sc-fill-begin (line-beginning-position)))))
1318 nil))
1319 #+end_src
1320
1321 * Blogging
1322 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1323
1324 #+begin_src emacs-lisp
1325 (use-package ox-hugo
1326   :after ox)
1327 #+end_src
1328
1329 * Post initialization
1330 :PROPERTIES:
1331 :CUSTOM_ID: post-initialization
1332 :END:
1333
1334 Display how long it took to load the init file.
1335
1336 #+begin_src emacs-lisp
1337 (message "Loading %s...done (%.3fs)" user-init-file
1338          (float-time (time-subtract (current-time)
1339                                     ab--before-user-init-time)))
1340 #+end_src
1341
1342 * Footer
1343 :PROPERTIES:
1344 :CUSTOM_ID: footer
1345 :END:
1346
1347 #+begin_src emacs-lisp :comments none
1348 ;;; init.el ends here
1349 #+end_src