git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 ;; (require 'borg-nix-shell)
 238 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c B A" . borg-activate)
 244    ("C-c B a" . borg-assimilate)
 245    ("C-c B b" . borg-build)
 246    ("C-c B c" . borg-clone)))
 247 #+end_src
 248
 249 *** =use-package=
 250
 251 #+begin_quote
 252 A use-package declaration for simplifying your .emacs
 253 #+end_quote
 254
 255 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 256 packages (in our case especially the latter) in a neatly organized way
 257 and without compromising on performance.
 258
 259 #+begin_src emacs-lisp
 260 (require 'use-package)
 261 (if nil  ; set to t when need to debug init
 262     (setq use-package-verbose t
 263           use-package-expand-minimally nil
 264           use-package-compute-statistics t
 265           debug-on-error t)
 266   (setq use-package-verbose nil
 267         use-package-expand-minimally t))
 268 #+end_src
 269
 270 *** Epkg
 271
 272 #+begin_quote
 273 Browse the Emacsmirror package database
 274 #+end_quote
 275
 276 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 277 database, low-level functions for querying the database, and a
 278 =package.el=-like user interface for browsing the available packages.
 279
 280 #+begin_src emacs-lisp
 281 (use-package epkg
 282   :defer t
 283   :bind
 284   (("C-c B d" . epkg-describe-package)
 285    ("C-c B p" . epkg-list-packages)
 286    ("C-c B r" . borg-remove)
 287    ("C-c B u" . epkg-update)))
 288 #+end_src
 289
 290 ** No littering in =~/.emacs.d=
 291
 292 #+begin_quote
 293 Help keeping ~/.emacs.d clean
 294 #+end_quote
 295
 296 By default, even for Emacs' built-in packages, the configuration files
 297 and persistent data are all over the place. Use =no-littering= to help
 298 contain the mess.
 299
 300 #+begin_src emacs-lisp
 301 (use-package no-littering
 302   :demand t
 303   :config
 304   (savehist-mode 1)
 305   (add-to-list 'savehist-additional-variables 'kill-ring)
 306   (save-place-mode 1)
 307   (setq auto-save-file-name-transforms
 308         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 309 #+end_src
 310
 311 ** Custom file (=custom.el=)
 312
 313 I'm not planning on using the custom file much, but even so, I
 314 definitely don't want it mixing with =init.el=. So, here; let's give
 315 it it's own file. While at it, treat themes as safe.
 316
 317 #+begin_src emacs-lisp
 318 (use-package custom
 319   :no-require t
 320   :config
 321   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 322   (when (file-exists-p custom-file)
 323     (load custom-file))
 324   (setf custom-safe-themes t))
 325 #+end_src
 326
 327 ** Better =$PATH= handling
 328
 329 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 330 in my shell.
 331
 332 #+begin_src emacs-lisp
 333 (use-package exec-path-from-shell
 334   :defer 1
 335   :init
 336   (setq exec-path-from-shell-check-startup-files nil)
 337   :config
 338   (exec-path-from-shell-initialize)
 339   ;; while we're at it, let's fix access to our running ssh-agent
 340   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 341   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 342 #+end_src
 343
 344 ** Only one custom theme at a time
 345
 346 #+begin_src emacs-lisp
 347 (defadvice load-theme (before clear-previous-themes activate)
 348   "Clear existing theme settings instead of layering them"
 349   (mapc #'disable-theme custom-enabled-themes))
 350 #+end_src
 351
 352 ** Server
 353
 354 Start server if not already running. Alternatively, can be done by
 355 issuing =emacs --daemon= in the terminal, which can be automated with
 356 a systemd service or using =brew services start emacs= on macOS. I use
 357 Emacs as my window manager (via EXWM), so I always start Emacs on
 358 login; so starting the server from inside Emacs is good enough for me.
 359
 360 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 361
 362 #+begin_src emacs-lisp
 363 (use-package server
 364   :config (or (server-running-p) (server-mode)))
 365 #+end_src
 366
 367 ** Unicode support
 368
 369 Font stack with better unicode support, around =Ubuntu Mono= and
 370 =Hack=.
 371
 372 #+begin_src emacs-lisp :tangle no
 373 (dolist (ft (fontset-list))
 374   (set-fontset-font
 375    ft
 376    'unicode
 377    (font-spec :name "Source Code Pro" :size 14))
 378   (set-fontset-font
 379    ft
 380    'unicode
 381    (font-spec :name "DejaVu Sans Mono")
 382    nil
 383    'append)
 384   ;; (set-fontset-font
 385   ;;  ft
 386   ;;  'unicode
 387   ;;  (font-spec
 388   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 389   ;;  nil
 390   ;;  'append)
 391   ;; (set-fontset-font
 392   ;;  ft
 393   ;;  #x2115  ; ℕ
 394   ;;  (font-spec :name "DejaVu Sans Mono")
 395   ;;  nil
 396   ;;  'append)
 397   (set-fontset-font
 398    ft
 399    (cons ?Α ?ω)
 400    (font-spec :name "DejaVu Sans Mono" :size 14)
 401    nil
 402    'prepend))
 403 #+end_src
 404
 405 ** Gentler font resizing
 406
 407 #+begin_src emacs-lisp
 408 (setq text-scale-mode-step 1.05)
 409 #+end_src
 410
 411 ** Libraries
 412
 413 #+begin_src emacs-lisp
 414 (require 'cl-lib)
 415 (require 'subr-x)
 416 #+end_src
 417
 418 ** Useful utilities
 419
 420 #+begin_src emacs-lisp
 421 (defun amin-enlist (exp)
 422   "Return EXP wrapped in a list, or as-is if already a list."
 423 (if (listp exp) exp (list exp)))
 424
 425 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 426 (defmacro after! (features &rest body)
 427   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 428 compilation."
 429   (declare (indent defun) (debug t))
 430   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 431                 (dolist (next (amin-enlist features))
 432                   (if (symbolp next)
 433                       (require next nil :no-error)
 434                     (load next :no-message :no-error))))
 435             #'progn
 436           #'with-no-warnings)
 437         (cond ((symbolp features)
 438                `(eval-after-load ',features '(progn ,@body)))
 439               ((and (consp features)
 440                     (memq (car features) '(:or :any)))
 441                `(progn
 442                   ,@(cl-loop for next in (cdr features)
 443                              collect `(after! ,next ,@body))))
 444               ((and (consp features)
 445                     (memq (car features) '(:and :all)))
 446                (dolist (next (cdr features))
 447                  (setq body `(after! ,next ,@body)))
 448                body)
 449               ((listp features)
 450                `(after! (:all ,@features) ,@body)))))
 451 #+end_src
 452
 453 Convenience macro for =setq='ing multiple variables to the same value:
 454
 455 #+begin_src emacs-lisp
 456 (defmacro setq-every! (value &rest vars)
 457   "Set all the variables from VARS to value VALUE."
 458   (declare (indent defun) (debug t))
 459   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 460 #+end_src
 461
 462 * Core
 463 :PROPERTIES:
 464 :CUSTOM_ID: core
 465 :END:
 466
 467 ** Defaults
 468
 469 *** Time and battery in mode-line
 470
 471 Enable displaying time and battery in the mode-line, since I'm not
 472 using the Xfce panel anymore. Also, I don't need to see the load
 473 average on a regular basis, so disable that.
 474
 475 Note: using =i3status= on sway at the moment, so disabling this.
 476
 477 #+begin_src emacs-lisp :tangle no
 478 (use-package time
 479   :init
 480   (setq display-time-default-load-average nil)
 481   :config
 482   (display-time-mode))
 483
 484 (use-package battery
 485   :config
 486   (display-battery-mode))
 487 #+end_src
 488
 489 *** Smaller fringe
 490
 491 Might want to set the fringe to a smaller value, especially if using
 492 EXWM. I'm fine with the default for now.
 493
 494 #+begin_src emacs-lisp
 495 ;; (fringe-mode '(3 . 1))
 496 (fringe-mode nil)
 497 #+end_src
 498
 499 *** Disable disabled commands
 500
 501 Emacs disables some commands by default that could persumably be
 502 confusing for novice users. Let's disable that.
 503
 504 #+begin_src emacs-lisp
 505 (setq disabled-command-function nil)
 506 #+end_src
 507
 508 *** Kill-ring
 509
 510 Save what I copy into clipboard from other applications into Emacs'
 511 kill-ring, which would allow me to still be able to easily access it
 512 in case I kill (cut or copy) something else inside Emacs before
 513 yanking (pasting) what I'd originally intended to.
 514
 515 #+begin_src emacs-lisp
 516 (setq save-interprogram-paste-before-kill t)
 517 #+end_src
 518
 519 *** Minibuffer
 520
 521 #+begin_src emacs-lisp
 522 (setq enable-recursive-minibuffers t
 523       resize-mini-windows t)
 524 #+end_src
 525
 526 *** Lazy-person-friendly yes/no prompts
 527
 528 Lazy people would prefer to type fewer keystrokes, especially for yes
 529 or no questions. I'm lazy.
 530
 531 #+begin_src emacs-lisp
 532 (defalias 'yes-or-no-p #'y-or-n-p)
 533 #+end_src
 534
 535 *** Startup screen and =*scratch*=
 536
 537 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 538 startup buffer.
 539
 540 #+begin_src emacs-lisp
 541 (setq initial-buffer-choice t)
 542 #+end_src
 543
 544 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 545 need the default hint.
 546
 547 #+begin_src emacs-lisp
 548 (setq initial-scratch-message nil)
 549 #+end_src
 550
 551 Also, let's use Text mode as the major mode, in case I want to
 552 customize it (=*scratch*='s default major mode, Fundamental mode,
 553 can't really be customized).
 554
 555 #+begin_src emacs-lisp
 556 (setq initial-major-mode 'text-mode)
 557 #+end_src
 558
 559 Inhibit the buffer list when more than 2 files are loaded.
 560
 561 #+begin_src emacs-lisp
 562 (setq inhibit-startup-buffer-menu t)
 563 #+end_src
 564
 565 I don't really need to see the startup screen or echo area message
 566 either.
 567
 568 #+begin_src emacs-lisp
 569 (advice-add #'display-startup-echo-area-message :override #'ignore)
 570 (setq inhibit-startup-screen t
 571       inhibit-startup-echo-area-message user-login-name)
 572 #+end_src
 573
 574 *** More useful frame titles
 575
 576 Show either the file name or the buffer name (in case the buffer isn't
 577 visiting a file). Borrowed from Emacs Prelude.
 578
 579 #+begin_src emacs-lisp
 580 (setq frame-title-format
 581       '("" invocation-name " - "
 582         (:eval (if (buffer-file-name)
 583                    (abbreviate-file-name (buffer-file-name))
 584                  "%b"))))
 585 #+end_src
 586
 587 *** Backups
 588
 589 Emacs' default backup settings aren't that great. Let's use more
 590 sensible options. See documentation for the ~make-backup-file~
 591 variable.
 592
 593 #+begin_src emacs-lisp
 594 (setq backup-by-copying t
 595       version-control t
 596       delete-old-versions t)
 597 #+end_src
 598
 599 *** Auto revert
 600
 601 Enable automatic reloading of changed buffers and files.
 602
 603 #+begin_src emacs-lisp
 604 (global-auto-revert-mode 1)
 605 (setq auto-revert-verbose nil
 606       global-auto-revert-non-file-buffers t)
 607 #+end_src
 608
 609 *** Always use space for indentation
 610
 611 #+begin_src emacs-lisp
 612 (setq-default
 613  indent-tabs-mode nil
 614  require-final-newline t
 615  tab-width 4)
 616 #+end_src
 617
 618 *** Winner mode
 619
 620 Enable =winner-mode=.
 621
 622 #+begin_src emacs-lisp
 623 (winner-mode 1)
 624 #+end_src
 625
 626 *** Close =*compilation*= on success
 627
 628 #+begin_src emacs-lisp
 629 (setq compilation-exit-message-function
 630       (lambda (status code msg)
 631         "Close the compilation window if successful."
 632         ;; if M-x compile exits with 0
 633          (when (and (eq status 'exit) (zerop code))
 634            (bury-buffer)
 635            (delete-window (get-buffer-window (get-buffer "*compilation*"))))
 636          ;; return the result of compilation-exit-message-function
 637          (cons msg code)))
 638 #+end_src
 639
 640 ** Bindings
 641
 642 #+begin_src emacs-lisp
 643 (bind-keys
 644  ("C-c b k" . kill-this-buffer)
 645  ("C-c s s" . save-buffer)
 646  ("C-c b s" . save-buffer)
 647  ("C-c S"   . save-buffer)
 648  ("C-c o"   . other-window)
 649  ("C-c q q" . save-buffers-kill-terminal)
 650  ("C-c F m" . make-frame-command)
 651  ("C-c F d" . delete-frame)
 652  ("C-c F D" . delete-other-frames))
 653 #+end_src
 654
 655 ** Packages
 656
 657 The packages in this section are absolutely essential to my everyday
 658 workflow, and they play key roles in how I do my computing. They
 659 immensely enhance the Emacs experience for me; both using Emacs, and
 660 customizing it.
 661
 662 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 663
 664 #+begin_src emacs-lisp
 665 (use-package auto-compile
 666   :demand t
 667   :config
 668   (auto-compile-on-load-mode)
 669   (auto-compile-on-save-mode)
 670   (setq auto-compile-display-buffer               nil
 671         auto-compile-mode-line-counter            t
 672         auto-compile-source-recreate-deletes-dest t
 673         auto-compile-toggle-deletes-nonlib-dest   t
 674         auto-compile-update-autoloads             t)
 675   (add-hook 'auto-compile-inhibit-compile-hook
 676             'auto-compile-inhibit-compile-detached-git-head))
 677 #+end_src
 678
 679 *** [[https://orgmode.org/][Org mode]]
 680
 681 #+begin_quote
 682 Org mode is for keeping notes, maintaining TODO lists, planning
 683 projects, and authoring documents with a fast and effective plain-text
 684 system.
 685 #+end_quote
 686
 687 In short, my favourite way of life.
 688
 689 #+begin_src emacs-lisp
 690 (use-package org
 691   :config
 692   (setq org-src-tab-acts-natively t
 693         org-src-preserve-indentation nil
 694         org-edit-src-content-indentation 0
 695         org-log-done 'time)
 696   :hook (org-mode . org-indent-mode)
 697   :custom
 698   (org-latex-packages-alist '(("" "listings") ("" "color"))))
 699
 700 (use-package ox-latex
 701   :config
 702   (setq org-latex-listings 'listings)
 703   (add-to-list 'org-latex-packages-alist '("" "listings"))
 704   (add-to-list 'org-latex-packages-alist '("" "color"))
 705   (add-to-list 'org-latex-classes
 706                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 707                  ("\\section{%s}" . "\\section*{%s}")
 708                  ("\\subsection{%s}" . "\\subsection*{%s}")
 709                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 710                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 711                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 712                t))
 713
 714 (use-package ox-beamer)
 715
 716 (use-package org-notmuch
 717   :after (:any org notmuch))
 718
 719 (use-package orgalist)
 720 #+end_src
 721
 722 **** asynchronous tangle
 723
 724 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 725 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 726 file.
 727
 728 #+begin_src emacs-lisp
 729 (after! org
 730   (defvar amin-show-async-tangle-results nil
 731     "Keep *emacs* async buffers around for later inspection.")
 732
 733   (defvar amin-show-async-tangle-time nil
 734     "Show the time spent tangling the file.")
 735
 736   (defvar amin-async-tangle-post-compile "make ti"
 737     "If non-nil, pass to `compile' after successful tangle.")
 738
 739   (defun amin/async-babel-tangle ()
 740     "Tangle org file asynchronously."
 741     (interactive)
 742     (let* ((file-tangle-start-time (current-time))
 743            (file (buffer-file-name))
 744            (file-nodir (file-name-nondirectory file))
 745            (async-quiet-switch "-q"))
 746       (async-start
 747        `(lambda ()
 748           (require 'org)
 749           (org-babel-tangle-file ,file))
 750        (unless amin-show-async-tangle-results
 751          `(lambda (result)
 752             (if result
 753                 (progn
 754                   (message "Tangled %s%s"
 755                            ,file-nodir
 756                            (if amin-show-async-tangle-time
 757                                (format " (%.3fs)"
 758                                        (float-time (time-subtract (current-time)
 759                                                                   ',file-tangle-start-time)))
 760                              ""))
 761                   (when amin-async-tangle-post-compile
 762                     (compile amin-async-tangle-post-compile)))
 763               (message "Tangling %s failed" ,file-nodir))))))))
 764
 765 (add-to-list
 766  'safe-local-variable-values
 767  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 768 #+end_src
 769
 770 *** [[https://magit.vc/][Magit]]
 771
 772 #+begin_quote
 773 It's Magit! A Git porcelain inside Emacs.
 774 #+end_quote
 775
 776 Not just how I do git, but /the/ way to do git.
 777
 778 #+begin_src emacs-lisp
 779 (use-package magit
 780   :defer t
 781   :bind
 782   (("s-g"   . magit-dispatch-popup)
 783    ("C-x g" . magit-status)
 784    :prefix-map amin--magit-prefix-map
 785    :prefix "C-c g"
 786    ("SPC" . magit-status)
 787    ("s"   . magit-status)
 788    ("S"   . magit-status-prefix)
 789    ("B"   . magit-blame-addition)
 790    ("C"   . magit-clone)
 791    ("f"   . magit-fetch-other)
 792    ("F"   . magit-pull-branch)
 793    ("P"   . magit-push-other)
 794    ("p"   . magit-dispatch-popup)
 795    ("c c" . magit-commit-create)
 796    ("c a" . magit-commit-amend)
 797    ("b b" . magit-checkout)
 798    ("b c" . magit-branch-create))
 799   :config
 800   (magit-add-section-hook 'magit-status-sections-hook
 801                           'magit-insert-modules
 802                           'magit-insert-stashes
 803                           'append)
 804   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 805 #+end_src
 806
 807 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 808
 809 #+begin_quote
 810 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 811 an overview, and more. Oh, man!
 812 #+end_quote
 813
 814 There's no way I could top that, so I won't attempt to.
 815
 816 **** Ivy
 817
 818 #+begin_src emacs-lisp
 819 (use-package ivy
 820   :defer 1
 821   :bind
 822   (("C-c b b" . ivy-switch-buffer)
 823    :map ivy-minibuffer-map
 824    ([escape] . keyboard-escape-quit)
 825    ([S-up]   . ivy-previous-history-element)
 826    ([S-down] . ivy-next-history-element)
 827    ("DEL"    . ivy-backward-delete-char))
 828   :config
 829   (setq ivy-wrap t)
 830   (ivy-mode 1)
 831   :custom-face
 832   (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 833   (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 834   (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold)))))
 835 #+end_src
 836
 837 **** Swiper
 838
 839 #+begin_src emacs-lisp
 840 (use-package swiper
 841   :bind (("C-s" . swiper)
 842          ("C-r" . swiper)))
 843 #+end_src
 844
 845 **** Counsel
 846
 847 #+begin_src emacs-lisp
 848 (use-package counsel
 849   :defer 1
 850   :bind (([remap execute-extended-command] . counsel-M-x)
 851          ([remap find-file]                . counsel-find-file)
 852          ("s-r"                            . counsel-recentf)
 853          ("C-c x"                          . counsel-M-x)
 854          ("C-c f ."                        . counsel-find-file)
 855          ("C-c f r"                        . counsel-recentf)
 856          :map minibuffer-local-map
 857          ("C-r" . counsel-minibuffer-history))
 858   :config
 859   (counsel-mode 1)
 860   (defalias 'locate #'counsel-locate))
 861 #+end_src
 862
 863 *** eshell
 864
 865 #+begin_src emacs-lisp
 866 (use-package eshell
 867   :commands eshell
 868   :config
 869   (eval-when-compile (defvar eshell-prompt-regexp))
 870   (defun amin/eshell-quit-or-delete-char (arg)
 871     (interactive "p")
 872     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 873         (eshell-life-is-too-much)
 874       (delete-char arg)))
 875
 876   (defun amin/eshell-clear ()
 877     (interactive)
 878     (let ((inhibit-read-only t))
 879       (erase-buffer))
 880     (eshell-send-input))
 881
 882   (defun amin|eshell-setup ()
 883     (bind-keys :map eshell-mode-map
 884                ("C-d" . amin/eshell-quit-or-delete-char)
 885                ("C-l" . amin/eshell-clear)))
 886
 887   :hook (eshell-mode . amin|eshell-setup))
 888 #+end_src
 889
 890 *** Ibuffer
 891
 892 #+begin_src emacs-lisp
 893 (use-package ibuffer
 894   :bind
 895   (("C-x C-b" . ibuffer-other-window)
 896    ("C-c b B" . ibuffer-other-window)
 897    :map ibuffer-mode-map
 898    ("P"   . ibuffer-backward-filter-group)
 899    ("N"   . ibuffer-forward-filter-group)
 900    ("M-p" . ibuffer-do-print)
 901    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 902   :config
 903   ;; Use human readable Size column instead of original one
 904   (define-ibuffer-column size-h
 905     (:name "Size" :inline t)
 906     (cond
 907      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
 908      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
 909      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
 910      (t (format "%8d" (buffer-size)))))
 911   :custom
 912   (ibuffer-saved-filter-groups
 913    '(("default"
 914       ("dired" (mode . dired-mode))
 915       ("org"   (mode . org-mode))
 916       ("web"
 917        (or
 918         (mode . web-mode)
 919         (mode . css-mode)
 920         (mode . scss-mode)
 921         (mode . js2-mode)))
 922       ("shell"
 923        (or
 924         (mode . eshell-mode)
 925         (mode . shell-mode)))
 926       ("notmuch" (name . "\*notmuch\*"))
 927       ("programming"
 928        (or
 929         (mode . python-mode)
 930         (mode . c++-mode)
 931         (mode . emacs-lisp-mode)))
 932       ("emacs"
 933        (or
 934         (name . "^\\*scratch\\*$")
 935         (name . "^\\*Messages\\*$"))))))
 936   (ibuffer-formats
 937    '((mark modified read-only locked " "
 938            (name 18 18 :left :elide)
 939            " "
 940            (size-h 9 -1 :right)
 941            " "
 942            (mode 16 16 :left :elide)
 943            " " filename-and-process)
 944      (mark " "
 945            (name 16 -1)
 946            " " filename)))
 947   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
 948 #+end_src
 949
 950 *** Outline
 951
 952 #+begin_src emacs-lisp
 953 (use-package outline
 954   :hook (prog-mode . outline-minor-mode)
 955   :bind
 956   (:map
 957    outline-minor-mode-map
 958    ("<s-tab>"  . outline-toggle-children)
 959    ("s-p"      . outline-previous-visible-heading)
 960    ("s-n"      . outline-next-visible-heading)
 961    :prefix-map amin--outline-prefix-map
 962    :prefix "s-o"
 963    ("TAB" . outline-toggle-children)
 964    ("a"   . outline-hide-body)
 965    ("H"   . outline-hide-body)
 966    ("S"   . outline-show-all)
 967    ("h"   . outline-hide-subtree)
 968    ("s"   . outline-show-subtree)))
 969 #+end_src
 970
 971 * Borg's =layer/essentials=
 972
 973 TODO: break this giant source block down into individual org sections.
 974
 975 #+begin_src emacs-lisp
 976 (use-package dash
 977   :config (dash-enable-font-lock))
 978
 979 (use-package diff-hl
 980   :config
 981   (setq diff-hl-draw-borders nil)
 982   (global-diff-hl-mode)
 983   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 984
 985 (use-package dired
 986   :defer t
 987   :config (setq dired-listing-switches "-alh"))
 988
 989 (use-package eldoc
 990   :when (version< "25" emacs-version)
 991   :config (global-eldoc-mode))
 992
 993 (use-package help
 994   :defer t
 995   :config (temp-buffer-resize-mode))
 996
 997 (progn ;    `isearch'
 998   (setq isearch-allow-scroll t))
 999
1000 (use-package lisp-mode
1001   :config
1002   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1003   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1004   (defun indent-spaces-mode ()
1005     (setq indent-tabs-mode nil))
1006   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1007
1008 (use-package man
1009   :defer t
1010   :config (setq Man-width 80))
1011
1012 (use-package paren
1013   :config (show-paren-mode))
1014
1015 (use-package prog-mode
1016   :config (global-prettify-symbols-mode)
1017   (defun indicate-buffer-boundaries-left ()
1018     (setq indicate-buffer-boundaries 'left))
1019   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1020
1021 (use-package recentf
1022   :demand t
1023   :config
1024   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1025   (setq recentf-max-saved-items 40))
1026
1027 (use-package savehist
1028   :config (savehist-mode))
1029
1030 (use-package saveplace
1031   :when (version< "25" emacs-version)
1032   :config (save-place-mode))
1033
1034 (use-package simple
1035   :config (column-number-mode))
1036
1037 (progn ;    `text-mode'
1038   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1039
1040 (use-package tramp
1041   :defer t
1042   :config
1043   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1044   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1045   (add-to-list 'tramp-default-proxies-alist
1046                (list (regexp-quote (system-name)) nil nil)))
1047
1048 (use-package undo-tree
1049   :bind (("C-?" . undo-tree-undo)
1050          ("M-_" . undo-tree-redo))
1051   :config
1052   (global-undo-tree-mode)
1053   (setq undo-tree-mode-lighter ""
1054         undo-tree-auto-save-history t))
1055 #+end_src
1056
1057 * Editing
1058
1059 ** Company
1060
1061 #+begin_src emacs-lisp
1062 (use-package company
1063   :defer 5
1064   :bind
1065   (:map company-active-map
1066         ([tab] . company-complete-common-or-cycle))
1067   :custom
1068   (company-idle-delay 0.3)
1069   (company-minimum-prefix-length 1)
1070   (company-selection-wrap-around t)
1071   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1072   (company-dabbrev-downcase nil)
1073   (company-dabbrev-ignore-case nil)
1074   :config
1075   (global-company-mode t))
1076 #+end_src
1077
1078 * Syntax and spell checking
1079 #+begin_src emacs-lisp
1080 (use-package flycheck
1081   :hook (prog-mode . flycheck-mode)
1082   :config
1083   ;; Use the load-path from running Emacs when checking elisp files
1084   (setq flycheck-emacs-lisp-load-path 'inherit)
1085
1086   ;; Only flycheck when I actually save the buffer
1087   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1088
1089 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1090 (use-package ispell
1091   :config
1092   ;; ’ can be part of a word
1093   (setq ispell-local-dictionary-alist
1094         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1095                "['\x2019]" nil ("-B") nil utf-8)))
1096   ;; don't send ’ to the subprocess
1097   (defun endless/replace-apostrophe (args)
1098     (cons (replace-regexp-in-string
1099            "’" "'" (car args))
1100           (cdr args)))
1101   (advice-add #'ispell-send-string :filter-args
1102               #'endless/replace-apostrophe)
1103
1104   ;; convert ' back to ’ from the subprocess
1105   (defun endless/replace-quote (args)
1106     (if (not (derived-mode-p 'org-mode))
1107         args
1108       (cons (replace-regexp-in-string
1109              "'" "’" (car args))
1110             (cdr args))))
1111   (advice-add #'ispell-parse-output :filter-args
1112               #'endless/replace-quote))
1113 #+end_src
1114 * Programming modes
1115
1116 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1117
1118 #+begin_src emacs-lisp
1119 (use-package alloy-mode
1120   :config (setq alloy-basic-offset 2))
1121 #+end_src
1122
1123 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1124
1125 #+begin_src emacs-lisp
1126 (use-package proof-site  ; Proof General
1127   :load-path "lib/proof-site/generic/")
1128 #+end_src
1129
1130 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1131
1132 #+begin_src emacs-lisp
1133 (eval-when-compile (defvar lean-mode-map))
1134 (use-package lean-mode
1135   :bind (:map lean-mode-map
1136               ("S-SPC" . company-complete)))
1137 #+end_src
1138
1139 ** Haskell
1140
1141 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1142
1143 #+begin_src emacs-lisp
1144 (use-package haskell-mode
1145   :config
1146   (setq haskell-indentation-layout-offset 4
1147         haskell-indentation-left-offset 4
1148         flycheck-checker 'haskell-hlint
1149         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1150 #+end_src
1151
1152 *** [[https://github.com/jyp/dante][dante]]
1153
1154 #+begin_src emacs-lisp
1155 (use-package dante
1156   :after haskell-mode
1157   :commands dante-mode
1158   :hook (haskell-mode . dante-mode))
1159 #+end_src
1160
1161 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1162
1163 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1164 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1165
1166 #+begin_src emacs-lisp
1167 (use-package hlint-refactor
1168   :bind (:map hlint-refactor-mode-map
1169               ("C-c l b" . hlint-refactor-refactor-buffer)
1170               ("C-c l r" . hlint-refactor-refactor-at-point))
1171   :hook (haskell-mode . hlint-refactor-mode))
1172 #+end_src
1173
1174 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1175
1176 #+begin_src emacs-lisp
1177 (use-package flycheck-haskell)
1178 #+end_src
1179
1180 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1181 :PROPERTIES:
1182 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1183 :END:
1184
1185 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1186 instead.
1187
1188 #+begin_src emacs-lisp :tangle no
1189 ;;; hs-lint.el --- minor mode for HLint code checking
1190
1191 ;; Copyright 2009 (C) Alex Ott
1192 ;;
1193 ;; Author: Alex Ott <alexott@gmail.com>
1194 ;; Keywords: haskell, lint, HLint
1195 ;; Requirements:
1196 ;; Status: distributed under terms of GPL2 or above
1197
1198 ;; Typical message from HLint looks like:
1199 ;;
1200 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1201 ;; Found:
1202 ;;   count1 p l = length (filter p l)
1203 ;; Why not:
1204 ;;   count1 p = length . filter p
1205
1206
1207 (require 'compile)
1208
1209 (defgroup hs-lint nil
1210   "Run HLint as inferior of Emacs, parse error messages."
1211   :group 'tools
1212   :group 'haskell)
1213
1214 (defcustom hs-lint-command "hlint"
1215   "The default hs-lint command for \\[hlint]."
1216   :type 'string
1217   :group 'hs-lint)
1218
1219 (defcustom hs-lint-save-files t
1220   "Save modified files when run HLint or no (ask user)"
1221   :type 'boolean
1222   :group 'hs-lint)
1223
1224 (defcustom hs-lint-replace-with-suggestions nil
1225   "Replace user's code with suggested replacements"
1226   :type 'boolean
1227   :group 'hs-lint)
1228
1229 (defcustom hs-lint-replace-without-ask nil
1230   "Replace user's code with suggested replacements automatically"
1231   :type 'boolean
1232   :group 'hs-lint)
1233
1234 (defun hs-lint-process-setup ()
1235   "Setup compilation variables and buffer for `hlint'."
1236   (run-hooks 'hs-lint-setup-hook))
1237
1238 ;; regex for replace suggestions
1239 ;;
1240 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1241 ;; Found:
1242 ;; \s +\(.*\)
1243 ;; Why not:
1244 ;; \s +\(.*\)
1245
1246 (defvar hs-lint-regex
1247   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1248   "Regex for HLint messages")
1249
1250 (defun make-short-string (str maxlen)
1251   (if (< (length str) maxlen)
1252       str
1253     (concat (substring str 0 (- maxlen 3)) "...")))
1254
1255 (defun hs-lint-replace-suggestions ()
1256   "Perform actual replacement of suggestions"
1257   (goto-char (point-min))
1258   (while (re-search-forward hs-lint-regex nil t)
1259     (let* ((fname (match-string 1))
1260           (fline (string-to-number (match-string 2)))
1261           (old-code (match-string 4))
1262           (new-code (match-string 5))
1263           (msg (concat "Replace '" (make-short-string old-code 30)
1264                        "' with '" (make-short-string new-code 30) "'"))
1265           (bline 0)
1266           (eline 0)
1267           (spos 0)
1268           (new-old-code ""))
1269       (save-excursion
1270         (switch-to-buffer (get-file-buffer fname))
1271         (goto-char (point-min))
1272         (forward-line (1- fline))
1273         (beginning-of-line)
1274         (setf bline (point))
1275         (when (or hs-lint-replace-without-ask
1276                   (yes-or-no-p msg))
1277           (end-of-line)
1278           (setf eline (point))
1279           (beginning-of-line)
1280           (setf old-code (regexp-quote old-code))
1281           (while (string-match "\\\\ " old-code spos)
1282             (setf new-old-code (concat new-old-code
1283                                  (substring old-code spos (match-beginning 0))
1284                                  "\\ *"))
1285             (setf spos (match-end 0)))
1286           (setf new-old-code (concat new-old-code (substring old-code spos)))
1287           (remove-text-properties bline eline '(composition nil))
1288           (when (re-search-forward new-old-code eline t)
1289             (replace-match new-code nil t)))))))
1290
1291 (defun hs-lint-finish-hook (buf msg)
1292   "Function, that is executed at the end of HLint execution"
1293   (if hs-lint-replace-with-suggestions
1294       (hs-lint-replace-suggestions)
1295       (next-error 1 t)))
1296
1297 (define-compilation-mode hs-lint-mode "HLint"
1298   "Mode for check Haskell source code."
1299   (set (make-local-variable 'compilation-process-setup-function)
1300        'hs-lint-process-setup)
1301   (set (make-local-variable 'compilation-disable-input) t)
1302   (set (make-local-variable 'compilation-scroll-output) nil)
1303   (set (make-local-variable 'compilation-finish-functions)
1304        (list 'hs-lint-finish-hook))
1305   )
1306
1307 (defun hs-lint ()
1308   "Run HLint for current buffer with haskell source"
1309   (interactive)
1310   (save-some-buffers hs-lint-save-files)
1311   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1312                      'hs-lint-mode))
1313
1314 (provide 'hs-lint)
1315 ;;; hs-lint.el ends here
1316 #+end_src
1317
1318 #+begin_src emacs-lisp :tangle no
1319 (use-package hs-lint
1320   :load-path "lisp/"
1321   :bind (:map haskell-mode-map
1322               ("C-c l l" . hs-lint)))
1323 #+end_src
1324
1325 ** Web dev
1326
1327 *** SGML and HTML
1328
1329 #+begin_src emacs-lisp
1330 (use-package sgml-mode
1331   :config
1332   (setq sgml-basic-offset 2))
1333 #+end_src
1334
1335 *** CSS and SCSS
1336
1337 #+begin_src emacs-lisp
1338 (use-package css-mode
1339   :config
1340   (setq css-indent-offset 2))
1341 #+end_src
1342
1343 *** Web mode
1344
1345 #+begin_src emacs-lisp
1346 (use-package web-mode
1347   :mode "\\.html\\'"
1348   :config
1349   (setq-every! 2
1350     web-mode-code-indent-offset
1351     web-mode-css-indent-offset
1352     web-mode-markup-indent-offset))
1353 #+end_src
1354
1355 *** Emmet mode
1356
1357 #+begin_src emacs-lisp
1358 (use-package emmet-mode
1359   :bind* (("C-)" . emmet-next-edit-point)
1360           ("C-(" . emmet-prev-edit-point))
1361   :config
1362   (unbind-key "C-j" emmet-mode-keymap)
1363   (setq emmet-move-cursor-between-quotes t)
1364   :hook (web-mode css-mode html-mode sgml-mode))
1365 #+end_src
1366
1367 ** Nix
1368
1369 #+begin_src emacs-lisp
1370 (use-package nix-mode
1371   :mode "\\.nix\\'")
1372 #+end_src
1373
1374 * Emacs Enhancements
1375
1376 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1377
1378 #+begin_quote
1379 Emacs package that displays available keybindings in popup
1380 #+end_quote
1381
1382 #+begin_src emacs-lisp
1383 (use-package which-key
1384   :defer 1
1385   :config (which-key-mode))
1386 #+end_src
1387
1388 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1389
1390 #+begin_src emacs-lisp
1391 (use-package doom-modeline
1392   :demand t
1393   :config (setq doom-modeline-height 32)
1394   :hook (after-init . doom-modeline-init))
1395 #+end_src
1396
1397 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1398
1399 #+begin_src emacs-lisp
1400 (setq doom-modeline-bar-width 5)
1401 (load-theme 'eink t)
1402 #+end_src
1403
1404 ** [[https://github.com/bbatsov/crux][crux]]
1405
1406 #+begin_src emacs-lisp
1407 (use-package crux
1408   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1409          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1410          ("C-c b K" . crux-kill-other-buffers)
1411          ("C-c f c" . crux-copy-file-preserve-attributes)
1412          ("C-c f D" . crux-delete-file-and-buffer)
1413          ("C-c f R" . crux-rename-file-and-buffer)
1414          ("C-S-j"   . crux-top-join-line)
1415          ("C-c j"   . crux-top-join-line)))
1416 #+end_src
1417
1418 ** [[https://github.com/alezost/mwim.el][mwim]]
1419
1420 #+begin_src emacs-lisp
1421 (use-package mwim
1422   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1423          ("C-e"    . mwim-end-of-code-or-line)
1424          ("<home>" . mwim-beginning-of-line-or-code)
1425          ("<end>"  . mwim-end-of-line-or-code)))
1426 #+end_src
1427
1428 ** projectile
1429
1430 #+begin_src emacs-lisp
1431 (use-package projectile
1432   :defer 5
1433   :bind-keymap ("C-c p" . projectile-command-map)
1434   :config
1435   (projectile-mode)
1436
1437   (defun my-projectile-invalidate-cache (&rest _args)
1438     ;; ignore the args to `magit-checkout'
1439     (projectile-invalidate-cache nil))
1440
1441   (eval-after-load 'magit-branch
1442     '(progn
1443        (advice-add 'magit-checkout
1444                    :after #'my-projectile-invalidate-cache)
1445        (advice-add 'magit-branch-and-checkout
1446                    :after #'my-projectile-invalidate-cache))))
1447 #+end_src
1448
1449 ** [[https://github.com/Wilfred/helpful][helpful]]
1450
1451 #+begin_src emacs-lisp
1452 (use-package helpful
1453   :bind
1454   (("C-h f"   . helpful-callable)
1455    ("C-h v"   . helpful-variable)
1456    ("C-h k"   . helpful-key)
1457    ("C-c C-d" . helpful-at-point)
1458    ("C-h F"   . helpful-function)
1459    ("C-h C"   . helpful-command)))
1460 #+end_src
1461
1462 ** [[https://github.com/kyagi/shell-pop-el][shell-pop]]
1463
1464 #+begin_src emacs-lisp
1465 (use-package shell-pop
1466   :custom
1467   (shell-pop-universal-key "C-c e")
1468   (shell-pop-shell-type '("eshell" "*eshell*" (lambda nil (eshell)))))
1469 #+end_src
1470
1471 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1472
1473 Make =*scratch*= and =*Messages*= unkillable.
1474
1475 #+begin_src emacs-lisp
1476 (use-package unkillable-scratch
1477   :config
1478   (unkillable-scratch 1)
1479   :custom
1480   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1481 #+end_src
1482
1483 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1484
1485 #+begin_example
1486 ,----
1487 | make pretty boxed quotes like this
1488 `----
1489 #+end_example
1490
1491 #+begin_src emacs-lisp
1492 (use-package boxquote
1493   :bind
1494   (:prefix-map amin--boxquote-prefix-map
1495    :prefix "C-c q"
1496    ("b"   . boxquote-buffer)
1497    ("B"   . boxquote-insert-buffer)
1498    ("d"   . boxquote-defun)
1499    ("F"   . boxquote-insert-file)
1500    ("hf"  . boxquote-describe-function)
1501    ("hk"  . boxquote-describe-key)
1502    ("hv"  . boxquote-describe-variable)
1503    ("hw"  . boxquote-where-is)
1504    ("k"   . boxquote-kill)
1505    ("p"   . boxquote-paragraph)
1506    ("q"   . boxquote-boxquote)
1507    ("r"   . boxquote-region)
1508    ("s"   . boxquote-shell-command)
1509    ("t"   . boxquote-text)
1510    ("T"   . boxquote-title)
1511    ("u"   . boxquote-unbox)
1512    ("U"   . boxquote-unbox-region)
1513    ("y"   . boxquote-yank)
1514    ("M-q" . boxquote-fill-paragraph)
1515    ("M-w" . boxquote-kill-ring-save)))
1516 #+end_src
1517
1518 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1519
1520 ** [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]
1521
1522 #+begin_src emacs-lisp
1523 (use-package highlight-indent-guides
1524   :demand t
1525   :hook ((prog-mode . highlight-indent-guides-mode)
1526          (org-mode  . highlight-indent-guides-mode))
1527   :config
1528   (setq highlight-indent-guides-character ?\|)
1529   (setq highlight-indent-guides-auto-enabled nil)
1530   (setq highlight-indent-guides-method 'character)
1531   (setq highlight-indent-guides-responsive 'top)
1532   (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
1533   (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
1534 #+end_src
1535
1536 ** pdf-tools
1537
1538 #+begin_src emacs-lisp
1539 (use-package pdf-tools
1540   :magic ("%PDF" . pdf-view-mode)
1541   :config (pdf-tools-install)
1542   :bind
1543   (:map pdf-view-mode-map
1544         ("C-s" . isearch-forward)
1545         ("C-r" . isearch-backward)
1546         ("j"   . pdf-view-next-line-or-next-page)
1547         ("k"   . pdf-view-previous-line-or-previous-page)))
1548 #+end_src
1549
1550 ** anzu
1551
1552 #+begin_src emacs-lisp
1553 (use-package anzu)
1554 #+end_src
1555
1556 ** typo.el
1557
1558 #+begin_src emacs-lisp
1559 (use-package typo
1560   :config
1561   (typo-global-mode 1)
1562   :hook (text-mode . typo-mode))
1563 #+end_src
1564
1565 * Email
1566
1567 #+begin_src emacs-lisp
1568 (defvar amin-maildir (expand-file-name "~/mail/"))
1569 (after! recentf
1570   (add-to-list 'recentf-exclude amin-maildir))
1571 #+end_src
1572
1573 ** sendmail
1574
1575 #+begin_src emacs-lisp
1576 (use-package sendmail
1577   :config
1578   (setq sendmail-program "/usr/bin/msmtp"
1579         ;; message-sendmail-extra-arguments '("-v" "-d")
1580         mail-specify-envelope-from t
1581         mail-envelope-from 'header))
1582 #+end_src
1583
1584 ** message
1585
1586 #+begin_src emacs-lisp
1587 (use-package message
1588   :config
1589   (setq message-kill-buffer-on-exit t
1590         message-send-mail-function 'message-send-mail-with-sendmail
1591         message-sendmail-envelope-from 'header
1592         ;; message-directory "drafts"
1593         message-user-fqdn "aminb.org")
1594   ;; (add-hook 'message-mode-hook 'electric-quote-local-mode)
1595   (add-hook 'message-mode-hook
1596             (lambda () (setq fill-column 65
1597                         message-fill-column 65)))
1598   (add-hook 'message-mode-hook
1599             #'flyspell-mode)
1600   ;; (add-hook 'message-setup-hook
1601   ;;           #'mml-secure-message-sign-pgpmime)
1602   :custom-face
1603   (message-header-subject ((t (:foreground "navy blue" :weight semi-bold))))
1604   (message-header-to ((t (:foreground "MidnightBlue" :weight semi-bold)))))
1605
1606 (after! mml-sec
1607   (setq mml-secure-openpgp-encrypt-to-self t
1608         mml-secure-openpgp-sign-with-sender t))
1609 #+end_src
1610
1611 ** [[https://notmuchmail.org][notmuch]]
1612
1613 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1614
1615 #+begin_src emacs-lisp
1616 (defun amin/notmuch ()
1617   "Delete other windows, then launch `notmuch'."
1618   (interactive)
1619   (delete-other-windows)
1620   (notmuch))
1621
1622 (use-package notmuch
1623   :commands notmuch
1624   :bind ("C-c n" . amin/notmuch)
1625   :custom (notmuch-always-prompt-for-sender t)
1626   :config
1627   (setq notmuch-hello-sections
1628         '(notmuch-hello-insert-header
1629           notmuch-hello-insert-saved-searches
1630           ;; notmuch-hello-insert-search
1631           notmuch-hello-insert-alltags)
1632         notmuch-search-oldest-first nil
1633         notmuch-show-all-tags-list t
1634         notmuch-message-headers  ; see bug follow-up above
1635         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1636         notmuch-hello-thousands-separator ","
1637         notmuch-fcc-dirs
1638         '(("amin@aminb.org"        . "amin/Sent")
1639           ("bandali@gnu.org"       . "gnu/Sent")
1640           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1641           ("mab@gnu.org"           . "gnu/Sent")
1642           ("amin@gnu.org"          . "gnu/Sent")
1643           ("aminb@gnu.org"         . "gnu/Sent")
1644           (".*"                    . "sent"))
1645         notmuch-search-result-format
1646         '(("date"    . "%12s ")
1647           ("count"   . "%-7s ")
1648           ("authors" . "%-40s ")
1649           ("subject" . "%s ")
1650           ("tags"    . "(%s)"))
1651         notmuch-saved-searches
1652         '((:name "inbox"     :query "tag:inbox"     :key "i")
1653           (:name "unread"    :query "tag:unread"    :key "u")
1654           (:name "latest"    :query "tag:latest"    :key "l")
1655           (:name "encrypted" :query "tag:encrypted" :key "e")
1656           (:name "flagged"   :query "tag:flagged"   :key "f")
1657           (:name "sent"      :query "tag:sent"      :key "s")
1658           (:name "drafts"    :query "tag:draft"     :key "d")
1659           (:name "all mail"  :query "*"             :key "a")))
1660   ;; (add-hook 'visual-fill-column-mode-hook
1661   ;;           (lambda ()
1662   ;;             (when (string= major-mode 'notmuch-message-mode)
1663   ;;               (setq visual-fill-column-width 70))))
1664   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1665   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1666   ;;             :override #'kill-this-buffer)
1667   :hook (notmuch-message-mode . doom-modeline-set-special-modeline)
1668   :bind
1669   (:map notmuch-hello-mode-map
1670         ("u" . (lambda ()
1671                  "Search for `unread'-tagged messages"
1672                  (interactive)
1673                  (notmuch-hello-search "tag:unread")))
1674         ("i" . (lambda ()
1675                  "Search for `inbox'-tagged messages"
1676                  (interactive)
1677                  (notmuch-hello-search "tag:inbox")))
1678         ("l" . (lambda ()
1679                  "Search for `latest'-tagged messages"
1680                  (interactive)
1681                  (notmuch-hello-search "tag:latest")))
1682         ("e" . (lambda ()
1683                  "Search for `encrypted'-tagged messages"
1684                  (interactive)
1685                  (notmuch-hello-search "tag:encrypted"))))
1686   (:map notmuch-search-mode-map
1687         ("k" . (lambda ()
1688                  "Mark message read"
1689                  (interactive)
1690                  (notmuch-search-tag '("-unread"))
1691                  ;; (notmuch-search-archive-thread)
1692                  (notmuch-search-next-thread)))
1693         ("u" . (lambda ()
1694                  "Mark message unread"
1695                  (interactive)
1696                  (notmuch-search-tag '("+unread"))
1697                  (notmuch-search-next-thread)))
1698         ("K" . (lambda ()
1699                  "Mark message deleted"
1700                  (interactive)
1701                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1702                  (notmuch-search-next-thread)))
1703         ("S" . (lambda ()
1704                  "Mark message as spam"
1705                  (interactive)
1706                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1707                  (notmuch-search-next-thread))))
1708   (:map notmuch-tree-mode-map
1709         ("k" . (lambda ()
1710                  "Mark message read"
1711                  (interactive)
1712                  (notmuch-tree-tag '("-unread"))
1713                  ;; (notmuch-tree-archive-thread)
1714                  (notmuch-tree-next-message)))
1715         ("u" . (lambda ()
1716                  "Mark message unread"
1717                  (interactive)
1718                  (notmuch-tree-tag '("+unread"))
1719                  (notmuch-tree-next-message)))
1720         ("K" . (lambda ()
1721                  "Mark message deleted"
1722                  (interactive)
1723                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
1724                  (notmuch-tree-next-message)))
1725         ("S" . (lambda ()
1726                  "Mark message as spam"
1727                  (interactive)
1728                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1729                  (notmuch-tree-next-message))))
1730   :custom-face
1731   (notmuch-search-unread-face ((t (:weight semi-bold))))
1732   (notmuch-tag-face ((t (:foreground "navy blue" :weight semi-bold)))))
1733
1734 (use-package counsel-notmuch
1735   :bind ("C-c s m" . counsel-notmuch))
1736
1737 (after! notmuch-crypto
1738   (setq notmuch-crypto-process-mime t))
1739 #+end_src
1740
1741 ** supercite
1742
1743 #+begin_src emacs-lisp :tangle no
1744 (use-package supercite
1745   :commands sc-cite-original
1746   :init
1747   (add-hook 'mail-citation-hook 'sc-cite-original)
1748
1749   (defun sc-remove-existing-signature ()
1750     (save-excursion
1751       (goto-char (region-beginning))
1752       (when (re-search-forward message-signature-separator (region-end) t)
1753         (delete-region (match-beginning 0) (region-end)))))
1754
1755   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1756
1757   (defun sc-remove-if-not-mailing-list ()
1758     (unless (assoc "list-id" sc-mail-info)
1759       (setq attribution sc-default-attribution
1760             citation (concat sc-citation-delimiter
1761                              sc-citation-separator))))
1762
1763   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1764
1765   :config
1766   (defun sc-fill-if-different (&optional prefix)
1767     "Fill the region bounded by `sc-fill-begin' and point.
1768 Only fill if optional PREFIX is different than
1769 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1770 fill region.  If PREFIX is not supplied, initialize fill
1771 variables.  This is useful for a regi `begin' frame-entry."
1772     (if (not prefix)
1773         (setq sc-fill-line-prefix ""
1774               sc-fill-begin (line-beginning-position))
1775       (if (and sc-auto-fill-region-p
1776                (not (string= prefix sc-fill-line-prefix)))
1777           (let ((fill-prefix sc-fill-line-prefix))
1778             (unless (or (string= fill-prefix "")
1779                         (save-excursion
1780                           (goto-char sc-fill-begin)
1781                           (or (looking-at ">+  +")
1782                               (< (length
1783                                   (buffer-substring (point)
1784                                                     (line-end-position)))
1785                                  65))))
1786               (fill-region sc-fill-begin (line-beginning-position)))
1787             (setq sc-fill-line-prefix prefix
1788                   sc-fill-begin (line-beginning-position)))))
1789 nil))
1790 #+end_src
1791
1792 * Blogging
1793 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1794
1795 #+begin_src emacs-lisp
1796 (use-package ox-hugo
1797   :after ox)
1798
1799 (use-package ox-hugo-auto-export
1800   :load-path "lib/ox-hugo")
1801 #+end_src
1802
1803 * Post initialization
1804 :PROPERTIES:
1805 :CUSTOM_ID: post-initialization
1806 :END:
1807
1808 Display how long it took to load the init file.
1809
1810 #+begin_src emacs-lisp
1811 (message "Loading %s...done (%.3fs)" user-init-file
1812          (float-time (time-subtract (current-time)
1813                                     amin--before-user-init-time)))
1814 #+end_src
1815
1816 * Footer
1817 :PROPERTIES:
1818 :CUSTOM_ID: footer
1819 :END:
1820
1821 #+begin_src emacs-lisp :comments none
1822 ;;; init.el ends here
1823 #+end_src
1824
1825 * COMMENT Local Variables                                           :ARCHIVE:
1826 # Local Variables:
1827 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
1828 # End: