git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#borg-essentials][Borg's =layer/essentials=]]
  58 - [[#editing][Editing]]
  59 - [[#syntax-spell-checking][Syntax and spell checking]]
  60 - [[#programming-modes][Programming modes]]
  61 - [[#emacs-enhancements][Emacs enhancements]]
  62 - [[#email][Email]]
  63 - [[#blogging][Blogging]]
  64 - [[#post-initialization][Post initialization]]
  65 - [[#footer][Footer]]
  66
  67 * Header
  68 :PROPERTIES:
  69 :CUSTOM_ID: header
  70 :END:
  71
  72 ** First line
  73
  74 #+begin_src emacs-lisp :comments none
  75 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t; eval: (view-mode 1) -*-
  76 #+end_src
  77
  78 Enable =view-mode=, which both makes the file read-only (as a reminder
  79 that =init.el= is an auto-generated file, not supposed to be edited),
  80 and provides some convenient key bindings for browsing through the
  81 file.
  82
  83 ** License
  84
  85 #+begin_src emacs-lisp :comments none
  86 ;; Copyright (C) 2018  Amin Bandali <bandali@gnu.org>
  87
  88 ;; This program is free software: you can redistribute it and/or modify
  89 ;; it under the terms of the GNU General Public License as published by
  90 ;; the Free Software Foundation, either version 3 of the License, or
  91 ;; (at your option) any later version.
  92
  93 ;; This program is distributed in the hope that it will be useful,
  94 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  95 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  96 ;; GNU General Public License for more details.
  97
  98 ;; You should have received a copy of the GNU General Public License
  99 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
 100 #+end_src
 101
 102 ** Commentary
 103
 104 #+begin_src emacs-lisp :comments none
 105 ;;; Commentary:
 106
 107 ;; Emacs configuration of Amin Bandali, computer scientist, functional
 108 ;; programmer, and free software advocate.
 109
 110 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 111 #+end_src
 112
 113 * Initial setup
 114 :PROPERTIES:
 115 :CUSTOM_ID: initial-setup
 116 :END:
 117
 118 ** Emacs initialization
 119
 120 I'd like to do a couple of measurements of Emacs' startup time. First,
 121 let's see how long Emacs takes to start up, before even loading
 122 =init.el=, i.e. =user-init-file=:
 123
 124 #+begin_src emacs-lisp
 125 (defvar a/before-user-init-time (current-time)
 126   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 127 (message "Loading Emacs...done (%.3fs)"
 128          (float-time (time-subtract a/before-user-init-time
 129                                     before-init-time)))
 130 #+end_src
 131
 132 Also, temporarily increase ~gc-cons-threshhold~ and
 133 ~gc-cons-percentage~ during startup to reduce garbage collection
 134 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 135 startup time as well.
 136
 137 #+begin_src emacs-lisp
 138 (defvar a/gc-cons-threshold gc-cons-threshold)
 139 (defvar a/gc-cons-percentage gc-cons-percentage)
 140 (defvar a/file-name-handler-alist file-name-handler-alist)
 141 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 142       gc-cons-percentage 0.6
 143       file-name-handler-alist nil
 144       ;; sidesteps a bug when profiling with esup
 145       esup-child-profile-require-level 0)
 146 #+end_src
 147
 148 Of course, we'd like to set them back to their defaults once we're
 149 done initializing.
 150
 151 #+begin_src emacs-lisp
 152 (add-hook
 153  'after-init-hook
 154  (lambda ()
 155    (setq gc-cons-threshold a/gc-cons-threshold
 156          gc-cons-percentage a/gc-cons-percentage
 157          file-name-handler-alist a/file-name-handler-alist)))
 158 #+end_src
 159
 160 Increase the number of lines kept in message logs (the =*Messages*=
 161 buffer).
 162
 163 #+begin_src emacs-lisp
 164 (setq message-log-max 20000)
 165 #+end_src
 166
 167 Optionally, we could suppress some byte compiler warnings like below,
 168 but for now I've decided to keep them enabled. See documentation for
 169 ~byte-compile-warnings~ for more details.
 170
 171 #+begin_src emacs-lisp
 172 ;; (setq byte-compile-warnings
 173 ;;       '(not free-vars unresolved noruntime lexical make-local))
 174 #+end_src
 175
 176 ** whoami
 177
 178 #+begin_src emacs-lisp
 179 (setq user-full-name "Amin Bandali"
 180       user-mail-address "amin@aminb.org")
 181 #+end_src
 182
 183 ** Package management
 184
 185 *** No =package.el=
 186
 187 I can do all my package management things with Borg, and don't need
 188 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 189 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 190
 191 #+begin_src emacs-lisp :tangle early-init.el
 192 (setq package-enable-at-startup nil)
 193 #+end_src
 194
 195 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 196 right now), and even when released it'll be long before most distros
 197 ship in their repos, I'll still put the old workaround with the
 198 commented call to ~package-initialize~ here anyway.
 199
 200 #+begin_src emacs-lisp
 201 (setq package-enable-at-startup nil)
 202 ;; (package-initialize)
 203 #+end_src
 204
 205 *** Borg
 206
 207 #+begin_quote
 208 Assimilate Emacs packages as Git submodules
 209 #+end_quote
 210
 211 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 212 short, it creates a git submodule in =lib/= for each package, which
 213 can then be managed with the help of Magit or other tools.
 214
 215 #+begin_src emacs-lisp
 216 (setq user-init-file (or load-file-name buffer-file-name)
 217       user-emacs-directory (file-name-directory user-init-file))
 218 (add-to-list 'load-path
 219              (expand-file-name "lib/borg" user-emacs-directory))
 220 (require 'borg)
 221 (borg-initialize)
 222
 223 ;; (require 'borg-nix-shell)
 224 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 225
 226 (with-eval-after-load 'bind-key
 227   (bind-keys
 228    :package borg
 229    ("C-c b A" . borg-activate)
 230    ("C-c b a" . borg-assimilate)
 231    ("C-c b b" . borg-build)
 232    ("C-c b c" . borg-clone)
 233    ("C-c b r" . borg-remove)))
 234 #+end_src
 235
 236 *** =use-package=
 237
 238 #+begin_quote
 239 A use-package declaration for simplifying your .emacs
 240 #+end_quote
 241
 242 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 243 packages (in our case especially the latter) in a neatly organized way
 244 and without compromising on performance.
 245
 246 #+begin_src emacs-lisp
 247 (require 'use-package)
 248 (if nil  ; set to t when need to debug init
 249     (setq use-package-verbose t
 250           use-package-expand-minimally nil
 251           use-package-compute-statistics t
 252           debug-on-error t)
 253   (setq use-package-verbose nil
 254         use-package-expand-minimally t))
 255 #+end_src
 256
 257 *** Epkg
 258
 259 #+begin_quote
 260 Browse the Emacsmirror package database
 261 #+end_quote
 262
 263 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 264 database, low-level functions for querying the database, and a
 265 =package.el=-like user interface for browsing the available packages.
 266
 267 #+begin_src emacs-lisp
 268 (use-package epkg
 269   :defer t
 270   :bind
 271   (("C-c b d" . epkg-describe-package)
 272    ("C-c b p" . epkg-list-packages)
 273    ("C-c b u" . epkg-update))
 274   :config
 275   (eval-when-compile (defvar ivy-initial-inputs-alist))
 276   (with-eval-after-load 'ivy
 277     (add-to-list
 278      'ivy-initial-inputs-alist '(epkg-describe-package . "^") t)))
 279 #+end_src
 280
 281 ** No littering in =~/.emacs.d=
 282
 283 #+begin_quote
 284 Help keeping ~/.emacs.d clean
 285 #+end_quote
 286
 287 By default, even for Emacs' built-in packages, the configuration files
 288 and persistent data are all over the place. Use =no-littering= to help
 289 contain the mess.
 290
 291 #+begin_src emacs-lisp
 292 (use-package no-littering
 293   :demand t
 294   :config
 295   (savehist-mode 1)
 296   (add-to-list 'savehist-additional-variables 'kill-ring)
 297   (save-place-mode 1)
 298   (setq auto-save-file-name-transforms
 299         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 300 #+end_src
 301
 302 ** Custom file (=custom.el=)
 303
 304 I'm not planning on using the custom file much, but even so, I
 305 definitely don't want it mixing with =init.el=. So, here; let's give
 306 it it's own file. While at it, treat themes as safe.
 307
 308 #+begin_src emacs-lisp
 309 (use-package custom
 310   :no-require t
 311   :config
 312   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 313   (when (file-exists-p custom-file)
 314     (load custom-file))
 315   (setf custom-safe-themes t))
 316 #+end_src
 317
 318 ** Secrets file
 319
 320 Load the secrets file if it exists, otherwise show a warning.
 321
 322 #+begin_src emacs-lisp
 323 (with-demoted-errors
 324     (load (no-littering-expand-etc-file-name "secrets")))
 325 #+end_src
 326
 327 ** Better =$PATH= handling
 328
 329 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 330 in my shell.
 331
 332 #+begin_src emacs-lisp
 333 (use-package exec-path-from-shell
 334   :defer 1
 335   :init
 336   (setq exec-path-from-shell-check-startup-files nil)
 337   :config
 338   (exec-path-from-shell-initialize)
 339   ;; while we're at it, let's fix access to our running ssh-agent
 340   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 341   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 342 #+end_src
 343
 344 ** COMMENT Only one custom theme at a time
 345
 346 #+begin_src emacs-lisp
 347 (defadvice load-theme (before clear-previous-themes activate)
 348   "Clear existing theme settings instead of layering them"
 349   (mapc #'disable-theme custom-enabled-themes))
 350 #+end_src
 351
 352 ** Server
 353
 354 Start server if not already running. Alternatively, can be done by
 355 issuing =emacs --daemon= in the terminal, which can be automated with
 356 a systemd service or using =brew services start emacs= on macOS. I use
 357 Emacs as my window manager (via EXWM), so I always start Emacs on
 358 login; so starting the server from inside Emacs is good enough for me.
 359
 360 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 361
 362 #+begin_src emacs-lisp
 363 (use-package server
 364   :defer 1
 365   :config (or (server-running-p) (server-mode)))
 366 #+end_src
 367
 368 ** COMMENT Unicode support
 369
 370 Font stack with better unicode support, around =Ubuntu Mono= and
 371 =Hack=.
 372
 373 #+begin_src emacs-lisp
 374 (dolist (ft (fontset-list))
 375   (set-fontset-font
 376    ft
 377    'unicode
 378    (font-spec :name "Source Code Pro" :size 14))
 379   (set-fontset-font
 380    ft
 381    'unicode
 382    (font-spec :name "DejaVu Sans Mono")
 383    nil
 384    'append)
 385   ;; (set-fontset-font
 386   ;;  ft
 387   ;;  'unicode
 388   ;;  (font-spec
 389   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 390   ;;  nil
 391   ;;  'append)
 392   ;; (set-fontset-font
 393   ;;  ft
 394   ;;  #x2115  ; ℕ
 395   ;;  (font-spec :name "DejaVu Sans Mono")
 396   ;;  nil
 397   ;;  'append)
 398   (set-fontset-font
 399    ft
 400    (cons ?Α ?ω)
 401    (font-spec :name "DejaVu Sans Mono" :size 14)
 402    nil
 403    'prepend))
 404 #+end_src
 405
 406 ** Gentler font resizing
 407
 408 #+begin_src emacs-lisp
 409 (setq text-scale-mode-step 1.05)
 410 #+end_src
 411
 412 ** Focus follows mouse
 413
 414 I’d like focus to follow the mouse when I move the cursor from one
 415 window to the next.
 416
 417 #+begin_src emacs-lisp
 418 (setq mouse-autoselect-window t)
 419 #+end_src
 420
 421 Let’s define a function to conveniently disable this for certain
 422 buffers and/or modes.
 423
 424 #+begin_src emacs-lisp
 425 (defun a/no-mouse-autoselect-window ()
 426   (make-local-variable 'mouse-autoselect-window)
 427   (setq mouse-autoselect-window nil))
 428 #+end_src
 429
 430 ** Libraries
 431
 432 #+begin_src emacs-lisp
 433 (require 'cl-lib)
 434 (require 'subr-x)
 435 #+end_src
 436
 437 ** Useful utilities
 438
 439 Convenience macro for =setq='ing multiple variables to the same value:
 440
 441 #+begin_src emacs-lisp
 442 (defmacro a/setq-every (value &rest vars)
 443   "Set all the variables from VARS to value VALUE."
 444   (declare (indent defun) (debug t))
 445   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 446 #+end_src
 447
 448 The following process-related stuff from [[https://github.com/alezost/emacs-config][alezost's emacs-config]].
 449
 450 #+begin_src emacs-lisp
 451 (defun a/start-process (program &rest args)
 452   "Same as `start-process', but doesn't bother about name and buffer."
 453   (let ((process-name (concat program "_process"))
 454         (buffer-name  (generate-new-buffer-name
 455                        (concat program "_output"))))
 456     (apply #'start-process
 457            process-name buffer-name program args)))
 458
 459 (defun a/dired-start-process (program &optional args)
 460   "Open current file with a PROGRAM."
 461   ;; Shell command looks like this: "program [ARGS]... FILE" (ARGS can
 462   ;; be nil, so remove it).
 463   (apply #'a/start-process
 464          program
 465          (remove nil (list args (dired-get-file-for-visit)))))
 466 #+end_src
 467
 468 * Core
 469 :PROPERTIES:
 470 :CUSTOM_ID: core
 471 :END:
 472
 473 ** Defaults
 474
 475 *** Time and battery in mode-line
 476
 477 Enable displaying time and battery in the mode-line, since I'm not
 478 using the Xfce panel anymore. Also, I don't need to see the load
 479 average on a regular basis, so disable that.
 480
 481 Note: using =i3status= on sway at the moment, so disabling this.
 482
 483 #+begin_src emacs-lisp :tangle no
 484 (use-package time
 485   :init
 486   (setq display-time-default-load-average nil)
 487   :config
 488   (display-time-mode))
 489
 490 (use-package battery
 491   :config
 492   (display-battery-mode))
 493 #+end_src
 494
 495 *** Smaller fringe
 496
 497 Might want to set the fringe to a smaller value, especially if using
 498 EXWM. I'm fine with the default for now.
 499
 500 #+begin_src emacs-lisp
 501 ;; (fringe-mode '(3 . 1))
 502 (fringe-mode nil)
 503 #+end_src
 504
 505 *** Disable disabled commands
 506
 507 Emacs disables some commands by default that could persumably be
 508 confusing for novice users. Let's disable that.
 509
 510 #+begin_src emacs-lisp
 511 (setq disabled-command-function nil)
 512 #+end_src
 513
 514 *** Kill-ring
 515
 516 Save what I copy into clipboard from other applications into Emacs'
 517 kill-ring, which would allow me to still be able to easily access it
 518 in case I kill (cut or copy) something else inside Emacs before
 519 yanking (pasting) what I'd originally intended to.
 520
 521 #+begin_src emacs-lisp
 522 (setq save-interprogram-paste-before-kill t)
 523 #+end_src
 524
 525 *** Minibuffer
 526
 527 #+begin_src emacs-lisp
 528 (setq enable-recursive-minibuffers t
 529       resize-mini-windows t)
 530 #+end_src
 531
 532 *** Lazy-person-friendly yes/no prompts
 533
 534 Lazy people would prefer to type fewer keystrokes, especially for yes
 535 or no questions. I'm lazy.
 536
 537 #+begin_src emacs-lisp
 538 (defalias 'yes-or-no-p #'y-or-n-p)
 539 #+end_src
 540
 541 *** Startup screen and =*scratch*=
 542
 543 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 544 startup buffer.
 545
 546 #+begin_src emacs-lisp
 547 (setq initial-buffer-choice t)
 548 #+end_src
 549
 550 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 551 need the default hint.
 552
 553 #+begin_src emacs-lisp
 554 (setq initial-scratch-message nil)
 555 #+end_src
 556
 557 Also, let's use Text mode as the major mode, in case I want to
 558 customize it (=*scratch*='s default major mode, Fundamental mode,
 559 can't really be customized).
 560
 561 #+begin_src emacs-lisp
 562 (setq initial-major-mode 'text-mode)
 563 #+end_src
 564
 565 Inhibit the buffer list when more than 2 files are loaded.
 566
 567 #+begin_src emacs-lisp
 568 (setq inhibit-startup-buffer-menu t)
 569 #+end_src
 570
 571 I don't really need to see the startup screen or echo area message
 572 either.
 573
 574 #+begin_src emacs-lisp
 575 (advice-add #'display-startup-echo-area-message :override #'ignore)
 576 (setq inhibit-startup-screen t
 577       inhibit-startup-echo-area-message user-login-name)
 578 #+end_src
 579
 580 *** More useful frame titles
 581
 582 Show either the file name or the buffer name (in case the buffer isn't
 583 visiting a file). Borrowed from Emacs Prelude.
 584
 585 #+begin_src emacs-lisp
 586 (setq frame-title-format
 587       '("" invocation-name " - "
 588         (:eval (if (buffer-file-name)
 589                    (abbreviate-file-name (buffer-file-name))
 590                  "%b"))))
 591 #+end_src
 592
 593 *** Backups
 594
 595 Emacs' default backup settings aren't that great. Let's use more
 596 sensible options. See documentation for the ~make-backup-file~
 597 variable.
 598
 599 #+begin_src emacs-lisp
 600 (setq backup-by-copying t
 601       version-control t
 602       delete-old-versions t)
 603 #+end_src
 604
 605 *** Auto revert
 606
 607 Enable automatic reloading of changed buffers and files.
 608
 609 #+begin_src emacs-lisp
 610 (global-auto-revert-mode 1)
 611 (setq auto-revert-verbose nil
 612       global-auto-revert-non-file-buffers nil)
 613 #+end_src
 614
 615 *** Always use space for indentation
 616
 617 #+begin_src emacs-lisp
 618 (setq-default
 619  indent-tabs-mode nil
 620  require-final-newline t
 621  tab-width 4)
 622 #+end_src
 623
 624 *** Winner mode
 625
 626 Enable =winner-mode=.
 627
 628 #+begin_src emacs-lisp
 629 (winner-mode 1)
 630 #+end_src
 631
 632 *** Don’t display =*compilation*= on success
 633
 634 Based on https://stackoverflow.com/a/17788551, with changes to use
 635 =cl-letf= instead of the now obsolete =flet=.
 636
 637 #+begin_src emacs-lisp
 638 (with-eval-after-load 'compile
 639   (defun a/compilation-finish-function (buffer outstr)
 640     (unless (string-match "finished" outstr)
 641       (switch-to-buffer-other-window buffer))
 642     t)
 643
 644   (setq compilation-finish-functions #'a/compilation-finish-function)
 645
 646   (require 'cl-macs)
 647
 648   (defadvice compilation-start
 649       (around inhibit-display
 650               (command &optional mode name-function highlight-regexp))
 651     (if (not (string-match "^\\(find\\|grep\\)" command))
 652         (cl-letf (((symbol-function 'display-buffer) #'ignore))
 653           (save-window-excursion ad-do-it))
 654       ad-do-it))
 655   (ad-activate 'compilation-start))
 656 #+end_src
 657
 658 *** Search for non-ASCII characters
 659
 660 I’d like non-ASCII characters such as ‘’“”«»‹›áⓐ𝒶 to be selected when
 661 I search for their ASCII counterpart.  Shoutout to [[http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html][endlessparentheses]]
 662 for this.
 663
 664 #+begin_src emacs-lisp
 665 (setq search-default-mode #'char-fold-to-regexp)
 666
 667 ;; uncomment to extend this behaviour to query-replace
 668 ;; (setq replace-char-fold t)
 669 #+end_src
 670
 671 *** Cursor shape
 672
 673 #+begin_src emacs-lisp
 674 (setq-default cursor-type 'bar)
 675 #+end_src
 676
 677 ** Bindings
 678
 679 #+begin_src emacs-lisp
 680 (bind-keys
 681  ("C-c a i" . ielm)
 682
 683  ("C-c e b" . eval-buffer)
 684  ("C-c e r" . eval-region)
 685
 686  ("C-c F m" . make-frame-command)
 687  ("C-c F d" . delete-frame)
 688  ("C-c F D" . delete-other-frames)
 689
 690  ("C-c o"   . other-window)
 691
 692  ("C-c Q"   . save-buffers-kill-terminal)
 693
 694  ("C-S-h C" . describe-char)
 695  ("C-S-h F" . describe-face)
 696
 697  ("C-x K"   . kill-this-buffer)
 698
 699  ("s-p"     . beginning-of-buffer)
 700  ("s-n"     . end-of-buffer))
 701 #+end_src
 702
 703 ** Packages
 704
 705 The packages in this section are absolutely essential to my everyday
 706 workflow, and they play key roles in how I do my computing. They
 707 immensely enhance the Emacs experience for me; both using Emacs, and
 708 customizing it.
 709
 710 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 711
 712 #+begin_src emacs-lisp
 713 (use-package auto-compile
 714   :demand t
 715   :config
 716   (auto-compile-on-load-mode)
 717   (auto-compile-on-save-mode)
 718   (setq auto-compile-display-buffer               nil
 719         auto-compile-mode-line-counter            t
 720         auto-compile-source-recreate-deletes-dest t
 721         auto-compile-toggle-deletes-nonlib-dest   t
 722         auto-compile-update-autoloads             t)
 723   (add-hook 'auto-compile-inhibit-compile-hook
 724             'auto-compile-inhibit-compile-detached-git-head))
 725 #+end_src
 726
 727 *** [[https://orgmode.org/][Org mode]]
 728
 729 #+begin_quote
 730 Org mode is for keeping notes, maintaining TODO lists, planning
 731 projects, and authoring documents with a fast and effective plain-text
 732 system.
 733 #+end_quote
 734
 735 In short, my favourite way of life.
 736
 737 #+begin_src emacs-lisp
 738 (use-package org
 739   :defer 1
 740   :config
 741   (setq org-src-tab-acts-natively t
 742         org-src-preserve-indentation nil
 743         org-edit-src-content-indentation 0
 744         org-email-link-description-format "Email %c: %s" ; %.30s
 745         org-highlight-latex-and-related '(entities)
 746         org-use-speed-commands t
 747         org-startup-folded 'content
 748         org-catch-invisible-edits 'show-and-error
 749         org-log-done 'time)
 750   (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
 751   (font-lock-add-keywords
 752    'org-mode
 753    '(("[ \t]*\\(#\\+\\(BEGIN\\|END\\|begin\\|end\\)_\\(\\S-+\\)\\)[ \t]*\\([^\n:]*\\)"
 754       (1 '(:foreground "#5a5b5a" :background "#292b2b") t) ; directive
 755       (3 '(:foreground "#81a2be" :background "#292b2b") t) ; kind
 756       (4 '(:foreground "#c5c8c6") t))) ; title
 757    t)
 758   :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
 759   :hook ((org-mode . org-indent-mode)
 760          (org-mode . auto-fill-mode)
 761          (org-mode . flyspell-mode))
 762   :custom
 763   (org-latex-packages-alist '(("" "listings") ("" "color")))
 764   :custom-face
 765   '(org-block-begin-line ((t (:foreground "#5a5b5a" :background "#1d1f21"))))
 766   '(org-block ((t (:background "#1d1f21"))))
 767   '(org-latex-and-related ((t (:foreground "#b294bb")))))
 768
 769 (use-package ox-latex
 770   :after ox
 771   :config
 772   (setq org-latex-listings 'listings
 773         ;; org-latex-prefer-user-labels t
 774         )
 775   (add-to-list 'org-latex-packages-alist '("" "listings"))
 776   (add-to-list 'org-latex-packages-alist '("" "color"))
 777   (add-to-list 'org-latex-classes
 778                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 779                  ("\\section{%s}" . "\\section*{%s}")
 780                  ("\\subsection{%s}" . "\\subsection*{%s}")
 781                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 782                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 783                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 784                t))
 785
 786 (use-package ox-beamer
 787   :after ox)
 788
 789 (use-package orgalist
 790   :after message
 791   :hook (message-mode . orgalist-mode))
 792 #+end_src
 793
 794 **** asynchronous tangle
 795
 796 =a/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 797 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 798 file.
 799
 800 #+begin_src emacs-lisp
 801 (with-eval-after-load 'org
 802   (defvar a/show-async-tangle-results nil
 803     "Keep *emacs* async buffers around for later inspection.")
 804
 805   (defvar a/show-async-tangle-time nil
 806     "Show the time spent tangling the file.")
 807
 808   (defvar a/async-tangle-post-compile "make ti"
 809     "If non-nil, pass to `compile' after successful tangle.")
 810
 811   (defun a/async-babel-tangle ()
 812     "Tangle org file asynchronously."
 813     (interactive)
 814     (let* ((file-tangle-start-time (current-time))
 815            (file (buffer-file-name))
 816            (file-nodir (file-name-nondirectory file))
 817            ;; (async-quiet-switch "-q")
 818            )
 819       (async-start
 820        `(lambda ()
 821           (require 'org)
 822           (org-babel-tangle-file ,file))
 823        (unless a/show-async-tangle-results
 824          `(lambda (result)
 825             (if result
 826                 (progn
 827                   (message "Tangled %s%s"
 828                            ,file-nodir
 829                            (if a/show-async-tangle-time
 830                                (format " (%.3fs)"
 831                                        (float-time (time-subtract (current-time)
 832                                                                   ',file-tangle-start-time)))
 833                              ""))
 834                   (when a/async-tangle-post-compile
 835                     (compile a/async-tangle-post-compile)))
 836               (message "Tangling %s failed" ,file-nodir))))))))
 837
 838 (add-to-list
 839  'safe-local-variable-values
 840  '(eval add-hook 'after-save-hook #'a/async-babel-tangle 'append 'local))
 841 #+end_src
 842
 843 *** [[https://magit.vc/][Magit]]
 844
 845 #+begin_quote
 846 It's Magit! A Git porcelain inside Emacs.
 847 #+end_quote
 848
 849 Not just how I do git, but /the/ way to do git.
 850
 851 #+begin_src emacs-lisp
 852 (use-package magit
 853   :defer 1
 854   :bind (("C-x g" . magit-status)
 855          ("s-g s" . magit-status)
 856          ("s-g l" . magit-log-buffer-file))
 857   :config
 858   (magit-add-section-hook 'magit-status-sections-hook
 859                           'magit-insert-modules
 860                           'magit-insert-stashes
 861                           'append)
 862   (setq
 863    magit-repository-directories '(("~/.emacs.d/" . 0)
 864                                   ("~/src/git/" . 1)))
 865   (nconc magit-section-initial-visibility-alist
 866          '(([unpulled status] . show)
 867            ([unpushed status] . show)))
 868   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 869 #+end_src
 870
 871 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 872
 873 #+begin_quote
 874 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 875 an overview, and more. Oh, man!
 876 #+end_quote
 877
 878 There's no way I could top that, so I won't attempt to.
 879
 880 **** Ivy
 881
 882 #+begin_src emacs-lisp
 883 (use-package ivy
 884   :defer 1
 885   :bind
 886   (:map ivy-minibuffer-map
 887    ([escape] . keyboard-escape-quit)
 888    ([S-up]   . ivy-previous-history-element)
 889    ([S-down] . ivy-next-history-element)
 890    ("DEL"    . ivy-backward-delete-char))
 891   :config
 892   (setq ivy-wrap t)
 893   (ivy-mode 1)
 894   ;; :custom-face
 895   ;; (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 896   ;; (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 897   ;; (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold))))
 898 )
 899 #+end_src
 900
 901 **** Swiper
 902
 903 #+begin_src emacs-lisp
 904 (use-package swiper
 905   :bind (("C-s"   . swiper)
 906          ("C-r"   . swiper)
 907          ("C-S-s" . isearch-forward)))
 908 #+end_src
 909
 910 **** Counsel
 911
 912 #+begin_src emacs-lisp
 913 (use-package counsel
 914   :defer 1
 915   :bind (([remap execute-extended-command] . counsel-M-x)
 916          ([remap find-file]                . counsel-find-file)
 917          ("s-r"                            . counsel-recentf)
 918          ("C-c x"                          . counsel-M-x)
 919          ("C-c f ."                        . counsel-find-file)
 920          :map minibuffer-local-map
 921          ("C-r" . counsel-minibuffer-history))
 922   :config
 923   (counsel-mode 1)
 924   (defalias 'locate #'counsel-locate))
 925 #+end_src
 926
 927 *** eshell
 928
 929 #+begin_src emacs-lisp
 930 (use-package eshell
 931   :defer 1
 932   :commands eshell
 933   :bind ("C-c a s e" . eshell)
 934   :config
 935   (eval-when-compile (defvar eshell-prompt-regexp))
 936   (defun a/eshell-quit-or-delete-char (arg)
 937     (interactive "p")
 938     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 939         (eshell-life-is-too-much)
 940       (delete-char arg)))
 941
 942   (defun a/eshell-clear ()
 943     (interactive)
 944     (let ((inhibit-read-only t))
 945       (erase-buffer))
 946     (eshell-send-input))
 947
 948   (defun a/eshell-setup ()
 949     (make-local-variable 'company-idle-delay)
 950     (defvar company-idle-delay)
 951     (setq company-idle-delay nil)
 952     (bind-keys :map eshell-mode-map
 953                ("C-d"   . a/eshell-quit-or-delete-char)
 954                ("C-S-l" . a/eshell-clear)
 955                ("M-r"   . counsel-esh-history)
 956                ([tab]   . company-complete)))
 957
 958   :hook (eshell-mode . a/eshell-setup)
 959   :custom
 960   (eshell-hist-ignoredups t)
 961   (eshell-input-filter 'eshell-input-filter-initial-space))
 962 #+end_src
 963
 964 *** Ibuffer
 965
 966 #+begin_src emacs-lisp
 967 (use-package ibuffer
 968   :defer t
 969   :bind
 970   (("C-x C-b" . ibuffer-other-window)
 971    :map ibuffer-mode-map
 972    ("P"   . ibuffer-backward-filter-group)
 973    ("N"   . ibuffer-forward-filter-group)
 974    ("M-p" . ibuffer-do-print)
 975    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 976   :config
 977   ;; Use human readable Size column instead of original one
 978   (define-ibuffer-column size-h
 979     (:name "Size" :inline t)
 980     (cond
 981      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
 982      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
 983      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
 984      (t (format "%8d" (buffer-size)))))
 985   :custom
 986   (ibuffer-saved-filter-groups
 987    '(("default"
 988       ("dired" (mode . dired-mode))
 989       ("org"   (mode . org-mode))
 990       ("gnus"
 991        (or
 992         (mode . gnus-group-mode)
 993         (mode . gnus-summary-mode)
 994         (mode . gnus-article-mode)
 995         ;; not really, but...
 996         (mode . message-mode)))
 997       ("web"
 998        (or
 999         (mode . web-mode)
1000         (mode . css-mode)
1001         (mode . scss-mode)
1002         (mode . js2-mode)))
1003       ("shell"
1004        (or
1005         (mode . eshell-mode)
1006         (mode . shell-mode)
1007         (mode . term-mode)))
1008       ("programming"
1009        (or
1010         (mode . python-mode)
1011         (mode . c-mode)
1012         (mode . c++-mode)
1013         (mode . emacs-lisp-mode)
1014         (mode . scheme-mode)
1015         (mode . haskell-mode)
1016         (mode . lean-mode)))
1017       ("emacs"
1018        (or
1019         (name . "^\\*scratch\\*$")
1020         (name . "^\\*Messages\\*$"))))))
1021   (ibuffer-formats
1022    '((mark modified read-only locked " "
1023            (name 18 18 :left :elide)
1024            " "
1025            (size-h 9 -1 :right)
1026            " "
1027            (mode 16 16 :left :elide)
1028            " " filename-and-process)
1029      (mark " "
1030            (name 16 -1)
1031            " " filename)))
1032   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
1033 #+end_src
1034
1035 *** Outline
1036
1037 #+begin_src emacs-lisp
1038 (use-package outline
1039   :defer t
1040   :hook (prog-mode . outline-minor-mode)
1041   :bind
1042   (:map
1043    outline-minor-mode-map
1044    ("<s-tab>"  . outline-toggle-children)
1045    ("M-p"      . outline-previous-visible-heading)
1046    ("M-n"      . outline-next-visible-heading)
1047    :prefix-map a/outline-prefix-map
1048    :prefix "s-o"
1049    ("TAB" . outline-toggle-children)
1050    ("a"   . outline-hide-body)
1051    ("H"   . outline-hide-body)
1052    ("S"   . outline-show-all)
1053    ("h"   . outline-hide-subtree)
1054    ("s"   . outline-show-subtree)))
1055 #+end_src
1056
1057 * Borg's =layer/essentials=
1058 :PROPERTIES:
1059 :CUSTOM_ID: borg-essentials
1060 :END:
1061
1062 TODO: break this giant source block down into individual org sections.
1063
1064 #+begin_src emacs-lisp
1065 (use-package dash
1066   :config (dash-enable-font-lock))
1067
1068 (use-package diff-hl
1069   :config
1070   (setq diff-hl-draw-borders nil)
1071   (global-diff-hl-mode)
1072   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
1073
1074 (use-package ls-lisp
1075   :custom (ls-lisp-dirs-first t))
1076
1077 (use-package dired
1078   :defer t
1079   :config
1080   (setq dired-listing-switches "-alh"
1081         ls-lisp-use-insert-directory-program nil)
1082
1083   ;; easily diff 2 marked files
1084   ;; https://oremacs.com/2017/03/18/dired-ediff/
1085   (defun dired-ediff-files ()
1086     (interactive)
1087     (defvar ediff-after-quit-hook-internal)
1088     (let ((files (dired-get-marked-files))
1089           (wnd (current-window-configuration)))
1090       (if (<= (length files) 2)
1091           (let ((file1 (car files))
1092                 (file2 (if (cdr files)
1093                            (cadr files)
1094                          (read-file-name
1095                           "file: "
1096                           (dired-dwim-target-directory)))))
1097             (if (file-newer-than-file-p file1 file2)
1098                 (ediff-files file2 file1)
1099               (ediff-files file1 file2))
1100             (add-hook 'ediff-after-quit-hook-internal
1101                       (lambda ()
1102                         (setq ediff-after-quit-hook-internal nil)
1103                         (set-window-configuration wnd))))
1104         (error "no more than 2 files should be marked"))))
1105   :bind (:map dired-mode-map
1106               ("e"  . dired-ediff-files)
1107               ("E"  . dired-toggle-read-only)
1108               ("\\" . dired-hide-details-mode)
1109               ("z"  . (lambda ()
1110                         (interactive)
1111                         (a/dired-start-process "zathura"))))
1112   :hook (dired-mode . dired-hide-details-mode))
1113
1114 (use-package eldoc
1115   :when (version< "25" emacs-version)
1116   :config (global-eldoc-mode))
1117
1118 (use-package help
1119   :defer t
1120   :config
1121   (temp-buffer-resize-mode)
1122   (setq help-window-select t))
1123
1124 (progn ;    `isearch'
1125   (setq isearch-allow-scroll t))
1126
1127 (use-package lisp-mode
1128   :config
1129   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1130   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1131   (defun indent-spaces-mode ()
1132     (setq indent-tabs-mode nil))
1133   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1134
1135 (use-package man
1136   :defer t
1137   :config (setq Man-width 80))
1138
1139 (use-package paren
1140   :config (show-paren-mode))
1141
1142 (use-package prog-mode
1143   :config (global-prettify-symbols-mode)
1144   (defun indicate-buffer-boundaries-left ()
1145     (setq indicate-buffer-boundaries 'left))
1146   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1147
1148 (use-package recentf
1149   :defer 0.5
1150   :config
1151   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1152   (setq recentf-max-saved-items 40))
1153
1154 (use-package savehist
1155   :config (savehist-mode))
1156
1157 (use-package saveplace
1158   :when (version< "25" emacs-version)
1159   :config (save-place-mode))
1160
1161 (use-package simple
1162   :config (column-number-mode))
1163
1164 (progn ;    `text-mode'
1165   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left)
1166   (add-hook 'text-mode-hook #'abbrev-mode))
1167
1168 (use-package tramp
1169   :defer t
1170   :config
1171   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1172   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1173   (add-to-list 'tramp-default-proxies-alist
1174                (list (regexp-quote (system-name)) nil nil)))
1175
1176 #+end_src
1177
1178 * Editing
1179 :PROPERTIES:
1180 :CUSTOM_ID: editing
1181 :END:
1182
1183 ** Company
1184
1185 #+begin_src emacs-lisp
1186 (use-package company
1187   :defer 1
1188   :bind
1189   (:map company-active-map
1190         ([tab]    . company-complete-common-or-cycle)
1191         ([escape] . company-abort))
1192   :custom
1193   (company-minimum-prefix-length 1)
1194   (company-selection-wrap-around t)
1195   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1196   (company-dabbrev-downcase nil)
1197   (company-dabbrev-ignore-case nil)
1198   :config
1199   (global-company-mode t))
1200 #+end_src
1201
1202 * Syntax and spell checking
1203 :PROPERTIES:
1204 :CUSTOM_ID: syntax-spell-checking
1205 :END:
1206
1207 #+begin_src emacs-lisp
1208 (use-package flycheck
1209   :defer 3
1210   :hook (prog-mode . flycheck-mode)
1211   :bind
1212   (:map flycheck-mode-map
1213         ("M-P" . flycheck-previous-error)
1214         ("M-N" . flycheck-next-error))
1215   :config
1216   ;; Use the load-path from running Emacs when checking elisp files
1217   (setq flycheck-emacs-lisp-load-path 'inherit)
1218
1219   ;; Only flycheck when I actually save the buffer
1220   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1221
1222 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1223 (use-package ispell
1224   :defer 3
1225   :config
1226   ;; ’ can be part of a word
1227   (setq ispell-local-dictionary-alist
1228         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1229                "['\x2019]" nil ("-B") nil utf-8)))
1230   ;; don't send ’ to the subprocess
1231   (defun endless/replace-apostrophe (args)
1232     (cons (replace-regexp-in-string
1233            "’" "'" (car args))
1234           (cdr args)))
1235   (advice-add #'ispell-send-string :filter-args
1236               #'endless/replace-apostrophe)
1237
1238   ;; convert ' back to ’ from the subprocess
1239   (defun endless/replace-quote (args)
1240     (if (not (derived-mode-p 'org-mode))
1241         args
1242       (cons (replace-regexp-in-string
1243              "'" "’" (car args))
1244             (cdr args))))
1245   (advice-add #'ispell-parse-output :filter-args
1246               #'endless/replace-quote))
1247 #+end_src
1248
1249 * Programming modes
1250 :PROPERTIES:
1251 :CUSTOM_ID: programming-modes
1252 :END:
1253
1254 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1255
1256 #+begin_src emacs-lisp
1257 (use-package alloy-mode
1258   :defer t
1259   :config (setq alloy-basic-offset 2))
1260 #+end_src
1261
1262 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1263
1264 #+begin_src emacs-lisp
1265 (use-package proof-site  ; Proof General
1266   :defer t
1267   :load-path "lib/proof-site/generic/")
1268 #+end_src
1269
1270 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1271
1272 #+begin_src emacs-lisp
1273 (eval-when-compile (defvar lean-mode-map))
1274 (use-package lean-mode
1275   :defer 1
1276   :bind (:map lean-mode-map
1277               ("S-SPC" . company-complete))
1278   :config
1279   (require 'lean-input)
1280   (setq default-input-method "Lean"
1281         lean-input-tweak-all '(lean-input-compose
1282                                (lean-input-prepend "/")
1283                                (lean-input-nonempty))
1284         lean-input-user-translations '(("/" "/")))
1285   (lean-input-setup))
1286   #+end_src
1287
1288 ** Haskell
1289
1290 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1291
1292 #+begin_src emacs-lisp
1293 (use-package haskell-mode
1294   :defer t
1295   :config
1296   (setq haskell-indentation-layout-offset 4
1297         haskell-indentation-left-offset 4
1298         flycheck-checker 'haskell-hlint
1299         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1300 #+end_src
1301
1302 *** [[https://github.com/jyp/dante][dante]]
1303
1304 #+begin_src emacs-lisp
1305 (use-package dante
1306   :after haskell-mode
1307   :commands dante-mode
1308   :hook (haskell-mode . dante-mode))
1309 #+end_src
1310
1311 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1312
1313 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1314 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1315
1316 #+begin_src emacs-lisp
1317 (use-package hlint-refactor
1318   :after haskell-mode
1319   :bind (:map hlint-refactor-mode-map
1320               ("C-c l b" . hlint-refactor-refactor-buffer)
1321               ("C-c l r" . hlint-refactor-refactor-at-point))
1322   :hook (haskell-mode . hlint-refactor-mode))
1323 #+end_src
1324
1325 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1326
1327 #+begin_src emacs-lisp
1328 (use-package flycheck-haskell
1329   :after haskell-mode)
1330 #+end_src
1331
1332 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1333 :PROPERTIES:
1334 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1335 :END:
1336
1337 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1338 instead.
1339
1340 #+begin_src emacs-lisp :tangle no
1341 ;;; hs-lint.el --- minor mode for HLint code checking
1342
1343 ;; Copyright 2009 (C) Alex Ott
1344 ;;
1345 ;; Author: Alex Ott <alexott@gmail.com>
1346 ;; Keywords: haskell, lint, HLint
1347 ;; Requirements:
1348 ;; Status: distributed under terms of GPL2 or above
1349
1350 ;; Typical message from HLint looks like:
1351 ;;
1352 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1353 ;; Found:
1354 ;;   count1 p l = length (filter p l)
1355 ;; Why not:
1356 ;;   count1 p = length . filter p
1357
1358
1359 (require 'compile)
1360
1361 (defgroup hs-lint nil
1362   "Run HLint as inferior of Emacs, parse error messages."
1363   :group 'tools
1364   :group 'haskell)
1365
1366 (defcustom hs-lint-command "hlint"
1367   "The default hs-lint command for \\[hlint]."
1368   :type 'string
1369   :group 'hs-lint)
1370
1371 (defcustom hs-lint-save-files t
1372   "Save modified files when run HLint or no (ask user)"
1373   :type 'boolean
1374   :group 'hs-lint)
1375
1376 (defcustom hs-lint-replace-with-suggestions nil
1377   "Replace user's code with suggested replacements"
1378   :type 'boolean
1379   :group 'hs-lint)
1380
1381 (defcustom hs-lint-replace-without-ask nil
1382   "Replace user's code with suggested replacements automatically"
1383   :type 'boolean
1384   :group 'hs-lint)
1385
1386 (defun hs-lint-process-setup ()
1387   "Setup compilation variables and buffer for `hlint'."
1388   (run-hooks 'hs-lint-setup-hook))
1389
1390 ;; regex for replace suggestions
1391 ;;
1392 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1393 ;; Found:
1394 ;; \s +\(.*\)
1395 ;; Why not:
1396 ;; \s +\(.*\)
1397
1398 (defvar hs-lint-regex
1399   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1400   "Regex for HLint messages")
1401
1402 (defun make-short-string (str maxlen)
1403   (if (< (length str) maxlen)
1404       str
1405     (concat (substring str 0 (- maxlen 3)) "...")))
1406
1407 (defun hs-lint-replace-suggestions ()
1408   "Perform actual replacement of suggestions"
1409   (goto-char (point-min))
1410   (while (re-search-forward hs-lint-regex nil t)
1411     (let* ((fname (match-string 1))
1412           (fline (string-to-number (match-string 2)))
1413           (old-code (match-string 4))
1414           (new-code (match-string 5))
1415           (msg (concat "Replace '" (make-short-string old-code 30)
1416                        "' with '" (make-short-string new-code 30) "'"))
1417           (bline 0)
1418           (eline 0)
1419           (spos 0)
1420           (new-old-code ""))
1421       (save-excursion
1422         (switch-to-buffer (get-file-buffer fname))
1423         (goto-char (point-min))
1424         (forward-line (1- fline))
1425         (beginning-of-line)
1426         (setf bline (point))
1427         (when (or hs-lint-replace-without-ask
1428                   (yes-or-no-p msg))
1429           (end-of-line)
1430           (setf eline (point))
1431           (beginning-of-line)
1432           (setf old-code (regexp-quote old-code))
1433           (while (string-match "\\\\ " old-code spos)
1434             (setf new-old-code (concat new-old-code
1435                                  (substring old-code spos (match-beginning 0))
1436                                  "\\ *"))
1437             (setf spos (match-end 0)))
1438           (setf new-old-code (concat new-old-code (substring old-code spos)))
1439           (remove-text-properties bline eline '(composition nil))
1440           (when (re-search-forward new-old-code eline t)
1441             (replace-match new-code nil t)))))))
1442
1443 (defun hs-lint-finish-hook (buf msg)
1444   "Function, that is executed at the end of HLint execution"
1445   (if hs-lint-replace-with-suggestions
1446       (hs-lint-replace-suggestions)
1447       (next-error 1 t)))
1448
1449 (define-compilation-mode hs-lint-mode "HLint"
1450   "Mode for check Haskell source code."
1451   (set (make-local-variable 'compilation-process-setup-function)
1452        'hs-lint-process-setup)
1453   (set (make-local-variable 'compilation-disable-input) t)
1454   (set (make-local-variable 'compilation-scroll-output) nil)
1455   (set (make-local-variable 'compilation-finish-functions)
1456        (list 'hs-lint-finish-hook))
1457   )
1458
1459 (defun hs-lint ()
1460   "Run HLint for current buffer with haskell source"
1461   (interactive)
1462   (save-some-buffers hs-lint-save-files)
1463   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1464                      'hs-lint-mode))
1465
1466 (provide 'hs-lint)
1467 ;;; hs-lint.el ends here
1468 #+end_src
1469
1470 #+begin_src emacs-lisp :tangle no
1471 (use-package hs-lint
1472   :load-path "lisp/"
1473   :bind (:map haskell-mode-map
1474               ("C-c l l" . hs-lint)))
1475 #+end_src
1476
1477 ** Web dev
1478
1479 *** SGML and HTML
1480
1481 #+begin_src emacs-lisp
1482 (use-package sgml-mode
1483   :defer t
1484   :config
1485   (setq sgml-basic-offset 2))
1486 #+end_src
1487
1488 *** CSS and SCSS
1489
1490 #+begin_src emacs-lisp
1491 (use-package css-mode
1492   :defer t
1493   :config
1494   (setq css-indent-offset 2))
1495 #+end_src
1496
1497 *** Web mode
1498
1499 #+begin_src emacs-lisp
1500 (use-package web-mode
1501   :defer t
1502   :mode "\\.html\\'"
1503   :config
1504   (a/setq-every 2
1505     web-mode-code-indent-offset
1506     web-mode-css-indent-offset
1507     web-mode-markup-indent-offset))
1508 #+end_src
1509
1510 *** Emmet mode
1511
1512 #+begin_src emacs-lisp
1513 (use-package emmet-mode
1514   :after (:any web-mode css-mode sgml-mode)
1515   :bind* (("C-)" . emmet-next-edit-point)
1516           ("C-(" . emmet-prev-edit-point))
1517   :config
1518   (unbind-key "C-j" emmet-mode-keymap)
1519   (setq emmet-move-cursor-between-quotes t)
1520   :hook (web-mode css-mode html-mode sgml-mode))
1521 #+end_src
1522
1523 ** COMMENT Java
1524
1525 *** meghanada
1526
1527 #+begin_src emacs-lisp
1528 (use-package meghanada
1529   :bind
1530   (:map meghanada-mode-map
1531         (("C-M-o" . meghanada-optimize-import)
1532          ("C-M-t" . meghanada-import-all)))
1533   :hook (java-mode . meghanada-mode))
1534 #+end_src
1535
1536 *** lsp-java
1537
1538 #+begin_comment
1539 dependencies:
1540
1541 ace-window
1542 avy
1543 bui
1544 company-lsp
1545 dap-mode
1546 lsp-java
1547 lsp-mode
1548 lsp-ui
1549 pfuture
1550 tree-mode
1551 treemacs
1552 #+end_comment
1553
1554 #+begin_src emacs-lisp
1555 (use-package treemacs
1556   :config (setq treemacs-never-persist t))
1557
1558 (use-package yasnippet
1559   :config
1560   ;; (yas-global-mode)
1561   )
1562
1563 (use-package lsp-mode
1564   :init (setq lsp-eldoc-render-all nil
1565               lsp-highlight-symbol-at-point nil)
1566   )
1567
1568 (use-package hydra)
1569
1570 (use-package company-lsp
1571   :after  company
1572   :config
1573   (setq company-lsp-cache-candidates t
1574         company-lsp-async t))
1575
1576 (use-package lsp-ui
1577   :config
1578   (setq lsp-ui-sideline-update-mode 'point))
1579
1580 (use-package lsp-java
1581   :config
1582   (add-hook 'java-mode-hook
1583             (lambda ()
1584               (setq-local company-backends (list 'company-lsp))))
1585
1586   (add-hook 'java-mode-hook 'lsp-java-enable)
1587   (add-hook 'java-mode-hook 'flycheck-mode)
1588   (add-hook 'java-mode-hook 'company-mode)
1589   (add-hook 'java-mode-hook 'lsp-ui-mode))
1590
1591 (use-package dap-mode
1592   :after lsp-mode
1593   :config
1594   (dap-mode t)
1595   (dap-ui-mode t))
1596
1597 (use-package dap-java
1598   :after (lsp-java))
1599
1600 (use-package lsp-java-treemacs
1601   :after (treemacs))
1602 #+end_src
1603
1604 ** geiser
1605
1606 #+begin_src emacs-lisp
1607 (use-package geiser)
1608
1609 (use-package geiser-guile
1610   :config
1611   (setq geiser-guile-load-path "~/src/git/guix"))
1612 #+end_src
1613
1614 ** guix
1615
1616 #+begin_src emacs-lisp
1617 (use-package guix
1618   :load-path "lib/guix/elisp")
1619 #+end_src
1620
1621 * Emacs enhancements
1622 :PROPERTIES:
1623 :CUSTOM_ID: emacs-enhancements
1624 :END:
1625
1626 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1627
1628 #+begin_quote
1629 Emacs package that displays available keybindings in popup
1630 #+end_quote
1631
1632 #+begin_src emacs-lisp
1633 (use-package which-key
1634   :defer 1
1635   :config (which-key-mode))
1636 #+end_src
1637
1638 ** theme
1639
1640 #+begin_src emacs-lisp
1641 (add-to-list 'custom-theme-load-path "~/.emacs.d/lisp")
1642 (load-theme 'tangomod t)
1643 #+end_src
1644
1645 ** smart-mode-line
1646
1647 #+begin_src emacs-lisp
1648 (use-package smart-mode-line
1649   :config
1650   (sml/setup))
1651 #+end_src
1652
1653 ** doom-themes
1654
1655 #+begin_src emacs-lisp
1656 (use-package doom-themes)
1657 #+end_src
1658
1659 ** theme helper functions
1660
1661 #+begin_src emacs-lisp
1662 (defun a/lights-on ()
1663   "Enable my favourite light theme."
1664   (interactive)
1665   (mapc #'disable-theme custom-enabled-themes)
1666   (load-theme 'tangomod t)
1667   (sml/apply-theme 'automatic))
1668
1669 (defun a/lights-off ()
1670   "Go dark."
1671   (interactive)
1672   (mapc #'disable-theme custom-enabled-themes)
1673   (load-theme 'doom-tomorrow-night t)
1674   (sml/apply-theme 'automatic))
1675
1676 (bind-keys
1677  ("s-t d" . a/lights-off)
1678  ("s-t l" . a/lights-on))
1679 #+end_src
1680
1681 ** [[https://github.com/bbatsov/crux][crux]]
1682
1683 #+begin_src emacs-lisp
1684 (use-package crux
1685   :defer 1
1686   :bind (("C-c b k" . crux-kill-other-buffers)
1687          ("C-c d"   . crux-duplicate-current-line-or-region)
1688          ("C-c D"   . crux-duplicate-and-comment-current-line-or-region)
1689          ("C-c f c" . crux-copy-file-preserve-attributes)
1690          ("C-c f d" . crux-delete-file-and-buffer)
1691          ("C-c f r" . crux-rename-file-and-buffer)
1692          ("C-c j"   . crux-top-join-line)
1693          ("C-S-j"   . crux-top-join-line)))
1694 #+end_src
1695
1696 ** [[https://github.com/alezost/mwim.el][mwim]]
1697
1698 #+begin_src emacs-lisp
1699 (use-package mwim
1700   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1701          ("C-e"    . mwim-end-of-code-or-line)
1702          ("<home>" . mwim-beginning-of-line-or-code)
1703          ("<end>"  . mwim-end-of-line-or-code)))
1704 #+end_src
1705
1706 ** projectile
1707
1708 #+begin_src emacs-lisp
1709 (use-package projectile
1710   :defer t
1711   :bind-keymap ("C-c p" . projectile-command-map)
1712   :config
1713   (projectile-mode)
1714
1715   (defun my-projectile-invalidate-cache (&rest _args)
1716     ;; ignore the args to `magit-checkout'
1717     (projectile-invalidate-cache nil))
1718
1719   (eval-after-load 'magit-branch
1720     '(progn
1721        (advice-add 'magit-checkout
1722                    :after #'my-projectile-invalidate-cache)
1723        (advice-add 'magit-branch-and-checkout
1724                    :after #'my-projectile-invalidate-cache)))
1725   :custom (projectile-completion-system 'ivy))
1726 #+end_src
1727
1728 ** [[https://github.com/Wilfred/helpful][helpful]]
1729
1730 #+begin_src emacs-lisp
1731 (use-package helpful
1732   :defer 1
1733   :bind
1734   (("C-S-h c" . helpful-command)
1735    ("C-S-h f" . helpful-callable)        ; helpful-function
1736    ("C-S-h v" . helpful-variable)
1737    ("C-S-h k" . helpful-key)
1738    ("C-S-h p" . helpful-at-point)))
1739 #+end_src
1740
1741 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1742
1743 Make =*scratch*= and =*Messages*= unkillable.
1744
1745 #+begin_src emacs-lisp
1746 (use-package unkillable-scratch
1747   :defer 3
1748   :config
1749   (unkillable-scratch 1)
1750   :custom
1751   (unkillable-scratch-behavior 'do-nothing)
1752   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1753 #+end_src
1754
1755 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1756
1757 #+begin_example
1758 ,----
1759 | make pretty boxed quotes like this
1760 `----
1761 #+end_example
1762
1763 #+begin_src emacs-lisp
1764 (use-package boxquote
1765   :defer 3
1766   :bind
1767   (:prefix-map a/boxquote-prefix-map
1768    :prefix "C-c q"
1769    ("b"   . boxquote-buffer)
1770    ("B"   . boxquote-insert-buffer)
1771    ("d"   . boxquote-defun)
1772    ("F"   . boxquote-insert-file)
1773    ("hf"  . boxquote-describe-function)
1774    ("hk"  . boxquote-describe-key)
1775    ("hv"  . boxquote-describe-variable)
1776    ("hw"  . boxquote-where-is)
1777    ("k"   . boxquote-kill)
1778    ("p"   . boxquote-paragraph)
1779    ("q"   . boxquote-boxquote)
1780    ("r"   . boxquote-region)
1781    ("s"   . boxquote-shell-command)
1782    ("t"   . boxquote-text)
1783    ("T"   . boxquote-title)
1784    ("u"   . boxquote-unbox)
1785    ("U"   . boxquote-unbox-region)
1786    ("y"   . boxquote-yank)
1787    ("M-q" . boxquote-fill-paragraph)
1788    ("M-w" . boxquote-kill-ring-save)))
1789 #+end_src
1790
1791 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1792
1793 ** typo.el
1794
1795 #+begin_src emacs-lisp
1796 (use-package typo
1797   :defer 2
1798   :config
1799   (typo-global-mode 1)
1800   :hook (text-mode . typo-mode))
1801 #+end_src
1802
1803 ** hl-todo
1804
1805 #+begin_src emacs-lisp
1806 (use-package hl-todo
1807   :defer 4
1808   :config
1809   (global-hl-todo-mode))
1810 #+end_src
1811
1812 ** shrink-path
1813
1814 #+begin_src emacs-lisp
1815 (use-package shrink-path
1816   :after eshell
1817   :config
1818   (setq eshell-prompt-regexp "\\(.*\n\\)*λ "
1819         eshell-prompt-function #'+eshell/prompt)
1820
1821   (defun +eshell/prompt ()
1822     (let ((base/dir (shrink-path-prompt default-directory)))
1823       (concat (propertize (car base/dir)
1824                           'face 'font-lock-comment-face)
1825               (propertize (cdr base/dir)
1826                           'face 'font-lock-constant-face)
1827               (propertize (+eshell--current-git-branch)
1828                           'face 'font-lock-function-name-face)
1829               "\n"
1830               (propertize "λ" 'face 'eshell-prompt-face)
1831               ;; needed for the input text to not have prompt face
1832               (propertize " " 'face 'default))))
1833
1834   (defun +eshell--current-git-branch ()
1835     (let ((branch (car (loop for match in (split-string (shell-command-to-string "git branch") "\n")
1836                              when (string-match "^\*" match)
1837                              collect match))))
1838       (if (not (eq branch nil))
1839           (concat " " (substring branch 2))
1840         ""))))
1841 #+end_src
1842
1843 ** [[https://github.com/peterwvj/eshell-up][eshell-up]]
1844
1845 #+begin_src emacs-lisp
1846 (use-package eshell-up
1847   :after eshell)
1848 #+end_src
1849
1850 ** multi-term
1851
1852 #+begin_src emacs-lisp
1853 (use-package multi-term
1854   :defer 1
1855   :bind (("C-c a s m m" . multi-term)
1856          ("C-c a s m p" . multi-term-dedicated-toggle)
1857          :map term-mode-map
1858          ("C-c C-j" . term-char-mode)
1859          :map term-raw-map
1860          ("C-c C-j" . term-line-mode))
1861   :config
1862   (setq multi-term-program "/bin/screen"
1863         ;; TODO: add separate bindings for connecting to existing
1864         ;; session vs. always creating a new one
1865         multi-term-dedicated-select-after-open-p t
1866         multi-term-dedicated-window-height 20
1867         multi-term-dedicated-max-window-height 30
1868         term-bind-key-alist
1869         '(("C-c C-c" . term-interrupt-subjob)
1870           ("C-c C-e" . term-send-esc)
1871           ("C-k" . kill-line)
1872           ("C-y" . term-paste)
1873           ("M-f" . term-send-forward-word)
1874           ("M-b" . term-send-backward-word)
1875           ("M-p" . term-send-up)
1876           ("M-n" . term-send-down)
1877           ("<C-backspace>" . term-send-backward-kill-word)
1878           ("<M-DEL>" . term-send-backward-kill-word)
1879           ("M-d" . term-send-delete-word)
1880           ("M-," . term-send-raw)
1881           ("M-." . comint-dynamic-complete))
1882         term-unbind-key-alist
1883         '("C-z" "C-x" "C-c" "C-h" "C-y" "<ESC>")))
1884 #+end_src
1885
1886 ** page-break-lines
1887
1888 #+begin_src emacs-lisp
1889 (use-package page-break-lines
1890   :config
1891   (global-page-break-lines-mode))
1892 #+end_src
1893
1894 ** expand-region
1895
1896 #+begin_src emacs-lisp
1897 (use-package expand-region
1898   :bind ("C-=" . er/expand-region))
1899 #+end_src
1900
1901 ** multiple-cursors
1902
1903 #+begin_src emacs-lisp
1904 (use-package multiple-cursors
1905   :bind
1906   (("C-S-<mouse-1>" . mc/add-cursor-on-click)
1907    (:prefix-map a/mc-prefix-map
1908                :prefix "C-c m"
1909                ("c" . mc/edit-lines)
1910                ("n" . mc/mark-next-like-this)
1911                ("p" . mc/mark-previous-like-this)
1912                ("a" . mc/mark-all-like-this))))
1913 #+end_src
1914
1915 * Email
1916 :PROPERTIES:
1917 :CUSTOM_ID: email
1918 :END:
1919
1920 #+begin_src emacs-lisp
1921 (defvar a/maildir (expand-file-name "~/mail/"))
1922 (with-eval-after-load 'recentf
1923   (add-to-list 'recentf-exclude a/maildir))
1924 #+end_src
1925
1926 ** Gnus
1927
1928 #+begin_src emacs-lisp
1929 (setq
1930  a/gnus-init-file  (no-littering-expand-etc-file-name "gnus")
1931  mail-user-agent   'gnus-user-agent
1932  read-mail-command 'gnus)
1933
1934 (use-package gnus
1935   :bind (("s-m"   . gnus)
1936          ("s-M"   . gnus-unplugged))
1937   :init
1938   (setq
1939    gnus-select-method '(nnnil "")
1940    gnus-secondary-select-methods
1941    '((nnimap "amin"
1942             (nnimap-stream plain)
1943             (nnimap-address "127.0.0.1")
1944             (nnimap-server-port 143)
1945             (nnimap-authenticator plain)
1946             (nnimap-user "amin@aminb.org"))
1947      (nnimap "uwaterloo"
1948              (nnimap-stream plain)
1949              (nnimap-address "127.0.0.1")
1950              (nnimap-server-port 143)
1951              (nnimap-authenticator plain)
1952              (nnimap-user "abandali@uwaterloo.ca")))
1953    gnus-message-archive-group "nnimap+amin:Sent"
1954    gnus-parameters
1955    '(("gnu.*"
1956       (gcc-self . t)))
1957    gnus-large-newsgroup  50
1958    gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
1959    gnus-directory        (concat gnus-home-directory "news/")
1960    message-directory     (concat gnus-home-directory "mail/")
1961    nndraft-directory     (concat gnus-home-directory "drafts/")
1962    gnus-save-newsrc-file nil
1963    gnus-read-newsrc-file nil
1964    gnus-interactive-exit nil
1965    gnus-gcc-mark-as-read t))
1966
1967 (use-package gnus-art
1968   :config
1969   (setq
1970    gnus-visible-headers
1971    (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
1972    gnus-sorted-header-list
1973    '("^From:" "^Subject:" "^Summary:" "^Keywords:"
1974      "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
1975      "^Newsgroups:" "List-Id:" "^Organization:"
1976      "^User-Agent:" "^Date:")
1977   ;; local-lapsed article dates
1978   ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
1979   gnus-article-date-headers '(user-defined)
1980   gnus-article-time-format
1981   (lambda (time)
1982     (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
1983            (local (article-make-date-line date 'local))
1984            (combined-lapsed (article-make-date-line date
1985                                                     'combined-lapsed))
1986            (lapsed (progn
1987                      (string-match " (.+" combined-lapsed)
1988                      (match-string 0 combined-lapsed))))
1989       (concat local lapsed))))
1990   (bind-keys
1991    :map gnus-article-mode-map
1992    ("r"   . gnus-article-reply-with-original)
1993    ("R"   . gnus-article-wide-reply-with-original)
1994    ("M-L" . org-store-link)))
1995
1996 (use-package gnus-sum
1997   :bind (:map gnus-summary-mode-map
1998               :prefix-map a/gnus-summary-prefix-map
1999               :prefix "v"
2000               ("r" . gnus-summary-reply)
2001               ("w" . gnus-summary-wide-reply)
2002               ("v" . gnus-summary-show-raw-article))
2003   :config
2004   (bind-keys
2005    :map gnus-summary-mode-map
2006    ("r"   . gnus-summary-reply-with-original)
2007    ("R"   . gnus-summary-wide-reply-with-original)
2008    ("M-L" . org-store-link))
2009   :hook (gnus-summary-mode . a/no-mouse-autoselect-window))
2010
2011 (use-package gnus-msg
2012   :config
2013   (setq gnus-posting-styles
2014         '((".*"
2015            (address "amin@aminb.org")
2016            (body "\nBest,\namin\n")
2017            (eval (setq a/message-cite-say-hi t)))
2018           ("gnu.*"
2019            (address "bandali@gnu.org"))
2020           ((header "subject" "ThankCRM")
2021            (to "webmasters-comment@gnu.org")
2022            (body "\nAdded  to 2018supporters.html.\n\nMoving to campaigns.\n\n-amin\n")
2023            (eval (setq a/message-cite-say-hi nil)))
2024           ("nnimap\\+uwaterloo:.*"
2025            (address "abandali@uwaterloo.ca")
2026            (gcc "\"nnimap+uwaterloo:Sent Items\"")))))
2027
2028 (use-package gnus-topic
2029   :hook (gnus-group-mode . gnus-topic-mode))
2030
2031 (use-package gnus-agent
2032   :config
2033   (setq gnus-agent-synchronize-flags 'ask)
2034   :hook (gnus-group-mode . gnus-agent-mode))
2035
2036 (use-package gnus-group
2037   :config
2038   (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))
2039
2040 (use-package mm-decode
2041   :config
2042   (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
2043 #+end_src
2044
2045 ** sendmail
2046
2047 #+begin_src emacs-lisp
2048 (use-package sendmail
2049   :config
2050   (setq sendmail-program "/usr/bin/msmtp"
2051         ;; message-sendmail-extra-arguments '("-v" "-d")
2052         mail-specify-envelope-from t
2053         mail-envelope-from 'header))
2054 #+end_src
2055
2056 ** message
2057
2058 #+begin_src emacs-lisp
2059 (use-package message
2060   :config
2061   (defconst a/message-cite-style-format "On %Y-%m-%d %l:%M %p, %N wrote:")
2062   (defconst message-cite-style-bandali
2063     '((message-cite-function  'message-cite-original)
2064       (message-citation-line-function  'message-insert-formatted-citation-line)
2065       (message-cite-reply-position 'traditional)
2066       (message-yank-prefix  "> ")
2067       (message-yank-cited-prefix  ">")
2068       (message-yank-empty-prefix  ">")
2069       (message-citation-line-format
2070        (if a/message-cite-say-hi
2071            (concat "Hi %F,\n\n" a/message-cite-style-format)
2072          a/message-cite-style-format)))
2073     "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
2074   (setq message-cite-style 'message-cite-style-bandali
2075         message-kill-buffer-on-exit t
2076         message-send-mail-function 'message-send-mail-with-sendmail
2077         message-sendmail-envelope-from 'header
2078         message-dont-reply-to-names
2079         "\\(\\(.*@aminb\\.org\\)\\|\\(amin@bandali\\.me\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
2080         message-user-fqdn "aminb.org")
2081   :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
2082          (message-mode . flyspell-mode)
2083          (message-mode . (lambda ()
2084                            ;; (setq fill-column 65
2085                            ;;       message-fill-column 65)
2086                            (make-local-variable 'company-idle-delay)
2087                            (setq company-idle-delay 0.2))))
2088   ;; :custom-face
2089   ;; (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
2090   ;; (message-header-to      ((t (:foreground "#111" :weight normal))))
2091   ;; (message-header-cc      ((t (:foreground "#333" :weight normal))))
2092   )
2093
2094 (with-eval-after-load 'mml-sec
2095   (setq mml-secure-openpgp-encrypt-to-self t
2096         mml-secure-openpgp-sign-with-sender t))
2097 #+end_src
2098
2099 ** footnote
2100
2101 Convenient footnotes in =message-mode=.
2102
2103 #+begin_src emacs-lisp
2104 (use-package footnote
2105   :after message
2106   :bind
2107   (:map message-mode-map
2108         :prefix-map a/footnote-prefix-map
2109         :prefix "C-c f"
2110         ("a" . footnote-add-footnote)
2111         ("b" . footnote-back-to-message)
2112         ("c" . footnote-cycle-style)
2113         ("d" . footnote-delete-footnote)
2114         ("g" . footnote-goto-footnote)
2115         ("r" . footnote-renumber-footnotes)
2116         ("s" . footnote-set-style))
2117   :config
2118   (setq footnote-start-tag ""
2119         footnote-end-tag   ""
2120         footnote-style     'unicode))
2121 #+end_src
2122
2123 ** ebdb
2124
2125 #+begin_src emacs-lisp
2126 (use-package ebdb
2127   :defer 1
2128   :bind (:map gnus-group-mode-map ("e" . ebdb))
2129   :config
2130   (setq ebdb-sources (no-littering-expand-var-file-name "ebdb"))
2131   (with-eval-after-load 'swiper
2132     (add-to-list 'swiper-font-lock-exclude 'ebdb-mode t)))
2133
2134 (use-package ebdb-com
2135   :after ebdb)
2136
2137 ;; (use-package ebdb-complete
2138 ;;   :after ebdb
2139 ;;   :config
2140 ;;   (ebdb-complete-enable))
2141
2142 (use-package company-ebdb
2143   :after (:all company message)
2144   :config
2145   (defun company-ebdb--post-complete (_) nil)
2146   :hook
2147   (message-mode . (lambda ()
2148                     (add-to-list (make-local-variable 'company-backends)
2149                                  'company-ebdb))))
2150
2151 (use-package ebdb-gnus
2152   :after ebdb
2153   :custom
2154   (ebdb-gnus-window-configuration
2155    '(article
2156      (vertical 1.0
2157                (summary 0.25 point)
2158                (horizontal 1.0
2159                            (article 1.0)
2160                            (ebdb-gnus 0.3))))))
2161
2162 (use-package ebdb-mua
2163   :after ebdb
2164   ;; :custom (ebdb-mua-pop-up nil)
2165   )
2166
2167 ;; (use-package ebdb-message
2168 ;;   :after ebdb)
2169
2170
2171 ;; (use-package ebdb-vcard
2172 ;;   :after ebdb)
2173 #+end_src
2174
2175 ** COMMENT message-x
2176
2177 #+begin_src emacs-lisp
2178 (use-package message-x
2179   :custom
2180   (message-x-completion-alist
2181    (quote
2182     (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
2183      ((if
2184           (boundp
2185            (quote message-newgroups-header-regexp))
2186           message-newgroups-header-regexp message-newsgroups-header-regexp)
2187       . message-expand-group)))))
2188 #+end_src
2189
2190 ** COMMENT gnus-harvest
2191
2192 #+begin_src emacs-lisp
2193 (use-package gnus-harvest
2194   :commands gnus-harvest-install
2195   :demand t
2196   :config
2197   (if (featurep 'message-x)
2198       (gnus-harvest-install 'message-x)
2199     (gnus-harvest-install)))
2200 #+end_src
2201
2202 * Blogging
2203 :PROPERTIES:
2204 :CUSTOM_ID: blogging
2205 :END:
2206
2207 ** [[https://ox-hugo.scripter.co][ox-hugo]]
2208
2209 #+begin_src emacs-lisp
2210 (use-package ox-hugo
2211   :after ox)
2212
2213 (use-package ox-hugo-auto-export
2214   :load-path "lib/ox-hugo")
2215 #+end_src
2216
2217 * Post initialization
2218 :PROPERTIES:
2219 :CUSTOM_ID: post-initialization
2220 :END:
2221
2222 Display how long it took to load the init file.
2223
2224 #+begin_src emacs-lisp
2225 (message "Loading %s...done (%.3fs)" user-init-file
2226          (float-time (time-subtract (current-time)
2227                                     a/before-user-init-time)))
2228 #+end_src
2229
2230 * Footer
2231 :PROPERTIES:
2232 :CUSTOM_ID: footer
2233 :END:
2234
2235 #+begin_src emacs-lisp :comments none
2236 ;;; init.el ends here
2237 #+end_src
2238
2239 * COMMENT Local Variables                                           :ARCHIVE:
2240 # Local Variables:
2241 # eval: (add-hook 'after-save-hook #'a/async-babel-tangle 'append 'local)
2242 # eval: (typo-mode -1)
2243 # End: