git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 *** Auto revert
 569
 570 Enable automatic reloading of changed buffers and files.
 571
 572 #+begin_src emacs-lisp
 573 (global-auto-revert-mode 1)
 574 (setq auto-revert-verbose nil
 575       global-auto-revert-non-file-buffers t)
 576 #+end_src
 577
 578 *** Always use space for indentation
 579
 580 #+begin_src emacs-lisp
 581 (setq-default
 582  indent-tabs-mode nil
 583  require-final-newline t
 584  tab-width 4)
 585 #+end_src
 586
 587 ** Packages
 588
 589 The packages in this section are absolutely essential to my everyday
 590 workflow, and they play key roles in how I do my computing. They
 591 immensely enhance the Emacs experience for me; both using Emacs, and
 592 customizing it.
 593
 594 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 595
 596 #+begin_src emacs-lisp
 597 (use-package auto-compile
 598   :demand t
 599   :config
 600   (auto-compile-on-load-mode)
 601   (auto-compile-on-save-mode)
 602   (setq auto-compile-display-buffer               nil
 603         auto-compile-mode-line-counter            t
 604         auto-compile-source-recreate-deletes-dest t
 605         auto-compile-toggle-deletes-nonlib-dest   t
 606         auto-compile-update-autoloads             t)
 607   (add-hook 'auto-compile-inhibit-compile-hook
 608             'auto-compile-inhibit-compile-detached-git-head))
 609 #+end_src
 610
 611 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 612
 613 #+begin_quote
 614 Roll your own modal mode
 615 #+end_quote
 616
 617 #+begin_src emacs-lisp
 618 (use-package ryo-modal
 619   :commands ryo-modal-mode
 620   :bind ("M-m" . ryo-modal-mode)
 621   :after which-key
 622   :config
 623   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 624   (ryo-modal-keys
 625    ("," ryo-modal-repeat)
 626    ("b" backward-char)
 627    ("n" next-line)
 628    ("p" previous-line)
 629    ("f" forward-char)
 630    ("/" undo)
 631    ("SPC" (("b" (("b" ibuffer-list-buffers)
 632                  ("k" kill-this-buffer)
 633                  ("o" other-window)
 634                  ("s" save-buffer)))
 635            ("h" (("c" describe-char)
 636                  ("f" describe-function)
 637                  ("F" describe-face)
 638                  ("i" info)
 639                  ("k" describe-key)
 640                  ("l" view-lossage)
 641                  ("v" describe-variable)))
 642            ("q" (("q" save-buffers-kill-terminal)))))
 643    ("d" (("w" kill-word)
 644          ("b" backward-kill-word)))
 645    ("c w" kill-word :exit t))
 646
 647   (ryo-modal-keys
 648    ;; First argyment to ryo-modal-keys may be a list of keywords.
 649    ;; These keywords will be applied to all keybindings.
 650    (:norepeat t)
 651    ("0" "M-0")
 652    ("1" "M-1")
 653    ("2" "M-2")
 654    ("3" "M-3")
 655    ("4" "M-4")
 656    ("5" "M-5")
 657    ("6" "M-6")
 658    ("7" "M-7")
 659    ("8" "M-8")
 660    ("9" "M-9"))
 661   :hook ((text-mode . ryo-modal-mode)
 662          (prog-mode . ryo-modal-mode)))
 663 #+end_src
 664
 665 *** [[https://orgmode.org/][Org mode]]
 666
 667 #+begin_quote
 668 Org mode is for keeping notes, maintaining TODO lists, planning
 669 projects, and authoring documents with a fast and effective plain-text
 670 system.
 671 #+end_quote
 672
 673 In short, my favourite way of life.
 674
 675 #+begin_src emacs-lisp
 676 (use-package org
 677   :ryo ("SPC b t" org-babel-tangle)
 678   :config
 679   (setq org-src-tab-acts-natively t
 680         org-src-preserve-indentation nil
 681         org-edit-src-content-indentation 0
 682         org-html-divs '((preamble  "header" "preamble")
 683                         (content   "main"   "content")
 684                         (postamble "footer" "postamble"))
 685         org-html-doctype "html5"
 686         org-html-html5-fancy t
 687         org-html-postamble nil)
 688   :hook (org-mode . org-indent-mode))
 689 (use-package htmlize
 690   :after org)
 691 (use-package org-notmuch
 692   :after (:any org notmuch))
 693 #+end_src
 694
 695 *** [[https://magit.vc/][Magit]]
 696
 697 #+begin_quote
 698 It's Magit! A Git porcelain inside Emacs.
 699 #+end_quote
 700
 701 Not just how I do git, but /the/ way to do git.
 702
 703 #+begin_src emacs-lisp
 704 (use-package magit
 705   :ryo ("SPC" (("g s" magit-status)))
 706   :defer t
 707   :bind (("s-g"     . magit-status)
 708          ("C-x g"   . magit-status)
 709          ("C-x M-g" . magit-dispatch-popup))
 710   :config
 711   (magit-add-section-hook 'magit-status-sections-hook
 712                           'magit-insert-modules
 713                           'magit-insert-stashes
 714                           'append))
 715 #+end_src
 716
 717 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 718
 719 #+begin_quote
 720 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 721 an overview, and more. Oh, man!
 722 #+end_quote
 723
 724 There's no way I could top that, so I won't attempt to.
 725
 726 **** Ivy
 727
 728 #+begin_src emacs-lisp
 729 (use-package ivy
 730   :defer 1
 731   :bind
 732   (:map ivy-minibuffer-map
 733         ([escape] . keyboard-escape-quit)
 734         ;; ("C-j"    . ivy-next-line)
 735         ;; ("C-k"    . ivy-previous-line)
 736         ([S-up]   . ivy-previous-history-element)
 737         ([S-down] . ivy-next-history-element)
 738         ("DEL"    . ivy-backward-delete-char))
 739   :ryo ("SPC ," ivy-switch-buffer)
 740   :config
 741   (setq ivy-wrap t)
 742   (ivy-mode 1))
 743 #+end_src
 744
 745 **** Swiper
 746
 747 #+begin_src emacs-lisp
 748 (use-package swiper
 749   :ryo
 750   ("SPC /" swiper)
 751   ("s" swiper)
 752   :bind (([remap isearch-forward]  . swiper)
 753          ([remap isearch-backward] . swiper)))
 754 #+end_src
 755
 756 **** Counsel
 757
 758 #+begin_src emacs-lisp
 759 (use-package counsel
 760   :defer 1
 761   :ryo
 762   ("SPC" (("f r" counsel-recentf)
 763           ("SPC" counsel-M-x)
 764           ("."   counsel-find-file)))
 765   :bind (([remap execute-extended-command] . counsel-M-x)
 766          ([remap find-file] . counsel-find-file)
 767          ("s-r"     . counsel-recentf)
 768          :map minibuffer-local-map
 769          ("C-r" . counsel-minibuffer-history))
 770   :config
 771   (counsel-mode 1)
 772   (defalias 'locate #'counsel-locate))
 773 #+end_src
 774
 775 * Borg's =layer/essentials=
 776
 777 TODO: break this giant source block down into individual org sections.
 778
 779 #+begin_src emacs-lisp
 780 (use-package dash
 781   :config (dash-enable-font-lock))
 782
 783 (use-package diff-hl
 784   :config
 785   (setq diff-hl-draw-borders nil)
 786   (global-diff-hl-mode)
 787   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 788
 789 (use-package dired
 790   :defer t
 791   :config (setq dired-listing-switches "-alh"))
 792
 793 (use-package eldoc
 794   :when (version< "25" emacs-version)
 795   :config (global-eldoc-mode))
 796
 797 (use-package help
 798   :defer t
 799   :config (temp-buffer-resize-mode))
 800
 801 (progn ;    `isearch'
 802   (setq isearch-allow-scroll t))
 803
 804 (use-package lisp-mode
 805   :config
 806   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 807   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 808   (defun indent-spaces-mode ()
 809     (setq indent-tabs-mode nil))
 810   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 811
 812 (use-package man
 813   :defer t
 814   :config (setq Man-width 80))
 815
 816 (use-package paren
 817   :config (show-paren-mode))
 818
 819 (use-package prog-mode
 820   :config (global-prettify-symbols-mode)
 821   (defun indicate-buffer-boundaries-left ()
 822     (setq indicate-buffer-boundaries 'left))
 823   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 824
 825 (use-package recentf
 826   :demand t
 827   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 828
 829 (use-package savehist
 830   :config (savehist-mode))
 831
 832 (use-package saveplace
 833   :when (version< "25" emacs-version)
 834   :config (save-place-mode))
 835
 836 (use-package simple
 837   :config (column-number-mode))
 838
 839 (progn ;    `text-mode'
 840   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 841
 842 (use-package tramp
 843   :defer t
 844   :config
 845   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 846   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 847   (add-to-list 'tramp-default-proxies-alist
 848                (list (regexp-quote (system-name)) nil nil)))
 849
 850 (use-package undo-tree
 851   :ryo
 852   ("?" undo-tree-undo)
 853   ("_" undo-tree-redo)
 854   :bind (("C-?" . undo-tree-undo)
 855          ("M-_" . undo-tree-redo))
 856   :config
 857   (global-undo-tree-mode)
 858   (setq undo-tree-mode-lighter ""
 859         undo-tree-auto-save-history t))
 860 #+end_src
 861
 862 * Editing
 863
 864 ** Company
 865
 866 #+begin_src emacs-lisp
 867 (use-package company
 868   :defer 5
 869   :bind
 870   (:map company-active-map
 871         ([tab] . company-complete-common-or-cycle))
 872   :custom
 873   (company-idle-delay 0.3)
 874   (company-minimum-prefix-length 1)
 875   (company-selection-wrap-around t)
 876   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 877   :config
 878   (global-company-mode t))
 879 #+end_src
 880
 881 * Syntax and spell checking
 882 #+begin_src emacs-lisp
 883 (use-package flycheck
 884   :hook (prog-mode . flycheck-mode)
 885   :config
 886   ;; Use the load-path from running Emacs when checking elisp files
 887   (setq flycheck-emacs-lisp-load-path 'inherit)
 888
 889   ;; Only flycheck when I actually save the buffer
 890   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 891 #+end_src
 892 * Programming modes
 893
 894 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 895
 896 #+begin_src emacs-lisp
 897 (use-package alloy-mode
 898   :config (setq alloy-basic-offset 2))
 899 #+end_src
 900
 901 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 902
 903 #+begin_src emacs-lisp
 904 (use-package proof-site  ; Proof General
 905   :load-path "lib/proof-site/generic/")
 906 #+end_src
 907
 908 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 909
 910 #+begin_src emacs-lisp
 911 (use-package lean-mode
 912   :bind (:map lean-mode-map
 913               ("S-SPC" . company-complete)))
 914 #+end_src
 915
 916 ** Haskell
 917
 918 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 919
 920 #+begin_src emacs-lisp
 921 (use-package haskell-mode
 922   :config
 923   (setq haskell-indentation-layout-offset 4
 924         haskell-indentation-left-offset 4
 925         flycheck-checker 'haskell-hlint
 926         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 927 #+end_src
 928
 929 *** [[https://github.com/jyp/dante][dante]]
 930
 931 #+begin_src emacs-lisp
 932 (use-package dante
 933   :after haskell-mode
 934   :commands dante-mode
 935   :hook (haskell-mode . dante-mode))
 936 #+end_src
 937
 938 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 939
 940 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 941 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 942
 943 #+begin_src emacs-lisp
 944 (use-package hlint-refactor
 945   :bind (:map hlint-refactor-mode-map
 946               ("C-c l b" . hlint-refactor-refactor-buffer)
 947               ("C-c l r" . hlint-refactor-refactor-at-point))
 948   :hook (haskell-mode . hlint-refactor-mode))
 949 #+end_src
 950
 951 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 952
 953 #+begin_src emacs-lisp
 954 (use-package flycheck-haskell)
 955 #+end_src
 956
 957 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 958 :PROPERTIES:
 959 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 960 :END:
 961
 962 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 963 instead.
 964
 965 #+begin_src emacs-lisp :tangle no
 966 ;;; hs-lint.el --- minor mode for HLint code checking
 967
 968 ;; Copyright 2009 (C) Alex Ott
 969 ;;
 970 ;; Author: Alex Ott <alexott@gmail.com>
 971 ;; Keywords: haskell, lint, HLint
 972 ;; Requirements:
 973 ;; Status: distributed under terms of GPL2 or above
 974
 975 ;; Typical message from HLint looks like:
 976 ;;
 977 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 978 ;; Found:
 979 ;;   count1 p l = length (filter p l)
 980 ;; Why not:
 981 ;;   count1 p = length . filter p
 982
 983
 984 (require 'compile)
 985
 986 (defgroup hs-lint nil
 987   "Run HLint as inferior of Emacs, parse error messages."
 988   :group 'tools
 989   :group 'haskell)
 990
 991 (defcustom hs-lint-command "hlint"
 992   "The default hs-lint command for \\[hlint]."
 993   :type 'string
 994   :group 'hs-lint)
 995
 996 (defcustom hs-lint-save-files t
 997   "Save modified files when run HLint or no (ask user)"
 998   :type 'boolean
 999   :group 'hs-lint)
1000
1001 (defcustom hs-lint-replace-with-suggestions nil
1002   "Replace user's code with suggested replacements"
1003   :type 'boolean
1004   :group 'hs-lint)
1005
1006 (defcustom hs-lint-replace-without-ask nil
1007   "Replace user's code with suggested replacements automatically"
1008   :type 'boolean
1009   :group 'hs-lint)
1010
1011 (defun hs-lint-process-setup ()
1012   "Setup compilation variables and buffer for `hlint'."
1013   (run-hooks 'hs-lint-setup-hook))
1014
1015 ;; regex for replace suggestions
1016 ;;
1017 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1018 ;; Found:
1019 ;; \s +\(.*\)
1020 ;; Why not:
1021 ;; \s +\(.*\)
1022
1023 (defvar hs-lint-regex
1024   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1025   "Regex for HLint messages")
1026
1027 (defun make-short-string (str maxlen)
1028   (if (< (length str) maxlen)
1029       str
1030     (concat (substring str 0 (- maxlen 3)) "...")))
1031
1032 (defun hs-lint-replace-suggestions ()
1033   "Perform actual replacement of suggestions"
1034   (goto-char (point-min))
1035   (while (re-search-forward hs-lint-regex nil t)
1036     (let* ((fname (match-string 1))
1037           (fline (string-to-number (match-string 2)))
1038           (old-code (match-string 4))
1039           (new-code (match-string 5))
1040           (msg (concat "Replace '" (make-short-string old-code 30)
1041                        "' with '" (make-short-string new-code 30) "'"))
1042           (bline 0)
1043           (eline 0)
1044           (spos 0)
1045           (new-old-code ""))
1046       (save-excursion
1047         (switch-to-buffer (get-file-buffer fname))
1048         (goto-char (point-min))
1049         (forward-line (1- fline))
1050         (beginning-of-line)
1051         (setf bline (point))
1052         (when (or hs-lint-replace-without-ask
1053                   (yes-or-no-p msg))
1054           (end-of-line)
1055           (setf eline (point))
1056           (beginning-of-line)
1057           (setf old-code (regexp-quote old-code))
1058           (while (string-match "\\\\ " old-code spos)
1059             (setf new-old-code (concat new-old-code
1060                                  (substring old-code spos (match-beginning 0))
1061                                  "\\ *"))
1062             (setf spos (match-end 0)))
1063           (setf new-old-code (concat new-old-code (substring old-code spos)))
1064           (remove-text-properties bline eline '(composition nil))
1065           (when (re-search-forward new-old-code eline t)
1066             (replace-match new-code nil t)))))))
1067
1068 (defun hs-lint-finish-hook (buf msg)
1069   "Function, that is executed at the end of HLint execution"
1070   (if hs-lint-replace-with-suggestions
1071       (hs-lint-replace-suggestions)
1072       (next-error 1 t)))
1073
1074 (define-compilation-mode hs-lint-mode "HLint"
1075   "Mode for check Haskell source code."
1076   (set (make-local-variable 'compilation-process-setup-function)
1077        'hs-lint-process-setup)
1078   (set (make-local-variable 'compilation-disable-input) t)
1079   (set (make-local-variable 'compilation-scroll-output) nil)
1080   (set (make-local-variable 'compilation-finish-functions)
1081        (list 'hs-lint-finish-hook))
1082   )
1083
1084 (defun hs-lint ()
1085   "Run HLint for current buffer with haskell source"
1086   (interactive)
1087   (save-some-buffers hs-lint-save-files)
1088   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1089                      'hs-lint-mode))
1090
1091 (provide 'hs-lint)
1092 ;;; hs-lint.el ends here
1093 #+end_src
1094
1095 #+begin_src emacs-lisp :tangle no
1096 (use-package hs-lint
1097   :load-path "lisp/"
1098   :bind (:map haskell-mode-map
1099               ("C-c l l" . hs-lint)))
1100 #+end_src
1101 * Emacs Enhancements
1102
1103 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1104
1105 #+begin_quote
1106 Emacs package that displays available keybindings in popup
1107 #+end_quote
1108
1109 #+begin_src emacs-lisp
1110 (use-package which-key
1111   :defer 1
1112   :config (which-key-mode))
1113 #+end_src
1114
1115 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1116
1117 #+begin_src emacs-lisp
1118 (use-package doom-modeline
1119   :demand t
1120   :config (setq doom-modeline-height 32)
1121   :hook (after-init . doom-modeline-init))
1122 #+end_src
1123
1124 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1125
1126 #+begin_src emacs-lisp :tangle no
1127 (use-package tao-theme
1128   :demand t
1129   :config (load-theme 'tao-yang t))
1130 #+end_src
1131
1132 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1133
1134 #+begin_src emacs-lisp
1135 (load-theme 'eink t)
1136 #+end_src
1137
1138 ** [[https://github.com/bbatsov/crux][crux]]
1139
1140 #+begin_src emacs-lisp
1141 (use-package crux
1142   :bind (("C-c d"    . crux-duplicate-current-line-or-region)
1143          ("C-c M-d"  . crux-duplicate-and-comment-current-line-or-region))
1144   :ryo
1145   ("o" crux-smart-open-line :exit t)
1146   ("O" crux-smart-open-line-above :exit t)
1147   ("SPC b K" crux-kill-other-buffers)
1148   ("d d" crux-kill-whole-line)
1149   ("c c" crux-kill-whole-line :then '(crux-smart-open-line-above) :exit t)
1150   ("SPC f" (("c" crux-copy-file-preserve-attributes)
1151             ("D" crux-delete-file-and-buffer)
1152             ("R" crux-rename-file-and-buffer))))
1153 #+end_src
1154
1155 ** [[https://github.com/alezost/mwim.el][mwim]]
1156
1157 #+begin_src emacs-lisp
1158 (use-package mwim
1159   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1160          ("C-e"    . mwim-end-of-code-or-line)
1161          ("<home>" . mwim-beginning-of-line-or-code)
1162          ("<end>"  . mwim-end-of-line-or-code))
1163   :ryo
1164   ("a" mwim-beginning-of-code-or-line)
1165   ("e" mwim-end-of-code-or-line))
1166 #+end_src
1167
1168 * Email
1169 ** [[https://notmuchmail.org][notmuch]]
1170
1171 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1172
1173 #+begin_src emacs-lisp
1174 (defun ab/notmuch ()
1175   "Delete other windows, then launch `notmuch'."
1176   (interactive)
1177   (require 'notmuch)
1178   (delete-other-windows)
1179   (notmuch))
1180
1181 ;; (map!
1182 ;;  :leader
1183 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1184 ;;  (:desc "search" :prefix "/"
1185 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1186 #+end_src
1187
1188 #+begin_src emacs-lisp
1189 (defvar ab-maildir "~/mail")
1190
1191 (use-package sendmail
1192   ;; :ensure nil
1193   :config
1194   (setq sendmail-program "/usr/bin/msmtp"
1195         mail-specify-envelope-from t
1196         mail-envelope-from 'header))
1197
1198 (use-package message
1199   ;; :ensure nil
1200   :config
1201   (setq message-kill-buffer-on-exit t
1202         message-send-mail-function 'message-send-mail-with-sendmail
1203         message-sendmail-envelope-from 'header
1204         message-directory "drafts"
1205         message-user-fqdn "aminb.org")
1206   (add-hook 'message-mode-hook
1207             (lambda () (setq fill-column 65
1208                         message-fill-column 65)))
1209   (add-hook 'message-mode-hook
1210             #'flyspell-mode)
1211   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1212   ;; TODO: is there a way to only run this when replying and not composing?
1213   ;; (add-hook 'notmuch-message-mode-hook
1214   ;;           (lambda () (progn
1215   ;;                   (newline)
1216   ;;                   (newline)
1217   ;;                   (forward-line -1)
1218   ;;                   (forward-line -1))))
1219   ;; (add-hook 'message-setup-hook
1220   ;;           #'mml-secure-message-sign-pgpmime)
1221   )
1222
1223 (after! mml-sec
1224   (setq mml-secure-openpgp-encrypt-to-self t
1225         mml-secure-openpgp-sign-with-sender t))
1226
1227 (use-package notmuch
1228   :ryo ("SPC m" ab/notmuch)
1229   :config
1230   (setq notmuch-hello-sections
1231         '(notmuch-hello-insert-header
1232           notmuch-hello-insert-saved-searches
1233           ;; notmuch-hello-insert-search
1234           notmuch-hello-insert-alltags)
1235         notmuch-search-oldest-first nil
1236         notmuch-show-all-tags-list t
1237         notmuch-message-headers  ; see bug follow-up above
1238         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1239         notmuch-hello-thousands-separator ","
1240         notmuch-fcc-dirs
1241         '(("amin@aminb.org"            . "amin/Sent")
1242           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1243           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1244           ("aminb@gnu.org"             . "gnu/Sent")
1245           (".*"                        . "sent"))
1246         notmuch-search-result-format
1247         '(("date" . "%12s ")
1248           ("count" . "%-7s ")
1249           ("authors" . "%-40s ")
1250           ("subject" . "%s ")
1251           ("tags" . "(%s)")))
1252   ;; (add-hook 'visual-fill-column-mode-hook
1253   ;;           (lambda ()
1254   ;;             (when (string= major-mode 'notmuch-message-mode)
1255   ;;               (setq visual-fill-column-width 70))))
1256   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1257   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1258   ;;             :override #'kill-this-buffer)
1259   :bind
1260   (:map notmuch-hello-mode-map
1261         ("g" . notmuch-poll-and-refresh-this-buffer)
1262         ("i" . (lambda ()
1263                  "Search for `inbox' tagged messages"
1264                  (interactive)
1265                  (notmuch-hello-search "tag:inbox")))
1266         ("u" . (lambda ()
1267                  "Search for `unread' tagged messages"
1268                  (interactive)
1269                  (notmuch-hello-search "tag:unread")))
1270         ("l" . (lambda ()
1271                  "Search for `latest tagged messages"
1272                  (interactive)
1273                  (notmuch-hello-search "tag:latest")))
1274         ("M" . (lambda ()
1275                  "Compose new mail and prompt for sender"
1276                  (interactive)
1277                  (let ((current-prefix-arg t))
1278                    (call-interactively #'notmuch-mua-new-mail)))))
1279   (:map notmuch-search-mode-map
1280         ("g" . notmuch-poll-and-refresh-this-buffer)
1281         ("k" . (lambda ()
1282                  "Mark message read"
1283                  (interactive)
1284                  (notmuch-search-tag '("-unread"))
1285                  ;; (notmuch-search-archive-thread)
1286                  (notmuch-search-next-thread)))
1287         ("u" . (lambda ()
1288                  "Mark message unread"
1289                  (interactive)
1290                  (notmuch-search-tag '("+unread"))
1291                  (notmuch-search-next-thread)))
1292         ("K" . (lambda ()
1293                  "Mark message deleted"
1294                  (interactive)
1295                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1296                  (notmuch-search-archive-thread)))
1297         ("S" . (lambda ()
1298                  "Mark message as spam"
1299                  (interactive)
1300                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1301                  (notmuch-search-archive-thread))))
1302   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1303         ("S" . (lambda ()
1304                  "Mark message as spam"
1305                  (interactive)
1306                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1307                  (notmuch-tree-archive-thread))))
1308 )
1309
1310 ;; (use-package counsel-notmuch
1311 ;;   :commands counsel-notmuch)
1312
1313 (after! notmuch-crypto
1314   (setq notmuch-crypto-process-mime t))
1315
1316 ;; (after! evil
1317 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1318 ;;         '((notmuch-hello-mode . emacs)
1319 ;;           (notmuch-search-mode . emacs)
1320 ;;           (notmuch-tree-mode . emacs))))
1321
1322 (after! recentf
1323   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1324 #+end_src
1325
1326 ** supercite
1327
1328 #+begin_src emacs-lisp :tangle no
1329 (use-package supercite
1330   :commands sc-cite-original
1331   :init
1332   (add-hook 'mail-citation-hook 'sc-cite-original)
1333
1334   (defun sc-remove-existing-signature ()
1335     (save-excursion
1336       (goto-char (region-beginning))
1337       (when (re-search-forward message-signature-separator (region-end) t)
1338         (delete-region (match-beginning 0) (region-end)))))
1339
1340   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1341
1342   (defun sc-remove-if-not-mailing-list ()
1343     (unless (assoc "list-id" sc-mail-info)
1344       (setq attribution sc-default-attribution
1345             citation (concat sc-citation-delimiter
1346                              sc-citation-separator))))
1347
1348   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1349
1350   :config
1351   (defun sc-fill-if-different (&optional prefix)
1352     "Fill the region bounded by `sc-fill-begin' and point.
1353 Only fill if optional PREFIX is different than
1354 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1355 fill region.  If PREFIX is not supplied, initialize fill
1356 variables.  This is useful for a regi `begin' frame-entry."
1357     (if (not prefix)
1358         (setq sc-fill-line-prefix ""
1359               sc-fill-begin (line-beginning-position))
1360       (if (and sc-auto-fill-region-p
1361                (not (string= prefix sc-fill-line-prefix)))
1362           (let ((fill-prefix sc-fill-line-prefix))
1363             (unless (or (string= fill-prefix "")
1364                         (save-excursion
1365                           (goto-char sc-fill-begin)
1366                           (or (looking-at ">+  +")
1367                               (< (length
1368                                   (buffer-substring (point)
1369                                                     (line-end-position)))
1370                                  65))))
1371               (fill-region sc-fill-begin (line-beginning-position)))
1372             (setq sc-fill-line-prefix prefix
1373                   sc-fill-begin (line-beginning-position)))))
1374 nil))
1375 #+end_src
1376
1377 * Blogging
1378 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1379
1380 #+begin_src emacs-lisp
1381 (use-package ox-hugo
1382   :after ox)
1383 #+end_src
1384
1385 * Post initialization
1386 :PROPERTIES:
1387 :CUSTOM_ID: post-initialization
1388 :END:
1389
1390 Display how long it took to load the init file.
1391
1392 #+begin_src emacs-lisp
1393 (message "Loading %s...done (%.3fs)" user-init-file
1394          (float-time (time-subtract (current-time)
1395                                     ab--before-user-init-time)))
1396 #+end_src
1397
1398 * Footer
1399 :PROPERTIES:
1400 :CUSTOM_ID: footer
1401 :END:
1402
1403 #+begin_src emacs-lisp :comments none
1404 ;;; init.el ends here
1405 #+end_src