git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 ;; (require 'borg-nix-shell)
 238 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c B A" . borg-activate)
 244    ("C-c B a" . borg-assimilate)
 245    ("C-c B b" . borg-build)
 246    ("C-c B c" . borg-clone)))
 247 #+end_src
 248
 249 *** =use-package=
 250
 251 #+begin_quote
 252 A use-package declaration for simplifying your .emacs
 253 #+end_quote
 254
 255 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 256 packages (in our case especially the latter) in a neatly organized way
 257 and without compromising on performance.
 258
 259 #+begin_src emacs-lisp
 260 (require 'use-package)
 261 (if nil  ; set to t when need to debug init
 262     (setq use-package-verbose t
 263           use-package-expand-minimally nil
 264           use-package-compute-statistics t
 265           debug-on-error t)
 266   (setq use-package-verbose nil
 267         use-package-expand-minimally t))
 268 #+end_src
 269
 270 *** Epkg
 271
 272 #+begin_quote
 273 Browse the Emacsmirror package database
 274 #+end_quote
 275
 276 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 277 database, low-level functions for querying the database, and a
 278 =package.el=-like user interface for browsing the available packages.
 279
 280 #+begin_src emacs-lisp
 281 (use-package epkg
 282   :defer t
 283   :bind
 284   (("C-c B d" . epkg-describe-package)
 285    ("C-c B p" . epkg-list-packages)
 286    ("C-c B r" . borg-remove)
 287    ("C-c B u" . epkg-update)))
 288 #+end_src
 289
 290 ** No littering in =~/.emacs.d=
 291
 292 #+begin_quote
 293 Help keeping ~/.emacs.d clean
 294 #+end_quote
 295
 296 By default, even for Emacs' built-in packages, the configuration files
 297 and persistent data are all over the place. Use =no-littering= to help
 298 contain the mess.
 299
 300 #+begin_src emacs-lisp
 301 (use-package no-littering
 302   :demand t
 303   :config
 304   (savehist-mode 1)
 305   (add-to-list 'savehist-additional-variables 'kill-ring)
 306   (save-place-mode 1)
 307   (setq auto-save-file-name-transforms
 308         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 309 #+end_src
 310
 311 ** Custom file (=custom.el=)
 312
 313 I'm not planning on using the custom file much, but even so, I
 314 definitely don't want it mixing with =init.el=. So, here; let's give
 315 it it's own file. While at it, treat themes as safe.
 316
 317 #+begin_src emacs-lisp
 318 (use-package custom
 319   :no-require t
 320   :config
 321   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 322   (when (file-exists-p custom-file)
 323     (load custom-file))
 324   (setf custom-safe-themes t))
 325 #+end_src
 326
 327 ** Secrets file
 328
 329 #+begin_src emacs-lisp
 330 (load (no-littering-expand-etc-file-name "secrets"))
 331 #+end_src
 332
 333 ** Better =$PATH= handling
 334
 335 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 336 in my shell.
 337
 338 #+begin_src emacs-lisp
 339 (use-package exec-path-from-shell
 340   :defer 1
 341   :init
 342   (setq exec-path-from-shell-check-startup-files nil)
 343   :config
 344   (exec-path-from-shell-initialize)
 345   ;; while we're at it, let's fix access to our running ssh-agent
 346   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 347   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 348 #+end_src
 349
 350 ** Only one custom theme at a time
 351
 352 #+begin_src emacs-lisp
 353 (defadvice load-theme (before clear-previous-themes activate)
 354   "Clear existing theme settings instead of layering them"
 355   (mapc #'disable-theme custom-enabled-themes))
 356 #+end_src
 357
 358 ** Server
 359
 360 Start server if not already running. Alternatively, can be done by
 361 issuing =emacs --daemon= in the terminal, which can be automated with
 362 a systemd service or using =brew services start emacs= on macOS. I use
 363 Emacs as my window manager (via EXWM), so I always start Emacs on
 364 login; so starting the server from inside Emacs is good enough for me.
 365
 366 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 367
 368 #+begin_src emacs-lisp
 369 (use-package server
 370   :config (or (server-running-p) (server-mode)))
 371 #+end_src
 372
 373 ** Unicode support
 374
 375 Font stack with better unicode support, around =Ubuntu Mono= and
 376 =Hack=.
 377
 378 #+begin_src emacs-lisp :tangle no
 379 (dolist (ft (fontset-list))
 380   (set-fontset-font
 381    ft
 382    'unicode
 383    (font-spec :name "Source Code Pro" :size 14))
 384   (set-fontset-font
 385    ft
 386    'unicode
 387    (font-spec :name "DejaVu Sans Mono")
 388    nil
 389    'append)
 390   ;; (set-fontset-font
 391   ;;  ft
 392   ;;  'unicode
 393   ;;  (font-spec
 394   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 395   ;;  nil
 396   ;;  'append)
 397   ;; (set-fontset-font
 398   ;;  ft
 399   ;;  #x2115  ; ℕ
 400   ;;  (font-spec :name "DejaVu Sans Mono")
 401   ;;  nil
 402   ;;  'append)
 403   (set-fontset-font
 404    ft
 405    (cons ?Α ?ω)
 406    (font-spec :name "DejaVu Sans Mono" :size 14)
 407    nil
 408    'prepend))
 409 #+end_src
 410
 411 ** Gentler font resizing
 412
 413 #+begin_src emacs-lisp
 414 (setq text-scale-mode-step 1.05)
 415 #+end_src
 416
 417 ** Libraries
 418
 419 #+begin_src emacs-lisp
 420 (require 'cl-lib)
 421 (require 'subr-x)
 422 #+end_src
 423
 424 ** Useful utilities
 425
 426 #+begin_src emacs-lisp
 427 (defun amin-enlist (exp)
 428   "Return EXP wrapped in a list, or as-is if already a list."
 429 (if (listp exp) exp (list exp)))
 430
 431 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 432 (defmacro after! (features &rest body)
 433   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 434 compilation."
 435   (declare (indent defun) (debug t))
 436   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 437                 (dolist (next (amin-enlist features))
 438                   (if (symbolp next)
 439                       (require next nil :no-error)
 440                     (load next :no-message :no-error))))
 441             #'progn
 442           #'with-no-warnings)
 443         (cond ((symbolp features)
 444                `(eval-after-load ',features '(progn ,@body)))
 445               ((and (consp features)
 446                     (memq (car features) '(:or :any)))
 447                `(progn
 448                   ,@(cl-loop for next in (cdr features)
 449                              collect `(after! ,next ,@body))))
 450               ((and (consp features)
 451                     (memq (car features) '(:and :all)))
 452                (dolist (next (cdr features))
 453                  (setq body `(after! ,next ,@body)))
 454                body)
 455               ((listp features)
 456                `(after! (:all ,@features) ,@body)))))
 457 #+end_src
 458
 459 Convenience macro for =setq='ing multiple variables to the same value:
 460
 461 #+begin_src emacs-lisp
 462 (defmacro setq-every! (value &rest vars)
 463   "Set all the variables from VARS to value VALUE."
 464   (declare (indent defun) (debug t))
 465   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 466 #+end_src
 467
 468 * Core
 469 :PROPERTIES:
 470 :CUSTOM_ID: core
 471 :END:
 472
 473 ** Defaults
 474
 475 *** Time and battery in mode-line
 476
 477 Enable displaying time and battery in the mode-line, since I'm not
 478 using the Xfce panel anymore. Also, I don't need to see the load
 479 average on a regular basis, so disable that.
 480
 481 Note: using =i3status= on sway at the moment, so disabling this.
 482
 483 #+begin_src emacs-lisp :tangle no
 484 (use-package time
 485   :init
 486   (setq display-time-default-load-average nil)
 487   :config
 488   (display-time-mode))
 489
 490 (use-package battery
 491   :config
 492   (display-battery-mode))
 493 #+end_src
 494
 495 *** Smaller fringe
 496
 497 Might want to set the fringe to a smaller value, especially if using
 498 EXWM. I'm fine with the default for now.
 499
 500 #+begin_src emacs-lisp
 501 ;; (fringe-mode '(3 . 1))
 502 (fringe-mode nil)
 503 #+end_src
 504
 505 *** Disable disabled commands
 506
 507 Emacs disables some commands by default that could persumably be
 508 confusing for novice users. Let's disable that.
 509
 510 #+begin_src emacs-lisp
 511 (setq disabled-command-function nil)
 512 #+end_src
 513
 514 *** Kill-ring
 515
 516 Save what I copy into clipboard from other applications into Emacs'
 517 kill-ring, which would allow me to still be able to easily access it
 518 in case I kill (cut or copy) something else inside Emacs before
 519 yanking (pasting) what I'd originally intended to.
 520
 521 #+begin_src emacs-lisp
 522 (setq save-interprogram-paste-before-kill t)
 523 #+end_src
 524
 525 *** Minibuffer
 526
 527 #+begin_src emacs-lisp
 528 (setq enable-recursive-minibuffers t
 529       resize-mini-windows t)
 530 #+end_src
 531
 532 *** Lazy-person-friendly yes/no prompts
 533
 534 Lazy people would prefer to type fewer keystrokes, especially for yes
 535 or no questions. I'm lazy.
 536
 537 #+begin_src emacs-lisp
 538 (defalias 'yes-or-no-p #'y-or-n-p)
 539 #+end_src
 540
 541 *** Startup screen and =*scratch*=
 542
 543 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 544 startup buffer.
 545
 546 #+begin_src emacs-lisp
 547 (setq initial-buffer-choice t)
 548 #+end_src
 549
 550 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 551 need the default hint.
 552
 553 #+begin_src emacs-lisp
 554 (setq initial-scratch-message nil)
 555 #+end_src
 556
 557 Also, let's use Text mode as the major mode, in case I want to
 558 customize it (=*scratch*='s default major mode, Fundamental mode,
 559 can't really be customized).
 560
 561 #+begin_src emacs-lisp
 562 (setq initial-major-mode 'text-mode)
 563 #+end_src
 564
 565 Inhibit the buffer list when more than 2 files are loaded.
 566
 567 #+begin_src emacs-lisp
 568 (setq inhibit-startup-buffer-menu t)
 569 #+end_src
 570
 571 I don't really need to see the startup screen or echo area message
 572 either.
 573
 574 #+begin_src emacs-lisp
 575 (advice-add #'display-startup-echo-area-message :override #'ignore)
 576 (setq inhibit-startup-screen t
 577       inhibit-startup-echo-area-message user-login-name)
 578 #+end_src
 579
 580 *** More useful frame titles
 581
 582 Show either the file name or the buffer name (in case the buffer isn't
 583 visiting a file). Borrowed from Emacs Prelude.
 584
 585 #+begin_src emacs-lisp
 586 (setq frame-title-format
 587       '("" invocation-name " - "
 588         (:eval (if (buffer-file-name)
 589                    (abbreviate-file-name (buffer-file-name))
 590                  "%b"))))
 591 #+end_src
 592
 593 *** Backups
 594
 595 Emacs' default backup settings aren't that great. Let's use more
 596 sensible options. See documentation for the ~make-backup-file~
 597 variable.
 598
 599 #+begin_src emacs-lisp
 600 (setq backup-by-copying t
 601       version-control t
 602       delete-old-versions t)
 603 #+end_src
 604
 605 *** Auto revert
 606
 607 Enable automatic reloading of changed buffers and files.
 608
 609 #+begin_src emacs-lisp
 610 (global-auto-revert-mode 1)
 611 (setq auto-revert-verbose nil
 612       global-auto-revert-non-file-buffers t)
 613 #+end_src
 614
 615 *** Always use space for indentation
 616
 617 #+begin_src emacs-lisp
 618 (setq-default
 619  indent-tabs-mode nil
 620  require-final-newline t
 621  tab-width 4)
 622 #+end_src
 623
 624 *** Winner mode
 625
 626 Enable =winner-mode=.
 627
 628 #+begin_src emacs-lisp
 629 (winner-mode 1)
 630 #+end_src
 631
 632 *** Close =*compilation*= on success
 633
 634 #+begin_src emacs-lisp
 635 (setq compilation-exit-message-function
 636       (lambda (status code msg)
 637         "Close the compilation window if successful."
 638         ;; if M-x compile exits with 0
 639          (when (and (eq status 'exit) (zerop code))
 640            (bury-buffer)
 641            (delete-window (get-buffer-window (get-buffer "*compilation*"))))
 642          ;; return the result of compilation-exit-message-function
 643          (cons msg code)))
 644 #+end_src
 645
 646 ** Bindings
 647
 648 #+begin_src emacs-lisp
 649 (bind-keys
 650  ("C-c b k" . kill-this-buffer)
 651  ;; ("C-c s s" . save-buffer)
 652  ("C-c b s" . save-buffer)
 653  ("C-c S"   . save-buffer)
 654  ("C-c o"   . other-window)
 655  ("C-c q q" . save-buffers-kill-terminal)
 656  ("C-c F m" . make-frame-command)
 657  ("C-c F d" . delete-frame)
 658  ("C-c F D" . delete-other-frames))
 659 #+end_src
 660
 661 ** Packages
 662
 663 The packages in this section are absolutely essential to my everyday
 664 workflow, and they play key roles in how I do my computing. They
 665 immensely enhance the Emacs experience for me; both using Emacs, and
 666 customizing it.
 667
 668 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 669
 670 #+begin_src emacs-lisp
 671 (use-package auto-compile
 672   :demand t
 673   :config
 674   (auto-compile-on-load-mode)
 675   (auto-compile-on-save-mode)
 676   (setq auto-compile-display-buffer               nil
 677         auto-compile-mode-line-counter            t
 678         auto-compile-source-recreate-deletes-dest t
 679         auto-compile-toggle-deletes-nonlib-dest   t
 680         auto-compile-update-autoloads             t)
 681   (add-hook 'auto-compile-inhibit-compile-hook
 682             'auto-compile-inhibit-compile-detached-git-head))
 683 #+end_src
 684
 685 *** [[https://orgmode.org/][Org mode]]
 686
 687 #+begin_quote
 688 Org mode is for keeping notes, maintaining TODO lists, planning
 689 projects, and authoring documents with a fast and effective plain-text
 690 system.
 691 #+end_quote
 692
 693 In short, my favourite way of life.
 694
 695 #+begin_src emacs-lisp
 696 (use-package org
 697   :config
 698   (setq org-src-tab-acts-natively t
 699         org-src-preserve-indentation nil
 700         org-edit-src-content-indentation 0
 701         org-log-done 'time)
 702   :hook ((org-mode . org-indent-mode)
 703          (org-mode . auto-fill-mode)
 704          (org-mode . flyspell-mode))
 705   :custom
 706   (org-latex-packages-alist '(("" "listings") ("" "color"))))
 707
 708 (use-package ox-latex
 709   :config
 710   (setq org-latex-listings 'listings
 711         ;; org-latex-prefer-user-labels t
 712         )
 713   (add-to-list 'org-latex-packages-alist '("" "listings"))
 714   (add-to-list 'org-latex-packages-alist '("" "color"))
 715   (add-to-list 'org-latex-classes
 716                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 717                  ("\\section{%s}" . "\\section*{%s}")
 718                  ("\\subsection{%s}" . "\\subsection*{%s}")
 719                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 720                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 721                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 722                t))
 723
 724 (use-package ox-beamer)
 725
 726 (use-package org-notmuch
 727   :after (:any org notmuch))
 728
 729 (use-package orgalist
 730   :hook (message-mode . orgalist-mode))
 731 #+end_src
 732
 733 **** asynchronous tangle
 734
 735 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 736 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 737 file.
 738
 739 #+begin_src emacs-lisp
 740 (after! org
 741   (defvar amin-show-async-tangle-results nil
 742     "Keep *emacs* async buffers around for later inspection.")
 743
 744   (defvar amin-show-async-tangle-time nil
 745     "Show the time spent tangling the file.")
 746
 747   (defvar amin-async-tangle-post-compile "make ti"
 748     "If non-nil, pass to `compile' after successful tangle.")
 749
 750   (defun amin/async-babel-tangle ()
 751     "Tangle org file asynchronously."
 752     (interactive)
 753     (let* ((file-tangle-start-time (current-time))
 754            (file (buffer-file-name))
 755            (file-nodir (file-name-nondirectory file))
 756            (async-quiet-switch "-q"))
 757       (async-start
 758        `(lambda ()
 759           (require 'org)
 760           (org-babel-tangle-file ,file))
 761        (unless amin-show-async-tangle-results
 762          `(lambda (result)
 763             (if result
 764                 (progn
 765                   (message "Tangled %s%s"
 766                            ,file-nodir
 767                            (if amin-show-async-tangle-time
 768                                (format " (%.3fs)"
 769                                        (float-time (time-subtract (current-time)
 770                                                                   ',file-tangle-start-time)))
 771                              ""))
 772                   (when amin-async-tangle-post-compile
 773                     (compile amin-async-tangle-post-compile)))
 774               (message "Tangling %s failed" ,file-nodir))))))))
 775
 776 (add-to-list
 777  'safe-local-variable-values
 778  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 779 #+end_src
 780
 781 *** [[https://magit.vc/][Magit]]
 782
 783 #+begin_quote
 784 It's Magit! A Git porcelain inside Emacs.
 785 #+end_quote
 786
 787 Not just how I do git, but /the/ way to do git.
 788
 789 #+begin_src emacs-lisp
 790 (use-package magit
 791   :defer t
 792   :bind
 793   (("s-g"   . magit-dispatch-popup)
 794    ("C-x g" . magit-status)
 795    :prefix-map amin--magit-prefix-map
 796    :prefix "C-c g"
 797    ("SPC" . magit-status)
 798    ("s"   . magit-status)
 799    ("S"   . magit-status-prefix)
 800    ("B"   . magit-blame-addition)
 801    ("C"   . magit-clone)
 802    ("f"   . magit-fetch-other)
 803    ("F"   . magit-pull-branch)
 804    ("P"   . magit-push-other)
 805    ("p"   . magit-dispatch-popup)
 806    ("c c" . magit-commit-create)
 807    ("c a" . magit-commit-amend)
 808    ("b b" . magit-checkout)
 809    ("b c" . magit-branch-create))
 810   :config
 811   (magit-add-section-hook 'magit-status-sections-hook
 812                           'magit-insert-modules
 813                           'magit-insert-stashes
 814                           'append)
 815   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 816 #+end_src
 817
 818 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 819
 820 #+begin_quote
 821 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 822 an overview, and more. Oh, man!
 823 #+end_quote
 824
 825 There's no way I could top that, so I won't attempt to.
 826
 827 **** Ivy
 828
 829 #+begin_src emacs-lisp
 830 (use-package ivy
 831   :defer 1
 832   :bind
 833   (("C-c b b" . ivy-switch-buffer)
 834    :map ivy-minibuffer-map
 835    ([escape] . keyboard-escape-quit)
 836    ([S-up]   . ivy-previous-history-element)
 837    ([S-down] . ivy-next-history-element)
 838    ("DEL"    . ivy-backward-delete-char))
 839   :config
 840   (setq ivy-wrap t)
 841   (ivy-mode 1)
 842   :custom-face
 843   (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 844   (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 845   (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold)))))
 846 #+end_src
 847
 848 **** Swiper
 849
 850 #+begin_src emacs-lisp
 851 (use-package swiper
 852   :bind (("C-s" . swiper)
 853          ("C-r" . swiper)))
 854 #+end_src
 855
 856 **** Counsel
 857
 858 #+begin_src emacs-lisp
 859 (use-package counsel
 860   :defer 1
 861   :bind (([remap execute-extended-command] . counsel-M-x)
 862          ([remap find-file]                . counsel-find-file)
 863          ("s-r"                            . counsel-recentf)
 864          ("C-c x"                          . counsel-M-x)
 865          ("C-c f ."                        . counsel-find-file)
 866          ("C-c f r"                        . counsel-recentf)
 867          :map minibuffer-local-map
 868          ("C-r" . counsel-minibuffer-history))
 869   :config
 870   (counsel-mode 1)
 871   (defalias 'locate #'counsel-locate))
 872 #+end_src
 873
 874 *** eshell
 875
 876 #+begin_src emacs-lisp
 877 (use-package eshell
 878   :commands eshell
 879   :config
 880   (eval-when-compile (defvar eshell-prompt-regexp))
 881   (defun amin/eshell-quit-or-delete-char (arg)
 882     (interactive "p")
 883     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 884         (eshell-life-is-too-much)
 885       (delete-char arg)))
 886
 887   (defun amin/eshell-clear ()
 888     (interactive)
 889     (let ((inhibit-read-only t))
 890       (erase-buffer))
 891     (eshell-send-input))
 892
 893   (defun amin|eshell-setup ()
 894     (bind-keys :map eshell-mode-map
 895                ("C-d" . amin/eshell-quit-or-delete-char)
 896                ("C-l" . amin/eshell-clear)))
 897
 898   :hook (eshell-mode . amin|eshell-setup))
 899 #+end_src
 900
 901 *** Ibuffer
 902
 903 #+begin_src emacs-lisp
 904 (use-package ibuffer
 905   :bind
 906   (("C-x C-b" . ibuffer-other-window)
 907    ("C-c b B" . ibuffer-other-window)
 908    :map ibuffer-mode-map
 909    ("P"   . ibuffer-backward-filter-group)
 910    ("N"   . ibuffer-forward-filter-group)
 911    ("M-p" . ibuffer-do-print)
 912    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 913   :config
 914   ;; Use human readable Size column instead of original one
 915   (define-ibuffer-column size-h
 916     (:name "Size" :inline t)
 917     (cond
 918      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
 919      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
 920      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
 921      (t (format "%8d" (buffer-size)))))
 922   :custom
 923   (ibuffer-saved-filter-groups
 924    '(("default"
 925       ("dired" (mode . dired-mode))
 926       ("org"   (mode . org-mode))
 927       ("web"
 928        (or
 929         (mode . web-mode)
 930         (mode . css-mode)
 931         (mode . scss-mode)
 932         (mode . js2-mode)))
 933       ("shell"
 934        (or
 935         (mode . eshell-mode)
 936         (mode . shell-mode)))
 937       ("notmuch" (name . "\*notmuch\*"))
 938       ("programming"
 939        (or
 940         (mode . python-mode)
 941         (mode . c++-mode)
 942         (mode . emacs-lisp-mode)))
 943       ("emacs"
 944        (or
 945         (name . "^\\*scratch\\*$")
 946         (name . "^\\*Messages\\*$")))
 947       ("slack"
 948        (or
 949         (name . "^\\*Slack*"))))))
 950   (ibuffer-formats
 951    '((mark modified read-only locked " "
 952            (name 18 18 :left :elide)
 953            " "
 954            (size-h 9 -1 :right)
 955            " "
 956            (mode 16 16 :left :elide)
 957            " " filename-and-process)
 958      (mark " "
 959            (name 16 -1)
 960            " " filename)))
 961   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
 962 #+end_src
 963
 964 *** Outline
 965
 966 #+begin_src emacs-lisp
 967 (use-package outline
 968   :hook (prog-mode . outline-minor-mode)
 969   :bind
 970   (:map
 971    outline-minor-mode-map
 972    ("<s-tab>"  . outline-toggle-children)
 973    ("s-p"      . outline-previous-visible-heading)
 974    ("s-n"      . outline-next-visible-heading)
 975    :prefix-map amin--outline-prefix-map
 976    :prefix "s-o"
 977    ("TAB" . outline-toggle-children)
 978    ("a"   . outline-hide-body)
 979    ("H"   . outline-hide-body)
 980    ("S"   . outline-show-all)
 981    ("h"   . outline-hide-subtree)
 982    ("s"   . outline-show-subtree)))
 983 #+end_src
 984
 985 * Borg's =layer/essentials=
 986
 987 TODO: break this giant source block down into individual org sections.
 988
 989 #+begin_src emacs-lisp
 990 (use-package dash
 991   :config (dash-enable-font-lock))
 992
 993 (use-package diff-hl
 994   :config
 995   (setq diff-hl-draw-borders nil)
 996   (global-diff-hl-mode)
 997   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 998
 999 (use-package dired
1000   :defer t
1001   :config (setq dired-listing-switches "-alh"))
1002
1003 (use-package eldoc
1004   :when (version< "25" emacs-version)
1005   :config (global-eldoc-mode))
1006
1007 (use-package help
1008   :defer t
1009   :config (temp-buffer-resize-mode))
1010
1011 (progn ;    `isearch'
1012   (setq isearch-allow-scroll t))
1013
1014 (use-package lisp-mode
1015   :config
1016   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1017   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1018   (defun indent-spaces-mode ()
1019     (setq indent-tabs-mode nil))
1020   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1021
1022 (use-package man
1023   :defer t
1024   :config (setq Man-width 80))
1025
1026 (use-package paren
1027   :config (show-paren-mode))
1028
1029 (use-package prog-mode
1030   :config (global-prettify-symbols-mode)
1031   (defun indicate-buffer-boundaries-left ()
1032     (setq indicate-buffer-boundaries 'left))
1033   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1034
1035 (use-package recentf
1036   :demand t
1037   :config
1038   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1039   (setq recentf-max-saved-items 40))
1040
1041 (use-package savehist
1042   :config (savehist-mode))
1043
1044 (use-package saveplace
1045   :when (version< "25" emacs-version)
1046   :config (save-place-mode))
1047
1048 (use-package simple
1049   :config (column-number-mode))
1050
1051 (progn ;    `text-mode'
1052   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1053
1054 (use-package tramp
1055   :defer t
1056   :config
1057   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1058   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1059   (add-to-list 'tramp-default-proxies-alist
1060                (list (regexp-quote (system-name)) nil nil)))
1061
1062 (use-package undo-tree
1063   :bind (("C-?" . undo-tree-undo)
1064          ("M-_" . undo-tree-redo))
1065   :config
1066   (global-undo-tree-mode)
1067   (setq undo-tree-mode-lighter ""
1068         undo-tree-auto-save-history t))
1069 #+end_src
1070
1071 * Editing
1072
1073 ** Company
1074
1075 #+begin_src emacs-lisp
1076 (use-package company
1077   :defer 5
1078   :bind
1079   (:map company-active-map
1080         ([tab]    . company-complete-common-or-cycle)
1081         ([escape] . company-abort))
1082   :custom
1083   (company-idle-delay 0.3)
1084   (company-minimum-prefix-length 1)
1085   (company-selection-wrap-around t)
1086   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1087   (company-dabbrev-downcase nil)
1088   (company-dabbrev-ignore-case nil)
1089   :config
1090   (global-company-mode t))
1091 #+end_src
1092
1093 * Syntax and spell checking
1094 #+begin_src emacs-lisp
1095 (use-package flycheck
1096   :hook (prog-mode . flycheck-mode)
1097   :config
1098   ;; Use the load-path from running Emacs when checking elisp files
1099   (setq flycheck-emacs-lisp-load-path 'inherit)
1100
1101   ;; Only flycheck when I actually save the buffer
1102   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1103
1104 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1105 (use-package ispell
1106   :config
1107   ;; ’ can be part of a word
1108   (setq ispell-local-dictionary-alist
1109         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1110                "['\x2019]" nil ("-B") nil utf-8)))
1111   ;; don't send ’ to the subprocess
1112   (defun endless/replace-apostrophe (args)
1113     (cons (replace-regexp-in-string
1114            "’" "'" (car args))
1115           (cdr args)))
1116   (advice-add #'ispell-send-string :filter-args
1117               #'endless/replace-apostrophe)
1118
1119   ;; convert ' back to ’ from the subprocess
1120   (defun endless/replace-quote (args)
1121     (if (not (derived-mode-p 'org-mode))
1122         args
1123       (cons (replace-regexp-in-string
1124              "'" "’" (car args))
1125             (cdr args))))
1126   (advice-add #'ispell-parse-output :filter-args
1127               #'endless/replace-quote))
1128 #+end_src
1129 * Programming modes
1130
1131 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1132
1133 #+begin_src emacs-lisp
1134 (use-package alloy-mode
1135   :config (setq alloy-basic-offset 2))
1136 #+end_src
1137
1138 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1139
1140 #+begin_src emacs-lisp
1141 (use-package proof-site  ; Proof General
1142   :load-path "lib/proof-site/generic/")
1143 #+end_src
1144
1145 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1146
1147 #+begin_src emacs-lisp
1148 (eval-when-compile (defvar lean-mode-map))
1149 (use-package lean-mode
1150   :defer 2
1151   :bind (:map lean-mode-map
1152               ("S-SPC" . company-complete))
1153   :config
1154   (require 'lean-input)
1155   (setq default-input-method "Lean"))
1156   #+end_src
1157
1158 ** Haskell
1159
1160 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1161
1162 #+begin_src emacs-lisp
1163 (use-package haskell-mode
1164   :config
1165   (setq haskell-indentation-layout-offset 4
1166         haskell-indentation-left-offset 4
1167         flycheck-checker 'haskell-hlint
1168         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1169 #+end_src
1170
1171 *** [[https://github.com/jyp/dante][dante]]
1172
1173 #+begin_src emacs-lisp
1174 (use-package dante
1175   :after haskell-mode
1176   :commands dante-mode
1177   :hook (haskell-mode . dante-mode))
1178 #+end_src
1179
1180 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1181
1182 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1183 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1184
1185 #+begin_src emacs-lisp
1186 (use-package hlint-refactor
1187   :bind (:map hlint-refactor-mode-map
1188               ("C-c l b" . hlint-refactor-refactor-buffer)
1189               ("C-c l r" . hlint-refactor-refactor-at-point))
1190   :hook (haskell-mode . hlint-refactor-mode))
1191 #+end_src
1192
1193 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1194
1195 #+begin_src emacs-lisp
1196 (use-package flycheck-haskell)
1197 #+end_src
1198
1199 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1200 :PROPERTIES:
1201 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1202 :END:
1203
1204 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1205 instead.
1206
1207 #+begin_src emacs-lisp :tangle no
1208 ;;; hs-lint.el --- minor mode for HLint code checking
1209
1210 ;; Copyright 2009 (C) Alex Ott
1211 ;;
1212 ;; Author: Alex Ott <alexott@gmail.com>
1213 ;; Keywords: haskell, lint, HLint
1214 ;; Requirements:
1215 ;; Status: distributed under terms of GPL2 or above
1216
1217 ;; Typical message from HLint looks like:
1218 ;;
1219 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1220 ;; Found:
1221 ;;   count1 p l = length (filter p l)
1222 ;; Why not:
1223 ;;   count1 p = length . filter p
1224
1225
1226 (require 'compile)
1227
1228 (defgroup hs-lint nil
1229   "Run HLint as inferior of Emacs, parse error messages."
1230   :group 'tools
1231   :group 'haskell)
1232
1233 (defcustom hs-lint-command "hlint"
1234   "The default hs-lint command for \\[hlint]."
1235   :type 'string
1236   :group 'hs-lint)
1237
1238 (defcustom hs-lint-save-files t
1239   "Save modified files when run HLint or no (ask user)"
1240   :type 'boolean
1241   :group 'hs-lint)
1242
1243 (defcustom hs-lint-replace-with-suggestions nil
1244   "Replace user's code with suggested replacements"
1245   :type 'boolean
1246   :group 'hs-lint)
1247
1248 (defcustom hs-lint-replace-without-ask nil
1249   "Replace user's code with suggested replacements automatically"
1250   :type 'boolean
1251   :group 'hs-lint)
1252
1253 (defun hs-lint-process-setup ()
1254   "Setup compilation variables and buffer for `hlint'."
1255   (run-hooks 'hs-lint-setup-hook))
1256
1257 ;; regex for replace suggestions
1258 ;;
1259 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1260 ;; Found:
1261 ;; \s +\(.*\)
1262 ;; Why not:
1263 ;; \s +\(.*\)
1264
1265 (defvar hs-lint-regex
1266   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1267   "Regex for HLint messages")
1268
1269 (defun make-short-string (str maxlen)
1270   (if (< (length str) maxlen)
1271       str
1272     (concat (substring str 0 (- maxlen 3)) "...")))
1273
1274 (defun hs-lint-replace-suggestions ()
1275   "Perform actual replacement of suggestions"
1276   (goto-char (point-min))
1277   (while (re-search-forward hs-lint-regex nil t)
1278     (let* ((fname (match-string 1))
1279           (fline (string-to-number (match-string 2)))
1280           (old-code (match-string 4))
1281           (new-code (match-string 5))
1282           (msg (concat "Replace '" (make-short-string old-code 30)
1283                        "' with '" (make-short-string new-code 30) "'"))
1284           (bline 0)
1285           (eline 0)
1286           (spos 0)
1287           (new-old-code ""))
1288       (save-excursion
1289         (switch-to-buffer (get-file-buffer fname))
1290         (goto-char (point-min))
1291         (forward-line (1- fline))
1292         (beginning-of-line)
1293         (setf bline (point))
1294         (when (or hs-lint-replace-without-ask
1295                   (yes-or-no-p msg))
1296           (end-of-line)
1297           (setf eline (point))
1298           (beginning-of-line)
1299           (setf old-code (regexp-quote old-code))
1300           (while (string-match "\\\\ " old-code spos)
1301             (setf new-old-code (concat new-old-code
1302                                  (substring old-code spos (match-beginning 0))
1303                                  "\\ *"))
1304             (setf spos (match-end 0)))
1305           (setf new-old-code (concat new-old-code (substring old-code spos)))
1306           (remove-text-properties bline eline '(composition nil))
1307           (when (re-search-forward new-old-code eline t)
1308             (replace-match new-code nil t)))))))
1309
1310 (defun hs-lint-finish-hook (buf msg)
1311   "Function, that is executed at the end of HLint execution"
1312   (if hs-lint-replace-with-suggestions
1313       (hs-lint-replace-suggestions)
1314       (next-error 1 t)))
1315
1316 (define-compilation-mode hs-lint-mode "HLint"
1317   "Mode for check Haskell source code."
1318   (set (make-local-variable 'compilation-process-setup-function)
1319        'hs-lint-process-setup)
1320   (set (make-local-variable 'compilation-disable-input) t)
1321   (set (make-local-variable 'compilation-scroll-output) nil)
1322   (set (make-local-variable 'compilation-finish-functions)
1323        (list 'hs-lint-finish-hook))
1324   )
1325
1326 (defun hs-lint ()
1327   "Run HLint for current buffer with haskell source"
1328   (interactive)
1329   (save-some-buffers hs-lint-save-files)
1330   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1331                      'hs-lint-mode))
1332
1333 (provide 'hs-lint)
1334 ;;; hs-lint.el ends here
1335 #+end_src
1336
1337 #+begin_src emacs-lisp :tangle no
1338 (use-package hs-lint
1339   :load-path "lisp/"
1340   :bind (:map haskell-mode-map
1341               ("C-c l l" . hs-lint)))
1342 #+end_src
1343
1344 ** Web dev
1345
1346 *** SGML and HTML
1347
1348 #+begin_src emacs-lisp
1349 (use-package sgml-mode
1350   :config
1351   (setq sgml-basic-offset 2))
1352 #+end_src
1353
1354 *** CSS and SCSS
1355
1356 #+begin_src emacs-lisp
1357 (use-package css-mode
1358   :config
1359   (setq css-indent-offset 2))
1360 #+end_src
1361
1362 *** Web mode
1363
1364 #+begin_src emacs-lisp
1365 (use-package web-mode
1366   :mode "\\.html\\'"
1367   :config
1368   (setq-every! 2
1369     web-mode-code-indent-offset
1370     web-mode-css-indent-offset
1371     web-mode-markup-indent-offset))
1372 #+end_src
1373
1374 *** Emmet mode
1375
1376 #+begin_src emacs-lisp
1377 (use-package emmet-mode
1378   :bind* (("C-)" . emmet-next-edit-point)
1379           ("C-(" . emmet-prev-edit-point))
1380   :config
1381   (unbind-key "C-j" emmet-mode-keymap)
1382   (setq emmet-move-cursor-between-quotes t)
1383   :hook (web-mode css-mode html-mode sgml-mode))
1384 #+end_src
1385
1386 ** Nix
1387
1388 #+begin_src emacs-lisp
1389 (use-package nix-mode
1390   :mode "\\.nix\\'")
1391 #+end_src
1392
1393 ** Java
1394
1395 *** meghanada
1396
1397 #+begin_src emacs-lisp :tangle yes
1398 (use-package meghanada
1399   :bind
1400   (:map meghanada-mode-map
1401         (("C-M-o" . meghanada-optimize-import)
1402          ("C-M-t" . meghanada-import-all)))
1403   :hook (java-mode . meghanada-mode))
1404 #+end_src
1405
1406 *** lsp-java
1407
1408 #+begin_src emacs-lisp :tangle no
1409 (use-package treemacs)
1410
1411 (use-package yasnippet
1412   :config
1413   ;; (yas-global-mode)
1414   )
1415
1416 (use-package lsp-mode
1417   :init (setq lsp-eldoc-render-all nil
1418               lsp-highlight-symbol-at-point nil)
1419   )
1420
1421 (use-package hydra)
1422
1423 (use-package company-lsp
1424   :after  company
1425   :config
1426   (setq company-lsp-cache-candidates t
1427         company-lsp-async t))
1428
1429 (use-package lsp-ui
1430   :config
1431   (setq lsp-ui-sideline-update-mode 'point))
1432
1433 (use-package lsp-java
1434   :config
1435   (add-hook 'java-mode-hook
1436             (lambda ()
1437               (setq-local company-backends (list 'company-lsp))))
1438
1439   (add-hook 'java-mode-hook 'lsp-java-enable)
1440   (add-hook 'java-mode-hook 'flycheck-mode)
1441   (add-hook 'java-mode-hook 'company-mode)
1442   (add-hook 'java-mode-hook 'lsp-ui-mode))
1443
1444 (use-package dap-mode
1445   :after lsp-mode
1446   :config
1447   (dap-mode t)
1448   (dap-ui-mode t))
1449
1450 (use-package dap-java
1451   :after (lsp-java))
1452
1453 (use-package lsp-java-treemacs
1454   :after (treemacs))
1455 #+end_src
1456
1457 * Emacs Enhancements
1458
1459 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1460
1461 #+begin_quote
1462 Emacs package that displays available keybindings in popup
1463 #+end_quote
1464
1465 #+begin_src emacs-lisp
1466 (use-package which-key
1467   :defer 1
1468   :config (which-key-mode))
1469 #+end_src
1470
1471 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1472
1473 #+begin_src emacs-lisp
1474 (use-package doom-modeline
1475   :demand t
1476   :config (setq doom-modeline-height 32)
1477   :hook (after-init . doom-modeline-init))
1478 #+end_src
1479
1480 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1481
1482 #+begin_src emacs-lisp
1483 (setq doom-modeline-bar-width 5)
1484 (load-theme 'eink t)
1485 #+end_src
1486
1487 ** [[https://github.com/bbatsov/crux][crux]]
1488
1489 #+begin_src emacs-lisp
1490 (use-package crux
1491   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1492          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1493          ("C-c b K" . crux-kill-other-buffers)
1494          ("C-c f c" . crux-copy-file-preserve-attributes)
1495          ("C-c f D" . crux-delete-file-and-buffer)
1496          ("C-c f R" . crux-rename-file-and-buffer)
1497          ("C-S-j"   . crux-top-join-line)
1498          ("C-c j"   . crux-top-join-line)))
1499 #+end_src
1500
1501 ** [[https://github.com/alezost/mwim.el][mwim]]
1502
1503 #+begin_src emacs-lisp
1504 (use-package mwim
1505   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1506          ("C-e"    . mwim-end-of-code-or-line)
1507          ("<home>" . mwim-beginning-of-line-or-code)
1508          ("<end>"  . mwim-end-of-line-or-code)))
1509 #+end_src
1510
1511 ** projectile
1512
1513 #+begin_src emacs-lisp
1514 (use-package projectile
1515   :defer 5
1516   :bind-keymap ("C-c p" . projectile-command-map)
1517   :config
1518   (projectile-mode)
1519
1520   (defun my-projectile-invalidate-cache (&rest _args)
1521     ;; ignore the args to `magit-checkout'
1522     (projectile-invalidate-cache nil))
1523
1524   (eval-after-load 'magit-branch
1525     '(progn
1526        (advice-add 'magit-checkout
1527                    :after #'my-projectile-invalidate-cache)
1528        (advice-add 'magit-branch-and-checkout
1529                    :after #'my-projectile-invalidate-cache))))
1530 #+end_src
1531
1532 ** [[https://github.com/Wilfred/helpful][helpful]]
1533
1534 #+begin_src emacs-lisp
1535 (use-package helpful
1536   :bind
1537   (("C-h f"   . helpful-callable)
1538    ("C-h v"   . helpful-variable)
1539    ("C-h k"   . helpful-key)
1540    ("C-c C-d" . helpful-at-point)
1541    ("C-h F"   . helpful-function)
1542    ("C-h C"   . helpful-command)))
1543 #+end_src
1544
1545 ** [[https://github.com/kyagi/shell-pop-el][shell-pop]]
1546
1547 #+begin_src emacs-lisp
1548 (use-package shell-pop
1549   :custom
1550   (shell-pop-universal-key "C-c e")
1551   (shell-pop-shell-type '("eshell" "*eshell*" (lambda nil (eshell)))))
1552 #+end_src
1553
1554 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1555
1556 Make =*scratch*= and =*Messages*= unkillable.
1557
1558 #+begin_src emacs-lisp
1559 (use-package unkillable-scratch
1560   :config
1561   (unkillable-scratch 1)
1562   :custom
1563   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1564 #+end_src
1565
1566 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1567
1568 #+begin_example
1569 ,----
1570 | make pretty boxed quotes like this
1571 `----
1572 #+end_example
1573
1574 #+begin_src emacs-lisp
1575 (use-package boxquote
1576   :bind
1577   (:prefix-map amin--boxquote-prefix-map
1578    :prefix "C-c q"
1579    ("b"   . boxquote-buffer)
1580    ("B"   . boxquote-insert-buffer)
1581    ("d"   . boxquote-defun)
1582    ("F"   . boxquote-insert-file)
1583    ("hf"  . boxquote-describe-function)
1584    ("hk"  . boxquote-describe-key)
1585    ("hv"  . boxquote-describe-variable)
1586    ("hw"  . boxquote-where-is)
1587    ("k"   . boxquote-kill)
1588    ("p"   . boxquote-paragraph)
1589    ("q"   . boxquote-boxquote)
1590    ("r"   . boxquote-region)
1591    ("s"   . boxquote-shell-command)
1592    ("t"   . boxquote-text)
1593    ("T"   . boxquote-title)
1594    ("u"   . boxquote-unbox)
1595    ("U"   . boxquote-unbox-region)
1596    ("y"   . boxquote-yank)
1597    ("M-q" . boxquote-fill-paragraph)
1598    ("M-w" . boxquote-kill-ring-save)))
1599 #+end_src
1600
1601 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1602
1603 ** [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]
1604
1605 #+begin_src emacs-lisp
1606 (use-package highlight-indent-guides
1607   :demand t
1608   :hook ((prog-mode . highlight-indent-guides-mode)
1609          ;; (org-mode  . highlight-indent-guides-mode)
1610          )
1611   :config
1612   (setq highlight-indent-guides-character ?\|)
1613   (setq highlight-indent-guides-auto-enabled nil)
1614   (setq highlight-indent-guides-method 'character)
1615   (setq highlight-indent-guides-responsive 'top)
1616   (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
1617   (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
1618 #+end_src
1619
1620 ** pdf-tools
1621
1622 #+begin_src emacs-lisp
1623 (use-package pdf-tools
1624   :magic ("%PDF" . pdf-view-mode)
1625   :config
1626   (setq pdf-view-resize-factor 1.05)
1627   (pdf-tools-install)
1628   :bind
1629   (:map pdf-view-mode-map
1630         ("C-s" . isearch-forward)
1631         ("C-r" . isearch-backward)
1632         ("j"   . pdf-view-next-line-or-next-page)
1633         ("k"   . pdf-view-previous-line-or-previous-page)
1634         ("h"   . image-backward-hscroll)
1635         ("l"   . image-forward-hscroll)))
1636 #+end_src
1637
1638 ** anzu
1639
1640 #+begin_src emacs-lisp
1641 (use-package anzu)
1642 #+end_src
1643
1644 ** typo.el
1645
1646 #+begin_src emacs-lisp
1647 (use-package typo
1648   :config
1649   (typo-global-mode 1)
1650   :hook (text-mode . typo-mode))
1651 #+end_src
1652
1653 ** slack
1654
1655 Hopefully temporary.
1656
1657 #+begin_src emacs-lisp
1658 (use-package slack
1659   :commands (slack-start)
1660   :init
1661   (eval-when-compile                    ; silence the byte-compiler
1662     (defvar url-http-data nil)
1663     (defvar url-http-extra-headers nil)
1664     (defvar url-http-method nil)
1665     (defvar url-callback-function nil)
1666     (defvar url-callback-arguments nil)
1667     (defvar oauth--token-data nil))
1668   (setq slack-buffer-emojify t
1669         slack-prefer-current-team t)
1670   :config
1671   (slack-register-team
1672    :name "uw-apv"
1673    :default t
1674    :client-id uw-apv-client-id
1675    :client-secret uw-apv-client-secret
1676    :token uw-apv-token
1677    :subscribed-channels '(general)
1678    :full-and-display-names t)
1679   (slack-register-team
1680    :name "watform"
1681    :default nil
1682    :client-id watform-client-id
1683    :client-secret watform-client-secret
1684    :token watform-token
1685    :subscribed-channels '(general)
1686    :full-and-display-names t);
1687   :bind
1688   (("C-c s s" . slack-start)
1689    ("C-c s u" . slack-select-unread-rooms)
1690    ("C-c s b" . slack-select-rooms)
1691    ("C-c s t" . slack-change-current-team)
1692    ("C-c s c" . slack-ws-close)
1693    :map slack-mode-map
1694    ("M-p"     . slack-buffer-goto-prev-message)
1695    ("M-n"     . slack-buffer-goto-next-message)
1696    ("C-c e"   . slack-message-edit)
1697    ("C-c k"   . slack-message-delete)
1698    ("C-c C-k" . slack-channel-leave)
1699    ("C-c r a" . slack-message-add-reaction)
1700    ("C-c r r" . slack-message-remove-reaction)
1701    ("C-c r s" . slack-message-show-reaction-users)
1702    ("C-c p l" . slack-room-pins-list)
1703    ("C-c p a" . slack-message-pins-add)
1704    ("C-c p r" . slack-message-pins-remove)
1705    ("@"       . slack-message-embed-mention)
1706    ("#"       . slack-message-embed-channel)));
1707
1708 (use-package alert
1709   :commands (alert)
1710   :init
1711   (setq alert-default-style 'notifier))
1712 #+end_src
1713
1714 * Email
1715
1716 #+begin_src emacs-lisp
1717 (defvar amin-maildir (expand-file-name "~/mail/"))
1718 (after! recentf
1719   (add-to-list 'recentf-exclude amin-maildir))
1720 #+end_src
1721
1722 ** sendmail
1723
1724 #+begin_src emacs-lisp
1725 (use-package sendmail
1726   :config
1727   (setq sendmail-program "/usr/bin/msmtp"
1728         ;; message-sendmail-extra-arguments '("-v" "-d")
1729         mail-specify-envelope-from t
1730         mail-envelope-from 'header))
1731 #+end_src
1732
1733 ** message
1734
1735 #+begin_src emacs-lisp
1736 (use-package message
1737   :config
1738   (setq message-kill-buffer-on-exit t
1739         message-send-mail-function 'message-send-mail-with-sendmail
1740         message-sendmail-envelope-from 'header
1741         ;; message-directory "drafts"
1742         message-user-fqdn "aminb.org")
1743   ;; (add-hook 'message-mode-hook 'electric-quote-local-mode)
1744   (add-hook 'message-mode-hook
1745             (lambda () (setq fill-column 65
1746                         message-fill-column 65)))
1747   (add-hook 'message-mode-hook
1748             #'flyspell-mode)
1749   ;; (add-hook 'message-setup-hook
1750   ;;           #'mml-secure-message-sign-pgpmime)
1751   :custom-face
1752   (message-header-subject ((t (:foreground "navy blue" :weight semi-bold))))
1753   (message-header-to ((t (:foreground "MidnightBlue" :weight semi-bold)))))
1754
1755 (after! mml-sec
1756   (setq mml-secure-openpgp-encrypt-to-self t
1757         mml-secure-openpgp-sign-with-sender t))
1758 #+end_src
1759
1760 ** [[https://notmuchmail.org][notmuch]]
1761
1762 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1763
1764 #+begin_src emacs-lisp
1765 (defun amin/notmuch ()
1766   "Delete other windows, then launch `notmuch'."
1767   (interactive
1768    (when (equal current-prefix-arg nil)
1769      (delete-other-windows)))
1770   (notmuch))
1771
1772 (use-package notmuch
1773   :commands notmuch
1774   :bind ("C-c n" . amin/notmuch)
1775   :custom (notmuch-always-prompt-for-sender t)
1776   :config
1777   (setq notmuch-hello-sections
1778         '(notmuch-hello-insert-header
1779           notmuch-hello-insert-saved-searches
1780           ;; notmuch-hello-insert-search
1781           notmuch-hello-insert-alltags)
1782         notmuch-search-oldest-first nil
1783         notmuch-show-all-tags-list t
1784         notmuch-message-headers  ; see bug follow-up above
1785         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1786         notmuch-hello-thousands-separator ","
1787         notmuch-fcc-dirs
1788         '(("amin@aminb.org"        . "amin/Sent")
1789           ("bandali@gnu.org"       . "gnu/Sent")
1790           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1791           ("mab@gnu.org"           . "gnu/Sent")
1792           ("amin@gnu.org"          . "gnu/Sent")
1793           ("aminb@gnu.org"         . "gnu/Sent")
1794           (".*"                    . "sent"))
1795         notmuch-search-result-format
1796         '(("date"    . "%12s ")
1797           ("count"   . "%-7s ")
1798           ("authors" . "%-40s ")
1799           ("subject" . "%s ")
1800           ("tags"    . "(%s)"))
1801         notmuch-saved-searches
1802         '((:name "inbox"     :query "tag:inbox"     :key "i")
1803           (:name "unread"    :query "tag:unread"    :key "u")
1804           (:name "latest"    :query "tag:latest"    :key "l")
1805           (:name "encrypted" :query "tag:encrypted" :key "e")
1806           (:name "flagged"   :query "tag:flagged"   :key "f")
1807           (:name "sent"      :query "tag:sent"      :key "s")
1808           (:name "drafts"    :query "tag:draft"     :key "d")
1809           (:name "all mail"  :query "*"             :key "a")))
1810   ;; (add-hook 'visual-fill-column-mode-hook
1811   ;;           (lambda ()
1812   ;;             (when (string= major-mode 'notmuch-message-mode)
1813   ;;               (setq visual-fill-column-width 70))))
1814   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1815   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1816   ;;             :override #'kill-this-buffer)
1817   :hook (notmuch-message-mode . doom-modeline-set-special-modeline)
1818   :bind
1819   (:map notmuch-hello-mode-map
1820         ("u" . (lambda ()
1821                  "Search for `unread'-tagged messages"
1822                  (interactive)
1823                  (notmuch-hello-search "tag:unread")))
1824         ("i" . (lambda ()
1825                  "Search for `inbox'-tagged messages"
1826                  (interactive)
1827                  (notmuch-hello-search "tag:inbox")))
1828         ("l" . (lambda ()
1829                  "Search for `latest'-tagged messages"
1830                  (interactive)
1831                  (notmuch-hello-search "tag:latest")))
1832         ("e" . (lambda ()
1833                  "Search for `encrypted'-tagged messages"
1834                  (interactive)
1835                  (notmuch-hello-search "tag:encrypted"))))
1836   (:map notmuch-search-mode-map
1837         ("k" . (lambda ()
1838                  "Mark message read"
1839                  (interactive)
1840                  (notmuch-search-tag '("-unread"))
1841                  ;; (notmuch-search-archive-thread)
1842                  (notmuch-search-next-thread)))
1843         ("u" . (lambda ()
1844                  "Mark message unread"
1845                  (interactive)
1846                  (notmuch-search-tag '("+unread"))
1847                  (notmuch-search-next-thread)))
1848         ("K" . (lambda ()
1849                  "Mark message deleted"
1850                  (interactive)
1851                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1852                  (notmuch-search-next-thread)))
1853         ("S" . (lambda ()
1854                  "Mark message as spam"
1855                  (interactive)
1856                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1857                  (notmuch-search-next-thread))))
1858   (:map notmuch-tree-mode-map
1859         ("k" . (lambda ()
1860                  "Mark message read"
1861                  (interactive)
1862                  (notmuch-tree-tag '("-unread"))
1863                  ;; (notmuch-tree-archive-thread)
1864                  (notmuch-tree-next-message)))
1865         ("u" . (lambda ()
1866                  "Mark message unread"
1867                  (interactive)
1868                  (notmuch-tree-tag '("+unread"))
1869                  (notmuch-tree-next-message)))
1870         ("K" . (lambda ()
1871                  "Mark message deleted"
1872                  (interactive)
1873                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
1874                  (notmuch-tree-next-message)))
1875         ("S" . (lambda ()
1876                  "Mark message as spam"
1877                  (interactive)
1878                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1879                  (notmuch-tree-next-message))))
1880   :custom-face
1881   (notmuch-search-unread-face ((t (:weight semi-bold))))
1882   (notmuch-tag-face ((t (:foreground "navy blue" :weight semi-bold)))))
1883
1884 (use-package counsel-notmuch
1885   :bind ("C-c s m" . counsel-notmuch))
1886
1887 (after! notmuch-crypto
1888   (setq notmuch-crypto-process-mime t))
1889 #+end_src
1890
1891 ** supercite
1892
1893 #+begin_src emacs-lisp :tangle no
1894 (use-package supercite
1895   :commands sc-cite-original
1896   :init
1897   (add-hook 'mail-citation-hook 'sc-cite-original)
1898
1899   (defun sc-remove-existing-signature ()
1900     (save-excursion
1901       (goto-char (region-beginning))
1902       (when (re-search-forward message-signature-separator (region-end) t)
1903         (delete-region (match-beginning 0) (region-end)))))
1904
1905   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1906
1907   (defun sc-remove-if-not-mailing-list ()
1908     (unless (assoc "list-id" sc-mail-info)
1909       (setq attribution sc-default-attribution
1910             citation (concat sc-citation-delimiter
1911                              sc-citation-separator))))
1912
1913   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1914
1915   :config
1916   (defun sc-fill-if-different (&optional prefix)
1917     "Fill the region bounded by `sc-fill-begin' and point.
1918 Only fill if optional PREFIX is different than
1919 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1920 fill region.  If PREFIX is not supplied, initialize fill
1921 variables.  This is useful for a regi `begin' frame-entry."
1922     (if (not prefix)
1923         (setq sc-fill-line-prefix ""
1924               sc-fill-begin (line-beginning-position))
1925       (if (and sc-auto-fill-region-p
1926                (not (string= prefix sc-fill-line-prefix)))
1927           (let ((fill-prefix sc-fill-line-prefix))
1928             (unless (or (string= fill-prefix "")
1929                         (save-excursion
1930                           (goto-char sc-fill-begin)
1931                           (or (looking-at ">+  +")
1932                               (< (length
1933                                   (buffer-substring (point)
1934                                                     (line-end-position)))
1935                                  65))))
1936               (fill-region sc-fill-begin (line-beginning-position)))
1937             (setq sc-fill-line-prefix prefix
1938                   sc-fill-begin (line-beginning-position)))))
1939 nil))
1940 #+end_src
1941
1942 * Blogging
1943 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1944
1945 #+begin_src emacs-lisp
1946 (use-package ox-hugo
1947   :after ox)
1948
1949 (use-package ox-hugo-auto-export
1950   :load-path "lib/ox-hugo")
1951 #+end_src
1952
1953 * Post initialization
1954 :PROPERTIES:
1955 :CUSTOM_ID: post-initialization
1956 :END:
1957
1958 Display how long it took to load the init file.
1959
1960 #+begin_src emacs-lisp
1961 (message "Loading %s...done (%.3fs)" user-init-file
1962          (float-time (time-subtract (current-time)
1963                                     amin--before-user-init-time)))
1964 #+end_src
1965
1966 * Footer
1967 :PROPERTIES:
1968 :CUSTOM_ID: footer
1969 :END:
1970
1971 #+begin_src emacs-lisp :comments none
1972 ;;; init.el ends here
1973 #+end_src
1974
1975 * COMMENT Local Variables                                           :ARCHIVE:
1976 # Local Variables:
1977 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
1978 # End: