git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** Package management
 192
 193 *** No =package.el=
 194
 195 I can do all my package management things with Borg, and don't need
 196 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 197 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 198
 199 #+begin_src emacs-lisp :tangle early-init.el
 200 (setq package-enable-at-startup nil)
 201 #+end_src
 202
 203 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 204 right now), and even when released it'll be long before most distros
 205 ship in their repos, I'll still put the old workaround with the
 206 commented call to ~package-initialize~ here anyway.
 207
 208 #+begin_src emacs-lisp
 209 (setq package-enable-at-startup nil)
 210 ;; (package-initialize)
 211 #+end_src
 212
 213 *** Borg
 214
 215 #+begin_quote
 216 Assimilate Emacs packages as Git submodules
 217 #+end_quote
 218
 219 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 220 short, it creates a git submodule in =lib/= for each package, which
 221 can then be managed with the help of Magit or other tools.
 222
 223 #+begin_src emacs-lisp
 224 (setq user-init-file (or load-file-name buffer-file-name)
 225       user-emacs-directory (file-name-directory user-init-file))
 226 (add-to-list 'load-path
 227              (expand-file-name "lib/borg" user-emacs-directory))
 228 (require 'borg)
 229 (borg-initialize)
 230 #+end_src
 231
 232 *** =use-package=
 233
 234 #+begin_quote
 235 A use-package declaration for simplifying your .emacs
 236 #+end_quote
 237
 238 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 239 packages (in our case especially the latter) in a neatly organized way
 240 and without compromising on performance.
 241
 242 #+begin_src emacs-lisp
 243 (require 'use-package)
 244 (if nil                             ; set to t when need to debug init
 245     (setq use-package-verbose t
 246           use-package-expand-minimally nil
 247           use-package-compute-statistics t
 248           debug-on-error t)
 249   (setq use-package-verbose nil
 250         use-package-expand-minimally t))
 251 #+end_src
 252
 253 *** Epkg
 254
 255 #+begin_quote
 256 Browse the Emacsmirror package database
 257 #+end_quote
 258
 259 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 260 database, low-level functions for querying the database, and a
 261 =package.el=-like user interface for browsing the available packages.
 262
 263 #+begin_src emacs-lisp
 264 (use-package epkg
 265   :defer t)
 266 #+end_src
 267
 268 ** No littering in =~/.emacs.d=
 269
 270 #+begin_quote
 271 Help keeping ~/.emacs.d clean
 272 #+end_quote
 273
 274 By default, even for Emacs' built-in packages, the configuration files
 275 and persistent data are all over the place. Use =no-littering= to help
 276 contain the mess.
 277
 278 #+begin_src emacs-lisp
 279 (use-package no-littering
 280   :demand t
 281   :config
 282   (savehist-mode 1)
 283   (add-to-list 'savehist-additional-variables 'kill-ring)
 284   (save-place-mode 1)
 285   (setq auto-save-file-name-transforms
 286         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 287 #+end_src
 288
 289 ** Custom file (=custom.el=)
 290
 291 I'm not planning on using the custom file much, but even so, I
 292 definitely don't want it mixing with =init.el=. So, here; let's give
 293 it it's own file. While at it, treat themes as safe.
 294
 295 #+begin_src emacs-lisp
 296 (use-package custom
 297   :no-require t
 298   :config
 299   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 300   (when (file-exists-p custom-file)
 301     (load custom-file))
 302   (setf custom-safe-themes t))
 303 #+end_src
 304
 305 ** Better =$PATH= handling
 306
 307 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 308 in my shell.
 309
 310 #+begin_src emacs-lisp
 311 (use-package exec-path-from-shell
 312   :defer 1
 313   :init
 314   (setq exec-path-from-shell-check-startup-files nil)
 315   :config
 316   (exec-path-from-shell-initialize)
 317   ;; while we're at it, let's fix access to our running ssh-agent
 318   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 319   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 320 #+end_src
 321
 322 ** Only one custom theme at a time
 323
 324 #+begin_src emacs-lisp
 325 (defadvice load-theme (before clear-previous-themes activate)
 326   "Clear existing theme settings instead of layering them"
 327   (mapc #'disable-theme custom-enabled-themes))
 328 #+end_src
 329
 330 ** Server
 331
 332 Start server if not already running. Alternatively, can be done by
 333 issuing =emacs --daemon= in the terminal, which can be automated with
 334 a systemd service or using =brew services start emacs= on macOS. I use
 335 Emacs as my window manager (via EXWM), so I always start Emacs on
 336 login; so starting the server from inside Emacs is good enough for me.
 337
 338 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 339
 340 #+begin_src emacs-lisp
 341 (use-package server
 342   :config (or (server-running-p) (server-mode)))
 343 #+end_src
 344
 345 ** Unicode support
 346
 347 Font stack with better unicode support, around =Ubuntu Mono= and
 348 =Hack=.
 349
 350 #+begin_src emacs-lisp
 351 (dolist (ft (fontset-list))
 352   (set-fontset-font
 353    ft
 354    'unicode
 355    (font-spec :name "Ubuntu Mono"))
 356   (set-fontset-font
 357    ft
 358    'unicode
 359    (font-spec :name "DejaVu Sans Mono")
 360    nil
 361    'append)
 362   ;; (set-fontset-font
 363   ;;  ft
 364   ;;  'unicode
 365   ;;  (font-spec
 366   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 367   ;;  nil
 368   ;;  'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  #x2115  ; ℕ
 372   ;;  (font-spec :name "DejaVu Sans Mono")
 373   ;;  nil
 374   ;;  'append)
 375   (set-fontset-font
 376    ft
 377    (cons ?Α ?ω)
 378    (font-spec :name "DejaVu Sans Mono" :size 14)
 379    nil
 380    'prepend))
 381 #+end_src
 382
 383 ** Libraries
 384
 385 #+begin_src emacs-lisp
 386 (require 'cl-lib)
 387 (require 'subr-x)
 388 #+end_src
 389
 390 ** Useful utilities
 391
 392 #+begin_src emacs-lisp
 393 (defun ab-enlist (exp)
 394   "Return EXP wrapped in a list, or as-is if already a list."
 395 (if (listp exp) exp (list exp)))
 396
 397 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 398 (defmacro after! (features &rest body)
 399   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 400 compilation."
 401   (declare (indent defun) (debug t))
 402   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 403                 (dolist (next (ab-enlist features))
 404                   (if (symbolp next)
 405                       (require next nil :no-error)
 406                     (load next :no-message :no-error))))
 407             #'progn
 408           #'with-no-warnings)
 409         (cond ((symbolp features)
 410                `(eval-after-load ',features '(progn ,@body)))
 411               ((and (consp features)
 412                     (memq (car features) '(:or :any)))
 413                `(progn
 414                   ,@(cl-loop for next in (cdr features)
 415                              collect `(after! ,next ,@body))))
 416               ((and (consp features)
 417                     (memq (car features) '(:and :all)))
 418                (dolist (next (cdr features))
 419                  (setq body `(after! ,next ,@body)))
 420                body)
 421               ((listp features)
 422                `(after! (:all ,@features) ,@body)))))
 423 #+end_src
 424
 425 * Core
 426 :PROPERTIES:
 427 :CUSTOM_ID: core
 428 :END:
 429
 430 ** Defaults
 431
 432 *** Time and battery in mode-line
 433
 434 Enable displaying time and battery in the mode-line, since I'm not
 435 using the Xfce panel anymore. Also, I don't need to see the load
 436 average on a regular basis, so disable that.
 437
 438 #+begin_src emacs-lisp
 439 (use-package time
 440   :ensure nil
 441   :init
 442   (setq display-time-default-load-average nil)
 443   :config
 444   (display-time-mode))
 445
 446 (use-package battery
 447   :ensure nil
 448   :config
 449   (display-battery-mode))
 450 #+end_src
 451
 452 *** Smaller fringe
 453
 454 Might want to set the fringe to a smaller value, especially if using
 455 EXWM. I'm fine with the default for now.
 456
 457 #+begin_src emacs-lisp
 458 ;; (fringe-mode '(3 . 1))
 459 (fringe-mode nil)
 460 #+end_src
 461
 462 *** Disable disabled commands
 463
 464 Emacs disables some commands by default that could persumably be
 465 confusing for novice users. Let's disable that.
 466
 467 #+begin_src emacs-lisp
 468 (setq disabled-command-function nil)
 469 #+end_src
 470
 471 *** Kill-ring
 472
 473 Save what I copy into clipboard from other applications into Emacs'
 474 kill-ring, which would allow me to still be able to easily access it
 475 in case I kill (cut or copy) something else inside Emacs before
 476 yanking (pasting) what I'd originally intended to.
 477
 478 #+begin_src emacs-lisp
 479 (setq save-interprogram-paste-before-kill t)
 480 #+end_src
 481
 482 *** Minibuffer
 483
 484 #+begin_src emacs-lisp
 485 (setq enable-recursive-minibuffers t
 486       resize-mini-windows t)
 487 #+end_src
 488
 489 *** Lazy-person-friendly yes/no prompts
 490
 491 Lazy people would prefer to type fewer keystrokes, especially for yes
 492 or no questions. I'm lazy.
 493
 494 #+begin_src emacs-lisp
 495 (defalias 'yes-or-no-p #'y-or-n-p)
 496 #+end_src
 497
 498 *** Startup screen and =*scratch*=
 499
 500 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 501 startup buffer.
 502
 503 #+begin_src emacs-lisp
 504 (setq initial-buffer-choice t)
 505 #+end_src
 506
 507 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 508 need the default hint.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-scratch-message nil)
 512 #+end_src
 513
 514 Also, let's use Text mode as the major mode, in case I want to
 515 customize it (=*scratch*='s default major mode, Fundamental mode,
 516 can't really be customized).
 517
 518 #+begin_src emacs-lisp
 519 (setq initial-major-mode 'text-mode)
 520 #+end_src
 521
 522 Inhibit the buffer list when more than 2 files are loaded.
 523
 524 #+begin_src emacs-lisp
 525 (setq inhibit-startup-buffer-menu t)
 526 #+end_src
 527
 528 I don't really need to see the startup screen or echo area message
 529 either.
 530
 531 #+begin_src emacs-lisp
 532 (advice-add #'display-startup-echo-area-message :override #'ignore)
 533 (setq inhibit-startup-screen t
 534       inhibit-startup-echo-area-message user-login-name)
 535 #+end_src
 536
 537 *** More useful frame titles
 538
 539 Show either the file name or the buffer name (in case the buffer isn't
 540 visiting a file). Borrowed from Emacs Prelude.
 541
 542 #+begin_src emacs-lisp
 543 (setq frame-title-format
 544       '("" invocation-name " - "
 545         (:eval (if (buffer-file-name)
 546                    (abbreviate-file-name (buffer-file-name))
 547                  "%b"))))
 548 #+end_src
 549
 550 *** Backups
 551
 552 Emacs' default backup settings aren't that great. Let's use more
 553 sensible options. See documentation for the ~make-backup-file~
 554 variable.
 555
 556 #+begin_src emacs-lisp
 557 (setq backup-by-copying t
 558       version-control t)
 559 #+end_src
 560
 561 ** Packages
 562
 563 The packages in this section are absolutely essential to my everyday
 564 workflow, and they play key roles in how I do my computing. They
 565 immensely enhance the Emacs experience for me; both using Emacs, and
 566 customizing it.
 567
 568 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 569
 570 #+begin_src emacs-lisp
 571 (use-package auto-compile
 572   :demand t
 573   :config
 574   (auto-compile-on-load-mode)
 575   (auto-compile-on-save-mode)
 576   (setq auto-compile-display-buffer               nil
 577         auto-compile-mode-line-counter            t
 578         auto-compile-source-recreate-deletes-dest t
 579         auto-compile-toggle-deletes-nonlib-dest   t
 580         auto-compile-update-autoloads             t)
 581   (add-hook 'auto-compile-inhibit-compile-hook
 582             'auto-compile-inhibit-compile-detached-git-head))
 583 #+end_src
 584
 585 *** [[https://github.com/noctuid/general.el][general]]
 586
 587 #+begin_quote
 588 Roll your own modal mode
 589 #+end_quote
 590
 591 #+begin_src emacs-lisp
 592 (use-package general
 593   :demand t
 594   :config
 595   (general-evil-setup t)
 596
 597   (general-override-mode)
 598
 599   (general-create-definer
 600     ab--mode-leader-keys
 601     :keymaps 'override
 602     :states '(emacs normal visual motion insert)
 603     :non-normal-prefix "C-,"
 604     :prefix ",")
 605
 606   (general-create-definer
 607     ab--leader-keys
 608     :keymaps 'override
 609     :states '(emacs normal visual motion insert)
 610     :non-normal-prefix "M-m"
 611     :prefix "SPC"))
 612 #+end_src
 613
 614 *** evil
 615
 616 #+begin_src emacs-lisp
 617 (use-package evil
 618   :demand t
 619   :hook (view-mode . evil-motion-state)
 620   :config (evil-mode 1))
 621 #+end_src
 622
 623 #+begin_src emacs-lisp
 624 (use-package evil-escape
 625   :demand t
 626   :init
 627   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 628         evil-escape-excluded-major-modes '(neotree-mode)
 629         evil-escape-key-sequence "jk"
 630         evil-escape-delay 0.25)
 631   :general
 632   (:states '(insert replace visual operator)
 633     "C-g" #'evil-escape)
 634   :config
 635   (evil-escape-mode 1)
 636   ;; no `evil-escape' in minibuffer
 637   (push #'minibufferp evil-escape-inhibit-functions))
 638 #+end_src
 639
 640 *** [[https://orgmode.org/][Org mode]]
 641
 642 #+begin_quote
 643 Org mode is for keeping notes, maintaining TODO lists, planning
 644 projects, and authoring documents with a fast and effective plain-text
 645 system.
 646 #+end_quote
 647
 648 In short, my favourite way of life.
 649
 650 #+begin_src emacs-lisp
 651 (setq org-src-tab-acts-natively t
 652       org-src-preserve-indentation nil
 653       org-edit-src-content-indentation 0
 654       org-html-divs '((preamble  "header" "preamble")
 655                       (content   "main"   "content")
 656                       (postamble "footer" "postamble"))
 657       org-html-doctype "html5"
 658       org-html-html5-fancy t
 659       org-html-postamble nil)
 660 (add-hook 'org-mode-hook 'org-indent-mode)
 661 (use-package htmlize)
 662 #+end_src
 663
 664 *** [[https://magit.vc/][Magit]]
 665
 666 #+begin_quote
 667 It's Magit! A Git porcelain inside Emacs.
 668 #+end_quote
 669
 670 Not just how I do git, but /the/ way to do git.
 671
 672 #+begin_src emacs-lisp
 673 (use-package magit
 674   :general (ab--leader-keys "g s" 'magit-status)
 675   :defer t
 676   :bind (("s-g"     . magit-status)
 677          ("C-x g"   . magit-status)
 678          ("C-x M-g" . magit-dispatch-popup))
 679   :config
 680   (magit-add-section-hook 'magit-status-sections-hook
 681                           'magit-insert-modules
 682                           'magit-insert-stashes
 683                           'append))
 684 #+end_src
 685
 686 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 687
 688 #+begin_quote
 689 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 690 an overview, and more. Oh, man!
 691 #+end_quote
 692
 693 There's no way I could top that, so I won't attempt to.
 694
 695 **** Ivy
 696
 697 #+begin_src emacs-lisp
 698 (use-package ivy
 699   :defer 1
 700   :bind
 701   (:map ivy-minibuffer-map
 702         ([escape] . keyboard-escape-quit)
 703         ;; ("C-j"    . ivy-next-line)
 704         ;; ("C-k"    . ivy-previous-line)
 705         ([S-up]   . ivy-previous-history-element)
 706         ([S-down] . ivy-next-history-element)
 707         ("DEL"    . ivy-backward-delete-char))
 708   :config
 709   (setq ivy-wrap t)
 710   (ivy-mode 1))
 711 #+end_src
 712
 713 **** Swiper
 714
 715 #+begin_src emacs-lisp
 716 (use-package swiper
 717   :general (:states 'normal "/" 'swiper)
 718   :bind (([remap isearch-forward]  . swiper)
 719          ([remap isearch-backward] . swiper)))
 720 #+end_src
 721
 722 **** Counsel
 723
 724 #+begin_src emacs-lisp
 725 (use-package counsel
 726   :defer 1
 727   :general (ab--leader-keys
 728     "f r" 'counsel-recentf
 729     "SPC" 'counsel-M-x
 730     "."   'counsel-find-file)
 731   :bind (([remap execute-extended-command] . counsel-M-x)
 732          ([remap find-file] . counsel-find-file)
 733          ("s-r"     . counsel-recentf)
 734          :map minibuffer-local-map
 735          ("C-r" . counsel-minibuffer-history))
 736   :config
 737   (counsel-mode 1)
 738   (defalias 'locate #'counsel-locate))
 739 #+end_src
 740
 741 * Borg's =layer/essentials=
 742
 743 TODO: break this giant source block down into individual org sections.
 744
 745 #+begin_src emacs-lisp
 746 (use-package dash
 747   :config (dash-enable-font-lock))
 748
 749 (use-package diff-hl
 750   :config
 751   (setq diff-hl-draw-borders nil)
 752   (global-diff-hl-mode)
 753   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 754
 755 (use-package dired
 756   :defer t
 757   :config (setq dired-listing-switches "-alh"))
 758
 759 (use-package eldoc
 760   :when (version< "25" emacs-version)
 761   :config (global-eldoc-mode))
 762
 763 (use-package help
 764   :defer t
 765   :config (temp-buffer-resize-mode))
 766
 767 (progn ;    `isearch'
 768   (setq isearch-allow-scroll t))
 769
 770 (use-package lisp-mode
 771   :config
 772   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 773   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 774   (defun indent-spaces-mode ()
 775     (setq indent-tabs-mode nil))
 776   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 777
 778 (use-package man
 779   :defer t
 780   :config (setq Man-width 80))
 781
 782 (use-package paren
 783   :config (show-paren-mode))
 784
 785 (use-package prog-mode
 786   :config (global-prettify-symbols-mode)
 787   (defun indicate-buffer-boundaries-left ()
 788     (setq indicate-buffer-boundaries 'left))
 789   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 790
 791 (use-package recentf
 792   :demand t
 793   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 794
 795 (use-package savehist
 796   :config (savehist-mode))
 797
 798 (use-package saveplace
 799   :when (version< "25" emacs-version)
 800   :config (save-place-mode))
 801
 802 (use-package simple
 803   :config (column-number-mode))
 804
 805 (progn ;    `text-mode'
 806   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 807
 808 (use-package tramp
 809   :defer t
 810   :config
 811   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 812   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 813   (add-to-list 'tramp-default-proxies-alist
 814                (list (regexp-quote (system-name)) nil nil)))
 815
 816 (use-package undo-tree
 817   :config
 818   (global-undo-tree-mode)
 819   (setq undo-tree-mode-lighter ""))
 820 #+end_src
 821
 822 * Editing
 823
 824 ** Company
 825
 826 #+begin_src emacs-lisp
 827 (use-package company
 828   :defer 5
 829   :bind
 830   (:map company-active-map
 831         ([tab] . company-complete-common-or-cycle))
 832   :custom
 833   (company-idle-delay 0.3)
 834   (company-minimum-prefix-length 1)
 835   (company-selection-wrap-around t)
 836   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 837   :config
 838   (global-company-mode t))
 839 #+end_src
 840
 841 ** Customizations
 842
 843 #+begin_src emacs-lisp
 844 (ab--leader-keys
 845   "b s" 'save-buffer
 846   "b b" 'ivy-switch-buffer
 847   ","   'ivy-switch-buffer
 848   "b k" 'kill-this-buffer
 849   "q q" 'evil-save-and-quit)
 850 #+end_src
 851
 852 * Syntax and spell checking
 853 #+begin_src emacs-lisp
 854 (use-package flycheck
 855   :hook (prog-mode . flycheck-mode)
 856   :config
 857   ;; Use the load-path from running Emacs when checking elisp files
 858   (setq flycheck-emacs-lisp-load-path 'inherit)
 859
 860   ;; Only flycheck when I actually save the buffer
 861   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 862 #+end_src
 863 * Programming modes
 864
 865 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 866
 867 #+begin_src emacs-lisp
 868 (use-package alloy-mode
 869   :config (setq alloy-basic-offset 2))
 870 #+end_src
 871
 872 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 873
 874 #+begin_src emacs-lisp
 875 (use-package proof-site  ; Proof General
 876   :load-path "lib/proof-site/generic/")
 877 #+end_src
 878
 879 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 880
 881 #+begin_src emacs-lisp
 882 (use-package lean-mode
 883   :bind (:map lean-mode-map
 884               ("S-SPC" . company-complete)))
 885 #+end_src
 886
 887 ** Haskell
 888
 889 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 890
 891 #+begin_src emacs-lisp
 892 (use-package haskell-mode
 893   :config
 894   (setq haskell-indentation-layout-offset 4
 895         haskell-indentation-left-offset 4
 896         flycheck-checker 'haskell-hlint
 897         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 898 #+end_src
 899
 900 *** [[https://github.com/jyp/dante][dante]]
 901
 902 #+begin_src emacs-lisp
 903 (use-package dante
 904   :after haskell-mode
 905   :commands dante-mode
 906   :hook (haskell-mode . dante-mode))
 907 #+end_src
 908
 909 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 910
 911 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 912 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 913
 914 #+begin_src emacs-lisp
 915 (use-package hlint-refactor
 916   :bind (:map hlint-refactor-mode-map
 917               ("C-c l b" . hlint-refactor-refactor-buffer)
 918               ("C-c l r" . hlint-refactor-refactor-at-point))
 919   :hook (haskell-mode . hlint-refactor-mode))
 920 #+end_src
 921
 922 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 923
 924 #+begin_src emacs-lisp
 925 (use-package flycheck-haskell)
 926 #+end_src
 927
 928 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 929 :PROPERTIES:
 930 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 931 :END:
 932
 933 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 934 instead.
 935
 936 #+begin_src emacs-lisp :tangle no
 937 ;;; hs-lint.el --- minor mode for HLint code checking
 938
 939 ;; Copyright 2009 (C) Alex Ott
 940 ;;
 941 ;; Author: Alex Ott <alexott@gmail.com>
 942 ;; Keywords: haskell, lint, HLint
 943 ;; Requirements:
 944 ;; Status: distributed under terms of GPL2 or above
 945
 946 ;; Typical message from HLint looks like:
 947 ;;
 948 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 949 ;; Found:
 950 ;;   count1 p l = length (filter p l)
 951 ;; Why not:
 952 ;;   count1 p = length . filter p
 953
 954
 955 (require 'compile)
 956
 957 (defgroup hs-lint nil
 958   "Run HLint as inferior of Emacs, parse error messages."
 959   :group 'tools
 960   :group 'haskell)
 961
 962 (defcustom hs-lint-command "hlint"
 963   "The default hs-lint command for \\[hlint]."
 964   :type 'string
 965   :group 'hs-lint)
 966
 967 (defcustom hs-lint-save-files t
 968   "Save modified files when run HLint or no (ask user)"
 969   :type 'boolean
 970   :group 'hs-lint)
 971
 972 (defcustom hs-lint-replace-with-suggestions nil
 973   "Replace user's code with suggested replacements"
 974   :type 'boolean
 975   :group 'hs-lint)
 976
 977 (defcustom hs-lint-replace-without-ask nil
 978   "Replace user's code with suggested replacements automatically"
 979   :type 'boolean
 980   :group 'hs-lint)
 981
 982 (defun hs-lint-process-setup ()
 983   "Setup compilation variables and buffer for `hlint'."
 984   (run-hooks 'hs-lint-setup-hook))
 985
 986 ;; regex for replace suggestions
 987 ;;
 988 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 989 ;; Found:
 990 ;; \s +\(.*\)
 991 ;; Why not:
 992 ;; \s +\(.*\)
 993
 994 (defvar hs-lint-regex
 995   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
 996   "Regex for HLint messages")
 997
 998 (defun make-short-string (str maxlen)
 999   (if (< (length str) maxlen)
1000       str
1001     (concat (substring str 0 (- maxlen 3)) "...")))
1002
1003 (defun hs-lint-replace-suggestions ()
1004   "Perform actual replacement of suggestions"
1005   (goto-char (point-min))
1006   (while (re-search-forward hs-lint-regex nil t)
1007     (let* ((fname (match-string 1))
1008           (fline (string-to-number (match-string 2)))
1009           (old-code (match-string 4))
1010           (new-code (match-string 5))
1011           (msg (concat "Replace '" (make-short-string old-code 30)
1012                        "' with '" (make-short-string new-code 30) "'"))
1013           (bline 0)
1014           (eline 0)
1015           (spos 0)
1016           (new-old-code ""))
1017       (save-excursion
1018         (switch-to-buffer (get-file-buffer fname))
1019         (goto-char (point-min))
1020         (forward-line (1- fline))
1021         (beginning-of-line)
1022         (setf bline (point))
1023         (when (or hs-lint-replace-without-ask
1024                   (yes-or-no-p msg))
1025           (end-of-line)
1026           (setf eline (point))
1027           (beginning-of-line)
1028           (setf old-code (regexp-quote old-code))
1029           (while (string-match "\\\\ " old-code spos)
1030             (setf new-old-code (concat new-old-code
1031                                  (substring old-code spos (match-beginning 0))
1032                                  "\\ *"))
1033             (setf spos (match-end 0)))
1034           (setf new-old-code (concat new-old-code (substring old-code spos)))
1035           (remove-text-properties bline eline '(composition nil))
1036           (when (re-search-forward new-old-code eline t)
1037             (replace-match new-code nil t)))))))
1038
1039 (defun hs-lint-finish-hook (buf msg)
1040   "Function, that is executed at the end of HLint execution"
1041   (if hs-lint-replace-with-suggestions
1042       (hs-lint-replace-suggestions)
1043       (next-error 1 t)))
1044
1045 (define-compilation-mode hs-lint-mode "HLint"
1046   "Mode for check Haskell source code."
1047   (set (make-local-variable 'compilation-process-setup-function)
1048        'hs-lint-process-setup)
1049   (set (make-local-variable 'compilation-disable-input) t)
1050   (set (make-local-variable 'compilation-scroll-output) nil)
1051   (set (make-local-variable 'compilation-finish-functions)
1052        (list 'hs-lint-finish-hook))
1053   )
1054
1055 (defun hs-lint ()
1056   "Run HLint for current buffer with haskell source"
1057   (interactive)
1058   (save-some-buffers hs-lint-save-files)
1059   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1060                      'hs-lint-mode))
1061
1062 (provide 'hs-lint)
1063 ;;; hs-lint.el ends here
1064 #+end_src
1065
1066 #+begin_src emacs-lisp :tangle no
1067 (use-package hs-lint
1068   :load-path "lisp/"
1069   :bind (:map haskell-mode-map
1070               ("C-c l l" . hs-lint)))
1071 #+end_src
1072 * Emacs Enhancements
1073
1074 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1075
1076 #+begin_quote
1077 Emacs package that displays available keybindings in popup
1078 #+end_quote
1079
1080 #+begin_src emacs-lisp
1081 (use-package which-key
1082   :defer 1
1083   :config (which-key-mode))
1084 #+end_src
1085
1086 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1087
1088 #+begin_src emacs-lisp
1089 (use-package doom-modeline
1090   :demand t
1091   :config (setq doom-modeline-height 32)
1092   :hook (after-init . doom-modeline-init))
1093 #+end_src
1094
1095 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1096
1097 #+begin_src emacs-lisp
1098 (use-package tao-theme
1099   :demand t
1100   :config (load-theme 'tao-yang t))
1101 #+end_src
1102
1103 * Email
1104 ** [[https://notmuchmail.org][notmuch]]
1105
1106 #+begin_src emacs-lisp
1107 (defun ab/notmuch ()
1108   "Delete other windows, then launch `notmuch'."
1109   (interactive)
1110   (require 'notmuch)
1111   (delete-other-windows)
1112   (notmuch))
1113
1114 ;; (ab--leader-keys
1115 ;;   "m"   'ab/notmuch
1116 ;;   "s"   'save-buffer
1117 ;;   "SPC" 'counsel-M-x)
1118
1119 ;; (map!
1120 ;;  :leader
1121 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1122 ;;  (:desc "search" :prefix "/"
1123 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1124 #+end_src
1125
1126 #+begin_src emacs-lisp
1127 (defvar ab-maildir "~/mail")
1128
1129 (use-package sendmail
1130   ;; :ensure nil
1131   :config
1132   (setq sendmail-program "/usr/bin/msmtp"
1133         mail-specify-envelope-from t
1134         mail-envelope-from 'header))
1135
1136 (use-package message
1137   ;; :ensure nil
1138   :config
1139   (setq message-kill-buffer-on-exit t
1140         message-send-mail-function 'message-send-mail-with-sendmail
1141         message-sendmail-envelope-from 'header
1142         message-directory "drafts"
1143         message-user-fqdn "fencepost.gnu.org")
1144   (add-hook 'message-mode-hook
1145             (lambda () (setq fill-column 65
1146                         message-fill-column 65)))
1147   (add-hook 'message-mode-hook
1148             #'flyspell-mode)
1149   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1150   ;; TODO: is there a way to only run this when replying and not composing?
1151   (add-hook 'notmuch-message-mode-hook
1152             (lambda () (progn
1153                     (newline)
1154                     (newline)
1155                     (forward-line -1)
1156                     (forward-line -1))))
1157   ;; (add-hook 'message-setup-hook
1158   ;;           #'mml-secure-message-sign-pgpmime)
1159   )
1160
1161 (after! mml-sec
1162   (setq mml-secure-openpgp-encrypt-to-self t
1163         mml-secure-openpgp-sign-with-sender t))
1164
1165 (use-package notmuch
1166   :general (ab--leader-keys "m" 'ab/notmuch)
1167   :config
1168   (setq notmuch-hello-sections
1169         '(notmuch-hello-insert-header
1170           notmuch-hello-insert-saved-searches
1171           ;; notmuch-hello-insert-search
1172           notmuch-hello-insert-alltags)
1173         notmuch-search-oldest-first nil
1174         notmuch-show-all-tags-list t
1175         notmuch-hello-thousands-separator ","
1176         notmuch-fcc-dirs
1177         '(("amin@aminb.org"            . "amin/Sent")
1178           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1179           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1180           ("aminb@gnu.org"             . "gnu/Sent")
1181           (".*"                        . "sent"))
1182         notmuch-search-result-format
1183         '(("date" . "%12s ")
1184           ("count" . "%-7s ")
1185           ("authors" . "%-40s ")
1186           ("subject" . "%s ")
1187           ("tags" . "(%s)")))
1188   ;; (add-hook 'visual-fill-column-mode-hook
1189   ;;           (lambda ()
1190   ;;             (when (string= major-mode 'notmuch-message-mode)
1191   ;;               (setq visual-fill-column-width 70))))
1192   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1193   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1194   ;;             :override #'kill-this-buffer)
1195   :bind
1196   (:map notmuch-hello-mode-map
1197         ("g" . notmuch-poll-and-refresh-this-buffer)
1198         ("i" . (lambda ()
1199                  "Search for `inbox' tagged messages"
1200                  (interactive)
1201                  (notmuch-hello-search "tag:inbox")))
1202         ("u" . (lambda ()
1203                  "Search for `unread' tagged messages"
1204                  (interactive)
1205                  (notmuch-hello-search "tag:unread")))
1206         ("M" . (lambda ()
1207                  "Compose new mail and prompt for sender"
1208                  (interactive)
1209                  (let ((current-prefix-arg t))
1210                    (call-interactively #'notmuch-mua-new-mail)))))
1211   (:map notmuch-search-mode-map
1212         ("g" . notmuch-poll-and-refresh-this-buffer)
1213         ("k" . (lambda ()
1214                  "Mark message read"
1215                  (interactive)
1216                  (notmuch-search-tag '("-unread"))
1217                  ;; (notmuch-search-archive-thread)
1218                  (notmuch-search-next-thread)))
1219         ("u" . (lambda ()
1220                  "Mark message unread"
1221                  (interactive)
1222                  (notmuch-search-tag '("+unread"))
1223                  (notmuch-search-next-thread)))
1224         ("K" . (lambda ()
1225                  "Mark message deleted"
1226                  (interactive)
1227                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1228                  (notmuch-search-archive-thread)))
1229         ("S" . (lambda ()
1230                  "Mark message as spam"
1231                  (interactive)
1232                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1233                  (notmuch-search-archive-thread))))
1234   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1235         ("S" . (lambda ()
1236                  "Mark message as spam"
1237                  (interactive)
1238                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1239                  (notmuch-tree-archive-thread))))
1240 )
1241
1242 ;; (use-package counsel-notmuch
1243 ;;   :commands counsel-notmuch)
1244
1245 (after! notmuch-crypto
1246   (setq notmuch-crypto-process-mime t))
1247
1248 ;; (after! evil
1249 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1250 ;;         '((notmuch-hello-mode . emacs)
1251 ;;           (notmuch-search-mode . emacs)
1252 ;;           (notmuch-tree-mode . emacs))))
1253
1254 (after! recentf
1255   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1256 #+end_src
1257
1258 * Post initialization
1259 :PROPERTIES:
1260 :CUSTOM_ID: post-initialization
1261 :END:
1262
1263 Display how long it took to load the init file.
1264
1265 #+begin_src emacs-lisp
1266 (message "Loading %s...done (%.3fs)" user-init-file
1267          (float-time (time-subtract (current-time)
1268                                     ab--before-user-init-time)))
1269 #+end_src
1270
1271 * Footer
1272 :PROPERTIES:
1273 :CUSTOM_ID: footer
1274 :END:
1275
1276 #+begin_src emacs-lisp :comments none
1277 ;;; init.el ends here
1278 #+end_src