git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#borg-essentials][Borg's =layer/essentials=]]
  58 - [[#editing][Editing]]
  59 - [[#syntax-spell-checking][Syntax and spell checking]]
  60 - [[#programming-modes][Programming modes]]
  61 - [[#emacs-enhancements][Emacs enhancements]]
  62 - [[#email][Email]]
  63 - [[#blogging][Blogging]]
  64 - [[#post-initialization][Post initialization]]
  65 - [[#footer][Footer]]
  66
  67 * Header
  68 :PROPERTIES:
  69 :CUSTOM_ID: header
  70 :END:
  71
  72 ** First line
  73
  74 #+begin_src emacs-lisp :comments none
  75 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t; eval: (view-mode 1) -*-
  76 #+end_src
  77
  78 Enable =view-mode=, which both makes the file read-only (as a reminder
  79 that =init.el= is an auto-generated file, not supposed to be edited),
  80 and provides some convenient key bindings for browsing through the
  81 file.
  82
  83 ** License
  84
  85 #+begin_src emacs-lisp :comments none
  86 ;; Copyright (C) 2018  Amin Bandali <bandali@gnu.org>
  87
  88 ;; This program is free software: you can redistribute it and/or modify
  89 ;; it under the terms of the GNU General Public License as published by
  90 ;; the Free Software Foundation, either version 3 of the License, or
  91 ;; (at your option) any later version.
  92
  93 ;; This program is distributed in the hope that it will be useful,
  94 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  95 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  96 ;; GNU General Public License for more details.
  97
  98 ;; You should have received a copy of the GNU General Public License
  99 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
 100 #+end_src
 101
 102 ** Commentary
 103
 104 #+begin_src emacs-lisp :comments none
 105 ;;; Commentary:
 106
 107 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 108 ;; programmer.
 109
 110 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 111 #+end_src
 112
 113 ** Naming conventions
 114
 115 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 116
 117 #+begin_src emacs-lisp :comments none
 118 ;; Naming conventions:
 119 ;;
 120 ;;   amin-...   public variables or non-interactive functions
 121 ;;   amin--...  private anything (non-interactive), not safe for direct use
 122 ;;   amin/...   an interactive function; safe for M-x or keybinding
 123 ;;   amin|...   a hook function
 124 ;;   amin*...   an advising function
 125 ;;   amin@...   a hydra command
 126 ;;   ...!       a macro
 127 #+end_src
 128
 129 * Initial setup
 130 :PROPERTIES:
 131 :CUSTOM_ID: initial-setup
 132 :END:
 133
 134 ** Emacs initialization
 135
 136 I'd like to do a couple of measurements of Emacs' startup time. First,
 137 let's see how long Emacs takes to start up, before even loading
 138 =init.el=, i.e. =user-init-file=:
 139
 140 #+begin_src emacs-lisp
 141 (defvar amin--before-user-init-time (current-time)
 142   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 143 (message "Loading Emacs...done (%.3fs)"
 144          (float-time (time-subtract amin--before-user-init-time
 145                                     before-init-time)))
 146 #+end_src
 147
 148 Also, temporarily increase ~gc-cons-threshhold~ and
 149 ~gc-cons-percentage~ during startup to reduce garbage collection
 150 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 151 startup time as well.
 152
 153 #+begin_src emacs-lisp
 154 (defvar amin--gc-cons-threshold gc-cons-threshold)
 155 (defvar amin--gc-cons-percentage gc-cons-percentage)
 156 (defvar amin--file-name-handler-alist file-name-handler-alist)
 157 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 158       gc-cons-percentage 0.6
 159       file-name-handler-alist nil
 160       ;; sidesteps a bug when profiling with esup
 161       esup-child-profile-require-level 0)
 162 #+end_src
 163
 164 Of course, we'd like to set them back to their defaults once we're
 165 done initializing.
 166
 167 #+begin_src emacs-lisp
 168 (add-hook
 169  'after-init-hook
 170  (lambda ()
 171    (setq gc-cons-threshold amin--gc-cons-threshold
 172          gc-cons-percentage amin--gc-cons-percentage
 173          file-name-handler-alist amin--file-name-handler-alist)))
 174 #+end_src
 175
 176 Increase the number of lines kept in message logs (the =*Messages*=
 177 buffer).
 178
 179 #+begin_src emacs-lisp
 180 (setq message-log-max 20000)
 181 #+end_src
 182
 183 Optionally, we could suppress some byte compiler warnings like below,
 184 but for now I've decided to keep them enabled. See documentation for
 185 ~byte-compile-warnings~ for more details.
 186
 187 #+begin_src emacs-lisp
 188 ;; (setq byte-compile-warnings
 189 ;;       '(not free-vars unresolved noruntime lexical make-local))
 190 #+end_src
 191
 192 ** whoami
 193
 194 #+begin_src emacs-lisp
 195 (setq user-full-name "Amin Bandali"
 196       user-mail-address "amin@aminb.org")
 197 #+end_src
 198
 199 ** Package management
 200
 201 *** No =package.el=
 202
 203 I can do all my package management things with Borg, and don't need
 204 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 205 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 206
 207 #+begin_src emacs-lisp :tangle early-init.el
 208 (setq package-enable-at-startup nil)
 209 #+end_src
 210
 211 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 212 right now), and even when released it'll be long before most distros
 213 ship in their repos, I'll still put the old workaround with the
 214 commented call to ~package-initialize~ here anyway.
 215
 216 #+begin_src emacs-lisp
 217 (setq package-enable-at-startup nil)
 218 ;; (package-initialize)
 219 #+end_src
 220
 221 *** Borg
 222
 223 #+begin_quote
 224 Assimilate Emacs packages as Git submodules
 225 #+end_quote
 226
 227 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 228 short, it creates a git submodule in =lib/= for each package, which
 229 can then be managed with the help of Magit or other tools.
 230
 231 #+begin_src emacs-lisp
 232 (setq user-init-file (or load-file-name buffer-file-name)
 233       user-emacs-directory (file-name-directory user-init-file))
 234 (add-to-list 'load-path
 235              (expand-file-name "lib/borg" user-emacs-directory))
 236 (require 'borg)
 237 (borg-initialize)
 238
 239 ;; (require 'borg-nix-shell)
 240 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 241
 242 (with-eval-after-load 'bind-key
 243   (bind-keys
 244    :package borg
 245    ("C-c b A" . borg-activate)
 246    ("C-c b a" . borg-assimilate)
 247    ("C-c b b" . borg-build)
 248    ("C-c b c" . borg-clone)
 249    ("C-c b r" . borg-remove)))
 250 #+end_src
 251
 252 *** =use-package=
 253
 254 #+begin_quote
 255 A use-package declaration for simplifying your .emacs
 256 #+end_quote
 257
 258 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 259 packages (in our case especially the latter) in a neatly organized way
 260 and without compromising on performance.
 261
 262 #+begin_src emacs-lisp
 263 (require 'use-package)
 264 (if nil  ; set to t when need to debug init
 265     (setq use-package-verbose t
 266           use-package-expand-minimally nil
 267           use-package-compute-statistics t
 268           debug-on-error t)
 269   (setq use-package-verbose nil
 270         use-package-expand-minimally t))
 271 #+end_src
 272
 273 *** Epkg
 274
 275 #+begin_quote
 276 Browse the Emacsmirror package database
 277 #+end_quote
 278
 279 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 280 database, low-level functions for querying the database, and a
 281 =package.el=-like user interface for browsing the available packages.
 282
 283 #+begin_src emacs-lisp
 284 (use-package epkg
 285   :defer t
 286   :bind
 287   (("C-c b d" . epkg-describe-package)
 288    ("C-c b p" . epkg-list-packages)
 289    ("C-c b u" . epkg-update)))
 290 #+end_src
 291
 292 ** No littering in =~/.emacs.d=
 293
 294 #+begin_quote
 295 Help keeping ~/.emacs.d clean
 296 #+end_quote
 297
 298 By default, even for Emacs' built-in packages, the configuration files
 299 and persistent data are all over the place. Use =no-littering= to help
 300 contain the mess.
 301
 302 #+begin_src emacs-lisp
 303 (use-package no-littering
 304   :demand t
 305   :config
 306   (savehist-mode 1)
 307   (add-to-list 'savehist-additional-variables 'kill-ring)
 308   (save-place-mode 1)
 309   (setq auto-save-file-name-transforms
 310         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 311 #+end_src
 312
 313 ** Custom file (=custom.el=)
 314
 315 I'm not planning on using the custom file much, but even so, I
 316 definitely don't want it mixing with =init.el=. So, here; let's give
 317 it it's own file. While at it, treat themes as safe.
 318
 319 #+begin_src emacs-lisp
 320 (use-package custom
 321   :no-require t
 322   :config
 323   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 324   (when (file-exists-p custom-file)
 325     (load custom-file))
 326   (setf custom-safe-themes t))
 327 #+end_src
 328
 329 ** Secrets file
 330
 331 Load the secrets file if it exists, otherwise show a warning.
 332
 333 #+begin_src emacs-lisp
 334 (with-demoted-errors
 335     (load (no-littering-expand-etc-file-name "secrets")))
 336 #+end_src
 337
 338 ** Better =$PATH= handling
 339
 340 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 341 in my shell.
 342
 343 #+begin_src emacs-lisp
 344 (use-package exec-path-from-shell
 345   :defer 1
 346   :init
 347   (setq exec-path-from-shell-check-startup-files nil)
 348   :config
 349   (exec-path-from-shell-initialize)
 350   ;; while we're at it, let's fix access to our running ssh-agent
 351   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 352   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 353 #+end_src
 354
 355 ** COMMENT Only one custom theme at a time
 356
 357 #+begin_src emacs-lisp
 358 (defadvice load-theme (before clear-previous-themes activate)
 359   "Clear existing theme settings instead of layering them"
 360   (mapc #'disable-theme custom-enabled-themes))
 361 #+end_src
 362
 363 ** Server
 364
 365 Start server if not already running. Alternatively, can be done by
 366 issuing =emacs --daemon= in the terminal, which can be automated with
 367 a systemd service or using =brew services start emacs= on macOS. I use
 368 Emacs as my window manager (via EXWM), so I always start Emacs on
 369 login; so starting the server from inside Emacs is good enough for me.
 370
 371 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 372
 373 #+begin_src emacs-lisp
 374 (use-package server
 375   :defer 1
 376   :config (or (server-running-p) (server-mode)))
 377 #+end_src
 378
 379 ** COMMENT Unicode support
 380
 381 Font stack with better unicode support, around =Ubuntu Mono= and
 382 =Hack=.
 383
 384 #+begin_src emacs-lisp
 385 (dolist (ft (fontset-list))
 386   (set-fontset-font
 387    ft
 388    'unicode
 389    (font-spec :name "Source Code Pro" :size 14))
 390   (set-fontset-font
 391    ft
 392    'unicode
 393    (font-spec :name "DejaVu Sans Mono")
 394    nil
 395    'append)
 396   ;; (set-fontset-font
 397   ;;  ft
 398   ;;  'unicode
 399   ;;  (font-spec
 400   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 401   ;;  nil
 402   ;;  'append)
 403   ;; (set-fontset-font
 404   ;;  ft
 405   ;;  #x2115  ; ℕ
 406   ;;  (font-spec :name "DejaVu Sans Mono")
 407   ;;  nil
 408   ;;  'append)
 409   (set-fontset-font
 410    ft
 411    (cons ?Α ?ω)
 412    (font-spec :name "DejaVu Sans Mono" :size 14)
 413    nil
 414    'prepend))
 415 #+end_src
 416
 417 ** Gentler font resizing
 418
 419 #+begin_src emacs-lisp
 420 (setq text-scale-mode-step 1.05)
 421 #+end_src
 422
 423 ** Focus follows mouse
 424
 425 I’d like focus to follow the mouse when I move the cursor from one
 426 window to the next.
 427
 428 #+begin_src emacs-lisp
 429 (setq mouse-autoselect-window t)
 430 #+end_src
 431
 432 Let’s define a function to conveniently disable this for certain
 433 buffers and/or modes.
 434
 435 #+begin_src emacs-lisp
 436 (defun amin--no-mouse-autoselect-window ()
 437   (make-local-variable 'mouse-autoselect-window)
 438   (setq mouse-autoselect-window nil))
 439 #+end_src
 440
 441 ** Libraries
 442
 443 #+begin_src emacs-lisp
 444 (require 'cl-lib)
 445 (require 'subr-x)
 446 #+end_src
 447
 448 ** Useful utilities
 449
 450 #+begin_src emacs-lisp
 451 (defun amin-enlist (exp)
 452   "Return EXP wrapped in a list, or as-is if already a list."
 453 (if (listp exp) exp (list exp)))
 454
 455 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 456 (defmacro after! (features &rest body)
 457   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 458 compilation."
 459   (declare (indent defun) (debug t))
 460   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 461                 (dolist (next (amin-enlist features))
 462                   (if (symbolp next)
 463                       (require next nil :no-error)
 464                     (load next :no-message :no-error))))
 465             #'progn
 466           #'with-no-warnings)
 467         (cond ((symbolp features)
 468                `(eval-after-load ',features '(progn ,@body)))
 469               ((and (consp features)
 470                     (memq (car features) '(:or :any)))
 471                `(progn
 472                   ,@(cl-loop for next in (cdr features)
 473                              collect `(after! ,next ,@body))))
 474               ((and (consp features)
 475                     (memq (car features) '(:and :all)))
 476                (dolist (next (cdr features))
 477                  (setq body `(after! ,next ,@body)))
 478                body)
 479               ((listp features)
 480                `(after! (:all ,@features) ,@body)))))
 481 #+end_src
 482
 483 Convenience macro for =setq='ing multiple variables to the same value:
 484
 485 #+begin_src emacs-lisp
 486 (defmacro setq-every! (value &rest vars)
 487   "Set all the variables from VARS to value VALUE."
 488   (declare (indent defun) (debug t))
 489   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 490 #+end_src
 491
 492 * Core
 493 :PROPERTIES:
 494 :CUSTOM_ID: core
 495 :END:
 496
 497 ** Defaults
 498
 499 *** Time and battery in mode-line
 500
 501 Enable displaying time and battery in the mode-line, since I'm not
 502 using the Xfce panel anymore. Also, I don't need to see the load
 503 average on a regular basis, so disable that.
 504
 505 Note: using =i3status= on sway at the moment, so disabling this.
 506
 507 #+begin_src emacs-lisp :tangle no
 508 (use-package time
 509   :init
 510   (setq display-time-default-load-average nil)
 511   :config
 512   (display-time-mode))
 513
 514 (use-package battery
 515   :config
 516   (display-battery-mode))
 517 #+end_src
 518
 519 *** Smaller fringe
 520
 521 Might want to set the fringe to a smaller value, especially if using
 522 EXWM. I'm fine with the default for now.
 523
 524 #+begin_src emacs-lisp
 525 ;; (fringe-mode '(3 . 1))
 526 (fringe-mode nil)
 527 #+end_src
 528
 529 *** Disable disabled commands
 530
 531 Emacs disables some commands by default that could persumably be
 532 confusing for novice users. Let's disable that.
 533
 534 #+begin_src emacs-lisp
 535 (setq disabled-command-function nil)
 536 #+end_src
 537
 538 *** Kill-ring
 539
 540 Save what I copy into clipboard from other applications into Emacs'
 541 kill-ring, which would allow me to still be able to easily access it
 542 in case I kill (cut or copy) something else inside Emacs before
 543 yanking (pasting) what I'd originally intended to.
 544
 545 #+begin_src emacs-lisp
 546 (setq save-interprogram-paste-before-kill t)
 547 #+end_src
 548
 549 *** Minibuffer
 550
 551 #+begin_src emacs-lisp
 552 (setq enable-recursive-minibuffers t
 553       resize-mini-windows t)
 554 #+end_src
 555
 556 *** Lazy-person-friendly yes/no prompts
 557
 558 Lazy people would prefer to type fewer keystrokes, especially for yes
 559 or no questions. I'm lazy.
 560
 561 #+begin_src emacs-lisp
 562 (defalias 'yes-or-no-p #'y-or-n-p)
 563 #+end_src
 564
 565 *** Startup screen and =*scratch*=
 566
 567 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 568 startup buffer.
 569
 570 #+begin_src emacs-lisp
 571 (setq initial-buffer-choice t)
 572 #+end_src
 573
 574 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 575 need the default hint.
 576
 577 #+begin_src emacs-lisp
 578 (setq initial-scratch-message nil)
 579 #+end_src
 580
 581 Also, let's use Text mode as the major mode, in case I want to
 582 customize it (=*scratch*='s default major mode, Fundamental mode,
 583 can't really be customized).
 584
 585 #+begin_src emacs-lisp
 586 (setq initial-major-mode 'text-mode)
 587 #+end_src
 588
 589 Inhibit the buffer list when more than 2 files are loaded.
 590
 591 #+begin_src emacs-lisp
 592 (setq inhibit-startup-buffer-menu t)
 593 #+end_src
 594
 595 I don't really need to see the startup screen or echo area message
 596 either.
 597
 598 #+begin_src emacs-lisp
 599 (advice-add #'display-startup-echo-area-message :override #'ignore)
 600 (setq inhibit-startup-screen t
 601       inhibit-startup-echo-area-message user-login-name)
 602 #+end_src
 603
 604 *** More useful frame titles
 605
 606 Show either the file name or the buffer name (in case the buffer isn't
 607 visiting a file). Borrowed from Emacs Prelude.
 608
 609 #+begin_src emacs-lisp
 610 (setq frame-title-format
 611       '("" invocation-name " - "
 612         (:eval (if (buffer-file-name)
 613                    (abbreviate-file-name (buffer-file-name))
 614                  "%b"))))
 615 #+end_src
 616
 617 *** Backups
 618
 619 Emacs' default backup settings aren't that great. Let's use more
 620 sensible options. See documentation for the ~make-backup-file~
 621 variable.
 622
 623 #+begin_src emacs-lisp
 624 (setq backup-by-copying t
 625       version-control t
 626       delete-old-versions t)
 627 #+end_src
 628
 629 *** Auto revert
 630
 631 Enable automatic reloading of changed buffers and files.
 632
 633 #+begin_src emacs-lisp
 634 (global-auto-revert-mode 1)
 635 (setq auto-revert-verbose nil
 636       global-auto-revert-non-file-buffers nil)
 637 #+end_src
 638
 639 *** Always use space for indentation
 640
 641 #+begin_src emacs-lisp
 642 (setq-default
 643  indent-tabs-mode nil
 644  require-final-newline t
 645  tab-width 4)
 646 #+end_src
 647
 648 *** Winner mode
 649
 650 Enable =winner-mode=.
 651
 652 #+begin_src emacs-lisp
 653 (winner-mode 1)
 654 #+end_src
 655
 656 *** Don’t display =*compilation*= on success
 657
 658 Based on https://stackoverflow.com/a/17788551, with changes to use
 659 =cl-letf= instead of the now obsolete =flet=.
 660
 661 #+begin_src emacs-lisp
 662 (with-eval-after-load 'compile
 663   (defun amin--compilation-finish-function (buffer outstr)
 664     (unless (string-match "finished" outstr)
 665       (switch-to-buffer-other-window buffer))
 666     t)
 667
 668   (setq compilation-finish-functions #'amin--compilation-finish-function)
 669
 670   (require 'cl-macs)
 671
 672   (defadvice compilation-start
 673       (around inhibit-display
 674               (command &optional mode name-function highlight-regexp))
 675     (if (not (string-match "^\\(find\\|grep\\)" command))
 676         (cl-letf (((symbol-function 'display-buffer) #'ignore))
 677           (save-window-excursion ad-do-it))
 678       ad-do-it))
 679   (ad-activate 'compilation-start))
 680 #+end_src
 681
 682 *** Search for non-ASCII characters
 683
 684 I’d like non-ASCII characters such as ‘’“”«»‹›áⓐ𝒶 to be selected when
 685 I search for their ASCII counterpart.  Shoutout to [[http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html][endlessparentheses]]
 686 for this.
 687
 688 #+begin_src emacs-lisp
 689 (setq search-default-mode #'char-fold-to-regexp)
 690
 691 ;; uncomment to extend this behaviour to query-replace
 692 ;; (setq replace-char-fold t)
 693 #+end_src
 694
 695 *** Cursor shape
 696
 697 #+begin_src emacs-lisp
 698 (setq-default cursor-type 'bar)
 699 #+end_src
 700
 701 ** Bindings
 702
 703 #+begin_src emacs-lisp
 704 (bind-keys
 705  ("C-c a i" . ielm)
 706
 707  ("C-c e b" . eval-buffer)
 708  ("C-c e r" . eval-region)
 709
 710  ("C-c F m" . make-frame-command)
 711  ("C-c F d" . delete-frame)
 712  ("C-c F D" . delete-other-frames)
 713
 714  ("C-c o"   . other-window)
 715
 716  ("C-c Q"   . save-buffers-kill-terminal)
 717
 718  ("C-S-h C" . describe-char)
 719  ("C-S-h F" . describe-face)
 720
 721  ("C-x K"   . kill-this-buffer)
 722
 723  ("s-p"     . beginning-of-buffer)
 724  ("s-n"     . end-of-buffer))
 725 #+end_src
 726
 727 ** Packages
 728
 729 The packages in this section are absolutely essential to my everyday
 730 workflow, and they play key roles in how I do my computing. They
 731 immensely enhance the Emacs experience for me; both using Emacs, and
 732 customizing it.
 733
 734 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 735
 736 #+begin_src emacs-lisp
 737 (use-package auto-compile
 738   :demand t
 739   :config
 740   (auto-compile-on-load-mode)
 741   (auto-compile-on-save-mode)
 742   (setq auto-compile-display-buffer               nil
 743         auto-compile-mode-line-counter            t
 744         auto-compile-source-recreate-deletes-dest t
 745         auto-compile-toggle-deletes-nonlib-dest   t
 746         auto-compile-update-autoloads             t)
 747   (add-hook 'auto-compile-inhibit-compile-hook
 748             'auto-compile-inhibit-compile-detached-git-head))
 749 #+end_src
 750
 751 *** [[https://orgmode.org/][Org mode]]
 752
 753 #+begin_quote
 754 Org mode is for keeping notes, maintaining TODO lists, planning
 755 projects, and authoring documents with a fast and effective plain-text
 756 system.
 757 #+end_quote
 758
 759 In short, my favourite way of life.
 760
 761 #+begin_src emacs-lisp
 762 (use-package org
 763   :defer 1
 764   :config
 765   (setq org-src-tab-acts-natively t
 766         org-src-preserve-indentation nil
 767         org-edit-src-content-indentation 0
 768         org-email-link-description-format "Email %c: %s" ; %.30s
 769         org-highlight-latex-and-related '(entities)
 770         org-use-speed-commands t
 771         org-startup-folded 'content
 772         org-catch-invisible-edits 'show-and-error
 773         org-log-done 'time)
 774   (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
 775   (font-lock-add-keywords
 776    'org-mode
 777    '(("[ \t]*\\(#\\+\\(BEGIN\\|END\\|begin\\|end\\)_\\(\\S-+\\)\\)[ \t]*\\([^\n:]*\\)"
 778       (1 '(:foreground "#5a5b5a" :background "#292b2b") t) ; directive
 779       (3 '(:foreground "#81a2be" :background "#292b2b") t) ; kind
 780       (4 '(:foreground "#c5c8c6") t))) ; title
 781    t)
 782   :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
 783   :hook ((org-mode . org-indent-mode)
 784          (org-mode . auto-fill-mode)
 785          (org-mode . flyspell-mode))
 786   :custom
 787   (org-latex-packages-alist '(("" "listings") ("" "color")))
 788   :custom-face
 789   '(org-block-begin-line ((t (:foreground "#5a5b5a" :background "#1d1f21"))))
 790   '(org-block ((t (:background "#1d1f21"))))
 791   '(org-latex-and-related ((t (:foreground "#b294bb")))))
 792
 793 (use-package ox-latex
 794   :after ox
 795   :config
 796   (setq org-latex-listings 'listings
 797         ;; org-latex-prefer-user-labels t
 798         )
 799   (add-to-list 'org-latex-packages-alist '("" "listings"))
 800   (add-to-list 'org-latex-packages-alist '("" "color"))
 801   (add-to-list 'org-latex-classes
 802                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 803                  ("\\section{%s}" . "\\section*{%s}")
 804                  ("\\subsection{%s}" . "\\subsection*{%s}")
 805                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 806                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 807                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 808                t))
 809
 810 (use-package ox-beamer
 811   :after ox)
 812
 813 (use-package orgalist
 814   :after message
 815   :hook (message-mode . orgalist-mode))
 816 #+end_src
 817
 818 **** asynchronous tangle
 819
 820 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 821 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 822 file.
 823
 824 #+begin_src emacs-lisp
 825 (after! org
 826   (defvar amin-show-async-tangle-results nil
 827     "Keep *emacs* async buffers around for later inspection.")
 828
 829   (defvar amin-show-async-tangle-time nil
 830     "Show the time spent tangling the file.")
 831
 832   (defvar amin-async-tangle-post-compile "make ti"
 833     "If non-nil, pass to `compile' after successful tangle.")
 834
 835   (defun amin/async-babel-tangle ()
 836     "Tangle org file asynchronously."
 837     (interactive)
 838     (let* ((file-tangle-start-time (current-time))
 839            (file (buffer-file-name))
 840            (file-nodir (file-name-nondirectory file))
 841            ;; (async-quiet-switch "-q")
 842            )
 843       (async-start
 844        `(lambda ()
 845           (require 'org)
 846           (org-babel-tangle-file ,file))
 847        (unless amin-show-async-tangle-results
 848          `(lambda (result)
 849             (if result
 850                 (progn
 851                   (message "Tangled %s%s"
 852                            ,file-nodir
 853                            (if amin-show-async-tangle-time
 854                                (format " (%.3fs)"
 855                                        (float-time (time-subtract (current-time)
 856                                                                   ',file-tangle-start-time)))
 857                              ""))
 858                   (when amin-async-tangle-post-compile
 859                     (compile amin-async-tangle-post-compile)))
 860               (message "Tangling %s failed" ,file-nodir))))))))
 861
 862 (add-to-list
 863  'safe-local-variable-values
 864  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 865 #+end_src
 866
 867 *** [[https://magit.vc/][Magit]]
 868
 869 #+begin_quote
 870 It's Magit! A Git porcelain inside Emacs.
 871 #+end_quote
 872
 873 Not just how I do git, but /the/ way to do git.
 874
 875 #+begin_src emacs-lisp
 876 (use-package magit
 877   :defer 1
 878   :bind (("C-x g" . magit-status)
 879          ("s-g s" . magit-status)
 880          ("s-g l" . magit-log-buffer-file))
 881   :config
 882   (magit-add-section-hook 'magit-status-sections-hook
 883                           'magit-insert-modules
 884                           'magit-insert-stashes
 885                           'append)
 886   (setq
 887    magit-repository-directories '(("~/.emacs.d/" . 0)
 888                                   ("~/src/git/" . 1)))
 889   (nconc magit-section-initial-visibility-alist
 890          '(([unpulled status] . show)
 891            ([unpushed status] . show)))
 892   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 893 #+end_src
 894
 895 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 896
 897 #+begin_quote
 898 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 899 an overview, and more. Oh, man!
 900 #+end_quote
 901
 902 There's no way I could top that, so I won't attempt to.
 903
 904 **** Ivy
 905
 906 #+begin_src emacs-lisp
 907 (use-package ivy
 908   :defer 1
 909   :bind
 910   (:map ivy-minibuffer-map
 911    ([escape] . keyboard-escape-quit)
 912    ([S-up]   . ivy-previous-history-element)
 913    ([S-down] . ivy-next-history-element)
 914    ("DEL"    . ivy-backward-delete-char))
 915   :config
 916   (setq ivy-wrap t)
 917   (ivy-mode 1)
 918   ;; :custom-face
 919   ;; (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 920   ;; (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 921   ;; (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold))))
 922 )
 923 #+end_src
 924
 925 **** Swiper
 926
 927 #+begin_src emacs-lisp
 928 (use-package swiper
 929   :bind (("C-s"   . swiper)
 930          ("C-r"   . swiper)
 931          ("C-S-s" . isearch-forward)))
 932 #+end_src
 933
 934 **** Counsel
 935
 936 #+begin_src emacs-lisp
 937 (use-package counsel
 938   :defer 1
 939   :bind (([remap execute-extended-command] . counsel-M-x)
 940          ([remap find-file]                . counsel-find-file)
 941          ("s-r"                            . counsel-recentf)
 942          ("C-c x"                          . counsel-M-x)
 943          ("C-c f ."                        . counsel-find-file)
 944          :map minibuffer-local-map
 945          ("C-r" . counsel-minibuffer-history))
 946   :config
 947   (counsel-mode 1)
 948   (defalias 'locate #'counsel-locate))
 949 #+end_src
 950
 951 *** eshell
 952
 953 #+begin_src emacs-lisp
 954 (use-package eshell
 955   :defer 1
 956   :commands eshell
 957   :bind ("C-c a s e" . eshell)
 958   :config
 959   (eval-when-compile (defvar eshell-prompt-regexp))
 960   (defun amin/eshell-quit-or-delete-char (arg)
 961     (interactive "p")
 962     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 963         (eshell-life-is-too-much)
 964       (delete-char arg)))
 965
 966   (defun amin/eshell-clear ()
 967     (interactive)
 968     (let ((inhibit-read-only t))
 969       (erase-buffer))
 970     (eshell-send-input))
 971
 972   (defun amin|eshell-setup ()
 973     (make-local-variable 'company-idle-delay)
 974     (defvar company-idle-delay nil)
 975     (bind-keys :map eshell-mode-map
 976                ("C-d"   . amin/eshell-quit-or-delete-char)
 977                ("C-S-l" . amin/eshell-clear)
 978                ("M-r"   . counsel-esh-history)
 979                ([tab]   . company-complete)))
 980
 981   :hook (eshell-mode . amin|eshell-setup)
 982   :custom
 983   (eshell-hist-ignoredups t)
 984   (eshell-input-filter 'eshell-input-filter-initial-space))
 985 #+end_src
 986
 987 *** Ibuffer
 988
 989 #+begin_src emacs-lisp
 990 (use-package ibuffer
 991   :defer t
 992   :bind
 993   (("C-x C-b" . ibuffer-other-window)
 994    :map ibuffer-mode-map
 995    ("P"   . ibuffer-backward-filter-group)
 996    ("N"   . ibuffer-forward-filter-group)
 997    ("M-p" . ibuffer-do-print)
 998    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 999   :config
1000   ;; Use human readable Size column instead of original one
1001   (define-ibuffer-column size-h
1002     (:name "Size" :inline t)
1003     (cond
1004      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
1005      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
1006      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
1007      (t (format "%8d" (buffer-size)))))
1008   :custom
1009   (ibuffer-saved-filter-groups
1010    '(("default"
1011       ("dired" (mode . dired-mode))
1012       ("org"   (mode . org-mode))
1013       ("gnus"
1014        (or
1015         (mode . gnus-group-mode)
1016         (mode . gnus-summary-mode)
1017         (mode . gnus-article-mode)
1018         ;; not really, but...
1019         (mode . message-mode)))
1020       ("web"
1021        (or
1022         (mode . web-mode)
1023         (mode . css-mode)
1024         (mode . scss-mode)
1025         (mode . js2-mode)))
1026       ("shell"
1027        (or
1028         (mode . eshell-mode)
1029         (mode . shell-mode)
1030         (mode . term-mode)))
1031       ("programming"
1032        (or
1033         (mode . python-mode)
1034         (mode . c-mode)
1035         (mode . c++-mode)
1036         (mode . emacs-lisp-mode)
1037         (mode . scheme-mode)
1038         (mode . haskell-mode)
1039         (mode . lean-mode)))
1040       ("emacs"
1041        (or
1042         (name . "^\\*scratch\\*$")
1043         (name . "^\\*Messages\\*$"))))))
1044   (ibuffer-formats
1045    '((mark modified read-only locked " "
1046            (name 18 18 :left :elide)
1047            " "
1048            (size-h 9 -1 :right)
1049            " "
1050            (mode 16 16 :left :elide)
1051            " " filename-and-process)
1052      (mark " "
1053            (name 16 -1)
1054            " " filename)))
1055   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
1056 #+end_src
1057
1058 *** Outline
1059
1060 #+begin_src emacs-lisp
1061 (use-package outline
1062   :defer t
1063   :hook (prog-mode . outline-minor-mode)
1064   :bind
1065   (:map
1066    outline-minor-mode-map
1067    ("<s-tab>"  . outline-toggle-children)
1068    ("M-p"      . outline-previous-visible-heading)
1069    ("M-n"      . outline-next-visible-heading)
1070    :prefix-map amin--outline-prefix-map
1071    :prefix "s-o"
1072    ("TAB" . outline-toggle-children)
1073    ("a"   . outline-hide-body)
1074    ("H"   . outline-hide-body)
1075    ("S"   . outline-show-all)
1076    ("h"   . outline-hide-subtree)
1077    ("s"   . outline-show-subtree)))
1078 #+end_src
1079
1080 * Borg's =layer/essentials=
1081 :PROPERTIES:
1082 :CUSTOM_ID: borg-essentials
1083 :END:
1084
1085 TODO: break this giant source block down into individual org sections.
1086
1087 #+begin_src emacs-lisp
1088 (use-package dash
1089   :config (dash-enable-font-lock))
1090
1091 (use-package diff-hl
1092   :config
1093   (setq diff-hl-draw-borders nil)
1094   (global-diff-hl-mode)
1095   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
1096
1097 (use-package dired
1098   :defer t
1099   :config (setq dired-listing-switches "-alh"))
1100
1101 (use-package eldoc
1102   :when (version< "25" emacs-version)
1103   :config (global-eldoc-mode))
1104
1105 (use-package help
1106   :defer t
1107   :config
1108   (temp-buffer-resize-mode)
1109   (setq help-window-select t))
1110
1111 (progn ;    `isearch'
1112   (setq isearch-allow-scroll t))
1113
1114 (use-package lisp-mode
1115   :config
1116   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1117   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1118   (defun indent-spaces-mode ()
1119     (setq indent-tabs-mode nil))
1120   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1121
1122 (use-package man
1123   :defer t
1124   :config (setq Man-width 80))
1125
1126 (use-package paren
1127   :config (show-paren-mode))
1128
1129 (use-package prog-mode
1130   :config (global-prettify-symbols-mode)
1131   (defun indicate-buffer-boundaries-left ()
1132     (setq indicate-buffer-boundaries 'left))
1133   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1134
1135 (use-package recentf
1136   :defer 0.5
1137   :config
1138   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1139   (setq recentf-max-saved-items 40))
1140
1141 (use-package savehist
1142   :config (savehist-mode))
1143
1144 (use-package saveplace
1145   :when (version< "25" emacs-version)
1146   :config (save-place-mode))
1147
1148 (use-package simple
1149   :config (column-number-mode))
1150
1151 (progn ;    `text-mode'
1152   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left)
1153   (add-hook 'text-mode-hook #'abbrev-mode))
1154
1155 (use-package tramp
1156   :defer t
1157   :config
1158   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1159   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1160   (add-to-list 'tramp-default-proxies-alist
1161                (list (regexp-quote (system-name)) nil nil)))
1162
1163 #+end_src
1164
1165 * Editing
1166 :PROPERTIES:
1167 :CUSTOM_ID: editing
1168 :END:
1169
1170 ** Company
1171
1172 #+begin_src emacs-lisp
1173 (use-package company
1174   :defer 1
1175   :bind
1176   (:map company-active-map
1177         ([tab]    . company-complete-common-or-cycle)
1178         ([escape] . company-abort))
1179   :custom
1180   (company-minimum-prefix-length 1)
1181   (company-selection-wrap-around t)
1182   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1183   (company-dabbrev-downcase nil)
1184   (company-dabbrev-ignore-case nil)
1185   :config
1186   (global-company-mode t))
1187 #+end_src
1188
1189 * Syntax and spell checking
1190 :PROPERTIES:
1191 :CUSTOM_ID: syntax-spell-checking
1192 :END:
1193
1194 #+begin_src emacs-lisp
1195 (use-package flycheck
1196   :defer 3
1197   :hook (prog-mode . flycheck-mode)
1198   :bind
1199   (:map flycheck-mode-map
1200         ("M-P" . flycheck-previous-error)
1201         ("M-N" . flycheck-next-error))
1202   :config
1203   ;; Use the load-path from running Emacs when checking elisp files
1204   (setq flycheck-emacs-lisp-load-path 'inherit)
1205
1206   ;; Only flycheck when I actually save the buffer
1207   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1208
1209 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1210 (use-package ispell
1211   :defer 3
1212   :config
1213   ;; ’ can be part of a word
1214   (setq ispell-local-dictionary-alist
1215         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1216                "['\x2019]" nil ("-B") nil utf-8)))
1217   ;; don't send ’ to the subprocess
1218   (defun endless/replace-apostrophe (args)
1219     (cons (replace-regexp-in-string
1220            "’" "'" (car args))
1221           (cdr args)))
1222   (advice-add #'ispell-send-string :filter-args
1223               #'endless/replace-apostrophe)
1224
1225   ;; convert ' back to ’ from the subprocess
1226   (defun endless/replace-quote (args)
1227     (if (not (derived-mode-p 'org-mode))
1228         args
1229       (cons (replace-regexp-in-string
1230              "'" "’" (car args))
1231             (cdr args))))
1232   (advice-add #'ispell-parse-output :filter-args
1233               #'endless/replace-quote))
1234 #+end_src
1235
1236 * Programming modes
1237 :PROPERTIES:
1238 :CUSTOM_ID: programming-modes
1239 :END:
1240
1241 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1242
1243 #+begin_src emacs-lisp
1244 (use-package alloy-mode
1245   :defer t
1246   :config (setq alloy-basic-offset 2))
1247 #+end_src
1248
1249 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1250
1251 #+begin_src emacs-lisp
1252 (use-package proof-site  ; Proof General
1253   :defer t
1254   :load-path "lib/proof-site/generic/")
1255 #+end_src
1256
1257 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1258
1259 #+begin_src emacs-lisp
1260 (eval-when-compile (defvar lean-mode-map))
1261 (use-package lean-mode
1262   :defer 1
1263   :bind (:map lean-mode-map
1264               ("S-SPC" . company-complete))
1265   :config
1266   (require 'lean-input)
1267   (setq default-input-method "Lean"
1268         lean-input-tweak-all '(lean-input-compose
1269                                (lean-input-prepend "/")
1270                                (lean-input-nonempty))
1271         lean-input-user-translations '(("/" "/")))
1272   (lean-input-setup))
1273   #+end_src
1274
1275 ** Haskell
1276
1277 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1278
1279 #+begin_src emacs-lisp
1280 (use-package haskell-mode
1281   :defer t
1282   :config
1283   (setq haskell-indentation-layout-offset 4
1284         haskell-indentation-left-offset 4
1285         flycheck-checker 'haskell-hlint
1286         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1287 #+end_src
1288
1289 *** [[https://github.com/jyp/dante][dante]]
1290
1291 #+begin_src emacs-lisp
1292 (use-package dante
1293   :after haskell-mode
1294   :commands dante-mode
1295   :hook (haskell-mode . dante-mode))
1296 #+end_src
1297
1298 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1299
1300 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1301 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1302
1303 #+begin_src emacs-lisp
1304 (use-package hlint-refactor
1305   :after haskell-mode
1306   :bind (:map hlint-refactor-mode-map
1307               ("C-c l b" . hlint-refactor-refactor-buffer)
1308               ("C-c l r" . hlint-refactor-refactor-at-point))
1309   :hook (haskell-mode . hlint-refactor-mode))
1310 #+end_src
1311
1312 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1313
1314 #+begin_src emacs-lisp
1315 (use-package flycheck-haskell
1316   :after haskell-mode)
1317 #+end_src
1318
1319 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1320 :PROPERTIES:
1321 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1322 :END:
1323
1324 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1325 instead.
1326
1327 #+begin_src emacs-lisp :tangle no
1328 ;;; hs-lint.el --- minor mode for HLint code checking
1329
1330 ;; Copyright 2009 (C) Alex Ott
1331 ;;
1332 ;; Author: Alex Ott <alexott@gmail.com>
1333 ;; Keywords: haskell, lint, HLint
1334 ;; Requirements:
1335 ;; Status: distributed under terms of GPL2 or above
1336
1337 ;; Typical message from HLint looks like:
1338 ;;
1339 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1340 ;; Found:
1341 ;;   count1 p l = length (filter p l)
1342 ;; Why not:
1343 ;;   count1 p = length . filter p
1344
1345
1346 (require 'compile)
1347
1348 (defgroup hs-lint nil
1349   "Run HLint as inferior of Emacs, parse error messages."
1350   :group 'tools
1351   :group 'haskell)
1352
1353 (defcustom hs-lint-command "hlint"
1354   "The default hs-lint command for \\[hlint]."
1355   :type 'string
1356   :group 'hs-lint)
1357
1358 (defcustom hs-lint-save-files t
1359   "Save modified files when run HLint or no (ask user)"
1360   :type 'boolean
1361   :group 'hs-lint)
1362
1363 (defcustom hs-lint-replace-with-suggestions nil
1364   "Replace user's code with suggested replacements"
1365   :type 'boolean
1366   :group 'hs-lint)
1367
1368 (defcustom hs-lint-replace-without-ask nil
1369   "Replace user's code with suggested replacements automatically"
1370   :type 'boolean
1371   :group 'hs-lint)
1372
1373 (defun hs-lint-process-setup ()
1374   "Setup compilation variables and buffer for `hlint'."
1375   (run-hooks 'hs-lint-setup-hook))
1376
1377 ;; regex for replace suggestions
1378 ;;
1379 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1380 ;; Found:
1381 ;; \s +\(.*\)
1382 ;; Why not:
1383 ;; \s +\(.*\)
1384
1385 (defvar hs-lint-regex
1386   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1387   "Regex for HLint messages")
1388
1389 (defun make-short-string (str maxlen)
1390   (if (< (length str) maxlen)
1391       str
1392     (concat (substring str 0 (- maxlen 3)) "...")))
1393
1394 (defun hs-lint-replace-suggestions ()
1395   "Perform actual replacement of suggestions"
1396   (goto-char (point-min))
1397   (while (re-search-forward hs-lint-regex nil t)
1398     (let* ((fname (match-string 1))
1399           (fline (string-to-number (match-string 2)))
1400           (old-code (match-string 4))
1401           (new-code (match-string 5))
1402           (msg (concat "Replace '" (make-short-string old-code 30)
1403                        "' with '" (make-short-string new-code 30) "'"))
1404           (bline 0)
1405           (eline 0)
1406           (spos 0)
1407           (new-old-code ""))
1408       (save-excursion
1409         (switch-to-buffer (get-file-buffer fname))
1410         (goto-char (point-min))
1411         (forward-line (1- fline))
1412         (beginning-of-line)
1413         (setf bline (point))
1414         (when (or hs-lint-replace-without-ask
1415                   (yes-or-no-p msg))
1416           (end-of-line)
1417           (setf eline (point))
1418           (beginning-of-line)
1419           (setf old-code (regexp-quote old-code))
1420           (while (string-match "\\\\ " old-code spos)
1421             (setf new-old-code (concat new-old-code
1422                                  (substring old-code spos (match-beginning 0))
1423                                  "\\ *"))
1424             (setf spos (match-end 0)))
1425           (setf new-old-code (concat new-old-code (substring old-code spos)))
1426           (remove-text-properties bline eline '(composition nil))
1427           (when (re-search-forward new-old-code eline t)
1428             (replace-match new-code nil t)))))))
1429
1430 (defun hs-lint-finish-hook (buf msg)
1431   "Function, that is executed at the end of HLint execution"
1432   (if hs-lint-replace-with-suggestions
1433       (hs-lint-replace-suggestions)
1434       (next-error 1 t)))
1435
1436 (define-compilation-mode hs-lint-mode "HLint"
1437   "Mode for check Haskell source code."
1438   (set (make-local-variable 'compilation-process-setup-function)
1439        'hs-lint-process-setup)
1440   (set (make-local-variable 'compilation-disable-input) t)
1441   (set (make-local-variable 'compilation-scroll-output) nil)
1442   (set (make-local-variable 'compilation-finish-functions)
1443        (list 'hs-lint-finish-hook))
1444   )
1445
1446 (defun hs-lint ()
1447   "Run HLint for current buffer with haskell source"
1448   (interactive)
1449   (save-some-buffers hs-lint-save-files)
1450   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1451                      'hs-lint-mode))
1452
1453 (provide 'hs-lint)
1454 ;;; hs-lint.el ends here
1455 #+end_src
1456
1457 #+begin_src emacs-lisp :tangle no
1458 (use-package hs-lint
1459   :load-path "lisp/"
1460   :bind (:map haskell-mode-map
1461               ("C-c l l" . hs-lint)))
1462 #+end_src
1463
1464 ** Web dev
1465
1466 *** SGML and HTML
1467
1468 #+begin_src emacs-lisp
1469 (use-package sgml-mode
1470   :defer t
1471   :config
1472   (setq sgml-basic-offset 2))
1473 #+end_src
1474
1475 *** CSS and SCSS
1476
1477 #+begin_src emacs-lisp
1478 (use-package css-mode
1479   :defer t
1480   :config
1481   (setq css-indent-offset 2))
1482 #+end_src
1483
1484 *** Web mode
1485
1486 #+begin_src emacs-lisp
1487 (use-package web-mode
1488   :defer t
1489   :mode "\\.html\\'"
1490   :config
1491   (setq-every! 2
1492     web-mode-code-indent-offset
1493     web-mode-css-indent-offset
1494     web-mode-markup-indent-offset))
1495 #+end_src
1496
1497 *** Emmet mode
1498
1499 #+begin_src emacs-lisp
1500 (use-package emmet-mode
1501   :after (:any web-mode css-mode sgml-mode)
1502   :bind* (("C-)" . emmet-next-edit-point)
1503           ("C-(" . emmet-prev-edit-point))
1504   :config
1505   (unbind-key "C-j" emmet-mode-keymap)
1506   (setq emmet-move-cursor-between-quotes t)
1507   :hook (web-mode css-mode html-mode sgml-mode))
1508 #+end_src
1509
1510 ** COMMENT Java
1511
1512 *** meghanada
1513
1514 #+begin_src emacs-lisp
1515 (use-package meghanada
1516   :bind
1517   (:map meghanada-mode-map
1518         (("C-M-o" . meghanada-optimize-import)
1519          ("C-M-t" . meghanada-import-all)))
1520   :hook (java-mode . meghanada-mode))
1521 #+end_src
1522
1523 *** lsp-java
1524
1525 #+begin_comment
1526 dependencies:
1527
1528 ace-window
1529 avy
1530 bui
1531 company-lsp
1532 dap-mode
1533 lsp-java
1534 lsp-mode
1535 lsp-ui
1536 pfuture
1537 tree-mode
1538 treemacs
1539 #+end_comment
1540
1541 #+begin_src emacs-lisp
1542 (use-package treemacs
1543   :config (setq treemacs-never-persist t))
1544
1545 (use-package yasnippet
1546   :config
1547   ;; (yas-global-mode)
1548   )
1549
1550 (use-package lsp-mode
1551   :init (setq lsp-eldoc-render-all nil
1552               lsp-highlight-symbol-at-point nil)
1553   )
1554
1555 (use-package hydra)
1556
1557 (use-package company-lsp
1558   :after  company
1559   :config
1560   (setq company-lsp-cache-candidates t
1561         company-lsp-async t))
1562
1563 (use-package lsp-ui
1564   :config
1565   (setq lsp-ui-sideline-update-mode 'point))
1566
1567 (use-package lsp-java
1568   :config
1569   (add-hook 'java-mode-hook
1570             (lambda ()
1571               (setq-local company-backends (list 'company-lsp))))
1572
1573   (add-hook 'java-mode-hook 'lsp-java-enable)
1574   (add-hook 'java-mode-hook 'flycheck-mode)
1575   (add-hook 'java-mode-hook 'company-mode)
1576   (add-hook 'java-mode-hook 'lsp-ui-mode))
1577
1578 (use-package dap-mode
1579   :after lsp-mode
1580   :config
1581   (dap-mode t)
1582   (dap-ui-mode t))
1583
1584 (use-package dap-java
1585   :after (lsp-java))
1586
1587 (use-package lsp-java-treemacs
1588   :after (treemacs))
1589 #+end_src
1590
1591 ** geiser
1592
1593 #+begin_src emacs-lisp
1594 (use-package geiser)
1595
1596 (use-package geiser-guile
1597   :config
1598   (setq geiser-guile-load-path "~/src/git/guix"))
1599 #+end_src
1600
1601 ** guix
1602
1603 #+begin_src emacs-lisp
1604 (use-package guix
1605   :load-path "lib/guix/elisp")
1606 #+end_src
1607
1608 * Emacs enhancements
1609 :PROPERTIES:
1610 :CUSTOM_ID: emacs-enhancements
1611 :END:
1612
1613 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1614
1615 #+begin_quote
1616 Emacs package that displays available keybindings in popup
1617 #+end_quote
1618
1619 #+begin_src emacs-lisp
1620 (use-package which-key
1621   :defer 1
1622   :config (which-key-mode))
1623 #+end_src
1624
1625 ** theme
1626
1627 #+begin_src emacs-lisp
1628 (add-to-list 'custom-theme-load-path "~/.emacs.d/lisp")
1629 (load-theme 'tangomod t)
1630 #+end_src
1631
1632 ** smart-mode-line
1633
1634 #+begin_src emacs-lisp
1635 (use-package smart-mode-line
1636   :config
1637   (sml/setup))
1638 #+end_src
1639
1640 ** doom-themes
1641
1642 #+begin_src emacs-lisp
1643 (use-package doom-themes)
1644 #+end_src
1645
1646 ** theme helper functions
1647
1648 #+begin_src emacs-lisp
1649 (defun amin/lights-on ()
1650   "Enable my favourite light theme."
1651   (interactive)
1652   (mapc #'disable-theme custom-enabled-themes)
1653   (load-theme 'tangomod t)
1654   (sml/apply-theme 'automatic))
1655
1656 (defun amin/lights-off ()
1657   "Go dark."
1658   (interactive)
1659   (mapc #'disable-theme custom-enabled-themes)
1660   (load-theme 'doom-tomorrow-night t)
1661   (sml/apply-theme 'automatic))
1662
1663 (bind-keys
1664  ("s-t d" . amin/lights-off)
1665  ("s-t l" . amin/lights-on))
1666 #+end_src
1667
1668 ** [[https://github.com/bbatsov/crux][crux]]
1669
1670 #+begin_src emacs-lisp
1671 (use-package crux
1672   :defer 1
1673   :bind (("C-c b k" . crux-kill-other-buffers)
1674          ("C-c d"   . crux-duplicate-current-line-or-region)
1675          ("C-c D"   . crux-duplicate-and-comment-current-line-or-region)
1676          ("C-c f c" . crux-copy-file-preserve-attributes)
1677          ("C-c f d" . crux-delete-file-and-buffer)
1678          ("C-c f r" . crux-rename-file-and-buffer)
1679          ("C-c j"   . crux-top-join-line)
1680          ("C-S-j"   . crux-top-join-line)))
1681 #+end_src
1682
1683 ** [[https://github.com/alezost/mwim.el][mwim]]
1684
1685 #+begin_src emacs-lisp
1686 (use-package mwim
1687   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1688          ("C-e"    . mwim-end-of-code-or-line)
1689          ("<home>" . mwim-beginning-of-line-or-code)
1690          ("<end>"  . mwim-end-of-line-or-code)))
1691 #+end_src
1692
1693 ** projectile
1694
1695 #+begin_src emacs-lisp
1696 (use-package projectile
1697   :defer t
1698   :bind-keymap ("C-c p" . projectile-command-map)
1699   :config
1700   (projectile-mode)
1701
1702   (defun my-projectile-invalidate-cache (&rest _args)
1703     ;; ignore the args to `magit-checkout'
1704     (projectile-invalidate-cache nil))
1705
1706   (eval-after-load 'magit-branch
1707     '(progn
1708        (advice-add 'magit-checkout
1709                    :after #'my-projectile-invalidate-cache)
1710        (advice-add 'magit-branch-and-checkout
1711                    :after #'my-projectile-invalidate-cache)))
1712   :custom (projectile-completion-system 'ivy))
1713 #+end_src
1714
1715 ** [[https://github.com/Wilfred/helpful][helpful]]
1716
1717 #+begin_src emacs-lisp
1718 (use-package helpful
1719   :defer 1
1720   :bind
1721   (("C-S-h c" . helpful-command)
1722    ("C-S-h f" . helpful-callable)        ; helpful-function
1723    ("C-S-h v" . helpful-variable)
1724    ("C-S-h k" . helpful-key)
1725    ("C-S-h p" . helpful-at-point)))
1726 #+end_src
1727
1728 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1729
1730 Make =*scratch*= and =*Messages*= unkillable.
1731
1732 #+begin_src emacs-lisp
1733 (use-package unkillable-scratch
1734   :defer 3
1735   :config
1736   (unkillable-scratch 1)
1737   :custom
1738   (unkillable-scratch-behavior 'do-nothing)
1739   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1740 #+end_src
1741
1742 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1743
1744 #+begin_example
1745 ,----
1746 | make pretty boxed quotes like this
1747 `----
1748 #+end_example
1749
1750 #+begin_src emacs-lisp
1751 (use-package boxquote
1752   :defer 3
1753   :bind
1754   (:prefix-map amin--boxquote-prefix-map
1755    :prefix "C-c q"
1756    ("b"   . boxquote-buffer)
1757    ("B"   . boxquote-insert-buffer)
1758    ("d"   . boxquote-defun)
1759    ("F"   . boxquote-insert-file)
1760    ("hf"  . boxquote-describe-function)
1761    ("hk"  . boxquote-describe-key)
1762    ("hv"  . boxquote-describe-variable)
1763    ("hw"  . boxquote-where-is)
1764    ("k"   . boxquote-kill)
1765    ("p"   . boxquote-paragraph)
1766    ("q"   . boxquote-boxquote)
1767    ("r"   . boxquote-region)
1768    ("s"   . boxquote-shell-command)
1769    ("t"   . boxquote-text)
1770    ("T"   . boxquote-title)
1771    ("u"   . boxquote-unbox)
1772    ("U"   . boxquote-unbox-region)
1773    ("y"   . boxquote-yank)
1774    ("M-q" . boxquote-fill-paragraph)
1775    ("M-w" . boxquote-kill-ring-save)))
1776 #+end_src
1777
1778 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1779
1780 ** typo.el
1781
1782 #+begin_src emacs-lisp
1783 (use-package typo
1784   :defer 2
1785   :config
1786   (typo-global-mode 1)
1787   :hook (text-mode . typo-mode))
1788 #+end_src
1789
1790 ** hl-todo
1791
1792 #+begin_src emacs-lisp
1793 (use-package hl-todo
1794   :defer 4
1795   :config
1796   (global-hl-todo-mode))
1797 #+end_src
1798
1799 ** shrink-path
1800
1801 #+begin_src emacs-lisp
1802 (use-package shrink-path
1803   :after eshell
1804   :config
1805   (setq eshell-prompt-regexp "\\(.*\n\\)*λ "
1806         eshell-prompt-function #'+eshell/prompt)
1807
1808   (defun +eshell/prompt ()
1809     (let ((base/dir (shrink-path-prompt default-directory)))
1810       (concat (propertize (car base/dir)
1811                           'face 'font-lock-comment-face)
1812               (propertize (cdr base/dir)
1813                           'face 'font-lock-constant-face)
1814               (propertize (+eshell--current-git-branch)
1815                           'face 'font-lock-function-name-face)
1816               "\n"
1817               (propertize "λ" 'face 'eshell-prompt-face)
1818               ;; needed for the input text to not have prompt face
1819               (propertize " " 'face 'default))))
1820
1821   (defun +eshell--current-git-branch ()
1822     (let ((branch (car (loop for match in (split-string (shell-command-to-string "git branch") "\n")
1823                              when (string-match "^\*" match)
1824                              collect match))))
1825       (if (not (eq branch nil))
1826           (concat " " (substring branch 2))
1827         ""))))
1828 #+end_src
1829
1830 ** [[https://github.com/peterwvj/eshell-up][eshell-up]]
1831
1832 #+begin_src emacs-lisp
1833 (use-package eshell-up
1834   :after eshell)
1835 #+end_src
1836
1837 ** multi-term
1838
1839 #+begin_src emacs-lisp
1840 (use-package multi-term
1841   :defer 1
1842   :bind (("C-c a s m m" . multi-term)
1843          ("C-c a s m p" . multi-term-dedicated-toggle)
1844          :map term-mode-map
1845          ("C-c C-j" . term-char-mode)
1846          :map term-raw-map
1847          ("C-c C-j" . term-line-mode))
1848   :config
1849   (setq multi-term-program "/bin/screen"
1850         ;; TODO: add separate bindings for connecting to existing
1851         ;; session vs. always creating a new one
1852         multi-term-dedicated-select-after-open-p t
1853         multi-term-dedicated-window-height 20
1854         multi-term-dedicated-max-window-height 30
1855         term-bind-key-alist
1856         '(("C-c C-c" . term-interrupt-subjob)
1857           ("C-c C-e" . term-send-esc)
1858           ("C-k" . kill-line)
1859           ("C-y" . term-paste)
1860           ("M-f" . term-send-forward-word)
1861           ("M-b" . term-send-backward-word)
1862           ("M-p" . term-send-up)
1863           ("M-n" . term-send-down)
1864           ("<C-backspace>" . term-send-backward-kill-word)
1865           ("<M-DEL>" . term-send-backward-kill-word)
1866           ("M-d" . term-send-delete-word)
1867           ("M-," . term-send-raw)
1868           ("M-." . comint-dynamic-complete))
1869         term-unbind-key-alist
1870         '("C-z" "C-x" "C-c" "C-h" "C-y" "<ESC>")))
1871 #+end_src
1872
1873 ** page-break-lines
1874
1875 #+begin_src emacs-lisp
1876 (use-package page-break-lines
1877   :config
1878   (global-page-break-lines-mode))
1879 #+end_src
1880
1881 ** expand-region
1882
1883 #+begin_src emacs-lisp
1884 (use-package expand-region
1885   :bind ("C-=" . er/expand-region))
1886 #+end_src
1887
1888 * Email
1889 :PROPERTIES:
1890 :CUSTOM_ID: email
1891 :END:
1892
1893 #+begin_src emacs-lisp
1894 (defvar amin-maildir (expand-file-name "~/mail/"))
1895 (after! recentf
1896   (add-to-list 'recentf-exclude amin-maildir))
1897 #+end_src
1898
1899 ** Gnus
1900
1901 #+begin_src emacs-lisp
1902 (setq
1903  amin-gnus-init-file (no-littering-expand-etc-file-name "gnus")
1904  mail-user-agent     'gnus-user-agent
1905  read-mail-command   'gnus)
1906
1907 (use-package gnus
1908   :bind (("C-c m" . gnus)
1909          ("C-c M" . gnus-unplugged)
1910          ("s-m"   . gnus)
1911          ("s-M"   . gnus-unplugged))
1912   :init
1913   (setq
1914    gnus-select-method '(nnnil "")
1915    gnus-secondary-select-methods
1916    '((nnimap "amin"
1917             (nnimap-stream plain)
1918             (nnimap-address "127.0.0.1")
1919             (nnimap-server-port 143)
1920             (nnimap-authenticator plain)
1921             (nnimap-user "amin@aminb.org"))
1922      (nnimap "uwaterloo"
1923              (nnimap-stream plain)
1924              (nnimap-address "127.0.0.1")
1925              (nnimap-server-port 143)
1926              (nnimap-authenticator plain)
1927              (nnimap-user "abandali@uwaterloo.ca")))
1928    gnus-message-archive-group "nnimap+amin:Sent"
1929    gnus-parameters
1930    '(("gnu.*"
1931       (gcc-self . t)))
1932    gnus-large-newsgroup  50
1933    gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
1934    gnus-directory        (concat gnus-home-directory "news/")
1935    message-directory     (concat gnus-home-directory "mail/")
1936    nndraft-directory     (concat gnus-home-directory "drafts/")
1937    gnus-save-newsrc-file nil
1938    gnus-read-newsrc-file nil
1939    gnus-interactive-exit nil
1940    gnus-gcc-mark-as-read t))
1941
1942 (use-package gnus-art
1943   :config
1944   (setq
1945    gnus-visible-headers
1946    (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
1947    gnus-sorted-header-list
1948    '("^From:" "^Subject:" "^Summary:" "^Keywords:"
1949      "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
1950      "^Newsgroups:" "List-Id:" "^Organization:"
1951      "^User-Agent:" "^Date:")
1952   ;; local-lapsed article dates
1953   ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
1954   gnus-article-date-headers '(user-defined)
1955   gnus-article-time-format
1956   (lambda (time)
1957     (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
1958            (local (article-make-date-line date 'local))
1959            (combined-lapsed (article-make-date-line date
1960                                                     'combined-lapsed))
1961            (lapsed (progn
1962                      (string-match " (.+" combined-lapsed)
1963                      (match-string 0 combined-lapsed))))
1964       (concat local lapsed))))
1965   (bind-keys
1966    :map gnus-article-mode-map
1967    ("r"   . gnus-article-reply-with-original)
1968    ("R"   . gnus-article-wide-reply-with-original)
1969    ("M-L" . org-store-link)))
1970
1971 (use-package gnus-sum
1972   :bind (:map gnus-summary-mode-map
1973               :prefix-map amin--gnus-summary-prefix-map
1974               :prefix "v"
1975               ("r" . gnus-summary-reply)
1976               ("w" . gnus-summary-wide-reply)
1977               ("v" . gnus-summary-show-raw-article))
1978   :config
1979   (bind-keys
1980    :map gnus-summary-mode-map
1981    ("r"   . gnus-summary-reply-with-original)
1982    ("R"   . gnus-summary-wide-reply-with-original)
1983    ("M-L" . org-store-link))
1984   :hook (gnus-summary-mode . amin--no-mouse-autoselect-window))
1985
1986 (use-package gnus-msg
1987   :config
1988   (setq gnus-posting-styles
1989         '((".*"
1990            (address "amin@aminb.org")
1991            (body "\nBest,\namin\n")
1992            (eval (setq amin--message-cite-say-hi t)))
1993           ("gnu.*"
1994            (address "bandali@gnu.org"))
1995           ((header "subject" "ThankCRM")
1996            (to "webmasters-comment@gnu.org")
1997            (body "\nAdded  to 2018supporters.html.\n\nMoving to campaigns.\n\n-amin\n")
1998            (eval (setq amin--message-cite-say-hi nil)))
1999           ("nnimap\\+uwaterloo:.*"
2000            (address "abandali@uwaterloo.ca")
2001            (gcc "\"nnimap+uwaterloo:Sent Items\"")))))
2002
2003 (use-package gnus-topic
2004   :hook (gnus-group-mode . gnus-topic-mode))
2005
2006 (use-package gnus-agent
2007   :config
2008   (setq gnus-agent-synchronize-flags 'ask)
2009   :hook (gnus-group-mode . gnus-agent-mode))
2010
2011 (use-package gnus-group
2012   :config
2013   (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))
2014
2015 (use-package mm-decode
2016   :config
2017   (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
2018 #+end_src
2019
2020 ** sendmail
2021
2022 #+begin_src emacs-lisp
2023 (use-package sendmail
2024   :config
2025   (setq sendmail-program "/usr/bin/msmtp"
2026         ;; message-sendmail-extra-arguments '("-v" "-d")
2027         mail-specify-envelope-from t
2028         mail-envelope-from 'header))
2029 #+end_src
2030
2031 ** message
2032
2033 #+begin_src emacs-lisp
2034 (use-package message
2035   :config
2036   (defconst amin--message-cite-style-format "On %Y-%m-%d %l:%M %p, %N wrote:")
2037   (defconst message-cite-style-bandali
2038     '((message-cite-function  'message-cite-original)
2039       (message-citation-line-function  'message-insert-formatted-citation-line)
2040       (message-cite-reply-position 'traditional)
2041       (message-yank-prefix  "> ")
2042       (message-yank-cited-prefix  ">")
2043       (message-yank-empty-prefix  ">")
2044       (message-citation-line-format
2045        (if amin--message-cite-say-hi
2046            (concat "Hi %F,\n\n" amin--message-cite-style-format)
2047          amin--message-cite-style-format)))
2048     "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
2049   (setq message-cite-style 'message-cite-style-bandali
2050         message-kill-buffer-on-exit t
2051         message-send-mail-function 'message-send-mail-with-sendmail
2052         message-sendmail-envelope-from 'header
2053         message-dont-reply-to-names
2054         "\\(\\(.*@aminb\\.org\\)\\|\\(amin@bandali\\.me\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
2055         message-user-fqdn "aminb.org")
2056   :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
2057          (message-mode . flyspell-mode)
2058          (message-mode . (lambda ()
2059                            ;; (setq fill-column 65
2060                            ;;       message-fill-column 65)
2061                            (make-local-variable 'company-idle-delay)
2062                            (setq company-idle-delay 0.2))))
2063   ;; :custom-face
2064   ;; (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
2065   ;; (message-header-to      ((t (:foreground "#111" :weight normal))))
2066   ;; (message-header-cc      ((t (:foreground "#333" :weight normal))))
2067   )
2068
2069 (after! mml-sec
2070   (setq mml-secure-openpgp-encrypt-to-self t
2071         mml-secure-openpgp-sign-with-sender t))
2072 #+end_src
2073
2074 ** footnote
2075
2076 Convenient footnotes in =message-mode=.
2077
2078 #+begin_src emacs-lisp
2079 (use-package footnote
2080   :after message
2081   :bind
2082   (:map message-mode-map
2083         :prefix-map amin--footnote-prefix-map
2084         :prefix "C-c f"
2085         ("a" . footnote-add-footnote)
2086         ("b" . footnote-back-to-message)
2087         ("c" . footnote-cycle-style)
2088         ("d" . footnote-delete-footnote)
2089         ("g" . footnote-goto-footnote)
2090         ("r" . footnote-renumber-footnotes)
2091         ("s" . footnote-set-style))
2092   :config
2093   (setq footnote-start-tag ""
2094         footnote-end-tag   ""
2095         footnote-style     'unicode))
2096 #+end_src
2097
2098 ** ebdb
2099
2100 #+begin_src emacs-lisp
2101 (use-package ebdb
2102   :defer 1
2103   :bind (:map gnus-group-mode-map ("e" . ebdb))
2104   :config
2105   (setq ebdb-sources (no-littering-expand-var-file-name "ebdb"))
2106   (after! swiper
2107     (add-to-list 'swiper-font-lock-exclude 'ebdb-mode t)))
2108
2109 (use-package ebdb-com
2110   :after ebdb)
2111
2112 ;; (use-package ebdb-complete
2113 ;;   :after ebdb
2114 ;;   :config
2115 ;;   (ebdb-complete-enable))
2116
2117 (use-package company-ebdb
2118   :after (:all company message)
2119   :config
2120   (defun company-ebdb--post-complete (_) nil)
2121   :hook
2122   (message-mode . (lambda ()
2123                     (add-to-list (make-local-variable 'company-backends)
2124                                  'company-ebdb))))
2125
2126 (use-package ebdb-gnus
2127   :after ebdb
2128   :custom
2129   (ebdb-gnus-window-configuration
2130    '(article
2131      (vertical 1.0
2132                (summary 0.25 point)
2133                (horizontal 1.0
2134                            (article 1.0)
2135                            (ebdb-gnus 0.3))))))
2136
2137 (use-package ebdb-mua
2138   :after ebdb
2139   ;; :custom (ebdb-mua-pop-up nil)
2140   )
2141
2142 ;; (use-package ebdb-message
2143 ;;   :after ebdb)
2144
2145
2146 ;; (use-package ebdb-vcard
2147 ;;   :after ebdb)
2148 #+end_src
2149
2150 ** COMMENT message-x
2151
2152 #+begin_src emacs-lisp
2153 (use-package message-x
2154   :custom
2155   (message-x-completion-alist
2156    (quote
2157     (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
2158      ((if
2159           (boundp
2160            (quote message-newgroups-header-regexp))
2161           message-newgroups-header-regexp message-newsgroups-header-regexp)
2162       . message-expand-group)))))
2163 #+end_src
2164
2165 ** COMMENT gnus-harvest
2166
2167 #+begin_src emacs-lisp
2168 (use-package gnus-harvest
2169   :commands gnus-harvest-install
2170   :demand t
2171   :config
2172   (if (featurep 'message-x)
2173       (gnus-harvest-install 'message-x)
2174     (gnus-harvest-install)))
2175 #+end_src
2176
2177 * Blogging
2178 :PROPERTIES:
2179 :CUSTOM_ID: blogging
2180 :END:
2181
2182 ** [[https://ox-hugo.scripter.co][ox-hugo]]
2183
2184 #+begin_src emacs-lisp
2185 (use-package ox-hugo
2186   :after ox)
2187
2188 (use-package ox-hugo-auto-export
2189   :load-path "lib/ox-hugo")
2190 #+end_src
2191
2192 * Post initialization
2193 :PROPERTIES:
2194 :CUSTOM_ID: post-initialization
2195 :END:
2196
2197 Display how long it took to load the init file.
2198
2199 #+begin_src emacs-lisp
2200 (message "Loading %s...done (%.3fs)" user-init-file
2201          (float-time (time-subtract (current-time)
2202                                     amin--before-user-init-time)))
2203 #+end_src
2204
2205 * Footer
2206 :PROPERTIES:
2207 :CUSTOM_ID: footer
2208 :END:
2209
2210 #+begin_src emacs-lisp :comments none
2211 ;;; init.el ends here
2212 #+end_src
2213
2214 * COMMENT Local Variables                                           :ARCHIVE:
2215 # Local Variables:
2216 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
2217 # eval: (typo-mode -1)
2218 # End: