git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 ;; (require 'borg-nix-shell)
 238 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c B A" . borg-activate)
 244    ("C-c B a" . borg-assimilate)
 245    ("C-c B b" . borg-build)
 246    ("C-c B c" . borg-clone)))
 247 #+end_src
 248
 249 *** =use-package=
 250
 251 #+begin_quote
 252 A use-package declaration for simplifying your .emacs
 253 #+end_quote
 254
 255 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 256 packages (in our case especially the latter) in a neatly organized way
 257 and without compromising on performance.
 258
 259 #+begin_src emacs-lisp
 260 (require 'use-package)
 261 (if nil  ; set to t when need to debug init
 262     (setq use-package-verbose t
 263           use-package-expand-minimally nil
 264           use-package-compute-statistics t
 265           debug-on-error t)
 266   (setq use-package-verbose nil
 267         use-package-expand-minimally t))
 268 #+end_src
 269
 270 *** Epkg
 271
 272 #+begin_quote
 273 Browse the Emacsmirror package database
 274 #+end_quote
 275
 276 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 277 database, low-level functions for querying the database, and a
 278 =package.el=-like user interface for browsing the available packages.
 279
 280 #+begin_src emacs-lisp
 281 (use-package epkg
 282   :defer t
 283   :bind
 284   (("C-c B d" . epkg-describe-package)
 285    ("C-c B p" . epkg-list-packages)
 286    ("C-c B r" . borg-remove)
 287    ("C-c B u" . epkg-update)))
 288 #+end_src
 289
 290 ** No littering in =~/.emacs.d=
 291
 292 #+begin_quote
 293 Help keeping ~/.emacs.d clean
 294 #+end_quote
 295
 296 By default, even for Emacs' built-in packages, the configuration files
 297 and persistent data are all over the place. Use =no-littering= to help
 298 contain the mess.
 299
 300 #+begin_src emacs-lisp
 301 (use-package no-littering
 302   :demand t
 303   :config
 304   (savehist-mode 1)
 305   (add-to-list 'savehist-additional-variables 'kill-ring)
 306   (save-place-mode 1)
 307   (setq auto-save-file-name-transforms
 308         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 309 #+end_src
 310
 311 ** Custom file (=custom.el=)
 312
 313 I'm not planning on using the custom file much, but even so, I
 314 definitely don't want it mixing with =init.el=. So, here; let's give
 315 it it's own file. While at it, treat themes as safe.
 316
 317 #+begin_src emacs-lisp
 318 (use-package custom
 319   :no-require t
 320   :config
 321   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 322   (when (file-exists-p custom-file)
 323     (load custom-file))
 324   (setf custom-safe-themes t))
 325 #+end_src
 326
 327 ** Better =$PATH= handling
 328
 329 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 330 in my shell.
 331
 332 #+begin_src emacs-lisp
 333 (use-package exec-path-from-shell
 334   :defer 1
 335   :init
 336   (setq exec-path-from-shell-check-startup-files nil)
 337   :config
 338   (exec-path-from-shell-initialize)
 339   ;; while we're at it, let's fix access to our running ssh-agent
 340   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 341   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 342 #+end_src
 343
 344 ** Only one custom theme at a time
 345
 346 #+begin_src emacs-lisp
 347 (defadvice load-theme (before clear-previous-themes activate)
 348   "Clear existing theme settings instead of layering them"
 349   (mapc #'disable-theme custom-enabled-themes))
 350 #+end_src
 351
 352 ** Server
 353
 354 Start server if not already running. Alternatively, can be done by
 355 issuing =emacs --daemon= in the terminal, which can be automated with
 356 a systemd service or using =brew services start emacs= on macOS. I use
 357 Emacs as my window manager (via EXWM), so I always start Emacs on
 358 login; so starting the server from inside Emacs is good enough for me.
 359
 360 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 361
 362 #+begin_src emacs-lisp
 363 (use-package server
 364   :config (or (server-running-p) (server-mode)))
 365 #+end_src
 366
 367 ** Unicode support
 368
 369 Font stack with better unicode support, around =Ubuntu Mono= and
 370 =Hack=.
 371
 372 #+begin_src emacs-lisp :tangle no
 373 (dolist (ft (fontset-list))
 374   (set-fontset-font
 375    ft
 376    'unicode
 377    (font-spec :name "Source Code Pro" :size 14))
 378   (set-fontset-font
 379    ft
 380    'unicode
 381    (font-spec :name "DejaVu Sans Mono")
 382    nil
 383    'append)
 384   ;; (set-fontset-font
 385   ;;  ft
 386   ;;  'unicode
 387   ;;  (font-spec
 388   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 389   ;;  nil
 390   ;;  'append)
 391   ;; (set-fontset-font
 392   ;;  ft
 393   ;;  #x2115  ; ℕ
 394   ;;  (font-spec :name "DejaVu Sans Mono")
 395   ;;  nil
 396   ;;  'append)
 397   (set-fontset-font
 398    ft
 399    (cons ?Α ?ω)
 400    (font-spec :name "DejaVu Sans Mono" :size 14)
 401    nil
 402    'prepend))
 403 #+end_src
 404
 405 ** Gentler font resizing
 406
 407 #+begin_src emacs-lisp
 408 (setq text-scale-mode-step 1.05)
 409 #+end_src
 410
 411 ** Libraries
 412
 413 #+begin_src emacs-lisp
 414 (require 'cl-lib)
 415 (require 'subr-x)
 416 #+end_src
 417
 418 ** Useful utilities
 419
 420 #+begin_src emacs-lisp
 421 (defun amin-enlist (exp)
 422   "Return EXP wrapped in a list, or as-is if already a list."
 423 (if (listp exp) exp (list exp)))
 424
 425 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 426 (defmacro after! (features &rest body)
 427   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 428 compilation."
 429   (declare (indent defun) (debug t))
 430   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 431                 (dolist (next (amin-enlist features))
 432                   (if (symbolp next)
 433                       (require next nil :no-error)
 434                     (load next :no-message :no-error))))
 435             #'progn
 436           #'with-no-warnings)
 437         (cond ((symbolp features)
 438                `(eval-after-load ',features '(progn ,@body)))
 439               ((and (consp features)
 440                     (memq (car features) '(:or :any)))
 441                `(progn
 442                   ,@(cl-loop for next in (cdr features)
 443                              collect `(after! ,next ,@body))))
 444               ((and (consp features)
 445                     (memq (car features) '(:and :all)))
 446                (dolist (next (cdr features))
 447                  (setq body `(after! ,next ,@body)))
 448                body)
 449               ((listp features)
 450                `(after! (:all ,@features) ,@body)))))
 451 #+end_src
 452
 453 Convenience macro for =setq='ing multiple variables to the same value:
 454
 455 #+begin_src emacs-lisp
 456 (defmacro setq-every! (value &rest vars)
 457   "Set all the variables from VARS to value VALUE."
 458   (declare (indent defun) (debug t))
 459   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 460 #+end_src
 461
 462 * Core
 463 :PROPERTIES:
 464 :CUSTOM_ID: core
 465 :END:
 466
 467 ** Defaults
 468
 469 *** Time and battery in mode-line
 470
 471 Enable displaying time and battery in the mode-line, since I'm not
 472 using the Xfce panel anymore. Also, I don't need to see the load
 473 average on a regular basis, so disable that.
 474
 475 Note: using =i3status= on sway at the moment, so disabling this.
 476
 477 #+begin_src emacs-lisp :tangle no
 478 (use-package time
 479   :init
 480   (setq display-time-default-load-average nil)
 481   :config
 482   (display-time-mode))
 483
 484 (use-package battery
 485   :config
 486   (display-battery-mode))
 487 #+end_src
 488
 489 *** Smaller fringe
 490
 491 Might want to set the fringe to a smaller value, especially if using
 492 EXWM. I'm fine with the default for now.
 493
 494 #+begin_src emacs-lisp
 495 ;; (fringe-mode '(3 . 1))
 496 (fringe-mode nil)
 497 #+end_src
 498
 499 *** Disable disabled commands
 500
 501 Emacs disables some commands by default that could persumably be
 502 confusing for novice users. Let's disable that.
 503
 504 #+begin_src emacs-lisp
 505 (setq disabled-command-function nil)
 506 #+end_src
 507
 508 *** Kill-ring
 509
 510 Save what I copy into clipboard from other applications into Emacs'
 511 kill-ring, which would allow me to still be able to easily access it
 512 in case I kill (cut or copy) something else inside Emacs before
 513 yanking (pasting) what I'd originally intended to.
 514
 515 #+begin_src emacs-lisp
 516 (setq save-interprogram-paste-before-kill t)
 517 #+end_src
 518
 519 *** Minibuffer
 520
 521 #+begin_src emacs-lisp
 522 (setq enable-recursive-minibuffers t
 523       resize-mini-windows t)
 524 #+end_src
 525
 526 *** Lazy-person-friendly yes/no prompts
 527
 528 Lazy people would prefer to type fewer keystrokes, especially for yes
 529 or no questions. I'm lazy.
 530
 531 #+begin_src emacs-lisp
 532 (defalias 'yes-or-no-p #'y-or-n-p)
 533 #+end_src
 534
 535 *** Startup screen and =*scratch*=
 536
 537 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 538 startup buffer.
 539
 540 #+begin_src emacs-lisp
 541 (setq initial-buffer-choice t)
 542 #+end_src
 543
 544 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 545 need the default hint.
 546
 547 #+begin_src emacs-lisp
 548 (setq initial-scratch-message nil)
 549 #+end_src
 550
 551 Also, let's use Text mode as the major mode, in case I want to
 552 customize it (=*scratch*='s default major mode, Fundamental mode,
 553 can't really be customized).
 554
 555 #+begin_src emacs-lisp
 556 (setq initial-major-mode 'text-mode)
 557 #+end_src
 558
 559 Inhibit the buffer list when more than 2 files are loaded.
 560
 561 #+begin_src emacs-lisp
 562 (setq inhibit-startup-buffer-menu t)
 563 #+end_src
 564
 565 I don't really need to see the startup screen or echo area message
 566 either.
 567
 568 #+begin_src emacs-lisp
 569 (advice-add #'display-startup-echo-area-message :override #'ignore)
 570 (setq inhibit-startup-screen t
 571       inhibit-startup-echo-area-message user-login-name)
 572 #+end_src
 573
 574 *** More useful frame titles
 575
 576 Show either the file name or the buffer name (in case the buffer isn't
 577 visiting a file). Borrowed from Emacs Prelude.
 578
 579 #+begin_src emacs-lisp
 580 (setq frame-title-format
 581       '("" invocation-name " - "
 582         (:eval (if (buffer-file-name)
 583                    (abbreviate-file-name (buffer-file-name))
 584                  "%b"))))
 585 #+end_src
 586
 587 *** Backups
 588
 589 Emacs' default backup settings aren't that great. Let's use more
 590 sensible options. See documentation for the ~make-backup-file~
 591 variable.
 592
 593 #+begin_src emacs-lisp
 594 (setq backup-by-copying t
 595       version-control t
 596       delete-old-versions t)
 597 #+end_src
 598
 599 *** Auto revert
 600
 601 Enable automatic reloading of changed buffers and files.
 602
 603 #+begin_src emacs-lisp
 604 (global-auto-revert-mode 1)
 605 (setq auto-revert-verbose nil
 606       global-auto-revert-non-file-buffers t)
 607 #+end_src
 608
 609 *** Always use space for indentation
 610
 611 #+begin_src emacs-lisp
 612 (setq-default
 613  indent-tabs-mode nil
 614  require-final-newline t
 615  tab-width 4)
 616 #+end_src
 617
 618 *** Winner mode
 619
 620 Enable =winner-mode=.
 621
 622 #+begin_src emacs-lisp
 623 (winner-mode 1)
 624 #+end_src
 625
 626 *** Close =*compilation*= on success
 627
 628 #+begin_src emacs-lisp
 629 (setq compilation-exit-message-function
 630       (lambda (status code msg)
 631         "Close the compilation window if successful."
 632         ;; if M-x compile exits with 0
 633          (when (and (eq status 'exit) (zerop code))
 634            (bury-buffer)
 635            (delete-window (get-buffer-window (get-buffer "*compilation*"))))
 636          ;; return the result of compilation-exit-message-function
 637          (cons msg code)))
 638 #+end_src
 639
 640 ** Bindings
 641
 642 #+begin_src emacs-lisp
 643 (bind-keys
 644  ("C-c b k" . kill-this-buffer)
 645  ("C-c s s" . save-buffer)
 646  ("C-c b s" . save-buffer)
 647  ("C-c S"   . save-buffer)
 648  ("C-c o"   . other-window)
 649  ("C-c q q" . save-buffers-kill-terminal)
 650  ("C-c F m" . make-frame-command)
 651  ("C-c F d" . delete-frame)
 652  ("C-c F D" . delete-other-frames))
 653 #+end_src
 654
 655 ** Packages
 656
 657 The packages in this section are absolutely essential to my everyday
 658 workflow, and they play key roles in how I do my computing. They
 659 immensely enhance the Emacs experience for me; both using Emacs, and
 660 customizing it.
 661
 662 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 663
 664 #+begin_src emacs-lisp
 665 (use-package auto-compile
 666   :demand t
 667   :config
 668   (auto-compile-on-load-mode)
 669   (auto-compile-on-save-mode)
 670   (setq auto-compile-display-buffer               nil
 671         auto-compile-mode-line-counter            t
 672         auto-compile-source-recreate-deletes-dest t
 673         auto-compile-toggle-deletes-nonlib-dest   t
 674         auto-compile-update-autoloads             t)
 675   (add-hook 'auto-compile-inhibit-compile-hook
 676             'auto-compile-inhibit-compile-detached-git-head))
 677 #+end_src
 678
 679 *** [[https://orgmode.org/][Org mode]]
 680
 681 #+begin_quote
 682 Org mode is for keeping notes, maintaining TODO lists, planning
 683 projects, and authoring documents with a fast and effective plain-text
 684 system.
 685 #+end_quote
 686
 687 In short, my favourite way of life.
 688
 689 #+begin_src emacs-lisp
 690 (use-package org
 691   :config
 692   (setq org-src-tab-acts-natively t
 693         org-src-preserve-indentation nil
 694         org-edit-src-content-indentation 0
 695         org-log-done 'time)
 696   :hook ((org-mode . org-indent-mode)
 697          (org-mode . auto-fill-mode)
 698          (org-mode . flyspell-mode))
 699   :custom
 700   (org-latex-packages-alist '(("" "listings") ("" "color"))))
 701
 702 (use-package ox-latex
 703   :config
 704   (setq org-latex-listings 'listings)
 705   (add-to-list 'org-latex-packages-alist '("" "listings"))
 706   (add-to-list 'org-latex-packages-alist '("" "color"))
 707   (add-to-list 'org-latex-classes
 708                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 709                  ("\\section{%s}" . "\\section*{%s}")
 710                  ("\\subsection{%s}" . "\\subsection*{%s}")
 711                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 712                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 713                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 714                t))
 715
 716 (use-package ox-beamer)
 717
 718 (use-package org-notmuch
 719   :after (:any org notmuch))
 720
 721 (use-package orgalist)
 722 #+end_src
 723
 724 **** asynchronous tangle
 725
 726 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 727 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 728 file.
 729
 730 #+begin_src emacs-lisp
 731 (after! org
 732   (defvar amin-show-async-tangle-results nil
 733     "Keep *emacs* async buffers around for later inspection.")
 734
 735   (defvar amin-show-async-tangle-time nil
 736     "Show the time spent tangling the file.")
 737
 738   (defvar amin-async-tangle-post-compile "make ti"
 739     "If non-nil, pass to `compile' after successful tangle.")
 740
 741   (defun amin/async-babel-tangle ()
 742     "Tangle org file asynchronously."
 743     (interactive)
 744     (let* ((file-tangle-start-time (current-time))
 745            (file (buffer-file-name))
 746            (file-nodir (file-name-nondirectory file))
 747            (async-quiet-switch "-q"))
 748       (async-start
 749        `(lambda ()
 750           (require 'org)
 751           (org-babel-tangle-file ,file))
 752        (unless amin-show-async-tangle-results
 753          `(lambda (result)
 754             (if result
 755                 (progn
 756                   (message "Tangled %s%s"
 757                            ,file-nodir
 758                            (if amin-show-async-tangle-time
 759                                (format " (%.3fs)"
 760                                        (float-time (time-subtract (current-time)
 761                                                                   ',file-tangle-start-time)))
 762                              ""))
 763                   (when amin-async-tangle-post-compile
 764                     (compile amin-async-tangle-post-compile)))
 765               (message "Tangling %s failed" ,file-nodir))))))))
 766
 767 (add-to-list
 768  'safe-local-variable-values
 769  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 770 #+end_src
 771
 772 *** [[https://magit.vc/][Magit]]
 773
 774 #+begin_quote
 775 It's Magit! A Git porcelain inside Emacs.
 776 #+end_quote
 777
 778 Not just how I do git, but /the/ way to do git.
 779
 780 #+begin_src emacs-lisp
 781 (use-package magit
 782   :defer t
 783   :bind
 784   (("s-g"   . magit-dispatch-popup)
 785    ("C-x g" . magit-status)
 786    :prefix-map amin--magit-prefix-map
 787    :prefix "C-c g"
 788    ("SPC" . magit-status)
 789    ("s"   . magit-status)
 790    ("S"   . magit-status-prefix)
 791    ("B"   . magit-blame-addition)
 792    ("C"   . magit-clone)
 793    ("f"   . magit-fetch-other)
 794    ("F"   . magit-pull-branch)
 795    ("P"   . magit-push-other)
 796    ("p"   . magit-dispatch-popup)
 797    ("c c" . magit-commit-create)
 798    ("c a" . magit-commit-amend)
 799    ("b b" . magit-checkout)
 800    ("b c" . magit-branch-create))
 801   :config
 802   (magit-add-section-hook 'magit-status-sections-hook
 803                           'magit-insert-modules
 804                           'magit-insert-stashes
 805                           'append)
 806   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 807 #+end_src
 808
 809 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 810
 811 #+begin_quote
 812 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 813 an overview, and more. Oh, man!
 814 #+end_quote
 815
 816 There's no way I could top that, so I won't attempt to.
 817
 818 **** Ivy
 819
 820 #+begin_src emacs-lisp
 821 (use-package ivy
 822   :defer 1
 823   :bind
 824   (("C-c b b" . ivy-switch-buffer)
 825    :map ivy-minibuffer-map
 826    ([escape] . keyboard-escape-quit)
 827    ([S-up]   . ivy-previous-history-element)
 828    ([S-down] . ivy-next-history-element)
 829    ("DEL"    . ivy-backward-delete-char))
 830   :config
 831   (setq ivy-wrap t)
 832   (ivy-mode 1)
 833   :custom-face
 834   (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 835   (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 836   (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold)))))
 837 #+end_src
 838
 839 **** Swiper
 840
 841 #+begin_src emacs-lisp
 842 (use-package swiper
 843   :bind (("C-s" . swiper)
 844          ("C-r" . swiper)))
 845 #+end_src
 846
 847 **** Counsel
 848
 849 #+begin_src emacs-lisp
 850 (use-package counsel
 851   :defer 1
 852   :bind (([remap execute-extended-command] . counsel-M-x)
 853          ([remap find-file]                . counsel-find-file)
 854          ("s-r"                            . counsel-recentf)
 855          ("C-c x"                          . counsel-M-x)
 856          ("C-c f ."                        . counsel-find-file)
 857          ("C-c f r"                        . counsel-recentf)
 858          :map minibuffer-local-map
 859          ("C-r" . counsel-minibuffer-history))
 860   :config
 861   (counsel-mode 1)
 862   (defalias 'locate #'counsel-locate))
 863 #+end_src
 864
 865 *** eshell
 866
 867 #+begin_src emacs-lisp
 868 (use-package eshell
 869   :commands eshell
 870   :config
 871   (eval-when-compile (defvar eshell-prompt-regexp))
 872   (defun amin/eshell-quit-or-delete-char (arg)
 873     (interactive "p")
 874     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 875         (eshell-life-is-too-much)
 876       (delete-char arg)))
 877
 878   (defun amin/eshell-clear ()
 879     (interactive)
 880     (let ((inhibit-read-only t))
 881       (erase-buffer))
 882     (eshell-send-input))
 883
 884   (defun amin|eshell-setup ()
 885     (bind-keys :map eshell-mode-map
 886                ("C-d" . amin/eshell-quit-or-delete-char)
 887                ("C-l" . amin/eshell-clear)))
 888
 889   :hook (eshell-mode . amin|eshell-setup))
 890 #+end_src
 891
 892 *** Ibuffer
 893
 894 #+begin_src emacs-lisp
 895 (use-package ibuffer
 896   :bind
 897   (("C-x C-b" . ibuffer-other-window)
 898    ("C-c b B" . ibuffer-other-window)
 899    :map ibuffer-mode-map
 900    ("P"   . ibuffer-backward-filter-group)
 901    ("N"   . ibuffer-forward-filter-group)
 902    ("M-p" . ibuffer-do-print)
 903    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 904   :config
 905   ;; Use human readable Size column instead of original one
 906   (define-ibuffer-column size-h
 907     (:name "Size" :inline t)
 908     (cond
 909      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
 910      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
 911      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
 912      (t (format "%8d" (buffer-size)))))
 913   :custom
 914   (ibuffer-saved-filter-groups
 915    '(("default"
 916       ("dired" (mode . dired-mode))
 917       ("org"   (mode . org-mode))
 918       ("web"
 919        (or
 920         (mode . web-mode)
 921         (mode . css-mode)
 922         (mode . scss-mode)
 923         (mode . js2-mode)))
 924       ("shell"
 925        (or
 926         (mode . eshell-mode)
 927         (mode . shell-mode)))
 928       ("notmuch" (name . "\*notmuch\*"))
 929       ("programming"
 930        (or
 931         (mode . python-mode)
 932         (mode . c++-mode)
 933         (mode . emacs-lisp-mode)))
 934       ("emacs"
 935        (or
 936         (name . "^\\*scratch\\*$")
 937         (name . "^\\*Messages\\*$"))))))
 938   (ibuffer-formats
 939    '((mark modified read-only locked " "
 940            (name 18 18 :left :elide)
 941            " "
 942            (size-h 9 -1 :right)
 943            " "
 944            (mode 16 16 :left :elide)
 945            " " filename-and-process)
 946      (mark " "
 947            (name 16 -1)
 948            " " filename)))
 949   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
 950 #+end_src
 951
 952 *** Outline
 953
 954 #+begin_src emacs-lisp
 955 (use-package outline
 956   :hook (prog-mode . outline-minor-mode)
 957   :bind
 958   (:map
 959    outline-minor-mode-map
 960    ("<s-tab>"  . outline-toggle-children)
 961    ("s-p"      . outline-previous-visible-heading)
 962    ("s-n"      . outline-next-visible-heading)
 963    :prefix-map amin--outline-prefix-map
 964    :prefix "s-o"
 965    ("TAB" . outline-toggle-children)
 966    ("a"   . outline-hide-body)
 967    ("H"   . outline-hide-body)
 968    ("S"   . outline-show-all)
 969    ("h"   . outline-hide-subtree)
 970    ("s"   . outline-show-subtree)))
 971 #+end_src
 972
 973 * Borg's =layer/essentials=
 974
 975 TODO: break this giant source block down into individual org sections.
 976
 977 #+begin_src emacs-lisp
 978 (use-package dash
 979   :config (dash-enable-font-lock))
 980
 981 (use-package diff-hl
 982   :config
 983   (setq diff-hl-draw-borders nil)
 984   (global-diff-hl-mode)
 985   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 986
 987 (use-package dired
 988   :defer t
 989   :config (setq dired-listing-switches "-alh"))
 990
 991 (use-package eldoc
 992   :when (version< "25" emacs-version)
 993   :config (global-eldoc-mode))
 994
 995 (use-package help
 996   :defer t
 997   :config (temp-buffer-resize-mode))
 998
 999 (progn ;    `isearch'
1000   (setq isearch-allow-scroll t))
1001
1002 (use-package lisp-mode
1003   :config
1004   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1005   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1006   (defun indent-spaces-mode ()
1007     (setq indent-tabs-mode nil))
1008   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1009
1010 (use-package man
1011   :defer t
1012   :config (setq Man-width 80))
1013
1014 (use-package paren
1015   :config (show-paren-mode))
1016
1017 (use-package prog-mode
1018   :config (global-prettify-symbols-mode)
1019   (defun indicate-buffer-boundaries-left ()
1020     (setq indicate-buffer-boundaries 'left))
1021   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1022
1023 (use-package recentf
1024   :demand t
1025   :config
1026   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1027   (setq recentf-max-saved-items 40))
1028
1029 (use-package savehist
1030   :config (savehist-mode))
1031
1032 (use-package saveplace
1033   :when (version< "25" emacs-version)
1034   :config (save-place-mode))
1035
1036 (use-package simple
1037   :config (column-number-mode))
1038
1039 (progn ;    `text-mode'
1040   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1041
1042 (use-package tramp
1043   :defer t
1044   :config
1045   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1046   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1047   (add-to-list 'tramp-default-proxies-alist
1048                (list (regexp-quote (system-name)) nil nil)))
1049
1050 (use-package undo-tree
1051   :bind (("C-?" . undo-tree-undo)
1052          ("M-_" . undo-tree-redo))
1053   :config
1054   (global-undo-tree-mode)
1055   (setq undo-tree-mode-lighter ""
1056         undo-tree-auto-save-history t))
1057 #+end_src
1058
1059 * Editing
1060
1061 ** Company
1062
1063 #+begin_src emacs-lisp
1064 (use-package company
1065   :defer 5
1066   :bind
1067   (:map company-active-map
1068         ([tab]    . company-complete-common-or-cycle)
1069         ([escape] . company-abort))
1070   :custom
1071   (company-idle-delay 0.3)
1072   (company-minimum-prefix-length 1)
1073   (company-selection-wrap-around t)
1074   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1075   (company-dabbrev-downcase nil)
1076   (company-dabbrev-ignore-case nil)
1077   :config
1078   (global-company-mode t))
1079 #+end_src
1080
1081 * Syntax and spell checking
1082 #+begin_src emacs-lisp
1083 (use-package flycheck
1084   :hook (prog-mode . flycheck-mode)
1085   :config
1086   ;; Use the load-path from running Emacs when checking elisp files
1087   (setq flycheck-emacs-lisp-load-path 'inherit)
1088
1089   ;; Only flycheck when I actually save the buffer
1090   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1091
1092 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1093 (use-package ispell
1094   :config
1095   ;; ’ can be part of a word
1096   (setq ispell-local-dictionary-alist
1097         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1098                "['\x2019]" nil ("-B") nil utf-8)))
1099   ;; don't send ’ to the subprocess
1100   (defun endless/replace-apostrophe (args)
1101     (cons (replace-regexp-in-string
1102            "’" "'" (car args))
1103           (cdr args)))
1104   (advice-add #'ispell-send-string :filter-args
1105               #'endless/replace-apostrophe)
1106
1107   ;; convert ' back to ’ from the subprocess
1108   (defun endless/replace-quote (args)
1109     (if (not (derived-mode-p 'org-mode))
1110         args
1111       (cons (replace-regexp-in-string
1112              "'" "’" (car args))
1113             (cdr args))))
1114   (advice-add #'ispell-parse-output :filter-args
1115               #'endless/replace-quote))
1116 #+end_src
1117 * Programming modes
1118
1119 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1120
1121 #+begin_src emacs-lisp
1122 (use-package alloy-mode
1123   :config (setq alloy-basic-offset 2))
1124 #+end_src
1125
1126 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1127
1128 #+begin_src emacs-lisp
1129 (use-package proof-site  ; Proof General
1130   :load-path "lib/proof-site/generic/")
1131 #+end_src
1132
1133 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1134
1135 #+begin_src emacs-lisp
1136 (eval-when-compile (defvar lean-mode-map))
1137 (use-package lean-mode
1138   :defer 2
1139   :bind (:map lean-mode-map
1140               ("S-SPC" . company-complete))
1141   :config
1142   (require 'lean-input)
1143   (setq default-input-method "Lean"))
1144   #+end_src
1145
1146 ** Haskell
1147
1148 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1149
1150 #+begin_src emacs-lisp
1151 (use-package haskell-mode
1152   :config
1153   (setq haskell-indentation-layout-offset 4
1154         haskell-indentation-left-offset 4
1155         flycheck-checker 'haskell-hlint
1156         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1157 #+end_src
1158
1159 *** [[https://github.com/jyp/dante][dante]]
1160
1161 #+begin_src emacs-lisp
1162 (use-package dante
1163   :after haskell-mode
1164   :commands dante-mode
1165   :hook (haskell-mode . dante-mode))
1166 #+end_src
1167
1168 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1169
1170 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1171 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1172
1173 #+begin_src emacs-lisp
1174 (use-package hlint-refactor
1175   :bind (:map hlint-refactor-mode-map
1176               ("C-c l b" . hlint-refactor-refactor-buffer)
1177               ("C-c l r" . hlint-refactor-refactor-at-point))
1178   :hook (haskell-mode . hlint-refactor-mode))
1179 #+end_src
1180
1181 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1182
1183 #+begin_src emacs-lisp
1184 (use-package flycheck-haskell)
1185 #+end_src
1186
1187 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1188 :PROPERTIES:
1189 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1190 :END:
1191
1192 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1193 instead.
1194
1195 #+begin_src emacs-lisp :tangle no
1196 ;;; hs-lint.el --- minor mode for HLint code checking
1197
1198 ;; Copyright 2009 (C) Alex Ott
1199 ;;
1200 ;; Author: Alex Ott <alexott@gmail.com>
1201 ;; Keywords: haskell, lint, HLint
1202 ;; Requirements:
1203 ;; Status: distributed under terms of GPL2 or above
1204
1205 ;; Typical message from HLint looks like:
1206 ;;
1207 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1208 ;; Found:
1209 ;;   count1 p l = length (filter p l)
1210 ;; Why not:
1211 ;;   count1 p = length . filter p
1212
1213
1214 (require 'compile)
1215
1216 (defgroup hs-lint nil
1217   "Run HLint as inferior of Emacs, parse error messages."
1218   :group 'tools
1219   :group 'haskell)
1220
1221 (defcustom hs-lint-command "hlint"
1222   "The default hs-lint command for \\[hlint]."
1223   :type 'string
1224   :group 'hs-lint)
1225
1226 (defcustom hs-lint-save-files t
1227   "Save modified files when run HLint or no (ask user)"
1228   :type 'boolean
1229   :group 'hs-lint)
1230
1231 (defcustom hs-lint-replace-with-suggestions nil
1232   "Replace user's code with suggested replacements"
1233   :type 'boolean
1234   :group 'hs-lint)
1235
1236 (defcustom hs-lint-replace-without-ask nil
1237   "Replace user's code with suggested replacements automatically"
1238   :type 'boolean
1239   :group 'hs-lint)
1240
1241 (defun hs-lint-process-setup ()
1242   "Setup compilation variables and buffer for `hlint'."
1243   (run-hooks 'hs-lint-setup-hook))
1244
1245 ;; regex for replace suggestions
1246 ;;
1247 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1248 ;; Found:
1249 ;; \s +\(.*\)
1250 ;; Why not:
1251 ;; \s +\(.*\)
1252
1253 (defvar hs-lint-regex
1254   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1255   "Regex for HLint messages")
1256
1257 (defun make-short-string (str maxlen)
1258   (if (< (length str) maxlen)
1259       str
1260     (concat (substring str 0 (- maxlen 3)) "...")))
1261
1262 (defun hs-lint-replace-suggestions ()
1263   "Perform actual replacement of suggestions"
1264   (goto-char (point-min))
1265   (while (re-search-forward hs-lint-regex nil t)
1266     (let* ((fname (match-string 1))
1267           (fline (string-to-number (match-string 2)))
1268           (old-code (match-string 4))
1269           (new-code (match-string 5))
1270           (msg (concat "Replace '" (make-short-string old-code 30)
1271                        "' with '" (make-short-string new-code 30) "'"))
1272           (bline 0)
1273           (eline 0)
1274           (spos 0)
1275           (new-old-code ""))
1276       (save-excursion
1277         (switch-to-buffer (get-file-buffer fname))
1278         (goto-char (point-min))
1279         (forward-line (1- fline))
1280         (beginning-of-line)
1281         (setf bline (point))
1282         (when (or hs-lint-replace-without-ask
1283                   (yes-or-no-p msg))
1284           (end-of-line)
1285           (setf eline (point))
1286           (beginning-of-line)
1287           (setf old-code (regexp-quote old-code))
1288           (while (string-match "\\\\ " old-code spos)
1289             (setf new-old-code (concat new-old-code
1290                                  (substring old-code spos (match-beginning 0))
1291                                  "\\ *"))
1292             (setf spos (match-end 0)))
1293           (setf new-old-code (concat new-old-code (substring old-code spos)))
1294           (remove-text-properties bline eline '(composition nil))
1295           (when (re-search-forward new-old-code eline t)
1296             (replace-match new-code nil t)))))))
1297
1298 (defun hs-lint-finish-hook (buf msg)
1299   "Function, that is executed at the end of HLint execution"
1300   (if hs-lint-replace-with-suggestions
1301       (hs-lint-replace-suggestions)
1302       (next-error 1 t)))
1303
1304 (define-compilation-mode hs-lint-mode "HLint"
1305   "Mode for check Haskell source code."
1306   (set (make-local-variable 'compilation-process-setup-function)
1307        'hs-lint-process-setup)
1308   (set (make-local-variable 'compilation-disable-input) t)
1309   (set (make-local-variable 'compilation-scroll-output) nil)
1310   (set (make-local-variable 'compilation-finish-functions)
1311        (list 'hs-lint-finish-hook))
1312   )
1313
1314 (defun hs-lint ()
1315   "Run HLint for current buffer with haskell source"
1316   (interactive)
1317   (save-some-buffers hs-lint-save-files)
1318   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1319                      'hs-lint-mode))
1320
1321 (provide 'hs-lint)
1322 ;;; hs-lint.el ends here
1323 #+end_src
1324
1325 #+begin_src emacs-lisp :tangle no
1326 (use-package hs-lint
1327   :load-path "lisp/"
1328   :bind (:map haskell-mode-map
1329               ("C-c l l" . hs-lint)))
1330 #+end_src
1331
1332 ** Web dev
1333
1334 *** SGML and HTML
1335
1336 #+begin_src emacs-lisp
1337 (use-package sgml-mode
1338   :config
1339   (setq sgml-basic-offset 2))
1340 #+end_src
1341
1342 *** CSS and SCSS
1343
1344 #+begin_src emacs-lisp
1345 (use-package css-mode
1346   :config
1347   (setq css-indent-offset 2))
1348 #+end_src
1349
1350 *** Web mode
1351
1352 #+begin_src emacs-lisp
1353 (use-package web-mode
1354   :mode "\\.html\\'"
1355   :config
1356   (setq-every! 2
1357     web-mode-code-indent-offset
1358     web-mode-css-indent-offset
1359     web-mode-markup-indent-offset))
1360 #+end_src
1361
1362 *** Emmet mode
1363
1364 #+begin_src emacs-lisp
1365 (use-package emmet-mode
1366   :bind* (("C-)" . emmet-next-edit-point)
1367           ("C-(" . emmet-prev-edit-point))
1368   :config
1369   (unbind-key "C-j" emmet-mode-keymap)
1370   (setq emmet-move-cursor-between-quotes t)
1371   :hook (web-mode css-mode html-mode sgml-mode))
1372 #+end_src
1373
1374 ** Nix
1375
1376 #+begin_src emacs-lisp
1377 (use-package nix-mode
1378   :mode "\\.nix\\'")
1379 #+end_src
1380
1381 ** Java
1382
1383 *** meghanada
1384
1385 #+begin_src emacs-lisp :tangle yes
1386 (use-package meghanada
1387   :bind
1388   (:map meghanada-mode-map
1389         (("C-M-o" . meghanada-optimize-import)
1390          ("C-M-t" . meghanada-import-all)))
1391   :hook (java-mode . meghanada-mode))
1392 #+end_src
1393
1394 *** lsp-java
1395
1396 #+begin_src emacs-lisp :tangle no
1397 (use-package treemacs)
1398
1399 (use-package yasnippet
1400   :config
1401   ;; (yas-global-mode)
1402   )
1403
1404 (use-package lsp-mode
1405   :init (setq lsp-eldoc-render-all nil
1406               lsp-highlight-symbol-at-point nil)
1407   )
1408
1409 (use-package hydra)
1410
1411 (use-package company-lsp
1412   :after  company
1413   :config
1414   (setq company-lsp-cache-candidates t
1415         company-lsp-async t))
1416
1417 (use-package lsp-ui
1418   :config
1419   (setq lsp-ui-sideline-update-mode 'point))
1420
1421 (use-package lsp-java
1422   :config
1423   (add-hook 'java-mode-hook
1424             (lambda ()
1425               (setq-local company-backends (list 'company-lsp))))
1426
1427   (add-hook 'java-mode-hook 'lsp-java-enable)
1428   (add-hook 'java-mode-hook 'flycheck-mode)
1429   (add-hook 'java-mode-hook 'company-mode)
1430   (add-hook 'java-mode-hook 'lsp-ui-mode))
1431
1432 (use-package dap-mode
1433   :after lsp-mode
1434   :config
1435   (dap-mode t)
1436   (dap-ui-mode t))
1437
1438 (use-package dap-java
1439   :after (lsp-java))
1440
1441 (use-package lsp-java-treemacs
1442   :after (treemacs))
1443 #+end_src
1444
1445 * Emacs Enhancements
1446
1447 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1448
1449 #+begin_quote
1450 Emacs package that displays available keybindings in popup
1451 #+end_quote
1452
1453 #+begin_src emacs-lisp
1454 (use-package which-key
1455   :defer 1
1456   :config (which-key-mode))
1457 #+end_src
1458
1459 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1460
1461 #+begin_src emacs-lisp
1462 (use-package doom-modeline
1463   :demand t
1464   :config (setq doom-modeline-height 32)
1465   :hook (after-init . doom-modeline-init))
1466 #+end_src
1467
1468 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1469
1470 #+begin_src emacs-lisp
1471 (setq doom-modeline-bar-width 5)
1472 (load-theme 'eink t)
1473 #+end_src
1474
1475 ** [[https://github.com/bbatsov/crux][crux]]
1476
1477 #+begin_src emacs-lisp
1478 (use-package crux
1479   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1480          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1481          ("C-c b K" . crux-kill-other-buffers)
1482          ("C-c f c" . crux-copy-file-preserve-attributes)
1483          ("C-c f D" . crux-delete-file-and-buffer)
1484          ("C-c f R" . crux-rename-file-and-buffer)
1485          ("C-S-j"   . crux-top-join-line)
1486          ("C-c j"   . crux-top-join-line)))
1487 #+end_src
1488
1489 ** [[https://github.com/alezost/mwim.el][mwim]]
1490
1491 #+begin_src emacs-lisp
1492 (use-package mwim
1493   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1494          ("C-e"    . mwim-end-of-code-or-line)
1495          ("<home>" . mwim-beginning-of-line-or-code)
1496          ("<end>"  . mwim-end-of-line-or-code)))
1497 #+end_src
1498
1499 ** projectile
1500
1501 #+begin_src emacs-lisp
1502 (use-package projectile
1503   :defer 5
1504   :bind-keymap ("C-c p" . projectile-command-map)
1505   :config
1506   (projectile-mode)
1507
1508   (defun my-projectile-invalidate-cache (&rest _args)
1509     ;; ignore the args to `magit-checkout'
1510     (projectile-invalidate-cache nil))
1511
1512   (eval-after-load 'magit-branch
1513     '(progn
1514        (advice-add 'magit-checkout
1515                    :after #'my-projectile-invalidate-cache)
1516        (advice-add 'magit-branch-and-checkout
1517                    :after #'my-projectile-invalidate-cache))))
1518 #+end_src
1519
1520 ** [[https://github.com/Wilfred/helpful][helpful]]
1521
1522 #+begin_src emacs-lisp
1523 (use-package helpful
1524   :bind
1525   (("C-h f"   . helpful-callable)
1526    ("C-h v"   . helpful-variable)
1527    ("C-h k"   . helpful-key)
1528    ("C-c C-d" . helpful-at-point)
1529    ("C-h F"   . helpful-function)
1530    ("C-h C"   . helpful-command)))
1531 #+end_src
1532
1533 ** [[https://github.com/kyagi/shell-pop-el][shell-pop]]
1534
1535 #+begin_src emacs-lisp
1536 (use-package shell-pop
1537   :custom
1538   (shell-pop-universal-key "C-c e")
1539   (shell-pop-shell-type '("eshell" "*eshell*" (lambda nil (eshell)))))
1540 #+end_src
1541
1542 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1543
1544 Make =*scratch*= and =*Messages*= unkillable.
1545
1546 #+begin_src emacs-lisp
1547 (use-package unkillable-scratch
1548   :config
1549   (unkillable-scratch 1)
1550   :custom
1551   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1552 #+end_src
1553
1554 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1555
1556 #+begin_example
1557 ,----
1558 | make pretty boxed quotes like this
1559 `----
1560 #+end_example
1561
1562 #+begin_src emacs-lisp
1563 (use-package boxquote
1564   :bind
1565   (:prefix-map amin--boxquote-prefix-map
1566    :prefix "C-c q"
1567    ("b"   . boxquote-buffer)
1568    ("B"   . boxquote-insert-buffer)
1569    ("d"   . boxquote-defun)
1570    ("F"   . boxquote-insert-file)
1571    ("hf"  . boxquote-describe-function)
1572    ("hk"  . boxquote-describe-key)
1573    ("hv"  . boxquote-describe-variable)
1574    ("hw"  . boxquote-where-is)
1575    ("k"   . boxquote-kill)
1576    ("p"   . boxquote-paragraph)
1577    ("q"   . boxquote-boxquote)
1578    ("r"   . boxquote-region)
1579    ("s"   . boxquote-shell-command)
1580    ("t"   . boxquote-text)
1581    ("T"   . boxquote-title)
1582    ("u"   . boxquote-unbox)
1583    ("U"   . boxquote-unbox-region)
1584    ("y"   . boxquote-yank)
1585    ("M-q" . boxquote-fill-paragraph)
1586    ("M-w" . boxquote-kill-ring-save)))
1587 #+end_src
1588
1589 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1590
1591 ** [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]
1592
1593 #+begin_src emacs-lisp
1594 (use-package highlight-indent-guides
1595   :demand t
1596   :hook ((prog-mode . highlight-indent-guides-mode)
1597          ;; (org-mode  . highlight-indent-guides-mode)
1598          )
1599   :config
1600   (setq highlight-indent-guides-character ?\|)
1601   (setq highlight-indent-guides-auto-enabled nil)
1602   (setq highlight-indent-guides-method 'character)
1603   (setq highlight-indent-guides-responsive 'top)
1604   (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
1605   (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
1606 #+end_src
1607
1608 ** pdf-tools
1609
1610 #+begin_src emacs-lisp
1611 (use-package pdf-tools
1612   :magic ("%PDF" . pdf-view-mode)
1613   :config (pdf-tools-install)
1614   :bind
1615   (:map pdf-view-mode-map
1616         ("C-s" . isearch-forward)
1617         ("C-r" . isearch-backward)
1618         ("j"   . pdf-view-next-line-or-next-page)
1619         ("k"   . pdf-view-previous-line-or-previous-page)))
1620 #+end_src
1621
1622 ** anzu
1623
1624 #+begin_src emacs-lisp
1625 (use-package anzu)
1626 #+end_src
1627
1628 ** typo.el
1629
1630 #+begin_src emacs-lisp
1631 (use-package typo
1632   :config
1633   (typo-global-mode 1)
1634   :hook (text-mode . typo-mode))
1635 #+end_src
1636
1637 * Email
1638
1639 #+begin_src emacs-lisp
1640 (defvar amin-maildir (expand-file-name "~/mail/"))
1641 (after! recentf
1642   (add-to-list 'recentf-exclude amin-maildir))
1643 #+end_src
1644
1645 ** sendmail
1646
1647 #+begin_src emacs-lisp
1648 (use-package sendmail
1649   :config
1650   (setq sendmail-program "/usr/bin/msmtp"
1651         ;; message-sendmail-extra-arguments '("-v" "-d")
1652         mail-specify-envelope-from t
1653         mail-envelope-from 'header))
1654 #+end_src
1655
1656 ** message
1657
1658 #+begin_src emacs-lisp
1659 (use-package message
1660   :config
1661   (setq message-kill-buffer-on-exit t
1662         message-send-mail-function 'message-send-mail-with-sendmail
1663         message-sendmail-envelope-from 'header
1664         ;; message-directory "drafts"
1665         message-user-fqdn "aminb.org")
1666   ;; (add-hook 'message-mode-hook 'electric-quote-local-mode)
1667   (add-hook 'message-mode-hook
1668             (lambda () (setq fill-column 65
1669                         message-fill-column 65)))
1670   (add-hook 'message-mode-hook
1671             #'flyspell-mode)
1672   ;; (add-hook 'message-setup-hook
1673   ;;           #'mml-secure-message-sign-pgpmime)
1674   :custom-face
1675   (message-header-subject ((t (:foreground "navy blue" :weight semi-bold))))
1676   (message-header-to ((t (:foreground "MidnightBlue" :weight semi-bold)))))
1677
1678 (after! mml-sec
1679   (setq mml-secure-openpgp-encrypt-to-self t
1680         mml-secure-openpgp-sign-with-sender t))
1681 #+end_src
1682
1683 ** [[https://notmuchmail.org][notmuch]]
1684
1685 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1686
1687 #+begin_src emacs-lisp
1688 (defun amin/notmuch ()
1689   "Delete other windows, then launch `notmuch'."
1690   (interactive
1691    (when (equal current-prefix-arg nil)
1692      (delete-other-windows)))
1693   (notmuch))
1694
1695 (use-package notmuch
1696   :commands notmuch
1697   :bind ("C-c n" . amin/notmuch)
1698   :custom (notmuch-always-prompt-for-sender t)
1699   :config
1700   (setq notmuch-hello-sections
1701         '(notmuch-hello-insert-header
1702           notmuch-hello-insert-saved-searches
1703           ;; notmuch-hello-insert-search
1704           notmuch-hello-insert-alltags)
1705         notmuch-search-oldest-first nil
1706         notmuch-show-all-tags-list t
1707         notmuch-message-headers  ; see bug follow-up above
1708         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1709         notmuch-hello-thousands-separator ","
1710         notmuch-fcc-dirs
1711         '(("amin@aminb.org"        . "amin/Sent")
1712           ("bandali@gnu.org"       . "gnu/Sent")
1713           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1714           ("mab@gnu.org"           . "gnu/Sent")
1715           ("amin@gnu.org"          . "gnu/Sent")
1716           ("aminb@gnu.org"         . "gnu/Sent")
1717           (".*"                    . "sent"))
1718         notmuch-search-result-format
1719         '(("date"    . "%12s ")
1720           ("count"   . "%-7s ")
1721           ("authors" . "%-40s ")
1722           ("subject" . "%s ")
1723           ("tags"    . "(%s)"))
1724         notmuch-saved-searches
1725         '((:name "inbox"     :query "tag:inbox"     :key "i")
1726           (:name "unread"    :query "tag:unread"    :key "u")
1727           (:name "latest"    :query "tag:latest"    :key "l")
1728           (:name "encrypted" :query "tag:encrypted" :key "e")
1729           (:name "flagged"   :query "tag:flagged"   :key "f")
1730           (:name "sent"      :query "tag:sent"      :key "s")
1731           (:name "drafts"    :query "tag:draft"     :key "d")
1732           (:name "all mail"  :query "*"             :key "a")))
1733   ;; (add-hook 'visual-fill-column-mode-hook
1734   ;;           (lambda ()
1735   ;;             (when (string= major-mode 'notmuch-message-mode)
1736   ;;               (setq visual-fill-column-width 70))))
1737   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1738   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1739   ;;             :override #'kill-this-buffer)
1740   :hook (notmuch-message-mode . doom-modeline-set-special-modeline)
1741   :bind
1742   (:map notmuch-hello-mode-map
1743         ("u" . (lambda ()
1744                  "Search for `unread'-tagged messages"
1745                  (interactive)
1746                  (notmuch-hello-search "tag:unread")))
1747         ("i" . (lambda ()
1748                  "Search for `inbox'-tagged messages"
1749                  (interactive)
1750                  (notmuch-hello-search "tag:inbox")))
1751         ("l" . (lambda ()
1752                  "Search for `latest'-tagged messages"
1753                  (interactive)
1754                  (notmuch-hello-search "tag:latest")))
1755         ("e" . (lambda ()
1756                  "Search for `encrypted'-tagged messages"
1757                  (interactive)
1758                  (notmuch-hello-search "tag:encrypted"))))
1759   (:map notmuch-search-mode-map
1760         ("k" . (lambda ()
1761                  "Mark message read"
1762                  (interactive)
1763                  (notmuch-search-tag '("-unread"))
1764                  ;; (notmuch-search-archive-thread)
1765                  (notmuch-search-next-thread)))
1766         ("u" . (lambda ()
1767                  "Mark message unread"
1768                  (interactive)
1769                  (notmuch-search-tag '("+unread"))
1770                  (notmuch-search-next-thread)))
1771         ("K" . (lambda ()
1772                  "Mark message deleted"
1773                  (interactive)
1774                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1775                  (notmuch-search-next-thread)))
1776         ("S" . (lambda ()
1777                  "Mark message as spam"
1778                  (interactive)
1779                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1780                  (notmuch-search-next-thread))))
1781   (:map notmuch-tree-mode-map
1782         ("k" . (lambda ()
1783                  "Mark message read"
1784                  (interactive)
1785                  (notmuch-tree-tag '("-unread"))
1786                  ;; (notmuch-tree-archive-thread)
1787                  (notmuch-tree-next-message)))
1788         ("u" . (lambda ()
1789                  "Mark message unread"
1790                  (interactive)
1791                  (notmuch-tree-tag '("+unread"))
1792                  (notmuch-tree-next-message)))
1793         ("K" . (lambda ()
1794                  "Mark message deleted"
1795                  (interactive)
1796                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
1797                  (notmuch-tree-next-message)))
1798         ("S" . (lambda ()
1799                  "Mark message as spam"
1800                  (interactive)
1801                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1802                  (notmuch-tree-next-message))))
1803   :custom-face
1804   (notmuch-search-unread-face ((t (:weight semi-bold))))
1805   (notmuch-tag-face ((t (:foreground "navy blue" :weight semi-bold)))))
1806
1807 (use-package counsel-notmuch
1808   :bind ("C-c s m" . counsel-notmuch))
1809
1810 (after! notmuch-crypto
1811   (setq notmuch-crypto-process-mime t))
1812 #+end_src
1813
1814 ** supercite
1815
1816 #+begin_src emacs-lisp :tangle no
1817 (use-package supercite
1818   :commands sc-cite-original
1819   :init
1820   (add-hook 'mail-citation-hook 'sc-cite-original)
1821
1822   (defun sc-remove-existing-signature ()
1823     (save-excursion
1824       (goto-char (region-beginning))
1825       (when (re-search-forward message-signature-separator (region-end) t)
1826         (delete-region (match-beginning 0) (region-end)))))
1827
1828   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1829
1830   (defun sc-remove-if-not-mailing-list ()
1831     (unless (assoc "list-id" sc-mail-info)
1832       (setq attribution sc-default-attribution
1833             citation (concat sc-citation-delimiter
1834                              sc-citation-separator))))
1835
1836   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1837
1838   :config
1839   (defun sc-fill-if-different (&optional prefix)
1840     "Fill the region bounded by `sc-fill-begin' and point.
1841 Only fill if optional PREFIX is different than
1842 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1843 fill region.  If PREFIX is not supplied, initialize fill
1844 variables.  This is useful for a regi `begin' frame-entry."
1845     (if (not prefix)
1846         (setq sc-fill-line-prefix ""
1847               sc-fill-begin (line-beginning-position))
1848       (if (and sc-auto-fill-region-p
1849                (not (string= prefix sc-fill-line-prefix)))
1850           (let ((fill-prefix sc-fill-line-prefix))
1851             (unless (or (string= fill-prefix "")
1852                         (save-excursion
1853                           (goto-char sc-fill-begin)
1854                           (or (looking-at ">+  +")
1855                               (< (length
1856                                   (buffer-substring (point)
1857                                                     (line-end-position)))
1858                                  65))))
1859               (fill-region sc-fill-begin (line-beginning-position)))
1860             (setq sc-fill-line-prefix prefix
1861                   sc-fill-begin (line-beginning-position)))))
1862 nil))
1863 #+end_src
1864
1865 * Blogging
1866 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1867
1868 #+begin_src emacs-lisp
1869 (use-package ox-hugo
1870   :after ox)
1871
1872 (use-package ox-hugo-auto-export
1873   :load-path "lib/ox-hugo")
1874 #+end_src
1875
1876 * Post initialization
1877 :PROPERTIES:
1878 :CUSTOM_ID: post-initialization
1879 :END:
1880
1881 Display how long it took to load the init file.
1882
1883 #+begin_src emacs-lisp
1884 (message "Loading %s...done (%.3fs)" user-init-file
1885          (float-time (time-subtract (current-time)
1886                                     amin--before-user-init-time)))
1887 #+end_src
1888
1889 * Footer
1890 :PROPERTIES:
1891 :CUSTOM_ID: footer
1892 :END:
1893
1894 #+begin_src emacs-lisp :comments none
1895 ;;; init.el ends here
1896 #+end_src
1897
1898 * COMMENT Local Variables                                           :ARCHIVE:
1899 # Local Variables:
1900 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
1901 # End: