git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** Package management
 192
 193 *** No =package.el=
 194
 195 I can do all my package management things with Borg, and don't need
 196 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 197 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 198
 199 #+begin_src emacs-lisp :tangle early-init.el
 200 (setq package-enable-at-startup nil)
 201 #+end_src
 202
 203 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 204 right now), and even when released it'll be long before most distros
 205 ship in their repos, I'll still put the old workaround with the
 206 commented call to ~package-initialize~ here anyway.
 207
 208 #+begin_src emacs-lisp
 209 (setq package-enable-at-startup nil)
 210 ;; (package-initialize)
 211 #+end_src
 212
 213 *** Borg
 214
 215 #+begin_quote
 216 Assimilate Emacs packages as Git submodules
 217 #+end_quote
 218
 219 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 220 short, it creates a git submodule in =lib/= for each package, which
 221 can then be managed with the help of Magit or other tools.
 222
 223 #+begin_src emacs-lisp
 224 (setq user-init-file (or load-file-name buffer-file-name)
 225       user-emacs-directory (file-name-directory user-init-file))
 226 (add-to-list 'load-path
 227              (expand-file-name "lib/borg" user-emacs-directory))
 228 (require 'borg)
 229 (borg-initialize)
 230 #+end_src
 231
 232 *** =use-package=
 233
 234 #+begin_quote
 235 A use-package declaration for simplifying your .emacs
 236 #+end_quote
 237
 238 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 239 packages (in our case especially the latter) in a neatly organized way
 240 and without compromising on performance.
 241
 242 #+begin_src emacs-lisp
 243 (require 'use-package)
 244 (if nil                             ; set to t when need to debug init
 245     (setq use-package-verbose t
 246           use-package-expand-minimally nil
 247           use-package-compute-statistics t
 248           debug-on-error t)
 249   (setq use-package-verbose nil
 250         use-package-expand-minimally t))
 251 #+end_src
 252
 253 *** Epkg
 254
 255 #+begin_quote
 256 Browse the Emacsmirror package database
 257 #+end_quote
 258
 259 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 260 database, low-level functions for querying the database, and a
 261 =package.el=-like user interface for browsing the available packages.
 262
 263 #+begin_src emacs-lisp
 264 (use-package epkg
 265   :defer t)
 266 #+end_src
 267
 268 ** No littering in =~/.emacs.d=
 269
 270 #+begin_quote
 271 Help keeping ~/.emacs.d clean
 272 #+end_quote
 273
 274 By default, even for Emacs' built-in packages, the configuration files
 275 and persistent data are all over the place. Use =no-littering= to help
 276 contain the mess.
 277
 278 #+begin_src emacs-lisp
 279 (use-package no-littering
 280   :demand t
 281   :config
 282   (savehist-mode 1)
 283   (add-to-list 'savehist-additional-variables 'kill-ring)
 284   (save-place-mode 1)
 285   (setq auto-save-file-name-transforms
 286         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 287 #+end_src
 288
 289 ** Custom file (=custom.el=)
 290
 291 I'm not planning on using the custom file much, but even so, I
 292 definitely don't want it mixing with =init.el=. So, here; let's give
 293 it it's own file. While at it, treat themes as safe.
 294
 295 #+begin_src emacs-lisp
 296 (use-package custom
 297   :no-require t
 298   :config
 299   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 300   (when (file-exists-p custom-file)
 301     (load custom-file))
 302   (setf custom-safe-themes t))
 303 #+end_src
 304
 305 ** Better =$PATH= handling
 306
 307 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 308 in my shell.
 309
 310 #+begin_src emacs-lisp
 311 (use-package exec-path-from-shell
 312   :defer 1
 313   :init
 314   (setq exec-path-from-shell-check-startup-files nil)
 315   :config
 316   (exec-path-from-shell-initialize)
 317   ;; while we're at it, let's fix access to our running ssh-agent
 318   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 319   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 320 #+end_src
 321
 322 ** Only one custom theme at a time
 323
 324 #+begin_src emacs-lisp
 325 (defadvice load-theme (before clear-previous-themes activate)
 326   "Clear existing theme settings instead of layering them"
 327   (mapc #'disable-theme custom-enabled-themes))
 328 #+end_src
 329
 330 ** Server
 331
 332 Start server if not already running. Alternatively, can be done by
 333 issuing =emacs --daemon= in the terminal, which can be automated with
 334 a systemd service or using =brew services start emacs= on macOS. I use
 335 Emacs as my window manager (via EXWM), so I always start Emacs on
 336 login; so starting the server from inside Emacs is good enough for me.
 337
 338 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 339
 340 #+begin_src emacs-lisp
 341 (use-package server
 342   :config (or (server-running-p) (server-mode)))
 343 #+end_src
 344
 345 ** Unicode support
 346
 347 Font stack with better unicode support, around =Ubuntu Mono= and
 348 =Hack=.
 349
 350 #+begin_src emacs-lisp
 351 (dolist (ft (fontset-list))
 352   (set-fontset-font
 353    ft
 354    'unicode
 355    (font-spec :name "Ubuntu Mono"))
 356   (set-fontset-font
 357    ft
 358    'unicode
 359    (font-spec :name "DejaVu Sans Mono")
 360    nil
 361    'append)
 362   ;; (set-fontset-font
 363   ;;  ft
 364   ;;  'unicode
 365   ;;  (font-spec
 366   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 367   ;;  nil
 368   ;;  'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  #x2115  ; ℕ
 372   ;;  (font-spec :name "DejaVu Sans Mono")
 373   ;;  nil
 374   ;;  'append)
 375   (set-fontset-font
 376    ft
 377    (cons ?Α ?ω)
 378    (font-spec :name "DejaVu Sans Mono" :size 14)
 379    nil
 380    'prepend))
 381 #+end_src
 382
 383 ** Libraries
 384
 385 #+begin_src emacs-lisp
 386 (require 'cl-lib)
 387 (require 'subr-x)
 388 #+end_src
 389
 390 ** Useful utilities
 391
 392 #+begin_src emacs-lisp
 393 (defun ab-enlist (exp)
 394   "Return EXP wrapped in a list, or as-is if already a list."
 395 (if (listp exp) exp (list exp)))
 396
 397 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 398 (defmacro after! (features &rest body)
 399   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 400 compilation."
 401   (declare (indent defun) (debug t))
 402   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 403                 (dolist (next (ab-enlist features))
 404                   (if (symbolp next)
 405                       (require next nil :no-error)
 406                     (load next :no-message :no-error))))
 407             #'progn
 408           #'with-no-warnings)
 409         (cond ((symbolp features)
 410                `(eval-after-load ',features '(progn ,@body)))
 411               ((and (consp features)
 412                     (memq (car features) '(:or :any)))
 413                `(progn
 414                   ,@(cl-loop for next in (cdr features)
 415                              collect `(after! ,next ,@body))))
 416               ((and (consp features)
 417                     (memq (car features) '(:and :all)))
 418                (dolist (next (cdr features))
 419                  (setq body `(after! ,next ,@body)))
 420                body)
 421               ((listp features)
 422                `(after! (:all ,@features) ,@body)))))
 423 #+end_src
 424
 425 * Core
 426 :PROPERTIES:
 427 :CUSTOM_ID: core
 428 :END:
 429
 430 ** Defaults
 431
 432 *** Time and battery in mode-line
 433
 434 Enable displaying time and battery in the mode-line, since I'm not
 435 using the Xfce panel anymore. Also, I don't need to see the load
 436 average on a regular basis, so disable that.
 437
 438 #+begin_src emacs-lisp
 439 (use-package time
 440   :ensure nil
 441   :init
 442   (setq display-time-default-load-average nil)
 443   :config
 444   (display-time-mode))
 445
 446 (use-package battery
 447   :ensure nil
 448   :config
 449   (display-battery-mode))
 450 #+end_src
 451
 452 *** Smaller fringe
 453
 454 Might want to set the fringe to a smaller value, especially if using
 455 EXWM. I'm fine with the default for now.
 456
 457 #+begin_src emacs-lisp
 458 ;; (fringe-mode '(3 . 1))
 459 (fringe-mode nil)
 460 #+end_src
 461
 462 *** Disable disabled commands
 463
 464 Emacs disables some commands by default that could persumably be
 465 confusing for novice users. Let's disable that.
 466
 467 #+begin_src emacs-lisp
 468 (setq disabled-command-function nil)
 469 #+end_src
 470
 471 *** Kill-ring
 472
 473 Save what I copy into clipboard from other applications into Emacs'
 474 kill-ring, which would allow me to still be able to easily access it
 475 in case I kill (cut or copy) something else inside Emacs before
 476 yanking (pasting) what I'd originally intended to.
 477
 478 #+begin_src emacs-lisp
 479 (setq save-interprogram-paste-before-kill t)
 480 #+end_src
 481
 482 *** Minibuffer
 483
 484 #+begin_src emacs-lisp
 485 (setq enable-recursive-minibuffers t
 486       resize-mini-windows t)
 487 #+end_src
 488
 489 *** Lazy-person-friendly yes/no prompts
 490
 491 Lazy people would prefer to type fewer keystrokes, especially for yes
 492 or no questions. I'm lazy.
 493
 494 #+begin_src emacs-lisp
 495 (defalias 'yes-or-no-p #'y-or-n-p)
 496 #+end_src
 497
 498 *** Startup screen and =*scratch*=
 499
 500 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 501 startup buffer.
 502
 503 #+begin_src emacs-lisp
 504 (setq initial-buffer-choice t)
 505 #+end_src
 506
 507 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 508 need the default hint.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-scratch-message nil)
 512 #+end_src
 513
 514 Also, let's use Text mode as the major mode, in case I want to
 515 customize it (=*scratch*='s default major mode, Fundamental mode,
 516 can't really be customized).
 517
 518 #+begin_src emacs-lisp
 519 (setq initial-major-mode 'text-mode)
 520 #+end_src
 521
 522 Inhibit the buffer list when more than 2 files are loaded.
 523
 524 #+begin_src emacs-lisp
 525 (setq inhibit-startup-buffer-menu t)
 526 #+end_src
 527
 528 I don't really need to see the startup screen or echo area message
 529 either.
 530
 531 #+begin_src emacs-lisp
 532 (advice-add #'display-startup-echo-area-message :override #'ignore)
 533 (setq inhibit-startup-screen t
 534       inhibit-startup-echo-area-message user-login-name)
 535 #+end_src
 536
 537 *** More useful frame titles
 538
 539 Show either the file name or the buffer name (in case the buffer isn't
 540 visiting a file). Borrowed from Emacs Prelude.
 541
 542 #+begin_src emacs-lisp
 543 (setq frame-title-format
 544       '("" invocation-name " - "
 545         (:eval (if (buffer-file-name)
 546                    (abbreviate-file-name (buffer-file-name))
 547                  "%b"))))
 548 #+end_src
 549
 550 *** Backups
 551
 552 Emacs' default backup settings aren't that great. Let's use more
 553 sensible options. See documentation for the ~make-backup-file~
 554 variable.
 555
 556 #+begin_src emacs-lisp
 557 (setq backup-by-copying t
 558       version-control t)
 559 #+end_src
 560
 561 ** Packages
 562
 563 The packages in this section are absolutely essential to my everyday
 564 workflow, and they play key roles in how I do my computing. They
 565 immensely enhance the Emacs experience for me; both using Emacs, and
 566 customizing it.
 567
 568 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 569
 570 #+begin_src emacs-lisp
 571 (use-package auto-compile
 572   :demand t
 573   :config
 574   (auto-compile-on-load-mode)
 575   (auto-compile-on-save-mode)
 576   (setq auto-compile-display-buffer               nil
 577         auto-compile-mode-line-counter            t
 578         auto-compile-source-recreate-deletes-dest t
 579         auto-compile-toggle-deletes-nonlib-dest   t
 580         auto-compile-update-autoloads             t)
 581   (add-hook 'auto-compile-inhibit-compile-hook
 582             'auto-compile-inhibit-compile-detached-git-head))
 583 #+end_src
 584
 585 *** [[https://github.com/noctuid/general.el][general]]
 586
 587 #+begin_quote
 588 Roll your own modal mode
 589 #+end_quote
 590
 591 #+begin_src emacs-lisp
 592 (use-package general
 593   :demand t
 594   :config
 595   (general-evil-setup t)
 596
 597   (general-override-mode)
 598
 599   (general-create-definer
 600     ab--mode-leader-keys
 601     :keymaps 'override
 602     :states '(emacs normal visual motion insert)
 603     :non-normal-prefix "C-,"
 604     :prefix ",")
 605
 606   (general-create-definer
 607     ab--leader-keys
 608     :keymaps 'override
 609     :states '(emacs normal visual motion insert)
 610     :non-normal-prefix "M-m"
 611     :prefix "SPC"))
 612 #+end_src
 613
 614 *** evil
 615
 616 #+begin_src emacs-lisp
 617 (use-package evil
 618   :demand t
 619   :hook (view-mode . evil-motion-state)
 620   :config (evil-mode 1))
 621 #+end_src
 622
 623 #+begin_src emacs-lisp
 624 (use-package evil-escape
 625   :demand t
 626   :init
 627   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 628         evil-escape-excluded-major-modes '(neotree-mode)
 629         evil-escape-key-sequence "jk"
 630         evil-escape-delay 0.25)
 631   :general
 632   (:states '(insert replace visual operator)
 633     "C-g" #'evil-escape)
 634   :config
 635   (evil-escape-mode 1)
 636   ;; no `evil-escape' in minibuffer
 637   (push #'minibufferp evil-escape-inhibit-functions))
 638 #+end_src
 639
 640 *** [[https://orgmode.org/][Org mode]]
 641
 642 #+begin_quote
 643 Org mode is for keeping notes, maintaining TODO lists, planning
 644 projects, and authoring documents with a fast and effective plain-text
 645 system.
 646 #+end_quote
 647
 648 In short, my favourite way of life.
 649
 650 #+begin_src emacs-lisp
 651 (setq org-src-tab-acts-natively t
 652       org-src-preserve-indentation nil
 653       org-edit-src-content-indentation 0
 654       org-html-doctype "html5"
 655       org-html-html5-fancy t)
 656 (add-hook 'org-mode-hook 'org-indent-mode)
 657 (use-package htmlize)
 658 #+end_src
 659
 660 *** [[https://magit.vc/][Magit]]
 661
 662 #+begin_quote
 663 It's Magit! A Git porcelain inside Emacs.
 664 #+end_quote
 665
 666 Not just how I do git, but /the/ way to do git.
 667
 668 #+begin_src emacs-lisp
 669 (use-package magit
 670   :general (ab--leader-keys "g s" 'magit-status)
 671   :defer t
 672   :bind (("s-g"     . magit-status)
 673          ("C-x g"   . magit-status)
 674          ("C-x M-g" . magit-dispatch-popup))
 675   :config
 676   (magit-add-section-hook 'magit-status-sections-hook
 677                           'magit-insert-modules
 678                           'magit-insert-stashes
 679                           'append))
 680 #+end_src
 681
 682 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 683
 684 #+begin_quote
 685 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 686 an overview, and more. Oh, man!
 687 #+end_quote
 688
 689 There's no way I could top that, so I won't attempt to.
 690
 691 **** Ivy
 692
 693 #+begin_src emacs-lisp
 694 (use-package ivy
 695   :defer 1
 696   :bind
 697   (:map ivy-minibuffer-map
 698         ([escape] . keyboard-escape-quit)
 699         ;; ("C-j"    . ivy-next-line)
 700         ;; ("C-k"    . ivy-previous-line)
 701         ([S-up]   . ivy-previous-history-element)
 702         ([S-down] . ivy-next-history-element)
 703         ("DEL"    . ivy-backward-delete-char))
 704   :config
 705   (setq ivy-wrap t)
 706   (ivy-mode 1))
 707 #+end_src
 708
 709 **** Swiper
 710
 711 #+begin_src emacs-lisp
 712 (use-package swiper
 713   :general (:states 'normal "/" 'swiper)
 714   :bind (([remap isearch-forward]  . swiper)
 715          ([remap isearch-backward] . swiper)))
 716 #+end_src
 717
 718 **** Counsel
 719
 720 #+begin_src emacs-lisp
 721 (use-package counsel
 722   :defer 1
 723   :general (ab--leader-keys
 724     "f r" 'counsel-recentf
 725     "SPC" 'counsel-M-x
 726     "."   'counsel-find-file)
 727   :bind (([remap execute-extended-command] . counsel-M-x)
 728          ([remap find-file] . counsel-find-file)
 729          ("s-r"     . counsel-recentf)
 730          :map minibuffer-local-map
 731          ("C-r" . counsel-minibuffer-history))
 732   :config
 733   (counsel-mode 1)
 734   (defalias 'locate #'counsel-locate))
 735 #+end_src
 736
 737 * Borg's =layer/essentials=
 738
 739 TODO: break this giant source block down into individual org sections.
 740
 741 #+begin_src emacs-lisp
 742 (use-package dash
 743   :config (dash-enable-font-lock))
 744
 745 (use-package diff-hl
 746   :config
 747   (setq diff-hl-draw-borders nil)
 748   (global-diff-hl-mode)
 749   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 750
 751 (use-package dired
 752   :defer t
 753   :config (setq dired-listing-switches "-alh"))
 754
 755 (use-package eldoc
 756   :when (version< "25" emacs-version)
 757   :config (global-eldoc-mode))
 758
 759 (use-package help
 760   :defer t
 761   :config (temp-buffer-resize-mode))
 762
 763 (progn ;    `isearch'
 764   (setq isearch-allow-scroll t))
 765
 766 (use-package lisp-mode
 767   :config
 768   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 769   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 770   (defun indent-spaces-mode ()
 771     (setq indent-tabs-mode nil))
 772   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 773
 774 (use-package man
 775   :defer t
 776   :config (setq Man-width 80))
 777
 778 (use-package paren
 779   :config (show-paren-mode))
 780
 781 (use-package prog-mode
 782   :config (global-prettify-symbols-mode)
 783   (defun indicate-buffer-boundaries-left ()
 784     (setq indicate-buffer-boundaries 'left))
 785   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 786
 787 (use-package recentf
 788   :demand t
 789   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 790
 791 (use-package savehist
 792   :config (savehist-mode))
 793
 794 (use-package saveplace
 795   :when (version< "25" emacs-version)
 796   :config (save-place-mode))
 797
 798 (use-package simple
 799   :config (column-number-mode))
 800
 801 (progn ;    `text-mode'
 802   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 803
 804 (use-package tramp
 805   :defer t
 806   :config
 807   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 808   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 809   (add-to-list 'tramp-default-proxies-alist
 810                (list (regexp-quote (system-name)) nil nil)))
 811
 812 (use-package undo-tree
 813   :config
 814   (global-undo-tree-mode)
 815   (setq undo-tree-mode-lighter ""))
 816 #+end_src
 817
 818 * Editing
 819
 820 ** Company
 821
 822 #+begin_src emacs-lisp
 823 (use-package company
 824   :defer 5
 825   :bind
 826   (:map company-active-map
 827         ([tab] . company-complete-common-or-cycle))
 828   :custom
 829   (company-idle-delay 0.3)
 830   (company-minimum-prefix-length 1)
 831   (company-selection-wrap-around t)
 832   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 833   :config
 834   (global-company-mode t))
 835 #+end_src
 836
 837 ** Customizations
 838
 839 #+begin_src emacs-lisp
 840 (ab--leader-keys
 841   "b s" 'save-buffer
 842   "b b" 'ivy-switch-buffer
 843   ","   'ivy-switch-buffer
 844   "b k" 'kill-this-buffer
 845   "q q" 'evil-save-and-quit)
 846 #+end_src
 847
 848 * Syntax and spell checking
 849 #+begin_src emacs-lisp
 850 (use-package flycheck
 851   :hook (prog-mode . flycheck-mode)
 852   :config
 853   ;; Use the load-path from running Emacs when checking elisp files
 854   (setq flycheck-emacs-lisp-load-path 'inherit)
 855
 856   ;; Only flycheck when I actually save the buffer
 857   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 858 #+end_src
 859 * Programming modes
 860
 861 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 862
 863 #+begin_src emacs-lisp
 864 (use-package alloy-mode
 865   :config (setq alloy-basic-offset 2))
 866 #+end_src
 867
 868 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 869
 870 #+begin_src emacs-lisp
 871 (use-package proof-site  ; Proof General
 872   :load-path "lib/proof-site/generic/")
 873 #+end_src
 874
 875 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 876
 877 #+begin_src emacs-lisp
 878 (use-package lean-mode
 879   :bind (:map lean-mode-map
 880               ("S-SPC" . company-complete)))
 881 #+end_src
 882
 883 ** Haskell
 884
 885 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 886
 887 #+begin_src emacs-lisp
 888 (use-package haskell-mode
 889   :config
 890   (setq haskell-indentation-layout-offset 4
 891         haskell-indentation-left-offset 4
 892         flycheck-checker 'haskell-hlint
 893         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 894 #+end_src
 895
 896 *** [[https://github.com/jyp/dante][dante]]
 897
 898 #+begin_src emacs-lisp
 899 (use-package dante
 900   :after haskell-mode
 901   :commands dante-mode
 902   :hook (haskell-mode . dante-mode))
 903 #+end_src
 904
 905 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 906
 907 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 908 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 909
 910 #+begin_src emacs-lisp
 911 (use-package hlint-refactor
 912   :bind (:map hlint-refactor-mode-map
 913               ("C-c l b" . hlint-refactor-refactor-buffer)
 914               ("C-c l r" . hlint-refactor-refactor-at-point))
 915   :hook (haskell-mode . hlint-refactor-mode))
 916 #+end_src
 917
 918 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 919
 920 #+begin_src emacs-lisp
 921 (use-package flycheck-haskell)
 922 #+end_src
 923
 924 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 925 :PROPERTIES:
 926 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 927 :END:
 928
 929 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 930 instead.
 931
 932 #+begin_src emacs-lisp :tangle no
 933 ;;; hs-lint.el --- minor mode for HLint code checking
 934
 935 ;; Copyright 2009 (C) Alex Ott
 936 ;;
 937 ;; Author: Alex Ott <alexott@gmail.com>
 938 ;; Keywords: haskell, lint, HLint
 939 ;; Requirements:
 940 ;; Status: distributed under terms of GPL2 or above
 941
 942 ;; Typical message from HLint looks like:
 943 ;;
 944 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 945 ;; Found:
 946 ;;   count1 p l = length (filter p l)
 947 ;; Why not:
 948 ;;   count1 p = length . filter p
 949
 950
 951 (require 'compile)
 952
 953 (defgroup hs-lint nil
 954   "Run HLint as inferior of Emacs, parse error messages."
 955   :group 'tools
 956   :group 'haskell)
 957
 958 (defcustom hs-lint-command "hlint"
 959   "The default hs-lint command for \\[hlint]."
 960   :type 'string
 961   :group 'hs-lint)
 962
 963 (defcustom hs-lint-save-files t
 964   "Save modified files when run HLint or no (ask user)"
 965   :type 'boolean
 966   :group 'hs-lint)
 967
 968 (defcustom hs-lint-replace-with-suggestions nil
 969   "Replace user's code with suggested replacements"
 970   :type 'boolean
 971   :group 'hs-lint)
 972
 973 (defcustom hs-lint-replace-without-ask nil
 974   "Replace user's code with suggested replacements automatically"
 975   :type 'boolean
 976   :group 'hs-lint)
 977
 978 (defun hs-lint-process-setup ()
 979   "Setup compilation variables and buffer for `hlint'."
 980   (run-hooks 'hs-lint-setup-hook))
 981
 982 ;; regex for replace suggestions
 983 ;;
 984 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 985 ;; Found:
 986 ;; \s +\(.*\)
 987 ;; Why not:
 988 ;; \s +\(.*\)
 989
 990 (defvar hs-lint-regex
 991   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
 992   "Regex for HLint messages")
 993
 994 (defun make-short-string (str maxlen)
 995   (if (< (length str) maxlen)
 996       str
 997     (concat (substring str 0 (- maxlen 3)) "...")))
 998
 999 (defun hs-lint-replace-suggestions ()
1000   "Perform actual replacement of suggestions"
1001   (goto-char (point-min))
1002   (while (re-search-forward hs-lint-regex nil t)
1003     (let* ((fname (match-string 1))
1004           (fline (string-to-number (match-string 2)))
1005           (old-code (match-string 4))
1006           (new-code (match-string 5))
1007           (msg (concat "Replace '" (make-short-string old-code 30)
1008                        "' with '" (make-short-string new-code 30) "'"))
1009           (bline 0)
1010           (eline 0)
1011           (spos 0)
1012           (new-old-code ""))
1013       (save-excursion
1014         (switch-to-buffer (get-file-buffer fname))
1015         (goto-char (point-min))
1016         (forward-line (1- fline))
1017         (beginning-of-line)
1018         (setf bline (point))
1019         (when (or hs-lint-replace-without-ask
1020                   (yes-or-no-p msg))
1021           (end-of-line)
1022           (setf eline (point))
1023           (beginning-of-line)
1024           (setf old-code (regexp-quote old-code))
1025           (while (string-match "\\\\ " old-code spos)
1026             (setf new-old-code (concat new-old-code
1027                                  (substring old-code spos (match-beginning 0))
1028                                  "\\ *"))
1029             (setf spos (match-end 0)))
1030           (setf new-old-code (concat new-old-code (substring old-code spos)))
1031           (remove-text-properties bline eline '(composition nil))
1032           (when (re-search-forward new-old-code eline t)
1033             (replace-match new-code nil t)))))))
1034
1035 (defun hs-lint-finish-hook (buf msg)
1036   "Function, that is executed at the end of HLint execution"
1037   (if hs-lint-replace-with-suggestions
1038       (hs-lint-replace-suggestions)
1039       (next-error 1 t)))
1040
1041 (define-compilation-mode hs-lint-mode "HLint"
1042   "Mode for check Haskell source code."
1043   (set (make-local-variable 'compilation-process-setup-function)
1044        'hs-lint-process-setup)
1045   (set (make-local-variable 'compilation-disable-input) t)
1046   (set (make-local-variable 'compilation-scroll-output) nil)
1047   (set (make-local-variable 'compilation-finish-functions)
1048        (list 'hs-lint-finish-hook))
1049   )
1050
1051 (defun hs-lint ()
1052   "Run HLint for current buffer with haskell source"
1053   (interactive)
1054   (save-some-buffers hs-lint-save-files)
1055   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1056                      'hs-lint-mode))
1057
1058 (provide 'hs-lint)
1059 ;;; hs-lint.el ends here
1060 #+end_src
1061
1062 #+begin_src emacs-lisp :tangle no
1063 (use-package hs-lint
1064   :load-path "lisp/"
1065   :bind (:map haskell-mode-map
1066               ("C-c l l" . hs-lint)))
1067 #+end_src
1068 * Emacs Enhancements
1069
1070 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1071
1072 #+begin_quote
1073 Emacs package that displays available keybindings in popup
1074 #+end_quote
1075
1076 #+begin_src emacs-lisp
1077 (use-package which-key
1078   :defer 1
1079   :config (which-key-mode))
1080 #+end_src
1081
1082 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1083
1084 #+begin_src emacs-lisp
1085 (use-package doom-modeline
1086   :demand t
1087   :config (setq doom-modeline-height 32)
1088   :hook (after-init . doom-modeline-init))
1089 #+end_src
1090
1091 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1092
1093 #+begin_src emacs-lisp
1094 (use-package tao-theme
1095   :demand t
1096   :config (load-theme 'tao-yang t))
1097 #+end_src
1098
1099 * Email
1100 ** [[https://notmuchmail.org][notmuch]]
1101
1102 #+begin_src emacs-lisp
1103 (defun ab/notmuch ()
1104   "Delete other windows, then launch `notmuch'."
1105   (interactive)
1106   (require 'notmuch)
1107   (delete-other-windows)
1108   (notmuch))
1109
1110 ;; (ab--leader-keys
1111 ;;   "m"   'ab/notmuch
1112 ;;   "s"   'save-buffer
1113 ;;   "SPC" 'counsel-M-x)
1114
1115 ;; (map!
1116 ;;  :leader
1117 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1118 ;;  (:desc "search" :prefix "/"
1119 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1120 #+end_src
1121
1122 #+begin_src emacs-lisp
1123 (defvar ab-maildir "~/mail")
1124
1125 (use-package sendmail
1126   ;; :ensure nil
1127   :config
1128   (setq sendmail-program "/usr/bin/msmtp"
1129         mail-specify-envelope-from t
1130         mail-envelope-from 'header))
1131
1132 (use-package message
1133   ;; :ensure nil
1134   :config
1135   (setq message-kill-buffer-on-exit t
1136         message-send-mail-function 'message-send-mail-with-sendmail
1137         message-sendmail-envelope-from 'header
1138         message-directory "drafts"
1139         message-user-fqdn "fencepost.gnu.org")
1140   (add-hook 'message-mode-hook
1141             (lambda () (setq fill-column 65
1142                         message-fill-column 65)))
1143   (add-hook 'message-mode-hook
1144             #'flyspell-mode)
1145   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1146   ;; TODO: is there a way to only run this when replying and not composing?
1147   (add-hook 'notmuch-message-mode-hook
1148             (lambda () (progn
1149                     (newline)
1150                     (newline)
1151                     (forward-line -1)
1152                     (forward-line -1))))
1153   ;; (add-hook 'message-setup-hook
1154   ;;           #'mml-secure-message-sign-pgpmime)
1155   )
1156
1157 (after! mml-sec
1158   (setq mml-secure-openpgp-encrypt-to-self t
1159         mml-secure-openpgp-sign-with-sender t))
1160
1161 (use-package notmuch
1162   :general (ab--leader-keys "m" 'ab/notmuch)
1163   :config
1164   (setq notmuch-hello-sections
1165         '(notmuch-hello-insert-header
1166           notmuch-hello-insert-saved-searches
1167           ;; notmuch-hello-insert-search
1168           notmuch-hello-insert-alltags)
1169         notmuch-search-oldest-first nil
1170         notmuch-show-all-tags-list t
1171         notmuch-hello-thousands-separator ","
1172         notmuch-fcc-dirs
1173         '(("amin@aminb.org"            . "amin/Sent")
1174           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1175           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1176           ("aminb@gnu.org"             . "gnu/Sent")
1177           (".*"                        . "sent")))
1178   ;; (add-hook 'visual-fill-column-mode-hook
1179   ;;           (lambda ()
1180   ;;             (when (string= major-mode 'notmuch-message-mode)
1181   ;;               (setq visual-fill-column-width 70))))
1182   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1183   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1184   ;;             :override #'kill-this-buffer)
1185   :bind
1186   (:map notmuch-hello-mode-map
1187         ("g" . notmuch-poll-and-refresh-this-buffer)
1188         ("i" . (lambda ()
1189                  "Search for `inbox' tagged messages"
1190                  (interactive)
1191                  (notmuch-hello-search "tag:inbox")))
1192         ("u" . (lambda ()
1193                  "Search for `unread' tagged messages"
1194                  (interactive)
1195                  (notmuch-hello-search "tag:unread")))
1196         ("M" . (lambda ()
1197                  "Compose new mail and prompt for sender"
1198                  (interactive)
1199                  (let ((current-prefix-arg t))
1200                    (call-interactively #'notmuch-mua-new-mail)))))
1201   (:map notmuch-search-mode-map
1202         ("g" . notmuch-poll-and-refresh-this-buffer)
1203         ("k" . (lambda ()
1204                  "Mark message read"
1205                  (interactive)
1206                  (notmuch-search-tag '("-unread"))
1207                  ;; (notmuch-search-archive-thread)
1208                  (notmuch-search-next-thread)))
1209         ("u" . (lambda ()
1210                  "Mark message unread"
1211                  (interactive)
1212                  (notmuch-search-tag '("+unread"))
1213                  (notmuch-search-next-thread)))
1214         ("K" . (lambda ()
1215                  "Mark message deleted"
1216                  (interactive)
1217                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1218                  (notmuch-search-archive-thread)))
1219         ("S" . (lambda ()
1220                  "Mark message as spam"
1221                  (interactive)
1222                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1223                  (notmuch-search-archive-thread))))
1224   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1225         ("S" . (lambda ()
1226                  "Mark message as spam"
1227                  (interactive)
1228                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1229                  (notmuch-tree-archive-thread))))
1230 )
1231
1232 ;; (use-package counsel-notmuch
1233 ;;   :commands counsel-notmuch)
1234
1235 (after! notmuch-crypto
1236   (setq notmuch-crypto-process-mime t))
1237
1238 ;; (after! evil
1239 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1240 ;;         '((notmuch-hello-mode . emacs)
1241 ;;           (notmuch-search-mode . emacs)
1242 ;;           (notmuch-tree-mode . emacs))))
1243
1244 (after! recentf
1245   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1246 #+end_src
1247
1248 * Post initialization
1249 :PROPERTIES:
1250 :CUSTOM_ID: post-initialization
1251 :END:
1252
1253 Display how long it took to load the init file.
1254
1255 #+begin_src emacs-lisp
1256 (message "Loading %s...done (%.3fs)" user-init-file
1257          (float-time (time-subtract (current-time)
1258                                     ab--before-user-init-time)))
1259 #+end_src
1260
1261 * Footer
1262 :PROPERTIES:
1263 :CUSTOM_ID: footer
1264 :END:
1265
1266 #+begin_src emacs-lisp :comments none
1267 ;;; init.el ends here
1268 #+end_src