[~bandali/configs] / init.org

#+title: =aminb='s Literate Emacs Configuration
#+author: Amin Bandali
#+babel: :cache yes
#+property: header-args :tangle yes

* About
:PROPERTIES:
:CUSTOM_ID: about
:END:

This org file is my literate configuration for GNU Emacs, and is
tangled to [[./init.el][init.el]]. Packages are installed and managed using
[[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
many different people. Some of the configurations that I can remember
off the top of my head are:

- [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  straight.el for managing packages
- [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  packages
- [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
- [[https://github.com/dakrone/eos][dakrone/eos]]
- Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
- [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
- [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
- [[https://github.com/hlissner/doom-emacs][Doom Emacs]]

I'd like to have a fully reproducible Emacs setup (part of the reason
why I store my configuration in this repository) but unfortunately out
of the box, that's not achievable with =package.el=, not currently
anyway. So, I've opted to use Borg. For what it's worth, I briefly
experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
to my init time; which is unacceptable for me: I use Emacs as my
window manager (via EXWM) and coming from bspwm, I'm too used to
having fast startup times.

** Installation

To use this config for your Emacs, first you need to clone this repo,
then bootstrap Borg, tell Borg to retrieve package submodules, and
byte-compiled the packages. Something along these lines should work:

#+begin_src sh :tangle no
git clone https://github.com/aminb/dotfiles ~/.emacs.d
cd ~/.emacs.d
make bootstrap-borg
make bootstrap
make build
#+end_src

* Contents                                                   :toc_1:noexport:

- [[#about][About]]
- [[#header][Header]]
- [[#initial-setup][Initial setup]]
- [[#core][Core]]
- [[#post-initialization][Post initialization]]
- [[#footer][Footer]]

* Header
:PROPERTIES:
:CUSTOM_ID: header
:END:

** First line

#+begin_src emacs-lisp :comments none
;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
#+end_src

Enable =view-mode=, which both makes the file read-only (as a reminder
that =init.el= is an auto-generated file, not supposed to be edited),
and provides some convenient key bindings for browsing through the
file.

** License

#+begin_src emacs-lisp :comments none
;; Copyright (C) 2018  Amin Bandali <bandali@gnu.org>

;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
#+end_src

** Commentary

#+begin_src emacs-lisp :comments none
;;; Commentary:

;; Emacs configuration of Amin Bandali, computer scientist and functional
;; programmer.

;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
#+end_src

** Naming conventions

The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].

#+begin_src emacs-lisp :comments none
;; Naming conventions:
;;
;;   amin-...   public variables or non-interactive functions
;;   amin--...  private anything (non-interactive), not safe for direct use
;;   amin/...   an interactive function; safe for M-x or keybinding
;;   amin:...   an evil operator, motion, or command
;;   amin|...   a hook function
;;   amin*...   an advising function
;;   amin@...   a hydra command
;;   ...!       a macro
#+end_src

* Initial setup
:PROPERTIES:
:CUSTOM_ID: initial-setup
:END:

#+begin_src emacs-lisp :comments none
;;; Code:
#+end_src

** Emacs initialization

I'd like to do a couple of measurements of Emacs' startup time. First,
let's see how long Emacs takes to start up, before even loading
=init.el=, i.e. =user-init-file=:

#+begin_src emacs-lisp
(defvar amin--before-user-init-time (current-time)
  "Value of `current-time' when Emacs begins loading `user-init-file'.")
(message "Loading Emacs...done (%.3fs)"
         (float-time (time-subtract amin--before-user-init-time
                                    before-init-time)))
#+end_src

Also, temporarily increase ~gc-cons-threshhold~ and
~gc-cons-percentage~ during startup to reduce garbage collection
frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
startup time as well.

#+begin_src emacs-lisp
(defvar amin--gc-cons-threshold gc-cons-threshold)
(defvar amin--gc-cons-percentage gc-cons-percentage)
(defvar amin--file-name-handler-alist file-name-handler-alist)
(setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
      gc-cons-percentage 0.6
      file-name-handler-alist nil
      ;; sidesteps a bug when profiling with esup
      esup-child-profile-require-level 0)
#+end_src

Of course, we'd like to set them back to their defaults once we're
done initializing.

#+begin_src emacs-lisp
(add-hook
 'after-init-hook
 (lambda ()
   (setq gc-cons-threshold amin--gc-cons-threshold
         gc-cons-percentage amin--gc-cons-percentage
         file-name-handler-alist amin--file-name-handler-alist)))
#+end_src

Increase the number of lines kept in message logs (the =*Messages*=
buffer).

#+begin_src emacs-lisp
(setq message-log-max 20000)
#+end_src

Optionally, we could suppress some byte compiler warnings like below,
but for now I've decided to keep them enabled. See documentation for
~byte-compile-warnings~ for more details.

#+begin_src emacs-lisp
;; (setq byte-compile-warnings
;;       '(not free-vars unresolved noruntime lexical make-local))
#+end_src

** whoami

#+begin_src emacs-lisp
(setq user-full-name "Amin Bandali"
      user-mail-address "amin@bandali.me")
#+end_src

** Package management

*** No =package.el=

I can do all my package management things with Borg, and don't need
Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).

#+begin_src emacs-lisp :tangle early-init.el
(setq package-enable-at-startup nil)
#+end_src

But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
right now), and even when released it'll be long before most distros
ship in their repos, I'll still put the old workaround with the
commented call to ~package-initialize~ here anyway.

#+begin_src emacs-lisp
(setq package-enable-at-startup nil)
;; (package-initialize)
#+end_src

*** Borg

#+begin_quote
Assimilate Emacs packages as Git submodules
#+end_quote

[[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
short, it creates a git submodule in =lib/= for each package, which
can then be managed with the help of Magit or other tools.

#+begin_src emacs-lisp
(setq user-init-file (or load-file-name buffer-file-name)
      user-emacs-directory (file-name-directory user-init-file))
(add-to-list 'load-path
             (expand-file-name "lib/borg" user-emacs-directory))
(require 'borg)
(borg-initialize)

;; (require 'borg-nix-shell)
;; (setq borg-build-shell-command 'borg-nix-shell-build-command)

(with-eval-after-load 'bind-key
  (bind-keys
   :package borg
   ("C-c b A" . borg-activate)
   ("C-c b a" . borg-assimilate)
   ("C-c b b" . borg-build)
   ("C-c b c" . borg-clone)
   ("C-c b m" . borg-insert-update-message)
   ("C-c b r" . borg-remove)))
#+end_src

*** =use-package=

#+begin_quote
A use-package declaration for simplifying your .emacs
#+end_quote

[[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
packages (in our case especially the latter) in a neatly organized way
and without compromising on performance.

#+begin_src emacs-lisp
(require 'use-package)
(if nil  ; set to t when need to debug init
    (setq use-package-verbose t
          use-package-expand-minimally nil
          use-package-compute-statistics t
          debug-on-error t)
  (setq use-package-verbose nil
        use-package-expand-minimally t))
#+end_src

*** Epkg

#+begin_quote
Browse the Emacsmirror package database
#+end_quote

Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
database, low-level functions for querying the database, and a
=package.el=-like user interface for browsing the available packages.

#+begin_src emacs-lisp
(use-package epkg
  :defer t
  :bind
  (("C-c b d" . epkg-describe-package)
   ("C-c b p" . epkg-list-packages)
   ("C-c b u" . epkg-update)))
#+end_src

** No littering in =~/.emacs.d=

#+begin_quote
Help keeping ~/.emacs.d clean
#+end_quote

By default, even for Emacs' built-in packages, the configuration files
and persistent data are all over the place. Use =no-littering= to help
contain the mess.

#+begin_src emacs-lisp
(use-package no-littering
  :demand t
  :config
  (savehist-mode 1)
  (add-to-list 'savehist-additional-variables 'kill-ring)
  (save-place-mode 1)
  (setq auto-save-file-name-transforms
        `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
#+end_src

** Custom file (=custom.el=)

I'm not planning on using the custom file much, but even so, I
definitely don't want it mixing with =init.el=. So, here; let's give
it it's own file. While at it, treat themes as safe.

#+begin_src emacs-lisp
(use-package custom
  :no-require t
  :config
  (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
  (when (file-exists-p custom-file)
    (load custom-file))
  (setf custom-safe-themes t))
#+end_src

** Secrets file

Load the secrets file if it exists, otherwise show a warning.

#+begin_src emacs-lisp
(with-demoted-errors
    (load (no-littering-expand-etc-file-name "secrets")))
#+end_src

** Better =$PATH= handling

Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
in my shell.

#+begin_src emacs-lisp
(use-package exec-path-from-shell
  :defer 1
  :init
  (setq exec-path-from-shell-check-startup-files nil)
  :config
  (exec-path-from-shell-initialize)
  ;; while we're at it, let's fix access to our running ssh-agent
  (exec-path-from-shell-copy-env "SSH_AGENT_PID")
  (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
#+end_src

** COMMENT Only one custom theme at a time

#+begin_src emacs-lisp
(defadvice load-theme (before clear-previous-themes activate)
  "Clear existing theme settings instead of layering them"
  (mapc #'disable-theme custom-enabled-themes))
#+end_src

** Server

Start server if not already running. Alternatively, can be done by
issuing =emacs --daemon= in the terminal, which can be automated with
a systemd service or using =brew services start emacs= on macOS. I use
Emacs as my window manager (via EXWM), so I always start Emacs on
login; so starting the server from inside Emacs is good enough for me.

See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].

#+begin_src emacs-lisp
(use-package server
  :defer 1
  :config (or (server-running-p) (server-mode)))
#+end_src

** COMMENT Unicode support

Font stack with better unicode support, around =Ubuntu Mono= and
=Hack=.

#+begin_src emacs-lisp :tangle no
(dolist (ft (fontset-list))
  (set-fontset-font
   ft
   'unicode
   (font-spec :name "Source Code Pro" :size 14))
  (set-fontset-font
   ft
   'unicode
   (font-spec :name "DejaVu Sans Mono")
   nil
   'append)
  ;; (set-fontset-font
  ;;  ft
  ;;  'unicode
  ;;  (font-spec
  ;;   :name "Symbola monospacified for DejaVu Sans Mono")
  ;;  nil
  ;;  'append)
  ;; (set-fontset-font
  ;;  ft
  ;;  #x2115  ; ℕ
  ;;  (font-spec :name "DejaVu Sans Mono")
  ;;  nil
  ;;  'append)
  (set-fontset-font
   ft
   (cons ?Α ?ω)
   (font-spec :name "DejaVu Sans Mono" :size 14)
   nil
   'prepend))
#+end_src

** Gentler font resizing

#+begin_src emacs-lisp
(setq text-scale-mode-step 1.05)
#+end_src

** Libraries

#+begin_src emacs-lisp
(require 'cl-lib)
(require 'subr-x)
#+end_src

** Useful utilities

#+begin_src emacs-lisp
(defun amin-enlist (exp)
  "Return EXP wrapped in a list, or as-is if already a list."
(if (listp exp) exp (list exp)))

; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
(defmacro after! (features &rest body)
  "A smart wrapper around `with-eval-after-load'. Supresses warnings during
compilation."
  (declare (indent defun) (debug t))
  (list (if (or (not (bound-and-true-p byte-compile-current-file))
                (dolist (next (amin-enlist features))
                  (if (symbolp next)
                      (require next nil :no-error)
                    (load next :no-message :no-error))))
            #'progn
          #'with-no-warnings)
        (cond ((symbolp features)
               `(eval-after-load ',features '(progn ,@body)))
              ((and (consp features)
                    (memq (car features) '(:or :any)))
               `(progn
                  ,@(cl-loop for next in (cdr features)
                             collect `(after! ,next ,@body))))
              ((and (consp features)
                    (memq (car features) '(:and :all)))
               (dolist (next (cdr features))
                 (setq body `(after! ,next ,@body)))
               body)
              ((listp features)
               `(after! (:all ,@features) ,@body)))))
#+end_src

Convenience macro for =setq='ing multiple variables to the same value:

#+begin_src emacs-lisp
(defmacro setq-every! (value &rest vars)
  "Set all the variables from VARS to value VALUE."
  (declare (indent defun) (debug t))
  `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
#+end_src

* Core
:PROPERTIES:
:CUSTOM_ID: core
:END:

** Defaults

*** Time and battery in mode-line

Enable displaying time and battery in the mode-line, since I'm not
using the Xfce panel anymore. Also, I don't need to see the load
average on a regular basis, so disable that.

Note: using =i3status= on sway at the moment, so disabling this.

#+begin_src emacs-lisp :tangle no
(use-package time
  :init
  (setq display-time-default-load-average nil)
  :config
  (display-time-mode))

(use-package battery
  :config
  (display-battery-mode))
#+end_src

*** Smaller fringe

Might want to set the fringe to a smaller value, especially if using
EXWM. I'm fine with the default for now.

#+begin_src emacs-lisp
;; (fringe-mode '(3 . 1))
(fringe-mode nil)
#+end_src

*** Disable disabled commands

Emacs disables some commands by default that could persumably be
confusing for novice users. Let's disable that.

#+begin_src emacs-lisp
(setq disabled-command-function nil)
#+end_src

*** Kill-ring

Save what I copy into clipboard from other applications into Emacs'
kill-ring, which would allow me to still be able to easily access it
in case I kill (cut or copy) something else inside Emacs before
yanking (pasting) what I'd originally intended to.

#+begin_src emacs-lisp
(setq save-interprogram-paste-before-kill t)
#+end_src

*** Minibuffer

#+begin_src emacs-lisp
(setq enable-recursive-minibuffers t
      resize-mini-windows t)
#+end_src

*** Lazy-person-friendly yes/no prompts

Lazy people would prefer to type fewer keystrokes, especially for yes
or no questions. I'm lazy.

#+begin_src emacs-lisp
(defalias 'yes-or-no-p #'y-or-n-p)
#+end_src

*** Startup screen and =*scratch*=

Firstly, let Emacs know that I'd like to have =*scratch*= as my
startup buffer.

#+begin_src emacs-lisp
(setq initial-buffer-choice t)
#+end_src

Now let's customize the =*scratch*= buffer a bit. First off, I don't
need the default hint.

#+begin_src emacs-lisp
(setq initial-scratch-message nil)
#+end_src

Also, let's use Text mode as the major mode, in case I want to
customize it (=*scratch*='s default major mode, Fundamental mode,
can't really be customized).

#+begin_src emacs-lisp
(setq initial-major-mode 'text-mode)
#+end_src

Inhibit the buffer list when more than 2 files are loaded.

#+begin_src emacs-lisp
(setq inhibit-startup-buffer-menu t)
#+end_src

I don't really need to see the startup screen or echo area message
either.

#+begin_src emacs-lisp
(advice-add #'display-startup-echo-area-message :override #'ignore)
(setq inhibit-startup-screen t
      inhibit-startup-echo-area-message user-login-name)
#+end_src

*** More useful frame titles

Show either the file name or the buffer name (in case the buffer isn't
visiting a file). Borrowed from Emacs Prelude.

#+begin_src emacs-lisp
(setq frame-title-format
      '("" invocation-name " - "
        (:eval (if (buffer-file-name)
                   (abbreviate-file-name (buffer-file-name))
                 "%b"))))
#+end_src

*** Backups

Emacs' default backup settings aren't that great. Let's use more
sensible options. See documentation for the ~make-backup-file~
variable.

#+begin_src emacs-lisp
(setq backup-by-copying t
      version-control t
      delete-old-versions t)
#+end_src

*** Auto revert

Enable automatic reloading of changed buffers and files.

#+begin_src emacs-lisp
(global-auto-revert-mode 1)
(setq auto-revert-verbose nil
      global-auto-revert-non-file-buffers nil)
#+end_src

*** Always use space for indentation

#+begin_src emacs-lisp
(setq-default
 indent-tabs-mode nil
 require-final-newline t
 tab-width 4)
#+end_src

*** Winner mode

Enable =winner-mode=.

#+begin_src emacs-lisp
(winner-mode 1)
#+end_src

*** Close =*compilation*= on success

#+begin_src emacs-lisp
(setq compilation-exit-message-function
      (lambda (status code msg)
        "Close the compilation window if successful."
        ;; if M-x compile exits with 0
         (when (and (eq status 'exit) (zerop code))
           (bury-buffer)
           (delete-window (get-buffer-window (get-buffer "*compilation*"))))
         ;; return the result of compilation-exit-message-function
         (cons msg code)))
#+end_src

*** Search for non-ASCII characters

I’d like non-ASCII characters such as ‘’“”«»‹›áⓐ𝒶 to be selected when
I search for their ASCII counterpart.  Shoutout to [[http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html][endlessparentheses]]
for this.

#+begin_src emacs-lisp
(setq search-default-mode #'char-fold-to-regexp)

;; uncomment to extend this behaviour to query-replace
;; (setq replace-char-fold t)
#+end_src

** Bindings

#+begin_src emacs-lisp
(bind-keys
 ("s-c e b" . eval-buffer)
 ("s-c e r" . eval-region)

 ("s-p"     . beginning-of-buffer)
 ("s-n"     . end-of-buffer))
#+end_src

** Packages

The packages in this section are absolutely essential to my everyday
workflow, and they play key roles in how I do my computing. They
immensely enhance the Emacs experience for me; both using Emacs, and
customizing it.

*** [[https://github.com/emacscollective/auto-compile][auto-compile]]

#+begin_src emacs-lisp
(use-package auto-compile
  :demand t
  :config
  (auto-compile-on-load-mode)
  (auto-compile-on-save-mode)
  (setq auto-compile-display-buffer               nil
        auto-compile-mode-line-counter            t
        auto-compile-source-recreate-deletes-dest t
        auto-compile-toggle-deletes-nonlib-dest   t
        auto-compile-update-autoloads             t)
  (add-hook 'auto-compile-inhibit-compile-hook
            'auto-compile-inhibit-compile-detached-git-head))
#+end_src

*** [[https://github.com/noctuid/general.el][general]]

#+begin_src emacs-lisp
(use-package general
  :demand t
  :config
  (general-evil-setup t)
  (general-override-mode)

  (general-create-definer
   amin--leader-keys
   :keymaps 'override
   :states '(emacs normal visual motion insert)
   :non-normal-prefix "M-m"
   :prefix "SPC"))
#+end_src

*** [[https://github.com/emacs-evil/evil][evil]]

#+begin_src emacs-lisp
(use-package evil
  :demand t
  ;; :hook (org-src-mode . evil-motion-state)
  :config
  (evil-mode 1)
  (general-swap-key nil '(normal motion) ";" ":")

  (setq evil-want-visual-char-semi-exclusive t
        evil-cross-lines t)

  ;; custom mode state mappings
  (dolist (mspair '((ebdb-mode    . emacs)
                    (helpful-mode . motion)
                    (view-mode    . motion)))
    (evil-set-initial-state (car mspair) (cdr mspair)))

  ;; fix tab and indentation in src blocks inside org-mode buffer
  ;; also see https://git.sr.ht/~bandali/dotfiles/commit/0e2ffd584aafdd4cf256bcdf2473f01c3aaaed55
  (unbind-key "TAB" evil-motion-state-map)

  (unbind-key "C-d" evil-insert-state-map)
  (unbind-key "C-v" evil-insert-state-map)
  (unbind-key "C-y" evil-insert-state-map)
  (unbind-key "C-a" evil-insert-state-map)
  (unbind-key "C-e" evil-insert-state-map)
  (unbind-key "C-p" evil-insert-state-map)
  (unbind-key "C-n" evil-insert-state-map)
  (unbind-key "C-k" evil-insert-state-map)
  (bind-keys
    :map evil-insert-state-map
    ("C-k"   . kill-line)
    ("C-S-k" . evil-insert-digraph)
    :map evil-motion-state-map
    ([down-mouse-1] . nil)))
#+end_src

#+begin_src emacs-lisp
(use-package evil-escape
  :after evil
  :init
  (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
        evil-escape-excluded-major-modes '(neotree-mode)
        evil-escape-key-sequence "jk"
        evil-escape-delay 0.25)
  ;; :general
  ;; (:states '(insert replace visual operator)
  ;;          "C-g" #'evil-escape)
  :config
  (evil-escape-mode 1)
  ;; no `evil-escape' in minibuffer
  (push #'minibufferp evil-escape-inhibit-functions))
#+end_src

#+begin_src emacs-lisp
(use-package evil-nerd-commenter
  :after evil
  :general
  (nmap
    "gc" 'evilnc-comment-operator
    "gy" 'evilnc-copy-and-comment-lines))
#+end_src

#+begin_src emacs-lisp
(use-package evil-surround
  :after evil
  :general
  (omap
    "s" 'evil-surround-edit
    "S" 'evil-Surround-edit)
  (vmap
    "S" 'evil-surround-region
    "gS" 'evil-Surround-region))
#+end_src

#+begin_src emacs-lisp
(amin--leader-keys
  "/"   '(:ignore t :wk "search")

  "a"   '(:ignore t :wk "apps")
  "a i" 'ielm

  "b"   '(:ignore t :wk "buffers")
  "b k" 'kill-this-buffer
  "b s" 'save-buffer

  "e"   '(:ignore t :wk "eval")
  "e b" 'eval-buffer
  "e r" 'eval-region

  "f"   '(:ignore t :wk "files")

  "F"   '(:ignore t :wk "frames")
  "F m" 'make-frame-command
  "F d" 'delete-frame
  "F D" 'delete-other-frames

  "h"   '(:ignore t :wk "help(ful)")
  "h c" 'describe-char
  "h f" 'describe-function
  "h F" 'describe-face
  "h H" 'view-hello-file
  "h i" 'info
  "h k" 'describe-key
  "h l" 'view-lossage
  "h v" 'describe-variable

  "o"   'other-window

  "w"   '(:ignore t :wk "window")
  "w o" 'other-window
  "w 0" 'delete-window
  "w 1" 'delete-other-windows
  "w 2" 'split-window-below
  "w 3" 'split-window-right
  "w u" 'winner-undo
  "w r" 'winner-redo

  "q"   '(:ignore t :wk "quit")
  "q q" 'save-buffers-kill-terminal)
#+end_src

*** [[https://orgmode.org/][Org mode]]

#+begin_quote
Org mode is for keeping notes, maintaining TODO lists, planning
projects, and authoring documents with a fast and effective plain-text
system.
#+end_quote

In short, my favourite way of life.

#+begin_src emacs-lisp
(use-package org
  :defer 1
  :general
  (amin--leader-keys
    :states 'normal
    :keymaps 'org-mode-map
    "'" 'org-edit-special)
  (amin--leader-keys
    :definer 'minor-mode
    :states 'normal
    :keymaps 'org-src-mode
    "'" 'org-edit-src-exit
    "k" 'org-edit-src-abort)
  (general-define-key
   :definer 'minor-mode
   :states 'normal
   :keymaps 'org-src-mode
   "q" 'org-edit-src-exit)
  :config
  (setq org-src-tab-acts-natively t
        org-src-preserve-indentation nil
        org-edit-src-content-indentation 0
        org-email-link-description-format "Email %c: %s" ; %.30s
        org-highlight-latex-and-related '(entities)
        org-log-done 'time)
  (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
  (after! org-src
    (define-key org-src-mode-map [remap evil-write] 'org-edit-src-save)
    (define-key org-src-mode-map [remap evil-save-and-close]
      (lambda () (interactive)
        (org-edit-src-save)
        (org-edit-src-exit)))
    (define-key org-src-mode-map [remap evil-save-modified-and-close]
      (lambda () (interactive)
        (org-edit-src-save)
        (org-edit-src-exit)))
    (define-key org-src-mode-map [remap evil-quit] 'org-edit-src-abort))
  (font-lock-add-keywords
   'org-mode
   '(("[ \t]*\\(#\\+\\(BEGIN\\|END\\|begin\\|end\\)_\\(\\S-+\\)\\)[ \t]*\\([^\n:]*\\)"
      (1 '(:foreground "#5a5b5a" :background "#292b2b") t) ; directive
      (3 '(:foreground "#81a2be" :background "#292b2b") t) ; kind
      (4 '(:foreground "#c5c8c6") t))) ; title
   t)
  :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
  :hook ((org-mode . org-indent-mode)
         (org-mode . auto-fill-mode)
         (org-mode . flyspell-mode))
  :custom
  (org-latex-packages-alist '(("" "listings") ("" "color")))
  :custom-face
  '(org-block-begin-line ((t (:foreground "#5a5b5a" :background "#1d1f21"))))
  '(org-block ((t (:background "#1d1f21"))))
  '(org-latex-and-related ((t (:foreground "#b294bb")))))

(use-package ox-latex
  :after ox
  :config
  (setq org-latex-listings 'listings
        ;; org-latex-prefer-user-labels t
        )
  (add-to-list 'org-latex-packages-alist '("" "listings"))
  (add-to-list 'org-latex-packages-alist '("" "color"))
  (add-to-list 'org-latex-classes
               '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
                 ("\\section{%s}" . "\\section*{%s}")
                 ("\\subsection{%s}" . "\\subsection*{%s}")
                 ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
                 ("\\paragraph{%s}" . "\\paragraph*{%s}")
                 ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
               t))

(use-package ox-beamer
  :after ox)

(use-package ob-tangle
  :general
  (amin--leader-keys
    :states 'normal
    :keymaps 'org-mode-map
    "b t" 'org-babel-tangle))

(use-package orgalist
  :after message
  :hook (message-mode . orgalist-mode))
#+end_src

**** asynchronous tangle

=amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
file.

#+begin_src emacs-lisp
(after! org
  (defvar amin-show-async-tangle-results nil
    "Keep *emacs* async buffers around for later inspection.")

  (defvar amin-show-async-tangle-time nil
    "Show the time spent tangling the file.")

  (defvar amin-async-tangle-post-compile "make ti"
    "If non-nil, pass to `compile' after successful tangle.")

  (defun amin/async-babel-tangle ()
    "Tangle org file asynchronously."
    (interactive)
    (let* ((file-tangle-start-time (current-time))
           (file (buffer-file-name))
           (file-nodir (file-name-nondirectory file))
           (async-quiet-switch "-q"))
      (async-start
       `(lambda ()
          (require 'org)
          (org-babel-tangle-file ,file))
       (unless amin-show-async-tangle-results
         `(lambda (result)
            (if result
                (progn
                  (message "Tangled %s%s"
                           ,file-nodir
                           (if amin-show-async-tangle-time
                               (format " (%.3fs)"
                                       (float-time (time-subtract (current-time)
                                                                  ',file-tangle-start-time)))
                             ""))
                  (when amin-async-tangle-post-compile
                    (compile amin-async-tangle-post-compile)))
              (message "Tangling %s failed" ,file-nodir))))))))

(add-to-list
 'safe-local-variable-values
 '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
#+end_src

*** [[https://magit.vc/][Magit]]

#+begin_quote
It's Magit! A Git porcelain inside Emacs.
#+end_quote

Not just how I do git, but /the/ way to do git.

#+begin_src emacs-lisp
(use-package magit
  :defer 1
  :general (amin--leader-keys "g s" 'magit-status)
  :bind ("s-g" . magit-status)
  :config
  (magit-add-section-hook 'magit-status-sections-hook
                          'magit-insert-modules
                          'magit-insert-stashes
                          'append)
  (setq
   magit-repository-directories '(("~/.emacs.d/" . 0)
                                  ("~/src/git/" . 1)))
  (nconc magit-section-initial-visibility-alist
         '(([unpulled status] . show)
           ([unpushed status] . show)))
  :custom-face (magit-diff-file-heading ((t (:weight normal)))))
#+end_src

*** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)

#+begin_quote
Ivy - a generic completion frontend for Emacs, Swiper - isearch with
an overview, and more. Oh, man!
#+end_quote

There's no way I could top that, so I won't attempt to.

**** Ivy

#+begin_src emacs-lisp
(use-package ivy
  :defer 1
  :general (amin--leader-keys "," 'ivy-switch-buffer)
  :bind
  (:map ivy-minibuffer-map
   ([escape] . keyboard-escape-quit)
   ([S-up]   . ivy-previous-history-element)
   ([S-down] . ivy-next-history-element)
   ("DEL"    . ivy-backward-delete-char))
  :config
  (setq ivy-wrap t)
  (ivy-mode 1)
  ;; :custom-face
  ;; (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
  ;; (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
  ;; (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold))))
)
#+end_src

**** Swiper

#+begin_src emacs-lisp
(use-package swiper
  :general (:states '(normal motion) "/" 'swiper)
  :bind (("C-s" . swiper)
         ("C-r" . swiper)))
#+end_src

**** Counsel

#+begin_src emacs-lisp
(use-package counsel
  :defer 1
  :general
  (amin--leader-keys
    "r" 'counsel-recentf
    "SPC" 'counsel-M-x
    "."   'counsel-find-file)
  :bind (([remap execute-extended-command] . counsel-M-x)
         ([remap find-file]                . counsel-find-file)
         ("s-r"                            . counsel-recentf)
         ("C-c x"                          . counsel-M-x)
         ("C-c f ."                        . counsel-find-file)
         :map minibuffer-local-map
         ("C-r" . counsel-minibuffer-history))
  :config
  (counsel-mode 1)
  (defalias 'locate #'counsel-locate))
#+end_src

*** eshell

#+begin_src emacs-lisp
(use-package eshell
  :defer 1
  :commands eshell
  :config
  (eval-when-compile (defvar eshell-prompt-regexp))
  (defun amin/eshell-quit-or-delete-char (arg)
    (interactive "p")
    (if (and (eolp) (looking-back eshell-prompt-regexp nil))
        (eshell-life-is-too-much)
      (delete-char arg)))

  (defun amin/eshell-clear ()
    (interactive)
    (let ((inhibit-read-only t))
      (erase-buffer))
    (eshell-send-input))

  (defun amin|eshell-setup ()
    (make-local-variable 'company-idle-delay)
    (setq company-idle-delay nil)
    (bind-keys :map eshell-mode-map
               ("C-d"   . amin/eshell-quit-or-delete-char)
               ("C-S-l" . amin/eshell-clear)
               ("M-r"   . counsel-esh-history)
               ([tab]   . company-complete)))

  :hook (eshell-mode . amin|eshell-setup)
  :custom
  (eshell-hist-ignoredups t)
  (eshell-input-filter 'eshell-input-filter-initial-space))
#+end_src

*** Ibuffer

#+begin_src emacs-lisp
(use-package ibuffer
  :defer t
  :general (amin--leader-keys "b b" 'ibuffer-other-window)
  :bind
  (("C-x C-b" . ibuffer-other-window)
   :map ibuffer-mode-map
   ("P"   . ibuffer-backward-filter-group)
   ("N"   . ibuffer-forward-filter-group)
   ("M-p" . ibuffer-do-print)
   ("M-n" . ibuffer-do-shell-command-pipe-replace))
  :config
  ;; Use human readable Size column instead of original one
  (define-ibuffer-column size-h
    (:name "Size" :inline t)
    (cond
     ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
     ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
     ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
     (t (format "%8d" (buffer-size)))))
  :custom
  (ibuffer-saved-filter-groups
   '(("default"
      ("dired" (mode . dired-mode))
      ("org"   (mode . org-mode))
      ("web"
       (or
        (mode . web-mode)
        (mode . css-mode)
        (mode . scss-mode)
        (mode . js2-mode)))
      ("shell"
       (or
        (mode . eshell-mode)
        (mode . shell-mode)))
      ("notmuch" (name . "\*notmuch\*"))
      ("programming"
       (or
        (mode . python-mode)
        (mode . c++-mode)
        (mode . emacs-lisp-mode)))
      ("emacs"
       (or
        (name . "^\\*scratch\\*$")
        (name . "^\\*Messages\\*$")))
      ("slack"
       (or
        (name . "^\\*Slack*"))))))
  (ibuffer-formats
   '((mark modified read-only locked " "
           (name 18 18 :left :elide)
           " "
           (size-h 9 -1 :right)
           " "
           (mode 16 16 :left :elide)
           " " filename-and-process)
     (mark " "
           (name 16 -1)
           " " filename)))
  :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
#+end_src

*** Outline

#+begin_src emacs-lisp
(use-package outline
  :defer t
  :hook (prog-mode . outline-minor-mode)
  :bind
  (:map
   outline-minor-mode-map
   ("<s-tab>"  . outline-toggle-children)
   ("M-p"      . outline-previous-visible-heading)
   ("M-n"      . outline-next-visible-heading)
   :prefix-map amin--outline-prefix-map
   :prefix "s-o"
   ("TAB" . outline-toggle-children)
   ("a"   . outline-hide-body)
   ("H"   . outline-hide-body)
   ("S"   . outline-show-all)
   ("h"   . outline-hide-subtree)
   ("s"   . outline-show-subtree)))
#+end_src

* Borg's =layer/essentials=

TODO: break this giant source block down into individual org sections.

#+begin_src emacs-lisp
(use-package dash
  :config (dash-enable-font-lock))

(use-package diff-hl
  :config
  (setq diff-hl-draw-borders nil)
  (global-diff-hl-mode)
  (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))

(use-package dired
  :defer t
  :config (setq dired-listing-switches "-alh"))

(use-package eldoc
  :when (version< "25" emacs-version)
  :config (global-eldoc-mode))

(use-package help
  :defer t
  :config
  (temp-buffer-resize-mode)
  (setq help-window-select t))

(progn ;    `isearch'
  (setq isearch-allow-scroll t))

(use-package lisp-mode
  :config
  (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
  (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
  (defun indent-spaces-mode ()
    (setq indent-tabs-mode nil))
  (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))

(use-package man
  :defer t
  :config (setq Man-width 80))

(use-package paren
  :config (show-paren-mode))

(use-package prog-mode
  :config (global-prettify-symbols-mode)
  (defun indicate-buffer-boundaries-left ()
    (setq indicate-buffer-boundaries 'left))
  (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))

(use-package recentf
  :defer 0.5
  :config
  (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
  (setq recentf-max-saved-items 40))

(use-package savehist
  :config (savehist-mode))

(use-package saveplace
  :when (version< "25" emacs-version)
  :config (save-place-mode))

(use-package simple
  :config (column-number-mode))

(progn ;    `text-mode'
  (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left)
  (add-hook 'text-mode-hook #'abbrev-mode))

(use-package tramp
  :defer t
  :config
  (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
  (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
  (add-to-list 'tramp-default-proxies-alist
               (list (regexp-quote (system-name)) nil nil)))

(use-package undo-tree
  :config
  (global-undo-tree-mode -1))
  ;; :bind (("C-?" . undo-tree-undo)
  ;;        ("M-_" . undo-tree-redo))
  ;; :config
  ;; (global-undo-tree-mode)
  ;; (setq undo-tree-mode-lighter ""
  ;;       undo-tree-auto-save-history t))
#+end_src

* Editing

** Company

#+begin_src emacs-lisp
(use-package company
  :defer 1
  :bind
  (:map company-active-map
        ([tab]    . company-complete-common-or-cycle)
        ([escape] . company-abort))
  :custom
  (company-minimum-prefix-length 1)
  (company-selection-wrap-around t)
  (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
  (company-dabbrev-downcase nil)
  (company-dabbrev-ignore-case nil)
  :config
  (global-company-mode t))
#+end_src

* Syntax and spell checking
#+begin_src emacs-lisp
(use-package flycheck
  :defer 3
  :hook (prog-mode . flycheck-mode)
  :bind
  (:map flycheck-mode-map
        ("M-P" . flycheck-previous-error)
        ("M-N" . flycheck-next-error))
  :config
  ;; Use the load-path from running Emacs when checking elisp files
  (setq flycheck-emacs-lisp-load-path 'inherit)

  ;; Only flycheck when I actually save the buffer
  (setq flycheck-check-syntax-automatically '(mode-enabled save)))

;; http://endlessparentheses.com/ispell-and-apostrophes.html
(use-package ispell
  :defer 3
  :config
  ;; ’ can be part of a word
  (setq ispell-local-dictionary-alist
        `((nil "[[:alpha:]]" "[^[:alpha:]]"
               "['\x2019]" nil ("-B") nil utf-8)))
  ;; don't send ’ to the subprocess
  (defun endless/replace-apostrophe (args)
    (cons (replace-regexp-in-string
           "’" "'" (car args))
          (cdr args)))
  (advice-add #'ispell-send-string :filter-args
              #'endless/replace-apostrophe)

  ;; convert ' back to ’ from the subprocess
  (defun endless/replace-quote (args)
    (if (not (derived-mode-p 'org-mode))
        args
      (cons (replace-regexp-in-string
             "'" "’" (car args))
            (cdr args))))
  (advice-add #'ispell-parse-output :filter-args
              #'endless/replace-quote))
#+end_src
* Programming modes

** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])

#+begin_src emacs-lisp
(use-package alloy-mode
  :defer t
  :config (setq alloy-basic-offset 2))
#+end_src

** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])

#+begin_src emacs-lisp
(use-package proof-site  ; Proof General
  :defer t
  :load-path "lib/proof-site/generic/")
#+end_src

** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])

#+begin_src emacs-lisp
(eval-when-compile (defvar lean-mode-map))
(use-package lean-mode
  :defer 1
  :bind (:map lean-mode-map
              ("S-SPC" . company-complete))
  :config
  (require 'lean-input)
  (setq default-input-method "Lean"
        lean-input-tweak-all '(lean-input-compose
                               (lean-input-prepend "/")
                               (lean-input-nonempty))
        lean-input-user-translations '(("/" "/")))
  (lean-input-setup))
  #+end_src

** Haskell

*** [[https://github.com/haskell/haskell-mode][haskell-mode]]

#+begin_src emacs-lisp
(use-package haskell-mode
  :defer t
  :config
  (setq haskell-indentation-layout-offset 4
        haskell-indentation-left-offset 4
        flycheck-checker 'haskell-hlint
        flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
#+end_src

*** [[https://github.com/jyp/dante][dante]]

#+begin_src emacs-lisp
(use-package dante
  :after haskell-mode
  :commands dante-mode
  :hook (haskell-mode . dante-mode))
#+end_src

*** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]

Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
executable from [[https://github.com/mpickering/apply-refact][apply-refact]].

#+begin_src emacs-lisp
(use-package hlint-refactor
  :after haskell-mode
  :bind (:map hlint-refactor-mode-map
              ("C-c l b" . hlint-refactor-refactor-buffer)
              ("C-c l r" . hlint-refactor-refactor-at-point))
  :hook (haskell-mode . hlint-refactor-mode))
#+end_src

*** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]

#+begin_src emacs-lisp
(use-package flycheck-haskell
  :after haskell-mode)
#+end_src

*** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
:PROPERTIES:
:header-args+: :tangle lisp/hs-lint.el :mkdirp yes
:END:

Currently using =flycheck-haskell= with the =haskell-hlint= checker
instead.

#+begin_src emacs-lisp :tangle no
;;; hs-lint.el --- minor mode for HLint code checking

;; Copyright 2009 (C) Alex Ott
;;
;; Author: Alex Ott <alexott@gmail.com>
;; Keywords: haskell, lint, HLint
;; Requirements:
;; Status: distributed under terms of GPL2 or above

;; Typical message from HLint looks like:
;;
;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
;; Found:
;;   count1 p l = length (filter p l)
;; Why not:
;;   count1 p = length . filter p


(require 'compile)

(defgroup hs-lint nil
  "Run HLint as inferior of Emacs, parse error messages."
  :group 'tools
  :group 'haskell)

(defcustom hs-lint-command "hlint"
  "The default hs-lint command for \\[hlint]."
  :type 'string
  :group 'hs-lint)

(defcustom hs-lint-save-files t
  "Save modified files when run HLint or no (ask user)"
  :type 'boolean
  :group 'hs-lint)

(defcustom hs-lint-replace-with-suggestions nil
  "Replace user's code with suggested replacements"
  :type 'boolean
  :group 'hs-lint)

(defcustom hs-lint-replace-without-ask nil
  "Replace user's code with suggested replacements automatically"
  :type 'boolean
  :group 'hs-lint)

(defun hs-lint-process-setup ()
  "Setup compilation variables and buffer for `hlint'."
  (run-hooks 'hs-lint-setup-hook))

;; regex for replace suggestions
;;
;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
;; Found:
;; \s +\(.*\)
;; Why not:
;; \s +\(.*\)

(defvar hs-lint-regex
  "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
  "Regex for HLint messages")

(defun make-short-string (str maxlen)
  (if (< (length str) maxlen)
      str
    (concat (substring str 0 (- maxlen 3)) "...")))

(defun hs-lint-replace-suggestions ()
  "Perform actual replacement of suggestions"
  (goto-char (point-min))
  (while (re-search-forward hs-lint-regex nil t)
    (let* ((fname (match-string 1))
          (fline (string-to-number (match-string 2)))
          (old-code (match-string 4))
          (new-code (match-string 5))
          (msg (concat "Replace '" (make-short-string old-code 30)
                       "' with '" (make-short-string new-code 30) "'"))
          (bline 0)
          (eline 0)
          (spos 0)
          (new-old-code ""))
      (save-excursion
        (switch-to-buffer (get-file-buffer fname))
        (goto-char (point-min))
        (forward-line (1- fline))
        (beginning-of-line)
        (setf bline (point))
        (when (or hs-lint-replace-without-ask
                  (yes-or-no-p msg))
          (end-of-line)
          (setf eline (point))
          (beginning-of-line)
          (setf old-code (regexp-quote old-code))
          (while (string-match "\\\\ " old-code spos)
            (setf new-old-code (concat new-old-code
                                 (substring old-code spos (match-beginning 0))
                                 "\\ *"))
            (setf spos (match-end 0)))
          (setf new-old-code (concat new-old-code (substring old-code spos)))
          (remove-text-properties bline eline '(composition nil))
          (when (re-search-forward new-old-code eline t)
            (replace-match new-code nil t)))))))

(defun hs-lint-finish-hook (buf msg)
  "Function, that is executed at the end of HLint execution"
  (if hs-lint-replace-with-suggestions
      (hs-lint-replace-suggestions)
      (next-error 1 t)))

(define-compilation-mode hs-lint-mode "HLint"
  "Mode for check Haskell source code."
  (set (make-local-variable 'compilation-process-setup-function)
       'hs-lint-process-setup)
  (set (make-local-variable 'compilation-disable-input) t)
  (set (make-local-variable 'compilation-scroll-output) nil)
  (set (make-local-variable 'compilation-finish-functions)
       (list 'hs-lint-finish-hook))
  )

(defun hs-lint ()
  "Run HLint for current buffer with haskell source"
  (interactive)
  (save-some-buffers hs-lint-save-files)
  (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
                     'hs-lint-mode))

(provide 'hs-lint)
;;; hs-lint.el ends here
#+end_src

#+begin_src emacs-lisp :tangle no
(use-package hs-lint
  :load-path "lisp/"
  :bind (:map haskell-mode-map
              ("C-c l l" . hs-lint)))
#+end_src

** Web dev

*** SGML and HTML

#+begin_src emacs-lisp
(use-package sgml-mode
  :defer t
  :config
  (setq sgml-basic-offset 2))
#+end_src

*** CSS and SCSS

#+begin_src emacs-lisp
(use-package css-mode
  :defer t
  :config
  (setq css-indent-offset 2))
#+end_src

*** Web mode

#+begin_src emacs-lisp
(use-package web-mode
  :defer t
  :mode "\\.html\\'"
  :config
  (setq-every! 2
    web-mode-code-indent-offset
    web-mode-css-indent-offset
    web-mode-markup-indent-offset))
#+end_src

*** Emmet mode

#+begin_src emacs-lisp
(use-package emmet-mode
  :after (:any web-mode css-mode sgml-mode)
  :bind* (("C-)" . emmet-next-edit-point)
          ("C-(" . emmet-prev-edit-point))
  :config
  (unbind-key "C-j" emmet-mode-keymap)
  (setq emmet-move-cursor-between-quotes t)
  :hook (web-mode css-mode html-mode sgml-mode))
#+end_src

** Nix

#+begin_src emacs-lisp
(use-package nix-mode
  :defer t
  :mode "\\.nix\\'")
#+end_src

** Java

*** meghanada

#+begin_src emacs-lisp :tangle no
(use-package meghanada
  :bind
  (:map meghanada-mode-map
        (("C-M-o" . meghanada-optimize-import)
         ("C-M-t" . meghanada-import-all)))
  :hook (java-mode . meghanada-mode))
#+end_src

*** lsp-java

#+begin_comment
dependencies:

ace-window
avy
bui
company-lsp
dap-mode
lsp-java
lsp-mode
lsp-ui
pfuture
tree-mode
treemacs
#+end_comment

#+begin_src emacs-lisp :tangle no
(use-package treemacs
  :config (setq treemacs-never-persist t))

(use-package yasnippet
  :config
  ;; (yas-global-mode)
  )

(use-package lsp-mode
  :init (setq lsp-eldoc-render-all nil
              lsp-highlight-symbol-at-point nil)
  )

(use-package hydra)

(use-package company-lsp
  :after  company
  :config
  (setq company-lsp-cache-candidates t
        company-lsp-async t))

(use-package lsp-ui
  :config
  (setq lsp-ui-sideline-update-mode 'point))

(use-package lsp-java
  :config
  (add-hook 'java-mode-hook
	    (lambda ()
	      (setq-local company-backends (list 'company-lsp))))

  (add-hook 'java-mode-hook 'lsp-java-enable)
  (add-hook 'java-mode-hook 'flycheck-mode)
  (add-hook 'java-mode-hook 'company-mode)
  (add-hook 'java-mode-hook 'lsp-ui-mode))

(use-package dap-mode
  :after lsp-mode
  :config
  (dap-mode t)
  (dap-ui-mode t))

(use-package dap-java
  :after (lsp-java))

(use-package lsp-java-treemacs
  :after (treemacs))
#+end_src

* Emacs Enhancements

** [[https://github.com/justbur/emacs-which-key][which-key]]

#+begin_quote
Emacs package that displays available keybindings in popup
#+end_quote

#+begin_src emacs-lisp
(use-package which-key
  :defer 1
  :config (which-key-mode))
#+end_src

** theme

#+begin_src emacs-lisp
(add-to-list 'custom-theme-load-path "~/.emacs.d/lisp")
(load-theme 'tangomod t)
#+end_src

** doom-modeline

#+begin_src emacs-lisp
(use-package doom-modeline
  :demand t
  :config (setq doom-modeline-height 32)
  :hook (after-init . doom-modeline-init))
#+end_src

** doom-themes

#+begin_src emacs-lisp
(use-package doom-themes)
#+end_src

** theme helper functions

#+begin_src emacs-lisp
(defun amin/lights-on ()
  "Enable my favourite light theme."
  (interactive)
  (progn
    (mapc #'disable-theme custom-enabled-themes)
    (load-theme 'tangomod t)))

(defun amin/lights-off ()
  "Go dark."
  (interactive)
  (progn
    (mapc #'disable-theme custom-enabled-themes)
    (load-theme 'doom-tomorrow-night t)))

(amin--leader-keys
  "t"   '(:ignore t :wk "theme")
  "t d" 'amin/lights-off
  "t l" 'amin/lights-on)
#+end_src

** [[https://github.com/bbatsov/crux][crux]]

#+begin_src emacs-lisp
(use-package crux
  :defer 1
  :general
  (amin--leader-keys
    "b K" 'crux-kill-other-buffers
    "c d" 'crux-duplicate-current-line-or-region
    "c D" 'crux-duplicate-and-comment-current-line-or-region
    "f c" 'crux-copy-file-preserve-attributes
    "f d" 'crux-delete-file-and-buffer
    "f r" 'crux-rename-file-and-buffer)
  :bind (("C-c d" . crux-duplicate-current-line-or-region)
         ("C-c D" . crux-duplicate-and-comment-current-line-or-region)
         ("C-S-j" . crux-top-join-line)
         ("C-c j" . crux-top-join-line)))
#+end_src

** [[https://github.com/alezost/mwim.el][mwim]]

#+begin_src emacs-lisp
(use-package mwim
  :general
  (:states '(normal visual)
           "0" 'mwim-beginning-of-code-or-line
           "$" 'mwim-end-of-code-or-line)
  :bind (("C-a"    . mwim-beginning-of-code-or-line)
         ("C-e"    . mwim-end-of-code-or-line)
         ("<home>" . mwim-beginning-of-line-or-code)
         ("<end>"  . mwim-end-of-line-or-code)))
#+end_src

** projectile

#+begin_src emacs-lisp
(use-package projectile
  :defer t
  :bind-keymap ("C-c p" . projectile-command-map)
  :config
  (projectile-mode)

  (defun my-projectile-invalidate-cache (&rest _args)
    ;; ignore the args to `magit-checkout'
    (projectile-invalidate-cache nil))

  (eval-after-load 'magit-branch
    '(progn
       (advice-add 'magit-checkout
                   :after #'my-projectile-invalidate-cache)
       (advice-add 'magit-branch-and-checkout
                   :after #'my-projectile-invalidate-cache))))
#+end_src

** [[https://github.com/Wilfred/helpful][helpful]]

#+begin_src emacs-lisp
(use-package helpful
  :defer 1
  :general
  (amin--leader-keys
    "h h"   '(:ignore t :wk "helpful")
    "h h c" 'helpful-command
    "h h f" 'helpful-callable           ; helpful-function
    "h h v" 'helpful-variable
    "h h k" 'helpful-key
    "h h p" 'helpful-at-point))
#+end_src

** [[https://github.com/knu/shell-toggle.el][shell-toggle]]

#+begin_src emacs-lisp
(use-package shell-toggle
  :after eshell
  :general (amin--leader-keys "a s" 'amin/shell-toggle)
  :bind ("C-c e" . amin/shell-toggle)
  :config
  (defun amin/shell-toggle (make-cd)
    "Toggle between the shell buffer and whatever buffer you are editing.
With a prefix argument MAKE-CD also insert a \"cd DIR\" command
into the shell, where DIR is the directory of the current buffer.

When called in the shell buffer returns you to the buffer you were editing
before calling this the first time.

Options: `shell-toggle-goto-eob'"
    (interactive "P")
    ;; Try to decide on one of three possibilities:
    ;; If not in shell-buffer, switch to it.
    ;; If in shell-buffer, return to state before going to the shell-buffer
    (if (eq (current-buffer) shell-toggle-shell-buffer)
        (shell-toggle-buffer-return-from-shell)
      (progn
        (shell-toggle-buffer-goto-shell make-cd)
        (if shell-toggle-full-screen-window-only (delete-other-windows)))))

  ;; override to split horizontally instead
  (defun shell-toggle-buffer-switch-to-other-window ()
    "Switch to other window.
If the current window is the only window in the current frame,
create a new window and switch to it.

\(This is less intrusive to the current window configuration than
`switch-buffer-other-window')"
    (let ((this-window (selected-window)))
      (other-window 1)
      ;; If we did not switch window then we only have one window and need to
      ;; create a new one.
      (if (eq this-window (selected-window))
	      (progn
	        (split-window-horizontally)
            (other-window 1)))))

  :custom
  (shell-toggle-launch-shell 'shell-toggle-eshell))
#+end_src

** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]

Make =*scratch*= and =*Messages*= unkillable.

#+begin_src emacs-lisp
(use-package unkillable-scratch
  :defer 3
  :config
  (unkillable-scratch 1)
  :custom
  (unkillable-scratch-behavior 'do-nothing)
  (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
#+end_src

** [[https://github.com/davep/boxquote.el][boxquote.el]]

#+begin_example
,----
| make pretty boxed quotes like this
`----
#+end_example

#+begin_src emacs-lisp
(use-package boxquote
  :defer 3
  :bind
  (:prefix-map amin--boxquote-prefix-map
   :prefix "C-c q"
   ("b"   . boxquote-buffer)
   ("B"   . boxquote-insert-buffer)
   ("d"   . boxquote-defun)
   ("F"   . boxquote-insert-file)
   ("hf"  . boxquote-describe-function)
   ("hk"  . boxquote-describe-key)
   ("hv"  . boxquote-describe-variable)
   ("hw"  . boxquote-where-is)
   ("k"   . boxquote-kill)
   ("p"   . boxquote-paragraph)
   ("q"   . boxquote-boxquote)
   ("r"   . boxquote-region)
   ("s"   . boxquote-shell-command)
   ("t"   . boxquote-text)
   ("T"   . boxquote-title)
   ("u"   . boxquote-unbox)
   ("U"   . boxquote-unbox-region)
   ("y"   . boxquote-yank)
   ("M-q" . boxquote-fill-paragraph)
   ("M-w" . boxquote-kill-ring-save)))
#+end_src

Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].

** COMMENT [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]                                 :ARCHIVE:

#+begin_src emacs-lisp
(use-package highlight-indent-guides
  :defer 3
  :hook ((prog-mode . highlight-indent-guides-mode)
         ;; (org-mode  . highlight-indent-guides-mode)
         )
  :config
  (setq highlight-indent-guides-character ?\|)
  (setq highlight-indent-guides-auto-enabled nil)
  (setq highlight-indent-guides-method 'character)
  (setq highlight-indent-guides-responsive 'top)
  (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
  (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
#+end_src

** pdf-tools

#+begin_src emacs-lisp
(use-package pdf-tools
  :defer t
  :magic ("%PDF" . pdf-view-mode)
  :config
  (setq pdf-view-resize-factor 1.05)
  (pdf-tools-install)
  :bind
  (:map pdf-view-mode-map
        ("C-s" . isearch-forward)
        ("C-r" . isearch-backward)
        ("j"   . pdf-view-next-line-or-next-page)
        ("k"   . pdf-view-previous-line-or-previous-page)
        ("h"   . image-backward-hscroll)
        ("l"   . image-forward-hscroll)))
#+end_src

** anzu

#+begin_src emacs-lisp
(use-package anzu)
#+end_src

** typo.el

#+begin_src emacs-lisp
(use-package typo
  :defer 2
  :config
  (typo-global-mode 1)
  :hook (text-mode . typo-mode))
#+end_src

** slack

Hopefully temporary.

#+begin_src emacs-lisp
(use-package slack
  :commands (slack-start)
  :init
  (eval-when-compile                    ; silence the byte-compiler
    (defvar url-http-data nil)
    (defvar url-http-extra-headers nil)
    (defvar url-http-method nil)
    (defvar url-callback-function nil)
    (defvar url-callback-arguments nil)
    (defvar oauth--token-data nil))
  (setq slack-buffer-emojify t
        slack-prefer-current-team t)
  :config
  (slack-register-team
   :name "uw-apv"
   :default t
   :client-id uw-apv-client-id
   :client-secret uw-apv-client-secret
   :token uw-apv-token
   :subscribed-channels '(general)
   :full-and-display-names t)
  (slack-register-team
   :name "watform"
   :default nil
   :client-id watform-client-id
   :client-secret watform-client-secret
   :token watform-token
   :subscribed-channels '(general)
   :full-and-display-names t)
  (add-to-list 'swiper-font-lock-exclude 'slack-message-buffer-mode t)
  (setq lui-time-stamp-format "[%Y-%m-%d %H:%M:%S]"
        lui-time-stamp-only-when-changed-p t
        lui-time-stamp-position 'right)
  :bind
  (("C-c s s" . slack-start)
   ("C-c s u" . slack-select-unread-rooms)
   ("C-c s b" . slack-select-rooms)
   ("C-c s t" . slack-change-current-team)
   ("C-c s c" . slack-ws-close)
   :map slack-mode-map
   ("M-p"     . slack-buffer-goto-prev-message)
   ("M-n"     . slack-buffer-goto-next-message)
   ("C-c e"   . slack-message-edit)
   ("C-c k"   . slack-message-delete)
   ("C-c C-k" . slack-channel-leave)
   ("C-c r a" . slack-message-add-reaction)
   ("C-c r r" . slack-message-remove-reaction)
   ("C-c r s" . slack-message-show-reaction-users)
   ("C-c p l" . slack-room-pins-list)
   ("C-c p a" . slack-message-pins-add)
   ("C-c p r" . slack-message-pins-remove)
   ("@"       . slack-message-embed-mention)
   ("#"       . slack-message-embed-channel)))

(use-package alert
  :commands (alert)
  :init
  (setq alert-default-style 'notifier))
#+end_src

** hl-todo

#+begin_src emacs-lisp
(use-package hl-todo
  :defer 4
  :config
  (global-hl-todo-mode))
#+end_src

** shrink-path

#+begin_src emacs-lisp
(use-package shrink-path
  :after eshell
  :config
  (setq eshell-prompt-regexp "\\(.*\n\\)*λ "
        eshell-prompt-function #'+eshell/prompt)

  (defun +eshell/prompt ()
    (let ((base/dir (shrink-path-prompt default-directory)))
      (concat (propertize (car base/dir)
                          'face 'font-lock-comment-face)
              (propertize (cdr base/dir)
                          'face 'font-lock-constant-face)
              (propertize (+eshell--current-git-branch)
                          'face 'font-lock-function-name-face)
              "\n"
              (propertize "λ" 'face 'eshell-prompt-face)
              ;; needed for the input text to not have prompt face
              (propertize " " 'face 'default))))

  (defun +eshell--current-git-branch ()
    (let ((branch (car (loop for match in (split-string (shell-command-to-string "git branch") "\n")
                             when (string-match "^\*" match)
                             collect match))))
      (if (not (eq branch nil))
          (concat " " (substring branch 2))
        ""))))
#+end_src

** magithub

For when I /have to/ use GH.

#+begin_src emacs-lisp
(use-package magithub
  :after magit
  :config
  (magithub-feature-autoinject t)
  (setq magithub-clone-default-directory "~/src/git"))
#+end_src

** [[https://github.com/peterwvj/eshell-up][eshell-up]]

#+begin_src emacs-lisp
(use-package eshell-up
  :after eshell)
#+end_src

* Email

#+begin_src emacs-lisp
(defvar amin-maildir (expand-file-name "~/mail/"))
(after! recentf
  (add-to-list 'recentf-exclude amin-maildir))
#+end_src

** Gnus

#+begin_src emacs-lisp
(setq
 amin-gnus-init-file (no-littering-expand-etc-file-name "gnus")
 mail-user-agent     'gnus-user-agent
 read-mail-command   'gnus)

(use-package gnus
  :general
  (amin--leader-keys
    "m" 'gnus
    "M" 'gnus-unplugged)
  :bind (("s-m" . gnus)
         ("s-M" . gnus-unplugged))
  :init
  (setq
   gnus-select-method '(nnnil "")
   gnus-secondary-select-methods
   '((nnimap "amin"
            (nnimap-stream plain)
            (nnimap-address "127.0.0.1")
            (nnimap-server-port 143)
            (nnimap-authenticator plain)
            (nnimap-user "amin@aminb.org"))
     (nnimap "uwaterloo"
             (nnimap-stream plain)
             (nnimap-address "127.0.0.1")
             (nnimap-server-port 143)
             (nnimap-authenticator plain)
             (nnimap-user "abandali@uwaterloo.ca")))
   gnus-message-archive-group "nnimap+amin:Sent"
   gnus-parameters
   '(("gnu.*"
      (gcc-self . t)))
   gnus-large-newsgroup  50
   gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
   gnus-directory        (concat gnus-home-directory "news/")
   message-directory     (concat gnus-home-directory "mail/")
   nndraft-directory     (concat gnus-home-directory "drafts/")
   gnus-save-newsrc-file nil
   gnus-read-newsrc-file nil
   gnus-interactive-exit nil
   gnus-gcc-mark-as-read t))

(use-package gnus-art
  :config
  (setq
   gnus-visible-headers
   (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
   gnus-sorted-header-list
   '("^From:" "^Subject:" "^Summary:" "^Keywords:"
     "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
     "^Newsgroups:" "List-Id:" "^Organization:"
     "^User-Agent:" "^Date:")
  ;; local-lapsed article dates
  ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
  gnus-article-date-headers '(user-defined)
  gnus-article-time-format
  (lambda (time)
    (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
           (local (article-make-date-line date 'local))
           (combined-lapsed (article-make-date-line date
                                                    'combined-lapsed))
           (lapsed (progn
                     (string-match " (.+" combined-lapsed)
                     (match-string 0 combined-lapsed))))
      (concat local lapsed))))
  (bind-keys
   :map gnus-article-mode-map
   ("r"   . gnus-article-reply-with-original)
   ("R"   . gnus-article-wide-reply-with-original)
   ("M-L" . org-store-link)))

(use-package gnus-sum
  :bind (:map gnus-summary-mode-map
              :prefix-map amin--gnus-summary-prefix-map
              :prefix "v"
              ("r" . gnus-summary-reply)
              ("w" . gnus-summary-wide-reply)
              ("v" . gnus-summary-show-raw-article))
  :config
  (bind-keys
   :map gnus-summary-mode-map
   ("r"   . gnus-summary-reply-with-original)
   ("R"   . gnus-summary-wide-reply-with-original)
   ("M-L" . org-store-link)))

(use-package gnus-msg
  :config
  (setq gnus-posting-styles
        '((".*"
           (address "amin@bandali.me")
           (body "\nBest,\namin\n")
           (signature-file "~/.signature-amin")
           (eval (setq amin--message-cite-say-hi t)))
          ("gnu.*"
           (address "bandali@gnu.org")
           (signature-file nil))
          ((header "subject" "ThankCRM")
           (to "webmasters-comment@gnu.org")
           (body "\nAdded  to 2018supporters.html.\n\nMoving to campaigns.\n\n-amin\n")
           (eval (setq amin--message-cite-say-hi nil)))
          ("nnimap\\+uwaterloo:.*"
           (address "abandali@uwaterloo.ca")
           (gcc "\"nnimap+uwaterloo:Sent Items\"")
           (signature-file nil)))))

(use-package gnus-topic
  :hook (gnus-group-mode . gnus-topic-mode))

(use-package gnus-agent
  :config
  (setq gnus-agent-synchronize-flags 'ask)
  :hook (gnus-group-mode . gnus-agent-mode))

(use-package gnus-group
  :config
  (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))

(use-package mm-decode
  :config
  (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
#+end_src

** sendmail

#+begin_src emacs-lisp
(use-package sendmail
  :config
  (setq sendmail-program "/usr/bin/msmtp"
        ;; message-sendmail-extra-arguments '("-v" "-d")
        mail-specify-envelope-from t
        mail-envelope-from 'header))
#+end_src

** message

#+begin_src emacs-lisp
(use-package message
  :config
  (defconst amin--message-cite-style-format "On %Y-%m-%d %l:%M %p, %N wrote:")
  (defconst message-cite-style-bandali
    '((message-cite-function  'message-cite-original)
      (message-citation-line-function  'message-insert-formatted-citation-line)
      (message-cite-reply-position 'traditional)
      (message-yank-prefix  "> ")
      (message-yank-cited-prefix  ">")
      (message-yank-empty-prefix  ">")
      (message-citation-line-format
       (if amin--message-cite-say-hi
           (concat "Hi %F,\n\n" amin--message-cite-style-format)
         amin--message-cite-style-format)))
    "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
  (setq message-cite-style 'message-cite-style-bandali
        message-kill-buffer-on-exit t
        message-send-mail-function 'message-send-mail-with-sendmail
        message-sendmail-envelope-from 'header
        message-dont-reply-to-names
        "\\(\\(amin@bandali\\.me\\)\\|\\(.*@aminb\\.org\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
        message-user-fqdn "aminb.org")
  :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
         (message-mode . flyspell-mode)
         (message-mode . (lambda ()
                           ;; (setq fill-column 65
                           ;;       message-fill-column 65)
                           (make-local-variable 'company-idle-delay)
                           (setq company-idle-delay 0.2))))
  ;; :custom-face
  ;; (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
  ;; (message-header-to      ((t (:foreground "#111" :weight normal))))
  ;; (message-header-cc      ((t (:foreground "#333" :weight normal))))
  )

(after! mml-sec
  (setq mml-secure-openpgp-encrypt-to-self t
        mml-secure-openpgp-sign-with-sender t))
#+end_src

** footnote

Convenient footnotes in =message-mode=.

#+begin_src emacs-lisp
(use-package footnote
  :after message
  :bind
  (:map message-mode-map
        :prefix-map amin--footnote-prefix-map
        :prefix "C-c f"
        ("a" . footnote-add-footnote)
        ("b" . footnote-back-to-message)
        ("c" . footnote-cycle-style)
        ("d" . footnote-delete-footnote)
        ("g" . footnote-goto-footnote)
        ("r" . footnote-renumber-footnotes)
        ("s" . footnote-set-style))
  :config
  (setq footnote-start-tag ""
        footnote-end-tag   ""
        footnote-style     'unicode))
#+end_src

** bbdb

Manually install bbdb (=lisp/bbdb= copied from an ELPA-based setup),
because installing it from source on Emacs 27 using the following
submodule configuration for some reason doesn’t work and results in
very strange errors when using any of the functions.

#+begin_src conf :tangle no
[submodule "bbdb"]
	path = lib/bbdb
	url = https://git.savannah.nongnu.org/git/bbdb.git
	load-path = lisp
	info-path = doc
	build-step = ./autogen.sh
	build-step = ./configure
	build-step = make
	build-step = make install
#+end_src

I tried using =borg-elpa= instead of doing it like this, but it added
2 seconds to my startup time, which is unacceptable to me.

#+begin_src emacs-lisp
(use-package bbdb
  :load-path "lisp/bbdb"
  :init
  (load (expand-file-name "lisp/bbdb/bbdb-autoloads.el" user-emacs-directory))
  ;; (bbdb-mua-auto-update-init 'message)
  (setq bbdb-mua-auto-update-p 'query
        bbdb-complete-mail nil)
  (bbdb-initialize 'gnus 'message))
#+end_src

** COMMENT message-x

#+begin_src emacs-lisp
(use-package message-x
  :custom
  (message-x-completion-alist
   (quote
    (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
     ((if
          (boundp
           (quote message-newgroups-header-regexp))
          message-newgroups-header-regexp message-newsgroups-header-regexp)
      . message-expand-group)))))
#+end_src

** COMMENT gnus-harvest

#+begin_src emacs-lisp
(use-package gnus-harvest
  :commands gnus-harvest-install
  :demand t
  :config
  (if (featurep 'message-x)
      (gnus-harvest-install 'message-x)
    (gnus-harvest-install)))
#+end_src

* Blogging
** [[https://ox-hugo.scripter.co][ox-hugo]]

#+begin_src emacs-lisp
(use-package ox-hugo
  :after ox)

(use-package ox-hugo-auto-export
  :load-path "lib/ox-hugo")
#+end_src

* Post initialization
:PROPERTIES:
:CUSTOM_ID: post-initialization
:END:

Display how long it took to load the init file.

#+begin_src emacs-lisp
(message "Loading %s...done (%.3fs)" user-init-file
         (float-time (time-subtract (current-time)
                                    amin--before-user-init-time)))
#+end_src

* Footer
:PROPERTIES:
:CUSTOM_ID: footer
:END:

#+begin_src emacs-lisp :comments none
;;; init.el ends here
#+end_src

* COMMENT Local Variables                                           :ARCHIVE:
# Local Variables:
# eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
# End: