emacs: update packages, switch from bbdb back to ebdb for now

[~bandali/configs] / .emacs.d / init.el

;;; init.el --- bandali's emacs configuration -*- lexical-binding: t -*-

;; Copyright (C) 2018-2019  Amin Bandali <bandali@gnu.org>

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Emacs configuration of Amin Bandali, computer scientist, functional
;; programmer, and free software activist.  Uses straight.el for
;; purely functional and fully reproducible package management.

;; Over the years, I've taken inspiration from configurations of many
;; great people.  Some that I can remember off the top of my head are:
;;
;; - https://github.com/dieggsy/dotfiles
;; - https://github.com/dakra/dmacs
;; - http://pages.sachachua.com/.emacs.d/Sacha.html
;; - https://github.com/dakrone/eos
;; - http://doc.rix.si/cce/cce.html
;; - https://github.com/jwiegley/dot-emacs
;; - https://github.com/wasamasa/dotemacs
;; - https://github.com/hlissner/doom-emacs

;;; Code:

;;; Emacs initialization

(defvar b/before-user-init-time (current-time)
  "Value of `current-time' when Emacs begins loading `user-init-file'.")
(defvar b/emacs-initialized nil
  "Whether Emacs has been initialized.")

(when (not (bound-and-true-p b/emacs-initialized))
  (message "Loading Emacs...done (%.3fs)"
           (float-time (time-subtract b/before-user-init-time
                                      before-init-time))))

;; temporarily increase `gc-cons-threshhold' and `gc-cons-percentage'
;; during startup to reduce garbage collection frequency.  clearing
;; `file-name-handler-alist' seems to help reduce startup time too.
(defvar b/gc-cons-threshold gc-cons-threshold)
(defvar b/gc-cons-percentage gc-cons-percentage)
(defvar b/file-name-handler-alist file-name-handler-alist)
(setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
      gc-cons-percentage 0.6
      file-name-handler-alist nil
      ;; sidesteps a bug when profiling with esup
      esup-child-profile-require-level 0)

;; set them back to their defaults once we're done initializing
(defun b/post-init ()
  "My post-initialize function, run after loading `user-init-file'."
  (setq b/emacs-initialized     t
        gc-cons-threshold       b/gc-cons-threshold
        gc-cons-percentage      b/gc-cons-percentage
        file-name-handler-alist b/file-name-handler-alist))
(add-hook 'after-init-hook #'b/post-init)

;; increase number of lines kept in *Messages* log
(setq message-log-max 20000)

;; optionally, uncomment to supress some byte-compiler warnings
;;   (see C-h v byte-compile-warnings RET for more info)
;; (setq byte-compile-warnings
;;       '(not free-vars unresolved noruntime lexical make-local))

\f
;;; whoami

(setq user-full-name "Amin Bandali"
      user-mail-address "bandali@gnu.org")

\f
;;; comment macro

;; useful for commenting out multiple sexps at a time
(defmacro comment (&rest _)
  "Comment out one or more s-expressions."
  (declare (indent defun))
  nil)

\f
;;; Package management

;; No package.el  (for emacs 26 and before, uncomment the following)
;; Not necessary when using straight.el
;;   (C-h v straight-package-neutering-mode RET)

(when (and
       (not (featurep 'straight))
       (version< emacs-version "27"))
  (setq package-enable-at-startup nil)
  ;; (package-initialize)
  )

;; for emacs 27 and later, we use early-init.el.  see
;; https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b

;; straight.el

;; Main engine start...

(setq straight-repository-branch "develop"
      straight-check-for-modifications '(check-on-save find-when-checking))

(defun b/bootstrap-straight ()
  (defvar bootstrap-version)
  (let ((bootstrap-file
         (expand-file-name "straight/repos/straight.el/bootstrap.el" user-emacs-directory))
        (bootstrap-version 5))
    (unless (file-exists-p bootstrap-file)
      (with-current-buffer
          (url-retrieve-synchronously
           "https://raw.githubusercontent.com/raxod502/straight.el/develop/install.el"
           'silent 'inhibit-cookies)
        (goto-char (point-max))
        (eval-print-last-sexp)))
    (load bootstrap-file nil 'nomessage)))

;; Solid rocket booster ignition...

(b/bootstrap-straight)

;; We have lift off!

(setq straight-use-package-by-default t)

(defmacro use-feature (name &rest args)
  "Like `use-package', but with `straight-use-package-by-default' disabled."
  (declare (indent 1))
  `(use-package ,name
     :straight nil
     ,@args))

(with-eval-after-load 'use-package-core
  (let ((upflk (car use-package-font-lock-keywords)))
    (font-lock-add-keywords
     'emacs-lisp-mode
     `((,(replace-regexp-in-string
          "use-package" "use-feature"
          (car upflk))
        ,@(cdr upflk))))))

(with-eval-after-load 'recentf
  (add-to-list 'recentf-exclude
               (expand-file-name "~/.emacs.d/straight/build/")))

(defun b/reload-init ()
  "Reload `user-init-file'."
  (interactive)
  (setq b/before-user-init-time   (current-time)
        b/file-name-handler-alist file-name-handler-alist)
  (load user-init-file nil 'nomessage)
  (b/post-init))

;; use-package
(straight-use-package 'use-package)

(if nil                             ; set to t when need to debug init
    (progn
      (setq use-package-verbose t
            use-package-expand-minimally nil
            use-package-compute-statistics t
            debug-on-error t)
      (require 'use-package))
  (setq use-package-verbose nil
        use-package-expand-minimally t))

(setq use-package-always-defer t)
(require 'bind-key)

\f
;;; Initial setup

(defvar b/exwm-p (string= (system-name) "jirud")
  "Whether or not we will be using `exwm'.")

;; keep ~/.emacs.d clean
(use-package no-littering
  :demand
  :config
  (defalias 'b/etc 'no-littering-expand-etc-file-name)
  (defalias 'b/var 'no-littering-expand-var-file-name))

;; separate custom file (don't want it mixing with init.el)
(use-feature custom
  :no-require
  :config
  (setq custom-file (b/etc "custom.el"))
  (when (file-exists-p custom-file)
    (load custom-file))
  ;; while at it, treat themes as safe
  (setf custom-safe-themes t)
  ;; only one custom theme at a time
  (comment
    (defadvice load-theme (before clear-previous-themes activate)
      "Clear existing theme settings instead of layering them"
      (mapc #'disable-theme custom-enabled-themes))))

;; load the secrets file if it exists, otherwise show a warning
(comment
  (with-demoted-errors
      (load (b/etc "secrets"))))

;; better $PATH (and other environment variable) handling
(use-package exec-path-from-shell
  :defer 0.4
  :init
  (setq exec-path-from-shell-arguments           nil
        exec-path-from-shell-check-startup-files nil)
  :config
  (exec-path-from-shell-initialize)
  ;; while we're at it, let's fix access to our running ssh-agent
  (exec-path-from-shell-copy-env "SSH_AGENT_PID")
  (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))

;; start up emacs server.  see
;; https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server
(use-feature server
  :defer 0.4
  :config (or (server-running-p) (server-mode)))

\f
;;; Useful utilities

;; useful libraries
(require 'cl-lib)
(require 'subr-x)

(defmacro b/setq-every (value &rest vars)
  "Set all the variables from VARS to value VALUE."
  (declare (indent defun) (debug t))
  `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))

(defun b/start-process (program &rest args)
  "Same as `start-process', but doesn't bother about name and buffer."
  (let ((process-name (concat program "_process"))
        (buffer-name  (generate-new-buffer-name
                       (concat program "_output"))))
    (apply #'start-process
           process-name buffer-name program args)))

(defun b/dired-start-process (program &optional args)
  "Open current file with a PROGRAM."
  ;; Shell command looks like this: "program [ARGS]... FILE" (ARGS can
  ;; be nil, so remove it).
  (apply #'b/start-process
         program
         (remove nil (list args (dired-get-file-for-visit)))))

(defun b/add-elisp-section ()
  (interactive)
  (insert "\n")
  (previous-line)
  (insert "\n\f\n;;; "))

(defvar b/fill-column 47
  "My custom `fill-column'.")

(defconst b/asterism "* * *")

(defun b/insert-asterism ()
  "Insert a centred asterism."
  (interactive)
  (insert
   (concat
    "\n\n"
    (make-string (floor (/ (- b/fill-column (length b/asterism)) 2))
                 ?\s)
    b/asterism
    "\n\n")))

(defun b/no-mouse-autoselect-window ()
  "Conveniently disable `focus-follows-mouse'.
For disabling the behaviour for certain buffers and/or modes."
  (make-local-variable 'mouse-autoselect-window)
  (setq mouse-autoselect-window nil))

\f
;;; Defaults

;;;; C-level customizations

(setq
 ;; minibuffer
 enable-recursive-minibuffers t
 resize-mini-windows t
 ;; more useful frame titles
 frame-title-format '("" invocation-name " - "
                      (:eval
                       (if (buffer-file-name)
                           (abbreviate-file-name (buffer-file-name))
                         "%b")))
 ;; i don't feel like jumping out of my chair every now and again; so
 ;; don't BEEP! at me, emacs
 ring-bell-function 'ignore
 ;; better scrolling
 ;; scroll-margin 1
 ;; scroll-conservatively 10000
 scroll-step 1
 scroll-conservatively 10
 scroll-preserve-screen-position 1
 ;; focus follows mouse
 mouse-autoselect-window t
 ;; custom fill-column
 fill-column b/fill-column)

(setq-default
 ;; always use space for indentation
 indent-tabs-mode nil
 tab-width 4
 ;; cursor shape
 cursor-type 'bar)

;; unicode support
(comment
  (dolist (ft (fontset-list))
    (set-fontset-font
     ft
     'unicode
     (font-spec :name "Source Code Pro" :size 14))
    (set-fontset-font
     ft
     'unicode
     (font-spec :name "DejaVu Sans Mono")
     nil
     'append)
    ;; (set-fontset-font
    ;;  ft
    ;;  'unicode
    ;;  (font-spec
    ;;   :name "Symbola monospacified for DejaVu Sans Mono")
    ;;  nil
    ;;  'append)
    ;; (set-fontset-font
    ;;  ft
    ;;  #x2115  ; ℕ
    ;;  (font-spec :name "DejaVu Sans Mono")
    ;;  nil
    ;;  'append)
    (set-fontset-font
     ft
     (cons ?Α ?ω)
     (font-spec :name "DejaVu Sans Mono" :size 14)
     nil
     'prepend)))

;;;; Elisp-level customizations

(use-feature startup
  :no-require
  :demand
  :config
  ;; don't need to see the startup echo area message
  (advice-add #'display-startup-echo-area-message :override #'ignore)
  :custom
  ;; i want *scratch* as my startup buffer
  (initial-buffer-choice t)
  ;; i don't need the default hint
  (initial-scratch-message nil)
  ;; use customizable text-mode as major mode for *scratch*
  ;; (initial-major-mode 'text-mode)
  ;; inhibit buffer list when more than 2 files are loaded
  (inhibit-startup-buffer-menu t)
  ;; don't need to see the startup screen or echo area message
  (inhibit-startup-screen t)
  (inhibit-startup-echo-area-message user-login-name))

(use-feature files
  :no-require
  :demand
  :custom
  ;; backups (C-h v make-backup-files RET)
  (backup-by-copying t)
  (version-control t)
  (delete-old-versions t)

  ;; auto-save
  (auto-save-file-name-transforms
   `((".*" ,(b/var "auto-save/") t)))

  ;; insert newline at the end of files
  (require-final-newline t)

  ;; open read-only file buffers in view-mode
  ;; (enables niceties like `q' for quit)
  (view-read-only t))

;; disable disabled commands
(setq disabled-command-function nil)

;; lazy-person-friendly yes/no prompts
(defalias 'yes-or-no-p #'y-or-n-p)

;; enable automatic reloading of changed buffers and files
(use-feature autorevert
  :demand
  :config
  (global-auto-revert-mode 1)
  :custom
  (auto-revert-verbose nil)
  (global-auto-revert-non-file-buffers nil))

;; time and battery in mode-line
(use-feature time
  :if b/exwm-p
  :demand
  :config
  (display-time-mode)
  :custom
  (display-time-default-load-average nil)
  (display-time-format "%a %b %-e, %-l:%M%P"))

(use-feature battery
  :if b/exwm-p
  :demand
  :config
  (display-battery-mode)
  :custom
  (battery-mode-line-format " %p%% %t"))

(use-feature fringe
  :demand
  :config
  ;; smaller fringe
  ;; (fringe-mode '(3 . 1))
  (fringe-mode nil))

(use-feature winner
  :demand
  :config
  ;; enable winner-mode (C-h f winner-mode RET)
  (winner-mode 1))

(use-feature compile
  :config
  ;; don't display *compilation* buffer on success.  based on
  ;; https://stackoverflow.com/a/17788551, with changes to use `cl-letf'
  ;; instead of the now obsolete `flet'.
  (defun b/compilation-finish-function (buffer outstr)
    (unless (string-match "finished" outstr)
      (switch-to-buffer-other-window buffer))
    t)

  (setq compilation-finish-functions #'b/compilation-finish-function)

  (require 'cl-macs)

  (defadvice compilation-start
      (around inhibit-display
              (command &optional mode name-function highlight-regexp))
    (if (not (string-match "^\\(find\\|grep\\)" command))
        (cl-letf (((symbol-function 'display-buffer) #'ignore))
          (save-window-excursion ad-do-it))
      ad-do-it))
  (ad-activate 'compilation-start))

(use-feature isearch
  :custom
  ;; allow scrolling in Isearch
  (isearch-allow-scroll t)
  ;; search for non-ASCII characters: i’d like non-ASCII characters such
  ;; as ‘’“”«»‹›áⓐ𝒶 to be selected when i search for their ASCII
  ;; counterpart.  shoutout to
  ;; http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html
  (search-default-mode #'char-fold-to-regexp))

;; uncomment to extend the above behaviour to query-replace
(comment
  (use-feature replace
    :custom
    (replace-char-fold t)))

(use-feature vc
  :bind ("C-x v C-=" . vc-ediff))

(use-feature vc-git
  :after vc
  :custom
  (vc-git-print-log-follow t))

(use-feature ediff
  :config (add-hook 'ediff-after-quit-hook-internal 'winner-undo)
  :custom ((ediff-window-setup-function 'ediff-setup-windows-plain)
           (ediff-split-window-function 'split-window-horizontally)))

(use-feature face-remap
  :custom
  ;; gentler font resizing
  (text-scale-mode-step 1.05))

(use-feature mwheel
  :defer 0.4
  :config
  (setq mouse-wheel-scroll-amount '(1 ((shift) . 1)) ; one line at a time
        mouse-wheel-progressive-speed nil            ; don't accelerate scrolling
        mouse-wheel-follow-mouse t))                 ; scroll window under mouse

(use-feature pixel-scroll
  :defer 0.4
  :config (pixel-scroll-mode 1))

(use-feature epg-config
  :custom
  ((epg-gpg-program (executable-find "gpg"))))

(use-feature auth-source
  :custom
  (auth-sources '("~/.authinfo.gpg"))
  (authinfo-hidden (regexp-opt '("password" "client-secret" "token"))))

\f
;;; General bindings

(bind-keys
 ("C-c a i" . ielm)

 ("C-c e b" . eval-buffer)
 ("C-c e e" . eval-last-sexp)
 ("C-c e r" . eval-region)

 ("C-c e i" . emacs-init-time)
 ("C-c e u" . emacs-uptime)
 ("C-c e v" . emacs-version)

 ("C-c F m" . make-frame-command)
 ("C-c F d" . delete-frame)
 ("C-c F D" . server-edit)

 ("C-S-h C" . describe-char)
 ("C-S-h F" . describe-face)

 ("C-x k"   . kill-this-buffer)
 ("C-x K"   . kill-buffer)
 ("C-x s"   . save-buffer)
 ("C-x S"   . save-some-buffers)

 :map emacs-lisp-mode-map
 ("<C-return>" . b/add-elisp-section))

(when (display-graphic-p)
  (unbind-key "C-z" global-map))

(bind-keys
 ;; for back and forward mouse keys
 ("<XF86Back>"     . previous-buffer)
 ("<mouse-8>"      . previous-buffer)
 ;; ("<drag-mouse-8>" . previous-buffer)
 ("<XF86Forward>"  . next-buffer)
 ("<mouse-9>"      . next-buffer)
 ;; ("<drag-mouse-9>" . next-buffer)
 ;; ("<drag-mouse-2>" . kill-this-buffer)
 ;; ("<drag-mouse-3>" . switch-to-buffer)
 )

(bind-keys
 :prefix-map b/straight-prefix-map
 :prefix "C-c p s"
 ("u" . straight-use-package)
 ("f" . straight-freeze-versions)
 ("t" . straight-thaw-versions)
 ("P" . straight-prune-build)
 ("g" . straight-get-recipe)
 ("r" . b/reload-init)
 ;; M-x ^straight-.*-all$
 ("a c" . straight-check-all)
 ("a f" . straight-fetch-all)
 ("a m" . straight-merge-all)
 ("a n" . straight-normalize-all)
 ("a F" . straight-pull-all)
 ("a P" . straight-push-all)
 ("a r" . straight-rebuild-all)
 ;; M-x ^straight-.*-package$
 ("p c" . straight-check-package)
 ("p f" . straight-fetch-package)
 ("p m" . straight-merge-package)
 ("p n" . straight-normalize-package)
 ("p F" . straight-pull-package)
 ("p P" . straight-push-package)
 ("p r" . straight-rebuild-package))

\f
;;; Essential packages

(use-package exwm
  :if b/exwm-p
  :demand
  :config
  ;; make class name the buffer name, truncating beyond 60 characters
  (defun b/exwm-rename-buffer ()
    (interactive)
    (exwm-workspace-rename-buffer
     (concat exwm-class-name ":"
             (if (<= (length exwm-title) 60) exwm-title
               (concat (substring exwm-title 0 59) "...")))))
  ;; Enable EXWM
  (exwm-enable)
  :hook ((exwm-update-class . b/exwm-rename-buffer)
         (exwm-update-title . b/exwm-rename-buffer)))

(use-feature exwm-config
  :demand
  :after exwm
  :hook (exwm-init . exwm-config--fix/ido-buffer-window-other-frame))

(use-feature exwm-input
  :demand
  :after exwm
  :config
  (defun b/exwm-ws-prev-index ()
    "Return the index for the previous EXWM workspace, wrapping
around if needed."
    (if (= exwm-workspace-current-index 0)
        (1- exwm-workspace-number)
      (1- exwm-workspace-current-index)))

  (defun b/exwm-ws-next-index ()
    "Return the index for the next EXWM workspace, wrapping
around if needed."
    (if (= exwm-workspace-current-index
           (1- exwm-workspace-number))
        0
      (1+ exwm-workspace-current-index)))

  ;; shorten 'C-c C-q' to 'C-q'
  (define-key exwm-mode-map [?\C-q] #'exwm-input-send-next-key)

  (setq exwm-workspace-number 4
        exwm-input-global-keys
        `(([?\s-R] . exwm-reset)
          ([?\s-\\] . exwm-workspace-switch)
          ([?\s-\s] . dmenu)
          ([?\S-\s-\s] . (lambda (command)
                              (interactive
                               (list (read-shell-command "➜ ")))
                              (start-process-shell-command
                               command nil command)))
          ([s-return] . (lambda ()
                          (interactive)
                          (start-process "" nil "urxvt")))
          ([?\C-\s-\s] . counsel-linux-app)
          ([?\M-\s-\s] . (lambda ()
                           (interactive)
                           (start-process-shell-command
                            "rofi-pass" nil "rofi-pass")))
          ([?\s-h] . windmove-left)
          ([?\s-j] . windmove-down)
          ([?\s-k] . windmove-up)
          ([?\s-l] . windmove-right)
          ([?\s-H] . windmove-swap-states-left)
          ([?\s-J] . windmove-swap-states-down)
          ([?\s-K] . windmove-swap-states-up)
          ([?\s-L] . windmove-swap-states-right)
          ([?\M-\s-h] . shrink-window-horizontally)
          ([?\M-\s-l] . enlarge-window-horizontally)
          ([?\M-\s-k] . shrink-window)
          ([?\M-\s-j] . enlarge-window)
          ([?\s-\[] . (lambda ()
                        (interactive)
                        (exwm-workspace-switch-create
                         (b/exwm-ws-prev-index))))
          ([?\s-\]] . (lambda ()
                        (interactive)
                        (exwm-workspace-switch-create
                         (b/exwm-ws-next-index))))
          ([?\s-{] . (lambda ()
                       (interactive)
                       (exwm-workspace-move-window
                        (b/exwm-ws-prev-index))))
          ([?\s-}] . (lambda ()
                       (interactive)
                       (exwm-workspace-move-window
                        (b/exwm-ws-next-index))))
          ,@(mapcar (lambda (i)
                      `(,(kbd (format "s-%d" i)) .
                        (lambda ()
                          (interactive)
                          (exwm-workspace-switch-create ,i))))
                    (number-sequence 0 (1- exwm-workspace-number)))
          ([?\s-t] . exwm-floating-toggle-floating)
          ([?\s-f] . exwm-layout-toggle-fullscreen)
          ([?\s-W] . (lambda ()
                       (interactive)
                       (kill-buffer (current-buffer))))
          ([?\s-Q] . (lambda ()
                       (interactive)
                       (exwm-manage--kill-client)))
          ([?\s-\'] . (lambda ()
                        (interactive)
                        (start-process-shell-command
                         "rofi-light" nil "rofi-light")))
          ([XF86AudioMute] .
           (lambda ()
             (interactive)
             (start-process "" nil "pamixer" "--toggle-mute")))
          ([XF86AudioLowerVolume] .
           (lambda ()
             (interactive)
             (start-process
              "" nil "pamixer" "--allow-boost" "--decrease" "5")))
          ([XF86AudioRaiseVolume] .
           (lambda ()
             (interactive)
             (start-process
              "" nil "pamixer" "--allow-boost" "--increase" "5")))
          ([XF86AudioPlay] .
           (lambda ()
             (interactive)
             (start-process "" nil "mpc" "toggle")))
          ([XF86AudioPrev] .
           (lambda ()
             (interactive)
             (start-process "" nil "mpc" "prev")))
          ([XF86AudioNext] .
           (lambda ()
             (interactive)
             (start-process "" nil "mpc" "next")))
          ([XF86ScreenSaver] .
           (lambda ()
		     (interactive)
		     (start-process "" nil "dm-tool" "lock")))
          ([\s-XF86Back] . previous-buffer)
          ([\s-XF86Forward] . next-buffer)))

  ;; Line-editing shortcuts
  (setq exwm-input-simulation-keys
    '(;; movement
      ([?\C-b] . [left])
      ([?\M-b] . [C-left])
      ([?\C-f] . [right])
      ([?\M-f] . [C-right])
      ([?\C-p] . [up])
      ([?\C-n] . [down])
      ([?\C-a] . [home])
      ([?\C-e] . [end])
      ([?\M-v] . [prior])
      ([?\C-v] . [next])
      ([?\C-d] . [delete])
      ([?\C-k] . [S-end ?\C-x])
      ([?\M-<] . C-home)
      ([?\M->] . C-end)
      ;; cut/copy/paste
      ([?\C-w] . [?\C-x])
      ([?\M-w] . [?\C-c])
      ([?\C-y] . [?\C-v])
      ([?\M-d] . [C-S-right ?\C-x])
      ([?\M-\d] . [C-S-left ?\C-x])
      ;; window
      ([?\s-w] . [?\C-w])
      ([?\s-q] . [?\C-q])
      ;; misc
      ([?\C-s] . [?\C-f])
      ([?\s-s] . [?\C-s])
      ([?\C-g] . [escape]))))

(use-feature exwm-manage
  :demand
  :after exwm
  :hook
  (exwm-manage-finish . (lambda ()
                          (when exwm-class-name
                            (cond
                             ((string= exwm-class-name "Abrowser")
                              (exwm-input-set-local-simulation-keys
                               `(,@exwm-input-simulation-keys
                                 ([?\C-\S-d] . [?\C-d]))))
                             ((string= exwm-class-name "URxvt")
                              (exwm-input-set-local-simulation-keys
                               '(([?\C-c ?\C-c] . [?\C-c])
                                 ([?\C-c ?\C-u] . [?\C-u]))))
                             ((string= exwm-class-name "Zathura")
                              (exwm-input-set-local-simulation-keys
                               '(([?\C-p] . [C-up])
                                 ([?\C-n] . [C-down])))))))))

(use-feature exwm-randr
  :demand
  :after exwm
  :config
  (exwm-randr-enable)
  :custom
  (exwm-randr-workspace-monitor-plist '(1 "VGA-1")))

(use-feature exwm-systemtray
  :demand
  :after exwm
  :config
  (exwm-systemtray-enable))

(use-feature exwm-workspace)

(use-package exwm-edit
  :demand
  :after exwm)

;; use the org-plus-contrib package to get the whole deal
(use-package org-plus-contrib)

(use-feature org
  :defer 0.5
  :config
  (setq org-src-tab-acts-natively t
        org-src-preserve-indentation nil
        org-edit-src-content-indentation 0
        org-link-email-description-format "Email %c: %s" ; %.30s
        org-highlight-latex-and-related '(entities)
        org-use-speed-commands t
        org-startup-folded 'content
        org-catch-invisible-edits 'show-and-error
        org-log-done 'time)
  (when (version< org-version "9.3")
    (setq org-email-link-description-format
          org-link-email-description-format))
  (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
  (add-to-list 'org-modules 'org-habit)
  :bind
  (("C-c a o a" . org-agenda)
   :map org-mode-map
   ("M-L" . org-insert-last-stored-link)
   ("M-O" . org-toggle-link-display))
  :hook ((org-mode . org-indent-mode)
         (org-mode . auto-fill-mode)
         (org-mode . flyspell-mode))
  :custom
  (org-pretty-entities t)
  (org-agenda-files '("~/usr/org/todos/personal.org"
                      "~/usr/org/todos/habits.org"
                      "~/src/git/masters-thesis/todo.org"))
  (org-agenda-start-on-weekday 0)
  (org-agenda-time-leading-zero t)
  (org-habit-graph-column 44)
  (org-latex-packages-alist '(("" "listings") ("" "color")))
  :custom-face
  '(org-block-begin-line ((t (:foreground "#5a5b5a" :background "#1d1f21"))))
  '(org-block ((t (:background "#1d1f21"))))
  '(org-latex-and-related ((t (:foreground "#b294bb")))))

(use-feature ox-latex
  :after ox
  :config
  (setq org-latex-listings 'listings
        ;; org-latex-prefer-user-labels t
        )
  (add-to-list 'org-latex-classes
               '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
                 ("\\section{%s}"       . "\\section*{%s}")
                 ("\\subsection{%s}"    . "\\subsection*{%s}")
                 ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
                 ("\\paragraph{%s}"     . "\\paragraph*{%s}")
                 ("\\subparagraph{%s}"  . "\\subparagraph*{%s}"))
               t)
  (require 'ox-beamer))

(use-feature ox-extra
  :config
  (ox-extras-activate '(latex-header-blocks ignore-headlines)))

;; asynchronous tangle, using emacs-async to asynchronously tangle an
;; org file.  closely inspired by
;; https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles
(with-eval-after-load 'org
  (defvar b/show-async-tangle-results nil
    "Keep *emacs* async buffers around for later inspection.")

  (defvar b/show-async-tangle-time nil
    "Show the time spent tangling the file.")

  (defun b/async-babel-tangle ()
    "Tangle org file asynchronously."
    (interactive)
    (let* ((file-tangle-start-time (current-time))
           (file (buffer-file-name))
           (file-nodir (file-name-nondirectory file))
           ;; (async-quiet-switch "-q")
           (file-noext (file-name-sans-extension file)))
      (async-start
       `(lambda ()
          (require 'org)
          (org-babel-tangle-file ,file))
       (unless b/show-async-tangle-results
         `(lambda (result)
            (if result
                (message "Tangled %s%s"
                         ,file-nodir
                         (if b/show-async-tangle-time
                             (format " (%.3fs)"
                                     (float-time (time-subtract (current-time)
                                                                ',file-tangle-start-time)))
                           ""))
              (message "Tangling %s failed" ,file-nodir))))))))

(add-to-list
 'safe-local-variable-values
 '(eval add-hook 'after-save-hook #'b/async-babel-tangle 'append 'local))

;; *the* right way to do git
(use-package magit
  :defer 0.5
  :bind (("C-x g"   . magit-status)
         ("C-c g g" . magit-status)
         ("C-c g b" . magit-blame-addition)
         ("C-c g l" . magit-log-buffer-file))
  :config
  (magit-add-section-hook 'magit-status-sections-hook
                          'magit-insert-modules
                          'magit-insert-stashes
                          'append)
  ;; (magit-add-section-hook 'magit-status-sections-hook
  ;;                         'magit-insert-ignored-files
  ;;                         'magit-insert-untracked-files
  ;;                         'append)
  (setq magit-repository-directories '(("~/" . 0)
                                       ("~/src/git/" . 1)))
  (nconc magit-section-initial-visibility-alist
         '(([unpulled status] . show)
           ([unpushed status] . show)))
  :custom
  (magit-diff-refine-hunk t)
  (magit-display-buffer-function #'magit-display-buffer-fullframe-status-v1)
  ;; (magit-completing-read-function 'magit-ido-completing-read)
  :custom-face (magit-diff-file-heading ((t (:weight normal)))))

;; recently opened files
(use-feature recentf
  :defer 0.2
  ;; :config
  ;; (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
  :config
  (recentf-mode)
  :custom
  (recentf-max-saved-items 2000))

;; smart M-x enhancement (needed by counsel for history)
;; (use-package smex)

(bind-keys
 ("C-c f ." . find-file)
 ("C-c f l" . find-library)
 ("C-c f r" . recentf-open-files)
 ("C-c x"   . execute-extended-command))

(comment
  (use-feature ido
    :demand
    :bind
    (:map ido-common-completion-map
          ([escape] . minibuffer-keyboard-quit)
          ("DEL"    . b/ido-backspace))
    :config
    (require 'delsel)
    (defun b/ido-backspace ()
      "Forward to `backward-delete-char'.  On error (read-only), quit."
      (interactive)
      (condition-case nil
          (backward-delete-char 1)
        (error
         (minibuffer-keyboard-quit))))
    (ido-mode 1)
    (ido-everywhere 1)
    :custom
    (ido-enable-flex-matching t)
    ;; (ido-enable-regexp t)
    ;; (ido-enable-prefix t)
    (ido-max-window-height 10)
    (ido-use-virtual-buffers t))

  (use-package ido-vertical-mode
    :defer 0.3
    :config
    (ido-vertical-mode 1)
    :custom
    (ido-vertical-define-keys 'C-n-C-p-up-and-down)
    (ido-vertical-show-count t))

  (use-package ido-completing-read+
    :defer 0.3
    :after ido
    :config
    (ido-ubiquitous-mode 1))

  (use-package crm-custom
    :defer 0.3
    :config
    (crm-custom-mode 1))

  (use-feature icomplete
    :defer 0.3
    :config
    (icomplete-mode 1)))

(use-package amx
  :defer 0.3
  :config
  (amx-mode))

(use-package ivy
  :defer 0.3
  :bind
  (:map ivy-minibuffer-map
   ([escape] . keyboard-escape-quit)
   ([S-up]   . ivy-previous-history-element)
   ([S-down] . ivy-next-history-element)
   ("DEL"    . ivy-backward-delete-char))
  :config
  (setq ivy-wrap t
        ;; ivy-height 14
        ivy-use-virtual-buffers t
        ivy-virtual-abbreviate 'abbreviate
        ivy-count-format "%d/%d ")

  (defvar b/ivy-ignore-buffer-modes '(magit-mode erc-mode dired-mode))
  (defun b/ivy-ignore-buffer-p (str)
    "Return non-nil if str names a buffer with a major mode
derived from one of `b/ivy-ignore-buffer-modes'.

This function is intended for use with `ivy-ignore-buffers'."
    (let* ((buf (get-buffer str))
           (mode (and buf (buffer-local-value 'major-mode buf))))
      (and mode
           (apply #'provided-mode-derived-p mode b/ivy-ignore-buffer-modes))))
  (add-to-list 'ivy-ignore-buffers 'b/ivy-ignore-buffer-p)

  (ivy-mode 1)
  :custom-face
  (ivy-minibuffer-match-face-1 ((t (:background "#eeeeee"))))
  (ivy-minibuffer-match-face-2 ((t (:background "#e7e7e7" :weight bold))))
  (ivy-minibuffer-match-face-3 ((t (:background "light goldenrod" :weight semi-bold))))
  (ivy-minibuffer-match-face-4 ((t (:background "misty rose" :weight semi-bold))))
  (ivy-current-match ((((class color) (background light))
                       :background "#d7d7d7" :foreground "black")
                      (((class color) (background dark))
                       :background "#65a7e2" :foreground "black"))))

(use-package swiper
  :demand
  :after ivy
  :bind (("C-S-s" . swiper-isearch)))

(use-package counsel
  :demand
  :after ivy
  :bind (("C-c f r" . counsel-recentf)
         :map minibuffer-local-map
         ("C-r" . counsel-minibuffer-history))
  :config
  (counsel-mode 1)
  (defalias 'locate #'counsel-locate))

(comment
  (use-package helm
    :commands (helm-M-x helm-mini helm-resume)
    :bind (("M-x"     . helm-M-x)
           ("M-y"     . helm-show-kill-ring)
           ("C-x b"   . helm-mini)
           ("C-x C-b" . helm-buffers-list)
           ("C-x C-f" . helm-find-files)
           ("C-h r"   . helm-info-emacs)
           ("C-s-r"   . helm-resume)
           :map helm-map
           ("<tab>" . helm-execute-persistent-action)
           ("C-i"   . helm-execute-persistent-action) ; Make TAB work in terminals
           ("C-z"   . helm-select-action))            ; List actions
    :config (helm-mode 1)))

(use-feature eshell
  :defer 0.5
  :commands eshell
  :bind ("C-c a s e" . eshell)
  :config
  (eval-when-compile (defvar eshell-prompt-regexp))
  (defun b/eshell-quit-or-delete-char (arg)
    (interactive "p")
    (if (and (eolp) (looking-back eshell-prompt-regexp nil))
        (eshell-life-is-too-much)
      (delete-char arg)))

  (defun b/eshell-clear ()
    (interactive)
    (let ((inhibit-read-only t))
      (erase-buffer))
    (eshell-send-input))

  (defun b/eshell-setup ()
    (make-local-variable 'company-idle-delay)
    (defvar company-idle-delay)
    (setq company-idle-delay nil)
    (bind-keys :map eshell-mode-map
               ("C-d"   . b/eshell-quit-or-delete-char)
               ("C-S-l" . b/eshell-clear)
               ("M-r"   . counsel-esh-history)
               ;; ([tab]   . company-complete)
               :map eshell-hist-mode-map
               ("M-r" . counsel-esh-history)))

  :hook (eshell-mode . b/eshell-setup)
  :custom
  (eshell-hist-ignoredups t)
  (eshell-input-filter 'eshell-input-filter-initial-space))

(use-feature ibuffer
  :bind
  (("C-x C-b" . ibuffer)
   :map ibuffer-mode-map
   ("P"   . ibuffer-backward-filter-group)
   ("N"   . ibuffer-forward-filter-group)
   ("M-p" . ibuffer-do-print)
   ("M-n" . ibuffer-do-shell-command-pipe-replace))
  :config
  ;; Use human readable Size column instead of original one
  (define-ibuffer-column size-h
    (:name "Size" :inline t)
    (cond
     ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
     ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
     ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
     (t (format "%8d" (buffer-size)))))
  :custom
  (ibuffer-saved-filter-groups
   '(("default"
      ("dired" (mode . dired-mode))
      ("org"   (mode . org-mode))
      ("gnus"
       (or
        (mode . gnus-group-mode)
        (mode . gnus-summary-mode)
        (mode . gnus-article-mode)
        ;; not really, but...
        (mode . message-mode)))
      ("web"
       (or
        (mode . web-mode)
        (mode . css-mode)
        (mode . scss-mode)
        (mode . js2-mode)))
      ("shell"
       (or
        (mode . eshell-mode)
        (mode . shell-mode)
        (mode . term-mode)))
      ("programming"
       (or
        (mode . python-mode)
        (mode . c-mode)
        (mode . c++-mode)
        (mode . java-mode)
        (mode . emacs-lisp-mode)
        (mode . scheme-mode)
        (mode . haskell-mode)
        (mode . lean-mode)
        (mode . go-mode)
        (mode . alloy-mode)))
      ("tex"
       (or
        (mode . bibtex-mode)
        (mode . latex-mode)))
      ("emacs"
       (or
        (name . "^\\*scratch\\*$")
        (name . "^\\*Messages\\*$")))
      ("exwm" (mode . exwm-mode))
      ("erc" (mode . erc-mode)))))
  (ibuffer-formats
   '((mark modified read-only locked " "
           (name 72 72 :left :elide)
           " "
           (size-h 9 -1 :right)
           " "
           (mode 16 16 :left :elide)
           " " filename-and-process)
     (mark " "
           (name 16 -1)
           " " filename)))
  :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))

(use-feature outline
  :disabled
  :hook (prog-mode . outline-minor-mode)
  :bind
  (:map
   outline-minor-mode-map
   ("<s-tab>"  . outline-toggle-children)
   ("M-p"      . outline-previous-visible-heading)
   ("M-n"      . outline-next-visible-heading)
   :prefix-map b/outline-prefix-map
   :prefix "s-O"
   ("TAB" . outline-toggle-children)
   ("a"   . outline-hide-body)
   ("H"   . outline-hide-body)
   ("S"   . outline-show-all)
   ("h"   . outline-hide-subtree)
   ("s"   . outline-show-subtree)))

(use-feature ls-lisp
  :custom (ls-lisp-dirs-first t))

(use-feature dired
  :config
  (setq dired-dwim-target t
        dired-listing-switches "-alh"
        ls-lisp-use-insert-directory-program nil)

  ;; easily diff 2 marked files
  ;; https://oremacs.com/2017/03/18/dired-ediff/
  (defun dired-ediff-files ()
    (interactive)
    (require 'dired-aux)
    (defvar ediff-after-quit-hook-internal)
    (let ((files (dired-get-marked-files))
          (wnd (current-window-configuration)))
      (if (<= (length files) 2)
          (let ((file1 (car files))
                (file2 (if (cdr files)
                           (cadr files)
                         (read-file-name
                          "file: "
                          (dired-dwim-target-directory)))))
            (if (file-newer-than-file-p file1 file2)
                (ediff-files file2 file1)
              (ediff-files file1 file2))
            (add-hook 'ediff-after-quit-hook-internal
                      (lambda ()
                        (setq ediff-after-quit-hook-internal nil)
                        (set-window-configuration wnd))))
        (error "no more than 2 files should be marked"))))

  (require 'dired-x)
  (setq dired-guess-shell-alist-user
        '(("\\.pdf\\'"  "evince" "zathura" "okular")
          ("\\.doc\\'"  "libreoffice")
          ("\\.docx\\'" "libreoffice")
          ("\\.ppt\\'"  "libreoffice")
          ("\\.pptx\\'" "libreoffice")
          ("\\.xls\\'"  "libreoffice")
          ("\\.xlsx\\'" "libreoffice")
          ("\\.flac\\'" "mpv")))
  :bind (:map dired-mode-map
              ("b"  . dired-up-directory)
              ("e"  . dired-ediff-files)
              ("E"  . dired-toggle-read-only)
              ("\\" . dired-hide-details-mode)
              ("z"  . (lambda ()
                        (interactive)
                        (b/dired-start-process "zathura"))))
  :hook (dired-mode . dired-hide-details-mode))

(use-feature help
  :config
  (temp-buffer-resize-mode)
  (setq help-window-select t))

(use-feature tramp
  :config
  (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
  (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
  (add-to-list 'tramp-default-proxies-alist
               (list (regexp-quote (system-name)) nil nil)))

(use-package dash
  :config (dash-enable-font-lock))

(use-feature doc-view
  :bind (:map doc-view-mode-map
              ("M-RET" . image-previous-line)))

\f
;;; Editing

;; highlight uncommitted changes in the left fringe
(use-package diff-hl
  :defer 0.6
  :config
  (setq diff-hl-draw-borders nil)
  (global-diff-hl-mode)
  :hook (magit-post-refresh . diff-hl-magit-post-refresh))

;; display Lisp objects at point in the echo area
(use-feature eldoc
  :when (version< "25" emacs-version)
  :config (global-eldoc-mode))

;; highlight matching parens
(use-feature paren
  :demand
  :config (show-paren-mode))

(use-feature elec-pair
  :demand
  :config (electric-pair-mode))

(use-feature simple
  :config (column-number-mode)
  :custom
  ;; Save what I copy into clipboard from other applications into Emacs'
  ;; kill-ring, which would allow me to still be able to easily access
  ;; it in case I kill (cut or copy) something else inside Emacs before
  ;; yanking (pasting) what I'd originally intended to.
  (save-interprogram-paste-before-kill t))

;; save minibuffer history
(use-feature savehist
  :demand
  :config
  (savehist-mode)
  (add-to-list 'savehist-additional-variables 'kill-ring))

;; automatically save place in files
(use-feature saveplace
  :when (version< "25" emacs-version)
  :config (save-place-mode))

(use-feature prog-mode
  :config (global-prettify-symbols-mode)
  (defun indicate-buffer-boundaries-left ()
    (setq indicate-buffer-boundaries 'left))
  (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))

(use-feature text-mode
  :bind (:map text-mode-map ("C-*" . b/insert-asterism))
  :hook ((text-mode . indicate-buffer-boundaries-left)
         (text-mode . flyspell-mode)))

(use-feature conf-mode
  :mode "\\.*rc$")

(use-feature sh-mode
  :mode "\\.bashrc$")

(use-package company
  :bind
  (:map company-active-map
        ([tab]    . company-complete-common-or-cycle)
        ([escape] . company-abort)
        ("C-p"    . company-select-previous-or-abort)
        ("C-n"    . company-select-next-or-abort))
  :custom
  (company-minimum-prefix-length 1)
  (company-selection-wrap-around t)
  (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
  (company-dabbrev-downcase nil)
  (company-dabbrev-ignore-case nil)
  ;; :config
  ;; (global-company-mode t)
  )

(use-package flycheck
  :defer 0.6
  :hook (prog-mode . flycheck-mode)
  :bind
  (:map flycheck-mode-map
        ("M-P" . flycheck-previous-error)
        ("M-N" . flycheck-next-error))
  :config
  ;; Use the load-path from running Emacs when checking elisp files
  (setq flycheck-emacs-lisp-load-path 'inherit)

  ;; Only flycheck when I actually save the buffer
  (setq flycheck-check-syntax-automatically '(mode-enabled save))
  :custom (flycheck-mode-line-prefix "flyc"))

(use-feature flyspell)

;; http://endlessparentheses.com/ispell-and-apostrophes.html
(use-feature ispell
  :defer 0.6
  :config
  ;; ’ can be part of a word
  (setq ispell-local-dictionary-alist
        `((nil "[[:alpha:]]" "[^[:alpha:]]"
               "['\x2019]" nil ("-B") nil utf-8))
        ispell-program-name (executable-find "hunspell"))
  ;; don't send ’ to the subprocess
  (defun endless/replace-apostrophe (args)
    (cons (replace-regexp-in-string
           "’" "'" (car args))
          (cdr args)))
  (advice-add #'ispell-send-string :filter-args
              #'endless/replace-apostrophe)

  ;; convert ' back to ’ from the subprocess
  (defun endless/replace-quote (args)
    (if (not (derived-mode-p 'org-mode))
        args
      (cons (replace-regexp-in-string
             "'" "’" (car args))
            (cdr args))))
  (advice-add #'ispell-parse-output :filter-args
              #'endless/replace-quote))

(use-feature abbrev
  :hook (text-mode . abbrev-mode))

\f
;;; Programming modes

(use-feature lisp-mode
  :config
  (defun indent-spaces-mode ()
    (setq indent-tabs-mode nil))
  (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))

(use-feature reveal
  :hook (emacs-lisp-mode . reveal-mode))

(use-feature elisp-mode)

(use-package alloy-mode
  :straight (:host github :repo "dwwmmn/alloy-mode")
  :mode "\\.als\\'"
  :config (setq alloy-basic-offset 2)
  :hook (alloy-mode . (lambda () (setq-local indent-tabs-mode nil))))

(eval-when-compile (defvar lean-mode-map))
(use-package lean-mode
  :defer 0.4
  :bind (:map lean-mode-map
              ("S-SPC" . company-complete))
  :config
  (require 'lean-input)
  (setq default-input-method "Lean"
        lean-input-tweak-all '(lean-input-compose
                               (lean-input-prepend "/")
                               (lean-input-nonempty))
        lean-input-user-translations '(("/" "/")))
  (lean-input-setup))

(comment
  (use-package proof-site                 ; for Coq
    :straight proof-general)

  (use-package haskell-mode
    :config
    (setq haskell-indentation-layout-offset 4
          haskell-indentation-left-offset 4
          flycheck-checker 'haskell-hlint
          flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))

  (use-package dante
    :after haskell-mode
    :commands dante-mode
    :hook (haskell-mode . dante-mode))

  (use-package hlint-refactor
    :after haskell-mode
    :bind (:map hlint-refactor-mode-map
                ("C-c l b" . hlint-refactor-refactor-buffer)
                ("C-c l r" . hlint-refactor-refactor-at-point))
    :hook (haskell-mode . hlint-refactor-mode))

  (use-package flycheck-haskell
    :after haskell-mode)
  ;; alternative: hs-lint https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el
  )

(use-feature sgml-mode
  :config
  (setq sgml-basic-offset 2))

(use-feature css-mode
  :config
  (setq css-indent-offset 2))

(use-package web-mode
  :mode "\\.html\\'"
  :config
  (b/setq-every 2
    web-mode-code-indent-offset
    web-mode-css-indent-offset
    web-mode-markup-indent-offset))

(use-package emmet-mode
  :after (:any web-mode css-mode sgml-mode)
  :bind* (("C-)" . emmet-next-edit-point)
          ("C-(" . emmet-prev-edit-point))
  :config
  (unbind-key "C-j" emmet-mode-keymap)
  (setq emmet-move-cursor-between-quotes t)
  :hook (web-mode css-mode html-mode sgml-mode))

(comment
  (use-package meghanada
    :bind
    (:map meghanada-mode-map
          (("C-M-o" . meghanada-optimize-import)
           ("C-M-t" . meghanada-import-all)))
    :hook (java-mode . meghanada-mode)))

(comment
  (use-package treemacs
    :config (setq treemacs-never-persist t))

  (use-package yasnippet
    :config
    ;; (yas-global-mode)
    )

  (use-package lsp-mode
    :init (setq lsp-eldoc-render-all nil
                lsp-highlight-symbol-at-point nil)
    )

  (use-package hydra)

  (use-package company-lsp
    :after company
    :config
    (setq company-lsp-cache-candidates t
          company-lsp-async t))

  (use-package lsp-ui
    :config
    (setq lsp-ui-sideline-update-mode 'point))

  (use-package lsp-java
    :config
    (add-hook 'java-mode-hook
              (lambda ()
                (setq-local company-backends (list 'company-lsp))))

    (add-hook 'java-mode-hook 'lsp-java-enable)
    (add-hook 'java-mode-hook 'flycheck-mode)
    (add-hook 'java-mode-hook 'company-mode)
    (add-hook 'java-mode-hook 'lsp-ui-mode))

  (use-package dap-mode
    :after lsp-mode
    :config
    (dap-mode t)
    (dap-ui-mode t))

  (use-package dap-java
    :after (lsp-java))

  (use-package lsp-java-treemacs
    :after (treemacs)))

(comment
  (use-package eclim
    :bind (:map eclim-mode-map ("S-SPC" . company-complete))
    :hook ((java-mode . eclim-mode)
           (eclim-mode . (lambda ()
                           (make-local-variable 'company-idle-delay)
                           (defvar company-idle-delay)
                           ;; (setq company-idle-delay 0.7)
                           (setq company-idle-delay nil))))
    :custom
    (eclim-auto-save nil)
    ;; (eclimd-default-workspace "~/src/eclipse-workspace-exp")
    (eclim-executable "~/.p2/pool/plugins/org.eclim_2.8.0/bin/eclim")
    (eclim-eclipse-dirs '("~/usr/eclipse/dsl-2018-09/eclipse"))))

(use-package geiser)

(use-feature geiser-guile
  :config
  (setq geiser-guile-load-path "~/src/git/guix"))

(use-package guix)

(comment
  (use-package auctex
    :custom
    (font-latex-fontify-sectioning 'color)))

(use-package go-mode)

(use-package po-mode
  :hook
  (po-mode . (lambda () (run-with-timer 0.1 nil 'View-exit))))

(use-feature tex-mode
  :config
  (cl-delete-if
   (lambda (p) (string-match "^---?" (car p)))
   tex--prettify-symbols-alist)
  :hook ((tex-mode . auto-fill-mode)
         (tex-mode . flyspell-mode)))

(use-package george-mode
  :straight (:host nil :repo "https://git.shemshak.org/amin/george-mode")
  :mode "\\.grg\\'")

\f
;;; Theme

(add-to-list 'custom-theme-load-path
             (expand-file-name
              (convert-standard-filename "lisp") user-emacs-directory))
(load-theme 'tangomod t)

(use-package smart-mode-line
  :commands (sml/apply-theme)
  :demand
  :config
  (setq sml/theme 'tangomod)
  (sml/setup)
  (smart-mode-line-enable))

(use-package doom-modeline
  :disabled
  :demand
  :hook (after-init . doom-modeline-init)
  :custom
  (doom-modeline-buffer-file-name-style 'relative-to-project))

(use-package doom-themes)

(use-package solarized-theme
  :disabled
  :config
  (load-theme 'solarized-light t))

(use-package moody
  :disabled
  :demand
  :config
  (setq x-underline-at-descent-line t)
  (let ((line (face-attribute 'mode-line :underline)))
    (set-face-attribute 'mode-line          nil :overline   line)
    (set-face-attribute 'mode-line-inactive nil :overline   line)
    (set-face-attribute 'mode-line-inactive nil :underline  line)
    (set-face-attribute 'mode-line          nil :box        nil)
    (set-face-attribute 'mode-line-inactive nil :box        nil)
    (set-face-attribute 'mode-line-inactive nil :background "#e1e1e1")) ; d3d7cf
  (moody-replace-mode-line-buffer-identification)
  (moody-replace-vc-mode))

(use-package mini-modeline
  :disabled
  :demand
  :config (mini-modeline-mode))

(defvar b/org-mode-font-lock-keywords
  '(("[ \t]*\\(#\\+\\(BEGIN\\|END\\|begin\\|end\\)_\\(\\S-+\\)\\)[ \t]*\\([^\n:]*\\)"
      (1 '(:foreground "#5a5b5a" :background "#292b2b") t) ; directive
      (3 '(:foreground "#81a2be" :background "#292b2b") t) ; kind
      (4 '(:foreground "#c5c8c6") t)))                     ; title
  "For use with the `doom-tomorrow-night' theme.")

(defun b/lights-on ()
  "Enable my favourite light theme."
  (interactive)
  (mapc #'disable-theme custom-enabled-themes)
  (load-theme 'tangomod t)
  (sml/apply-theme 'tangomod)
  (font-lock-remove-keywords
   'org-mode b/org-mode-font-lock-keywords)
  (when (featurep 'erc-hl-nicks)
    (erc-hl-nicks-reset-face-table))
  (when (featurep 'exwm-systemtray)
    (exwm-systemtray--refresh)))

(defun b/lights-off ()
  "Go dark."
  (interactive)
  (mapc #'disable-theme custom-enabled-themes)
  (load-theme 'doom-one t)
  (sml/apply-theme 'automatic)
  (font-lock-add-keywords
   'org-mode b/org-mode-font-lock-keywords t)
  (when (featurep 'erc-hl-nicks)
    (erc-hl-nicks-reset-face-table))
  (when (featurep 'exwm-systemtray)
    (exwm-systemtray--refresh)))

(bind-keys
 ("C-c t d" . b/lights-off)
 ("C-c t l" . b/lights-on))

\f
;;; Emacs enhancements & auxiliary packages

(use-package man
  :config (setq Man-width 80))

(use-package which-key
  :defer 0.4
  :config
  (which-key-add-key-based-replacements
    ;; prefixes for global prefixes and minor modes
    "C-c @"   "outline"
    "C-c !"   "flycheck"
    ;; "C-c 8"   "typo"
    ;; "C-c 8 -" "typo/dashes"
    ;; "C-c 8 <" "typo/left-brackets"
    ;; "C-c 8 >" "typo/right-brackets"
    "C-x RET" "coding system"
    "C-x 8"   "unicode"
    "C-x @"   "event modifiers"
    "C-x a"   "abbrev/expand"
    "C-x r"   "rectangle/register/bookmark"
    "C-x t"   "tabs"
    "C-x v"   "version control"
    "C-x X"   "edebug"
    "C-x C-a" "edebug"
    "C-x C-k" "kmacro"
    ;; prefixes for my personal bindings
    "C-c &"   "yasnippet"
    "C-c a"   "applications"
    "C-c a e" "erc"
    "C-c a o" "org"
    "C-c a s" "shells"
    "C-c b"   "buffers"
    "C-c c"   "compile-and-comments"
    "C-c e"   "eval"
    "C-c f"   "files"
    "C-c F"   "frames"
    "C-c g"   "magit"
    "C-S-h"   "help(ful)"
    "C-c m"   "multiple-cursors"
    "C-c P"   "projectile"
    "C-c P s" "projectile/search"
    "C-c P x" "projectile/execute"
    "C-c P 4" "projectile/other-window"
    "C-c p"   "package management"
    "C-c ps"  "straight"
    "C-c psa" "all"
    "C-c psp" "package"
    "C-c q"   "boxquote"
    "C-c t"   "themes"
    ;; "s-O"     "outline"
    )

  ;; prefixes for major modes
  (which-key-add-major-mode-key-based-replacements 'message-mode
    "C-c f n" "footnote")
  (which-key-add-major-mode-key-based-replacements 'org-mode
    "C-c C-v" "org-babel")
  (which-key-add-major-mode-key-based-replacements 'web-mode
    "C-c C-a" "web/attributes"
    "C-c C-b" "web/blocks"
    "C-c C-d" "web/dom"
    "C-c C-e" "web/element"
    "C-c C-t" "web/tags")

  (which-key-mode)
  :custom
  (which-key-add-column-padding 5)
  (which-key-max-description-length 32))

(use-package crux            ; results in Waiting for git... [2 times]
  :defer 0.4
  :bind (("C-c d"   . crux-duplicate-current-line-or-region)
         ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
         ("C-c f C" . crux-copy-file-preserve-attributes)
         ("C-c f D" . crux-delete-file-and-buffer)
         ("C-c f R" . crux-rename-file-and-buffer)
         ("C-c j"   . crux-top-join-line)
         ("C-S-j"   . crux-top-join-line)))

(use-package mwim
  :bind (("C-a"    . mwim-beginning-of-code-or-line)
         ("C-e"    . mwim-end-of-code-or-line)
         ("<home>" . mwim-beginning-of-line-or-code)
         ("<end>"  . mwim-end-of-line-or-code)))

(use-package projectile
  :defer 0.5
  :bind-keymap ("C-c P" . projectile-command-map)
  :config
  (projectile-mode)

  (defun b/projectile-mode-line-fun ()
  "Report project name and type in the modeline."
  (let ((project-name (projectile-project-name))
        (project-type (projectile-project-type)))
    (format "%s%s"
            projectile-mode-line-prefix
            (if project-type
                (format ":%s" project-type)
              ""))))
  (setq projectile-mode-line-function 'b/projectile-mode-line-fun)

  (defun my-projectile-invalidate-cache (&rest _args)
    ;; ignore the args to `magit-checkout'
    (projectile-invalidate-cache nil))

  (eval-after-load 'magit-branch
    '(progn
       (advice-add 'magit-checkout
                   :after #'my-projectile-invalidate-cache)
       (advice-add 'magit-branch-and-checkout
                   :after #'my-projectile-invalidate-cache)))
  :custom
  (projectile-completion-system 'ivy)
  (projectile-mode-line-prefix " proj"))

(use-package helpful
  :defer 0.6
  :bind
  (("C-S-h c" . helpful-command)
   ("C-S-h f" . helpful-callable)        ; helpful-function
   ("C-S-h v" . helpful-variable)
   ("C-S-h k" . helpful-key)
   ("C-S-h p" . helpful-at-point)))

(use-package unkillable-scratch
  :defer 0.6
  :config
  (unkillable-scratch 1)
  :custom
  (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))

;; ,----
;; | make pretty boxed quotes like this
;; `----
(use-package boxquote
  :defer 0.6
  :bind
  (:prefix-map b/boxquote-prefix-map
               :prefix "C-c q"
               ("b"   . boxquote-buffer)
               ("B"   . boxquote-insert-buffer)
               ("d"   . boxquote-defun)
               ("F"   . boxquote-insert-file)
               ("hf"  . boxquote-describe-function)
               ("hk"  . boxquote-describe-key)
               ("hv"  . boxquote-describe-variable)
               ("hw"  . boxquote-where-is)
               ("k"   . boxquote-kill)
               ("p"   . boxquote-paragraph)
               ("q"   . boxquote-boxquote)
               ("r"   . boxquote-region)
               ("s"   . boxquote-shell-command)
               ("t"   . boxquote-text)
               ("T"   . boxquote-title)
               ("u"   . boxquote-unbox)
               ("U"   . boxquote-unbox-region)
               ("y"   . boxquote-yank)
               ("M-q" . boxquote-fill-paragraph)
               ("M-w" . boxquote-kill-ring-save)))

(use-package orgalist
  ;; http://lists.gnu.org/archive/html/emacs-orgmode/2019-04/msg00007.html
  :disabled t
  :after message
  :hook (message-mode . orgalist-mode))

;; easily type pretty quotes & other typography, like ‘’“”-–—«»‹›
(use-package typo
  :disabled
  :defer 0.5
  :config
  (typo-global-mode 1)
  :hook (((text-mode erc-mode web-mode) . typo-mode)
         (tex-mode                      . (lambda ()(typo-mode -1)))))

(use-feature electric
  :disabled
  :demand
  :config
  (electric-quote-mode))

;; highlight TODOs in buffers
(use-package hl-todo
  :defer 0.5
  :config
  (global-hl-todo-mode))

(use-package shrink-path
  :defer 0.5
  :after eshell
  :config
  (defvar user-@-host (concat (user-login-name) "@" (system-name) ":"))
  (defun +eshell/prompt ()
    (concat (propertize user-@-host 'face 'default)
            (propertize (abbreviate-file-name default-directory)
                        'face 'font-lock-comment-face)
            (propertize "\n" 'face 'default)
            (if (= (user-uid) 0)
                (propertize "#" 'face 'red)
              (propertize "$" 'face 'default))
            (propertize " " 'face 'default)))
  (setq eshell-prompt-regexp "\\(.*\n\\)*[$#] "
        eshell-prompt-function #'+eshell/prompt))

(use-package eshell-up
  :after eshell
  :commands eshell-up)

(use-package multi-term
  :disabled
  :defer 0.6
  :bind (("C-c a s m m" . multi-term)
         ("C-c a s m d" . multi-term-dedicated-toggle)
         ("C-c a s m p" . multi-term-prev)
         ("C-c a s m n" . multi-term-next)
         :map term-mode-map
         ("C-c C-j" . term-char-mode))
  :config
  (setq multi-term-program "screen"
        multi-term-program-switches (concat "-c"
                                            (getenv "XDG_CONFIG_HOME")
                                            "/screen/screenrc")
        ;; TODO: add separate bindings for connecting to existing
        ;; session vs. always creating a new one
        multi-term-dedicated-select-after-open-p t
        multi-term-dedicated-window-height 20
        multi-term-dedicated-max-window-height 30
        term-bind-key-alist
        '(("C-c C-c" . term-interrupt-subjob)
          ("C-c C-e" . term-send-esc)
          ("C-c C-j" . term-line-mode)
          ("C-k" . kill-line)
          ;; ("C-y" . term-paste)
          ("C-y" . term-send-raw)
          ("M-f" . term-send-forward-word)
          ("M-b" . term-send-backward-word)
          ("M-p" . term-send-up)
          ("M-n" . term-send-down)
          ("M-j" . term-send-raw-meta)
          ("M-y" . term-send-raw-meta)
          ("M-/" . term-send-raw-meta)
          ("M-0" . term-send-raw-meta)
          ("M-1" . term-send-raw-meta)
          ("M-2" . term-send-raw-meta)
          ("M-3" . term-send-raw-meta)
          ("M-4" . term-send-raw-meta)
          ("M-5" . term-send-raw-meta)
          ("M-6" . term-send-raw-meta)
          ("M-7" . term-send-raw-meta)
          ("M-8" . term-send-raw-meta)
          ("M-9" . term-send-raw-meta)
          ("<C-backspace>" . term-send-backward-kill-word)
          ("<M-DEL>" . term-send-backward-kill-word)
          ("M-d" . term-send-delete-word)
          ("M-," . term-send-raw)
          ("M-." . comint-dynamic-complete))
        term-unbind-key-alist
        '("C-z" "C-x" "C-c" "C-h"
          ;; "C-y"
          "<ESC>")))

(use-package page-break-lines
  :defer 0.5
  :custom
  (page-break-lines-max-width fill-column)
  :config
  (global-page-break-lines-mode))

(use-package expand-region
  :bind ("C-=" . er/expand-region))

(use-package multiple-cursors
  :bind
  (("C-S-<mouse-1>" . mc/add-cursor-on-click)
   (:prefix-map b/mc-prefix-map
               :prefix "C-c m"
               ("c" . mc/edit-lines)
               ("n" . mc/mark-next-like-this)
               ("p" . mc/mark-previous-like-this)
               ("a" . mc/mark-all-like-this))))

(use-package forge
  :demand
  :after magit)

(use-package yasnippet
  :defer 0.6
  :config
  (defconst yas-verbosity-cur yas-verbosity)
  (setq yas-verbosity 2)
  (add-to-list 'yas-snippet-dirs "~/src/git/guix/etc/snippets" t)
  (yas-reload-all)
  (setq yas-verbosity yas-verbosity-cur)

  (defun b/yas--maybe-expand-key-filter (cmd)
    (when (and (yas--maybe-expand-key-filter cmd)
               (not (bound-and-true-p git-commit-mode)))
      cmd))
  (defconst b/yas-maybe-expand
    '(menu-item "" yas-expand :filter b/yas--maybe-expand-key-filter))
  (define-key yas-minor-mode-map
    (kbd "SPC") b/yas-maybe-expand)

  (yas-global-mode))

(use-package debbugs
  :straight (debbugs
             :host github
             :repo "emacs-straight/debbugs"
             :files (:defaults "Debbugs.wsdl"))
  :bind
  (("C-c D d" . debbugs-gnu)
   ("C-c D e" .
    (lambda ()
      (interactive)
      (setq debbugs-gnu-current-suppress t)
      (debbugs-gnu debbugs-gnu-default-severities '("emacs"))))
   ("C-c D g" .
    (lambda ()
      (interactive)
      (setq debbugs-gnu-current-suppress t)
      (debbugs-gnu debbugs-gnu-default-severities '("gnuzilla"))))))

(use-package org-ref
  :init
  (b/setq-every '("~/usr/org/references.bib")
    reftex-default-bibliography
    org-ref-default-bibliography)
  (setq
   org-ref-bibliography-notes "~/usr/org/notes.org"
   org-ref-pdf-directory "~/usr/org/bibtex-pdfs/"))

(use-package alert
  :commands (alert)
  :init (setq alert-default-style 'notifications))

;; (use-package fill-column-indicator)

(use-package emojify
  :disabled
  :hook (erc-mode . emojify-mode))

(use-feature window
  :bind
  (("C-c w e"   . (lambda ()
                    (interactive)
                    (split-window-right)
                    (other-window 1)
                    (erc-switch-to-buffer)))
   ("C-c w s l" . (lambda ()
                    (interactive)
                    (split-window-right)
                    (other-window 1)))
   ("C-c w s j" . (lambda ()
                    (interactive)
                    (split-window-below)
                    (other-window 1)))
   ("C-c w q"   . quit-window))
  :custom
  (split-width-threshold 150))

(use-feature windmove
  :defer 0.6
  :bind
  (("C-c w h" . windmove-left)
   ("C-c w j" . windmove-down)
   ("C-c w k" . windmove-up)
   ("C-c w l" . windmove-right)
   ("C-c w H" . windmove-swap-states-left)
   ("C-c w J" . windmove-swap-states-down)
   ("C-c w K" . windmove-swap-states-up)
   ("C-c w L" . windmove-swap-states-right)))

(use-package pass
  :commands pass
  :bind ("C-c a p" . pass)
  :hook (pass-mode . View-exit))

(use-package pdf-tools
  :defer 0.5
  :bind (:map pdf-view-mode-map
              ("<C-XF86Back>"    . pdf-history-backward)
              ("<mouse-8>"       . pdf-history-backward)
              ("<drag-mouse-8>"  . pdf-history-backward)
              ("<C-XF86Forward>" . pdf-history-forward)
              ("<mouse-9>"       . pdf-history-forward)
              ("<drag-mouse-9>"  . pdf-history-forward)
              ("M-RET"           . image-previous-line)
              ("C-s"             . isearch-forward)
              ("s s"             . isearch-forward))
  :config (pdf-tools-install nil t)
  :custom (pdf-view-resize-factor 1.05))

(use-package org-pdftools
  :straight (:host github :repo "fuxialexander/org-pdftools")
  :demand
  :after org
  :config
  (with-eval-after-load 'org
    (require 'org-pdftools)))

(use-package biblio)

(use-feature reftex
  :hook (latex-mode . reftex-mode))

(use-feature reftex-cite
  :after reftex
  :disabled                             ; enable to disable
                                        ; reftex-cite's default choice
                                        ; of previous word
  :config
  (defun reftex-get-bibkey-default ()
    "If the cursor is in a citation macro, return the word before the macro."
    (let* ((macro (reftex-what-macro 1)))
      (save-excursion
        (when (and macro (string-match "cite" (car macro)))
          (goto-char (cdr macro)))
        (reftex-this-word)))))

(use-package minions
  :demand
  :config (minions-mode))

(use-package dmenu
  :custom
  (dmenu-prompt-string "run: ")
  (dmenu-save-file (b/var "dmenu-items")))

(use-package eosd
  ;; TODO: fix build by properly building the eosd-pixbuf.c module
  ;; e.g. see https://github.com/raxod502/straight.el/issues/386
  :disabled
  :straight (:host github :repo "clarete/eosd")
  :demand
  :after exwm
  :config
  (eosd-start))

(use-package nnreddit
  :disabled
  :demand
  :after gnus
  :custom
  (nnreddit-python-command "python3"))

(use-package hyperbole
  :disabled
  :straight (hyperbole
             :host github :repo "rswgnu/hyperbole"
             :files ("*.el" ("kotl" "kotl/*.el")
                     "DEMO" "man/*.info" "man/*.texi")))

(use-package oddmuse-curl
  :straight (:host github :repo "kensanata/oddmuse-curl")
  :config
  (setq
   oddmuse-wikis
   (append
    '(("EmacsConf" "https://emacsconf.org" utf-8 "question" nil)
      ("EmacsConf 2019" "https://emacsconf.org/2019" utf-8 "question" nil))
    oddmuse-wikis))
  :custom
  (oddmuse-username "bandali"))

(use-package debpaste
  :custom
  (debpaste-paste-is-hidden t))

\f
;;; Email (with Gnus)

(defvar b/maildir (expand-file-name "~/mail/"))
(with-eval-after-load 'recentf
  (add-to-list 'recentf-exclude b/maildir))

(setq
 b/gnus-init-file  (b/etc "gnus")
 mail-user-agent   'gnus-user-agent
 read-mail-command 'gnus)

(use-feature gnus
  :bind (("s-m"     . gnus)
         ("s-M"     . gnus-unplugged)
         ("C-c a m" . gnus)
         ("C-c a M" . gnus-unplugged))
  :init
  (setq
   gnus-select-method '(nnnil "")
   gnus-secondary-select-methods
   '((nnimap "shemshak"
             (nnimap-stream plain)
             (nnimap-address "127.0.0.1")
             (nnimap-server-port 143)
             (nnimap-authenticator plain)
             (nnimap-user "amin@shemshak.local"))
     (nnimap "gnu"
             (nnimap-stream plain)
             (nnimap-address "127.0.0.1")
             (nnimap-server-port 143)
             (nnimap-authenticator plain)
             (nnimap-user "bandali@gnu.local")
             (nnimap-inbox "INBOX")
             (nnimap-split-methods 'nnimap-split-fancy)
             (nnimap-split-fancy (|
                                  ;; (: gnus-registry-split-fancy-with-parent)
                                  ;; (: gnus-group-split-fancy "INBOX" t "INBOX")
                                  ;; gnu
                                  (list ".*<\\(.*\\)\\.\\(non\\)?gnu\\.org>.*" "l.\\1")
                                  ;; gnus
                                  (list ".*<\\(.*\\)\\.gnus\\.org>.*" "l.\\1")
                                  ;; *.lists.sr.ht, omitting one dot if present
                                  ;;    add more \\.?\\([^.]*\\) if needed
                                  (list ".*<~\\(.*\\)/\\([^.]*\\)\\.?\\([^.]*\\)\\.lists.sr.ht>.*" "l.~\\1.\\2\\3")
                                  ;; webmasters
                                  (from "webmasters\\(-comment\\)?@gnu\\.org" "webmasters")
                                  ;; other
                                  (list ".*atreus.freelists.org" "l.atreus")
                                  (list ".*deepspec.lists.cs.princeton.edu" "l.deepspec")
                                  ;; (list ".*haskell-art.we.lurk.org" "l.haskell.art") ;d
                                  (list ".*haskell-cafe.haskell.org" "l.haskell-cafe")
                                  ;; (list ".*notmuch.notmuchmail.org" "l.notmuch") ;u
                                  ;; (list ".*dev.lists.parabola.nu" "l.parabola-dev") ;u
                                  ;; ----------------------------------
                                  ;; legend: (u)nsubscribed | (d)ead
                                  ;; ----------------------------------
                                  ;; otherwise, leave mail in INBOX
                                  "INBOX")))
     (nnimap "uw"
             (nnimap-stream plain)
             (nnimap-address "127.0.0.1")
             (nnimap-server-port 143)
             (nnimap-authenticator plain)
             (nnimap-user "abandali@uw.local")
             (nnimap-inbox "INBOX")
             (nnimap-split-methods 'nnimap-split-fancy)
             (nnimap-split-fancy (|
                                  ;; (: gnus-registry-split-fancy-with-parent)
                                  ;; se212-f19
                                  ("subject" "SE\\s-?212" "course.se212-f19")
                                  (from "SE\\s-?212" "course.se212-f19")
                                  ;; catch-all
                                  "INBOX")))
     (nnimap "csc"
             (nnimap-stream plain)
             (nnimap-address "127.0.0.1")
             (nnimap-server-port 143)
             (nnimap-authenticator plain)
             (nnimap-user "abandali@csc.uw.local")))
   gnus-message-archive-group "nnimap+gnu:INBOX"
   gnus-parameters
   '(("l\\.atreus"
      (to-address . "atreus@freelists.org")
      (to-list    . "atreus@freelists.org"))
     ("l\\.deepspec"
      (to-address . "deepspec@lists.cs.princeton.edu")
      (to-list    . "deepspec@lists.cs.princeton.edu")
      (list-identifier . "\\[deepspec\\]"))
     ("l\\.emacs-devel"
      (to-address . "emacs-devel@gnu.org")
      (to-list    . "emacs-devel@gnu.org"))
     ("l\\.help-gnu-emacs"
      (to-address . "help-gnu-emacs@gnu.org")
      (to-list    . "help-gnu-emacs@gnu.org"))
     ("l\\.info-gnu-emacs"
      (to-address . "info-gnu-emacs@gnu.org")
      (to-list    . "info-gnu-emacs@gnu.org"))
     ("l\\.emacs-orgmode"
      (to-address . "emacs-orgmode@gnu.org")
      (to-list    . "emacs-orgmode@gnu.org")
      (list-identifier . "\\[O\\]"))
     ("l\\.emacs-tangents"
      (to-address . "emacs-tangents@gnu.org")
      (to-list    . "emacs-tangents@gnu.org"))
     ("l\\.emacsconf-committee"
      (to-address . "emacsconf-committee@gnu.org")
      (to-list    . "emacsconf-committee@gnu.org"))
     ("l\\.emacsconf-discuss"
      (to-address . "emacsconf-discuss@gnu.org")
      (to-list    . "emacsconf-discuss@gnu.org"))
     ("l\\.emacsconf-register"
      (to-address . "emacsconf-register@gnu.org")
      (to-list    . "emacsconf-register@gnu.org"))
     ("l\\.emacsconf-submit"
      (to-address . "emacsconf-submit@gnu.org")
      (to-list    . "emacsconf-submit@gnu.org"))
     ("l\\.fencepost-users"
      (to-address . "fencepost-users@gnu.org")
      (to-list    . "fencepost-users@gnu.org")
      (list-identifier . "\\[Fencepost-users\\]"))
     ("l\\.gnewsense-art"
      (to-address . "gnewsense-art@nongnu.org")
      (to-list    . "gnewsense-art@nongnu.org")
      (list-identifier . "\\[gNewSense-art\\]"))
     ("l\\.gnewsense-dev"
      (to-address . "gnewsense-dev@nongnu.org")
      (to-list    . "gnewsense-dev@nongnu.org")
      (list-identifier . "\\[Gnewsense-dev\\]"))
     ("l\\.gnewsense-users"
      (to-address . "gnewsense-users@nongnu.org")
      (to-list    . "gnewsense-users@nongnu.org")
      (list-identifier . "\\[gNewSense-users\\]"))
     ("l\\.gnunet-developers"
      (to-address . "gnunet-developers@gnu.org")
      (to-list    . "gnunet-developers@gnu.org")
      (list-identifier . "\\[GNUnet-developers\\]"))
     ("l\\.help-gnunet"
      (to-address . "help-gnunet@gnu.org")
      (to-list    . "help-gnunet@gnu.org")
      (list-identifier . "\\[Help-gnunet\\]"))
     ("l\\.bug-gnuzilla"
      (to-address . "bug-gnuzilla@gnu.org")
      (to-list    . "bug-gnuzilla@gnu.org")
      (list-identifier . "\\[Bug-gnuzilla\\]"))
     ("l\\.gnuzilla-dev"
      (to-address . "gnuzilla-dev@gnu.org")
      (to-list    . "gnuzilla-dev@gnu.org")
      (list-identifier . "\\[Gnuzilla-dev\\]"))
     ("l\\.guile-devel"
      (to-address . "guile-devel@gnu.org")
      (to-list    . "guile-devel@gnu.org"))
     ("l\\.guile-user"
      (to-address . "guile-user@gnu.org")
      (to-list    . "guile-user@gnu.org"))
     ("l\\.guix-devel"
      (to-address . "guix-devel@gnu.org")
      (to-list    . "guix-devel@gnu.org"))
     ("l\\.help-guix"
      (to-address . "help-guix@gnu.org")
      (to-list    . "help-guix@gnu.org"))
     ("l\\.info-guix"
      (to-address . "info-guix@gnu.org")
      (to-list    . "info-guix@gnu.org"))
     ("l\\.savannah-hackers-public"
      (to-address . "savannah-hackers-public@gnu.org")
      (to-list    . "savannah-hackers-public@gnu.org"))
     ("l\\.savannah-users"
      (to-address . "savannah-users@gnu.org")
      (to-list    . "savannah-users@gnu.org"))
     ("l\\.www-commits"
      (to-address . "www-commits@gnu.org")
      (to-list    . "www-commits@gnu.org"))
     ("l\\.www-discuss"
      (to-address . "www-discuss@gnu.org")
      (to-list    . "www-discuss@gnu.org"))
     ("l\\.haskell-art"
      (to-address . "haskell-art@we.lurk.org")
      (to-list    . "haskell-art@we.lurk.org")
      (list-identifier . "\\[haskell-art\\]"))
     ("l\\.haskell-cafe"
      (to-address . "haskell-cafe@haskell.org")
      (to-list    . "haskell-cafe@haskell.org")
      (list-identifier . "\\[Haskell-cafe\\]"))
     ("l\\.notmuch"
      (to-address . "notmuch@notmuchmail.org")
      (to-list    . "notmuch@notmuchmail.org"))
     ("l\\.parabola-dev"
      (to-address . "dev@lists.parabola.nu")
      (to-list    . "dev@lists.parabola.nu")
      (list-identifier . "\\[Dev\\]"))
     ("l\\.~bandali\\.public-inbox"
      (to-address . "~bandali/public-inbox@lists.sr.ht")
      (to-list    . "~bandali/public-inbox@lists.sr.ht"))
     ("l\\.~sircmpwn\\.free-writers-club"
      (to-address . "~sircmpwn/free-writers-club@lists.sr.ht")
      (to-list    . "~sircmpwn/free-writers-club@lists.sr.ht"))
     ("l\\.~sircmpwn\\.srht-admins"
      (to-address . "~sircmpwn/sr.ht-admins@lists.sr.ht")
      (to-list    . "~sircmpwn/sr.ht-admins@lists.sr.ht"))
     ("l\\.~sircmpwn\\.srht-announce"
      (to-address . "~sircmpwn/sr.ht-announce@lists.sr.ht")
      (to-list    . "~sircmpwn/sr.ht-announce@lists.sr.ht"))
     ("l\\.~sircmpwn\\.srht-dev"
      (to-address . "~sircmpwn/sr.ht-dev@lists.sr.ht")
      (to-list    . "~sircmpwn/sr.ht-dev@lists.sr.ht"))
     ("l\\.~sircmpwn\\.srht-discuss"
      (to-address . "~sircmpwn/sr.ht-discuss@lists.sr.ht")
      (to-list    . "~sircmpwn/sr.ht-discuss@lists.sr.ht"))
     ("webmasters"
      (to-address . "webmasters@gnu.org")
      (to-list    . "webmasters@gnu.org"))
     ("gnu.*"
      (gcc-self . t))
     ("gnu\\."
      (subscribed . t))
     ("nnimap\\+uw:.*"
      (gcc-self . t)))
   gnus-large-newsgroup  50
   gnus-home-directory   (b/var "gnus/")
   gnus-directory        (concat gnus-home-directory "news/")
   message-directory     (concat gnus-home-directory "mail/")
   nndraft-directory     (concat gnus-home-directory "drafts/")
   gnus-save-newsrc-file nil
   gnus-read-newsrc-file nil
   gnus-interactive-exit nil
   gnus-gcc-mark-as-read t)
  :config
  (when (version< emacs-version "27")
    (add-to-list
     'nnmail-split-abbrev-alist
     '(list . "list-id\\|list-post\\|x-mailing-list\\|x-beenthere\\|x-loop")
     t))

  ;; (gnus-registry-initialize)

  (with-eval-after-load 'recentf
    (add-to-list 'recentf-exclude gnus-home-directory)))

(use-feature gnus-art
  :config
  (setq
   gnus-buttonized-mime-types '("multipart/\\(signed\\|encrypted\\)")
   gnus-sorted-header-list '("^From:"
                             "^X-RT-Originator"
                             "^Newsgroups:"
                             "^Subject:"
                             "^Date:"
                             "^Envelope-To:"
                             "^Followup-To:"
                             "^Reply-To:"
                             "^Organization:"
                             "^Summary:"
                             "^Abstract:"
                             "^Keywords:"
                             "^To:"
                             "^[BGF]?Cc:"
                             "^Posted-To:"
                             "^Mail-Copies-To:"
                             "^Mail-Followup-To:"
                             "^Apparently-To:"
                             "^Resent-From:"
                             "^User-Agent:"
                             "^X-detected-operating-system:"
                             "^Message-ID:"
                             ;; "^References:"
                             "^List-Id:"
                             "^Gnus-Warning:")
   gnus-visible-headers (mapconcat 'identity
                                   gnus-sorted-header-list
                                   "\\|")
  ;; local-lapsed article dates
  ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
  gnus-article-date-headers '(user-defined)
  gnus-article-time-format
  (lambda (time)
    (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
           (local (article-make-date-line date 'local))
           (combined-lapsed (article-make-date-line date
                                                    'combined-lapsed))
           (lapsed (progn
                     (string-match " (.+" combined-lapsed)
                     (match-string 0 combined-lapsed))))
      (concat local lapsed))))
  (bind-keys
   :map gnus-article-mode-map
   ("M-L" . org-store-link)))

(use-feature gnus-sum
  :bind (:map gnus-summary-mode-map
              :prefix-map b/gnus-summary-prefix-map
              :prefix "v"
              ("r" . gnus-summary-reply)
              ("w" . gnus-summary-wide-reply)
              ("v" . gnus-summary-show-raw-article))
  :config
  (bind-keys
   :map gnus-summary-mode-map
   ("M-L" . org-store-link))
  :hook (gnus-summary-mode . b/no-mouse-autoselect-window)
  :custom
  (gnus-thread-sort-functions '(gnus-thread-sort-by-number
                                gnus-thread-sort-by-subject
                                gnus-thread-sort-by-date)))

(use-feature gnus-msg
  :config
  (defvar b/gnu-signature "Amin Bandali
Free Software Activist | GNU Maintainer & Webmaster
GPG: BE62 7373 8E61 6D6D 1B3A  08E8 A21A 0202 4881 6103
https://bandali.eu.org")
  (defvar b/shemshak-signature "Amin Bandali
https://shemshak.org/~amin")
  (defvar b/uw-signature "Amin Bandali, MMath Student
Cheriton School of Computer Science
University of Waterloo
https://bandali.eu.org")
  (defvar b/csc-signature "Amin Bandali
Systems Committee
Computer Science Club, University of Waterloo
https://csclub.uwaterloo.ca/~abandali")
  (setq gnus-message-replysign t
        gnus-posting-styles
        '((".*"
           (address "bandali@gnu.org")
           (signature b/gnu-signature))
          ("nnimap\\+gnu:l\\..*"
           (signature nil))
          ((header "subject" "ThankCRM")
           (to "webmasters-comment@gnu.org")
           (body "")
           (eval (setq b/message-cite-say-hi nil)))
          ("nnimap\\+shemshak:.*"
           (address "amin@shemshak.org")
           (body "\nBest,\n")
           (signature b/shemshak-signature)
           (gcc "nnimap+shemshak:Sent")
           (eval (setq b/message-cite-say-hi t)))
          ("nnimap\\+uw:.*"
           (address "bandali@uwaterloo.ca")
           (body "\nBest,\n")
           (signature b/uw-signature))
          ("nnimap\\+uw:INBOX"
           (gcc "\"nnimap+uw:Sent Items\""))
          ("nnimap\\+csc:.*"
           (address "bandali@csclub.uwaterloo.ca")
           (signature b/csc-signature)
           (gcc "nnimap+csc:Sent"))))
  ;; :hook (gnus-message-setup . mml-secure-message-sign)
  )

(use-feature gnus-topic
  :hook (gnus-group-mode . gnus-topic-mode)
  :config (setq gnus-topic-line-format "%i[ %A: %(%{%n%}%) ]%v\n"))

(use-feature gnus-agent
  :config
  (setq gnus-agent-synchronize-flags 'ask)
  :hook (gnus-group-mode . gnus-agent-mode))

(use-feature gnus-group
  :config
  (setq gnus-permanently-visible-groups "\\(:INBOX$\\|:gnu$\\)"))

(comment
  ;; problematic with ebdb's popup, *EBDB-Gnus*
  (use-feature gnus-win
    :config
    (setq gnus-use-full-window nil)))

(use-feature gnus-dired
  :commands gnus-dired-mode
  :init
  (add-hook 'dired-mode-hook 'gnus-dired-mode))

(comment
  (use-feature gnus-utils
    :custom
    (gnus-completing-read-function 'gnus-ido-completing-read)))

(use-feature mm-decode
  :config
  (setq mm-discouraged-alternatives '("text/html" "text/richtext")
        mm-decrypt-option 'known
        mm-verify-option 'known))

(use-feature mm-uu
  :custom
  (mm-uu-diff-groups-regexp
   "\\(gmane\\|gnu\\|l\\)\\..*\\(diff\\|commit\\|cvs\\|bug\\|dev\\)"))

(use-feature sendmail
  :config
  (setq sendmail-program (executable-find "msmtp")
        ;; message-sendmail-extra-arguments '("-v" "-d")
        mail-specify-envelope-from t
        mail-envelope-from 'header))

(use-feature message
  :bind (:map message-mode-map ("<C-return>" . b/insert-asterism))
  :config
  ;; redefine for a simplified In-Reply-To header
  ;; (see https://todo.sr.ht/~sircmpwn/lists.sr.ht/67)
  (defun message-make-in-reply-to ()
    "Return the In-Reply-To header for this message."
    (when message-reply-headers
      (let ((from (mail-header-from message-reply-headers))
            (msg-id (mail-header-id message-reply-headers)))
        (when from
          msg-id))))

  (defconst b/message-cite-style-format "On %Y-%m-%d %l:%M %p, %N wrote:")
  (defconst message-cite-style-bandali
    '((message-cite-function  'message-cite-original)
      (message-citation-line-function  'message-insert-formatted-citation-line)
      (message-cite-reply-position 'traditional)
      (message-yank-prefix  "> ")
      (message-yank-cited-prefix  ">")
      (message-yank-empty-prefix  ">")
      (message-citation-line-format
       (if b/message-cite-say-hi
           (concat "Hi %F,\n\n" b/message-cite-style-format)
         b/message-cite-style-format)))
    "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
  (setq ;; message-cite-style 'message-cite-style-bandali
        message-kill-buffer-on-exit t
        message-send-mail-function 'message-send-mail-with-sendmail
        message-sendmail-envelope-from 'header
        message-subscribed-address-functions
        '(gnus-find-subscribed-addresses)
        message-dont-reply-to-names
        "\\(\\(\\(amin\\|mab\\)@shemshak\\.org\\)\\|\\(.*@aminb\\.org\\)\\|\\(\\(bandali\\|mab\\|aminb?\\)@gnu\\.org\\)\\|\\(a?bandali@\\(csclub\\.\\)?uwaterloo\\.ca\\)\\)")
  ;; (require 'company-ebdb)
  :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
         (message-mode . flyspell-mode)
         (message-mode . (lambda ()
                           (setq-local fill-column b/fill-column
                                       message-fill-column b/fill-column)
                           (make-local-variable 'company-idle-delay)
                           (setq company-idle-delay 0.2))))
  ;; :custom-face
  ;; (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
  ;; (message-header-to      ((t (:foreground "#111" :weight normal))))
  ;; (message-header-cc      ((t (:foreground "#333" :weight normal))))
  :custom
  (message-elide-ellipsis "[...]\n"))

(use-feature mml)

(use-feature mml-sec
  :custom
  (mml-secure-openpgp-encrypt-to-self t)
  (mml-secure-openpgp-sign-with-sender t))

(use-feature footnote
  :after message
  ;; :config
  ;; (setq footnote-start-tag ""
  ;;       footnote-end-tag   ""
  ;;       footnote-style     'unicode)
  :bind
  (:map message-mode-map
        :prefix-map b/footnote-prefix-map
        :prefix "C-c f n"
        ("a" . footnote-add-footnote)
        ("b" . footnote-back-to-message)
        ("c" . footnote-cycle-style)
        ("d" . footnote-delete-footnote)
        ("g" . footnote-goto-footnote)
        ("r" . footnote-renumber-footnotes)
        ("s" . footnote-set-style)))

(use-package bbdb
  :disabled
  :demand
  :after gnus
  :bind (:map gnus-group-mode-map ("e" . bbdb))
  :config
  (bbdb-initialize 'gnus 'message)
  :custom
  (bbdb-complete-mail-allow-cycling t)
  (bbdb-user-mail-address-re message-dont-reply-to-names))

(use-package ebdb
  :demand
  :after gnus
  :bind (:map gnus-group-mode-map ("e" . ebdb))
  :config
  (setq ebdb-sources (b/var "ebdb"))
  (with-eval-after-load 'swiper
    (add-to-list 'swiper-font-lock-exclude 'ebdb-mode t)))

(use-feature ebdb-com
  :after ebdb)

(use-feature ebdb-complete
  :after ebdb
  :config
  ;; (setq ebdb-complete-mail 'capf)
  (ebdb-complete-enable))

(use-feature ebdb-message
  :demand
  :after ebdb)

;; (use-package company-ebdb
;;   :config
;;   (defun company-ebdb--post-complete (_) nil))

(use-feature ebdb-gnus
  :after ebdb
  :custom
  (ebdb-gnus-window-size 0.3))

(use-feature ebdb-mua
  :demand
  :after ebdb
  :custom (ebdb-mua-pop-up t))

;; (use-package ebdb-message
;;   :after ebdb)

;; (use-package ebdb-vcard
;;   :after ebdb)

(use-package message-x)

(comment
  (use-package message-x
    :custom
    (message-x-completion-alist
     (quote
      (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
       ((if
            (boundp
             (quote message-newgroups-header-regexp))
            message-newgroups-header-regexp message-newsgroups-header-regexp)
        . message-expand-group))))))

(comment
  (use-package gnus-harvest
    :commands gnus-harvest-install
    :demand t
    :config
    (if (featurep 'message-x)
        (gnus-harvest-install 'message-x)
      (gnus-harvest-install))))

(use-feature gnus-article-treat-patch
  :disabled
  :demand
  :load-path "lisp/"
  :config
  ;; note: be sure to customize faces with `:foreground "white"' when
  ;; using a theme with a white/light background :)
  (setq ft/gnus-article-patch-conditions
        '("^@@ -[0-9]+,[0-9]+ \\+[0-9]+,[0-9]+ @@")))

\f
;;; IRC (with ERC and ZNC)

(use-feature erc
  :bind (("C-c b b" . erc-switch-to-buffer)
         :map erc-mode-map
         ("M-a" . erc-track-switch-buffer))
  :custom
  (erc-join-buffer 'bury)
  (erc-lurker-hide-list '("JOIN" "PART" "QUIT"))
  (erc-nick "bandali")
  (erc-prompt "erc>")
  (erc-rename-buffers t)
  (erc-server-reconnect-attempts 5)
  (erc-server-reconnect-timeout 3)
  :config
  (defun erc-cmd-OPME ()
    "Request chanserv to op me."
    (erc-message "PRIVMSG"
                 (format "chanserv op %s %s"
                         (erc-default-target)
                         (erc-current-nick)) nil))
  (defun erc-cmd-DEOPME ()
    "Deop myself from current channel."
    (erc-cmd-DEOP (format "%s" (erc-current-nick))))
  (add-to-list 'erc-modules 'keep-place)
  (add-to-list 'erc-modules 'notifications)
  (add-to-list 'erc-modules 'spelling)
  (add-to-list 'erc-modules 'scrolltoplace)
  (erc-update-modules))

(use-feature erc-fill
  :after erc
  :custom
  (erc-fill-column 77)
  (erc-fill-function 'erc-fill-static)
  (erc-fill-static-center 18))

(use-feature erc-pcomplete
  :after erc
  :custom
  (erc-pcomplete-nick-postfix ", "))

(use-feature erc-track
  :after erc
  :bind (("C-c a e t d" . erc-track-disable)
         ("C-c a e t e" . erc-track-enable))
  :custom
  (erc-track-enable-keybindings nil)
  (erc-track-exclude-types '("JOIN" "MODE" "NICK" "PART" "QUIT"
                             "324" "329" "332" "333" "353" "477"))
  (erc-track-position-in-mode-line t)
  (erc-track-priority-faces-only 'all)
  (erc-track-shorten-function nil))

(use-package erc-hl-nicks
  :after erc)

(use-package erc-scrolltoplace
  :after erc)

(use-package znc
  :straight (:host nil :repo "https://git.shemshak.org/amin/znc.el")
  :bind (("C-c a e e" . znc-erc)
         ("C-c a e a" . znc-all))
  :config
  (let ((pwd (let ((auth (auth-source-search :host "znca")))
               (cond
                ((null auth) (error "Couldn't find znca's authinfo"))
                (t (funcall (plist-get (car auth) :secret)))))))
    (setq znc-servers
          `(("znc.shemshak.org" 1337 t
             ((freenode "amin/freenode" ,pwd)))
            ("znc.shemshak.org" 1337 t
             ((moznet "amin/moznet" ,pwd)))
            ("znc.shemshak.org" 1337 t
             ((oftc "amin/oftc" ,pwd)))))))

\f
;;; Post initialization

(message "Loading %s...done (%.3fs)" user-init-file
         (float-time (time-subtract (current-time)
                                    b/before-user-init-time)))

;;; init.el ends here