git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** Package management
 192
 193 *** No =package.el=
 194
 195 I can do all my package management things with Borg, and don't need
 196 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 197 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 198
 199 #+begin_src emacs-lisp :tangle early-init.el
 200 (setq package-enable-at-startup nil)
 201 #+end_src
 202
 203 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 204 right now), and even when released it'll be long before most distros
 205 ship in their repos, I'll still put the old workaround with the
 206 commented call to ~package-initialize~ here anyway.
 207
 208 #+begin_src emacs-lisp
 209 (setq package-enable-at-startup nil)
 210 ;; (package-initialize)
 211 #+end_src
 212
 213 *** Borg
 214
 215 #+begin_quote
 216 Assimilate Emacs packages as Git submodules
 217 #+end_quote
 218
 219 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 220 short, it creates a git submodule in =lib/= for each package, which
 221 can then be managed with the help of Magit or other tools.
 222
 223 #+begin_src emacs-lisp
 224 (setq user-init-file (or load-file-name buffer-file-name)
 225       user-emacs-directory (file-name-directory user-init-file))
 226 (add-to-list 'load-path
 227              (expand-file-name "lib/borg" user-emacs-directory))
 228 (require 'borg)
 229 (borg-initialize)
 230 #+end_src
 231
 232 *** =use-package=
 233
 234 #+begin_quote
 235 A use-package declaration for simplifying your .emacs
 236 #+end_quote
 237
 238 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 239 packages (in our case especially the latter) in a neatly organized way
 240 and without compromising on performance.
 241
 242 #+begin_src emacs-lisp
 243 (require 'use-package)
 244 (if nil                             ; set to t when need to debug init
 245     (setq use-package-verbose t
 246           use-package-expand-minimally nil
 247           use-package-compute-statistics t
 248           debug-on-error t)
 249   (setq use-package-verbose nil
 250         use-package-expand-minimally t))
 251 #+end_src
 252
 253 *** Epkg
 254
 255 #+begin_quote
 256 Browse the Emacsmirror package database
 257 #+end_quote
 258
 259 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 260 database, low-level functions for querying the database, and a
 261 =package.el=-like user interface for browsing the available packages.
 262
 263 #+begin_src emacs-lisp
 264 (use-package epkg
 265   :defer t)
 266 #+end_src
 267
 268 ** No littering in =~/.emacs.d=
 269
 270 #+begin_quote
 271 Help keeping ~/.emacs.d clean
 272 #+end_quote
 273
 274 By default, even for Emacs' built-in packages, the configuration files
 275 and persistent data are all over the place. Use =no-littering= to help
 276 contain the mess.
 277
 278 #+begin_src emacs-lisp
 279 (use-package no-littering
 280   :demand t
 281   :config
 282   (savehist-mode 1)
 283   (add-to-list 'savehist-additional-variables 'kill-ring)
 284   (save-place-mode 1)
 285   (setq auto-save-file-name-transforms
 286         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 287 #+end_src
 288
 289 ** Custom file (=custom.el=)
 290
 291 I'm not planning on using the custom file much, but even so, I
 292 definitely don't want it mixing with =init.el=. So, here; let's give
 293 it it's own file. While at it, treat themes as safe.
 294
 295 #+begin_src emacs-lisp
 296 (use-package custom
 297   :no-require t
 298   :config
 299   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 300   (when (file-exists-p custom-file)
 301     (load custom-file))
 302   (setf custom-safe-themes t))
 303 #+end_src
 304
 305 ** Better =$PATH= handling
 306
 307 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 308 in my shell.
 309
 310 #+begin_src emacs-lisp
 311 (use-package exec-path-from-shell
 312   :defer 1
 313   :init
 314   (setq exec-path-from-shell-check-startup-files nil)
 315   :config
 316   (exec-path-from-shell-initialize)
 317   ;; while we're at it, let's fix access to our running ssh-agent
 318   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 319   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 320 #+end_src
 321
 322 ** Only one custom theme at a time
 323
 324 #+begin_src emacs-lisp
 325 (defadvice load-theme (before clear-previous-themes activate)
 326   "Clear existing theme settings instead of layering them"
 327   (mapc #'disable-theme custom-enabled-themes))
 328 #+end_src
 329
 330 ** Server
 331
 332 Start server if not already running. Alternatively, can be done by
 333 issuing =emacs --daemon= in the terminal, which can be automated with
 334 a systemd service or using =brew services start emacs= on macOS. I use
 335 Emacs as my window manager (via EXWM), so I always start Emacs on
 336 login; so starting the server from inside Emacs is good enough for me.
 337
 338 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 339
 340 #+begin_src emacs-lisp
 341 (use-package server
 342   :config (or (server-running-p) (server-mode)))
 343 #+end_src
 344
 345 ** Unicode support
 346
 347 Font stack with better unicode support, around =Ubuntu Mono= and
 348 =Hack=.
 349
 350 #+begin_src emacs-lisp
 351 (dolist (ft (fontset-list))
 352   (set-fontset-font
 353    ft
 354    'unicode
 355    (font-spec :name "Ubuntu Mono"))
 356   (set-fontset-font
 357    ft
 358    'unicode
 359    (font-spec :name "DejaVu Sans Mono")
 360    nil
 361    'append)
 362   ;; (set-fontset-font
 363   ;;  ft
 364   ;;  'unicode
 365   ;;  (font-spec
 366   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 367   ;;  nil
 368   ;;  'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  #x2115  ; ℕ
 372   ;;  (font-spec :name "DejaVu Sans Mono")
 373   ;;  nil
 374   ;;  'append)
 375   (set-fontset-font
 376    ft
 377    (cons ?Α ?ω)
 378    (font-spec :name "DejaVu Sans Mono" :size 14)
 379    nil
 380    'prepend))
 381 #+end_src
 382
 383 ** Libraries
 384
 385 #+begin_src emacs-lisp
 386 (require 'cl-lib)
 387 (require 'subr-x)
 388 #+end_src
 389
 390 ** Useful utilities
 391
 392 #+begin_src emacs-lisp
 393 (defun ab-enlist (exp)
 394   "Return EXP wrapped in a list, or as-is if already a list."
 395 (if (listp exp) exp (list exp)))
 396
 397 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 398 (defmacro after! (features &rest body)
 399   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 400 compilation."
 401   (declare (indent defun) (debug t))
 402   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 403                 (dolist (next (ab-enlist features))
 404                   (if (symbolp next)
 405                       (require next nil :no-error)
 406                     (load next :no-message :no-error))))
 407             #'progn
 408           #'with-no-warnings)
 409         (cond ((symbolp features)
 410                `(eval-after-load ',features '(progn ,@body)))
 411               ((and (consp features)
 412                     (memq (car features) '(:or :any)))
 413                `(progn
 414                   ,@(cl-loop for next in (cdr features)
 415                              collect `(after! ,next ,@body))))
 416               ((and (consp features)
 417                     (memq (car features) '(:and :all)))
 418                (dolist (next (cdr features))
 419                  (setq body `(after! ,next ,@body)))
 420                body)
 421               ((listp features)
 422                `(after! (:all ,@features) ,@body)))))
 423 #+end_src
 424
 425 * Core
 426 :PROPERTIES:
 427 :CUSTOM_ID: core
 428 :END:
 429
 430 ** Defaults
 431
 432 *** Time and battery in mode-line
 433
 434 Enable displaying time and battery in the mode-line, since I'm not
 435 using the Xfce panel anymore. Also, I don't need to see the load
 436 average on a regular basis, so disable that.
 437
 438 #+begin_src emacs-lisp
 439 (use-package time
 440   :ensure nil
 441   :init
 442   (setq display-time-default-load-average nil)
 443   :config
 444   (display-time-mode))
 445
 446 (use-package battery
 447   :ensure nil
 448   :config
 449   (display-battery-mode))
 450 #+end_src
 451
 452 *** Smaller fringe
 453
 454 Might want to set the fringe to a smaller value, especially if using
 455 EXWM. I'm fine with the default for now.
 456
 457 #+begin_src emacs-lisp
 458 ;; (fringe-mode '(3 . 1))
 459 (fringe-mode nil)
 460 #+end_src
 461
 462 *** Disable disabled commands
 463
 464 Emacs disables some commands by default that could persumably be
 465 confusing for novice users. Let's disable that.
 466
 467 #+begin_src emacs-lisp
 468 (setq disabled-command-function nil)
 469 #+end_src
 470
 471 *** Kill-ring
 472
 473 Save what I copy into clipboard from other applications into Emacs'
 474 kill-ring, which would allow me to still be able to easily access it
 475 in case I kill (cut or copy) something else inside Emacs before
 476 yanking (pasting) what I'd originally intended to.
 477
 478 #+begin_src emacs-lisp
 479 (setq save-interprogram-paste-before-kill t)
 480 #+end_src
 481
 482 *** Minibuffer
 483
 484 #+begin_src emacs-lisp
 485 (setq enable-recursive-minibuffers t
 486       resize-mini-windows t)
 487 #+end_src
 488
 489 *** Lazy-person-friendly yes/no prompts
 490
 491 Lazy people would prefer to type fewer keystrokes, especially for yes
 492 or no questions. I'm lazy.
 493
 494 #+begin_src emacs-lisp
 495 (defalias 'yes-or-no-p #'y-or-n-p)
 496 #+end_src
 497
 498 *** Startup screen and =*scratch*=
 499
 500 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 501 startup buffer.
 502
 503 #+begin_src emacs-lisp
 504 (setq initial-buffer-choice t)
 505 #+end_src
 506
 507 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 508 need the default hint.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-scratch-message nil)
 512 #+end_src
 513
 514 Also, let's use Text mode as the major mode, in case I want to
 515 customize it (=*scratch*='s default major mode, Fundamental mode,
 516 can't really be customized).
 517
 518 #+begin_src emacs-lisp
 519 (setq initial-major-mode 'text-mode)
 520 #+end_src
 521
 522 Inhibit the buffer list when more than 2 files are loaded.
 523
 524 #+begin_src emacs-lisp
 525 (setq inhibit-startup-buffer-menu t)
 526 #+end_src
 527
 528 I don't really need to see the startup screen or echo area message
 529 either.
 530
 531 #+begin_src emacs-lisp
 532 (advice-add #'display-startup-echo-area-message :override #'ignore)
 533 (setq inhibit-startup-screen t
 534       inhibit-startup-echo-area-message user-login-name)
 535 #+end_src
 536
 537 *** More useful frame titles
 538
 539 Show either the file name or the buffer name (in case the buffer isn't
 540 visiting a file). Borrowed from Emacs Prelude.
 541
 542 #+begin_src emacs-lisp
 543 (setq frame-title-format
 544       '("" invocation-name " - "
 545         (:eval (if (buffer-file-name)
 546                    (abbreviate-file-name (buffer-file-name))
 547                  "%b"))))
 548 #+end_src
 549
 550 *** Backups
 551
 552 Emacs' default backup settings aren't that great. Let's use more
 553 sensible options. See documentation for the ~make-backup-file~
 554 variable.
 555
 556 #+begin_src emacs-lisp
 557 (setq backup-by-copying t
 558       version-control t)
 559 #+end_src
 560
 561 ** Packages
 562
 563 The packages in this section are absolutely essential to my everyday
 564 workflow, and they play key roles in how I do my computing. They
 565 immensely enhance the Emacs experience for me; both using Emacs, and
 566 customizing it.
 567
 568 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 569
 570 #+begin_src emacs-lisp
 571 (use-package auto-compile
 572   :demand t
 573   :config
 574   (auto-compile-on-load-mode)
 575   (auto-compile-on-save-mode)
 576   (setq auto-compile-display-buffer               nil
 577         auto-compile-mode-line-counter            t
 578         auto-compile-source-recreate-deletes-dest t
 579         auto-compile-toggle-deletes-nonlib-dest   t
 580         auto-compile-update-autoloads             t)
 581   (add-hook 'auto-compile-inhibit-compile-hook
 582             'auto-compile-inhibit-compile-detached-git-head))
 583 #+end_src
 584
 585 *** TODO [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 586
 587 #+begin_quote
 588 Roll your own modal mode
 589 #+end_quote
 590
 591 *** [[https://github.com/ch11ng/exwm][EXWM]] (window manager)
 592
 593 #+begin_src emacs-lisp :tangle no
 594 (use-package exwm
 595   :demand t
 596   :config
 597   (require 'exwm-config)
 598
 599   ;; Set the initial workspace number.
 600   (setq exwm-workspace-number 4)
 601
 602   ;; Make class name the buffer name, truncating beyond 50 characters
 603   (defun exwm-rename-buffer ()
 604     (interactive)
 605     (exwm-workspace-rename-buffer
 606      (concat exwm-class-name ":"
 607              (if (<= (length exwm-title) 50) exwm-title
 608                (concat (substring exwm-title 0 49) "...")))))
 609   (add-hook 'exwm-update-class-hook 'exwm-rename-buffer)
 610   (add-hook 'exwm-update-title-hook 'exwm-rename-buffer)
 611
 612   ;; 's-R': Reset
 613   (exwm-input-set-key (kbd "s-R") #'exwm-reset)
 614   ;; 's-\': Switch workspace
 615   (exwm-input-set-key (kbd "s-\\") #'exwm-workspace-switch)
 616   ;; 's-N': Switch to certain workspace
 617   (dotimes (i 10)
 618     (exwm-input-set-key (kbd (format "s-%d" i))
 619                         (lambda ()
 620                           (interactive)
 621                           (exwm-workspace-switch-create i))))
 622   ;; 's-SPC': Launch application
 623   ;; (exwm-input-set-key
 624   ;;  (kbd "s-SPC")
 625   ;;  (lambda (command)
 626   ;;    (interactive (list (read-shell-command "➜ ")))
 627   ;;    (start-process-shell-command command nil command)))
 628
 629   (exwm-input-set-key (kbd "M-s-SPC") #'counsel-linux-app)
 630
 631   ;; Shorten 'C-c C-q' to 'C-q'
 632   (define-key exwm-mode-map [?\C-q] #'exwm-input-send-next-key)
 633
 634   ;; Line-editing shortcuts
 635   (setq exwm-input-simulation-keys
 636         '(;; movement
 637           ([?\C-b] . [left])
 638           ([?\M-b] . [C-left])
 639           ([?\C-f] . [right])
 640           ([?\M-f] . [C-right])
 641           ([?\C-p] . [up])
 642           ([?\C-n] . [down])
 643           ([?\C-a] . [home])
 644           ([?\C-e] . [end])
 645           ([?\M-v] . [prior])
 646           ([?\C-v] . [next])
 647           ([?\C-d] . [delete])
 648           ([?\C-k] . [S-end delete])
 649           ;; cut/copy/paste
 650           ;; ([?\C-w] . [?\C-x])
 651           ([?\M-w] . [?\C-c])
 652           ([?\C-y] . [?\C-v])
 653           ;; search
 654           ([?\C-s] . [?\C-f])))
 655
 656   ;; Enable EXWM
 657   (exwm-enable)
 658
 659   (add-hook 'exwm-init-hook #'exwm-config--fix/ido-buffer-window-other-frame)
 660
 661   (require 'exwm-systemtray)
 662   (exwm-systemtray-enable)
 663
 664   (require 'exwm-randr)
 665   (exwm-randr-enable)
 666
 667   ;; (exwm-input-set-key
 668   ;;  (kbd "s-<return>")
 669   ;;  (lambda ()
 670   ;;    (interactive)
 671   ;;    (start-process "urxvt" nil "urxvt")))
 672
 673   ;; (exwm-input-set-key
 674   ;;  (kbd "s-SPC")  ;; rofi doesn't properly launch programs when started from emacs
 675   ;;  (lambda ()
 676   ;;    (interactive)
 677   ;;    (start-process-shell-command "rofi-run" nil "rofi -show run -display-run '> ' -display-window ' 🗔 '")))
 678
 679   ;; (exwm-input-set-key
 680   ;;  (kbd "s-/")
 681   ;;  (lambda ()
 682   ;;    (interactive)
 683   ;;    (start-process-shell-command "rofi-win" nil "rofi -show window  -display-run '> ' -display-window ' 🗔 '")))
 684
 685   ;; (exwm-input-set-key
 686   ;;  (kbd "M-SPC")
 687   ;;  (lambda ()
 688   ;;    (interactive)
 689   ;;    (start-process "rofi-pass" nil "rofi-pass")))
 690
 691   ;; (exwm-input-set-key
 692   ;;  (kbd "<XF86AudioMute>")
 693   ;;  (lambda ()
 694   ;;    (interactive)
 695   ;;    (start-process-shell-command "pamixer" nil "pamixer --toggle-mute")))
 696
 697   ;; (exwm-input-set-key
 698   ;;  (kbd "<XF86AudioLowerVolume>")
 699   ;;  (lambda ()
 700   ;;    (interactive)
 701   ;;    (start-process-shell-command "pamixer" nil "pamixer --allow-boost --decrease 5")))
 702
 703   ;; (exwm-input-set-key
 704   ;;  (kbd "<XF86AudioRaiseVolume>")
 705   ;;  (lambda ()
 706   ;;    (interactive)
 707   ;;    (start-process-shell-command "pamixer" nil "pamixer --allow-boost --increase 5")))
 708
 709   ;; (exwm-input-set-key
 710   ;;  (kbd "<XF86AudioPlay>")
 711   ;;  (lambda ()
 712   ;;    (interactive)
 713   ;;    (start-process-shell-command "mpc" nil "mpc toggle")))
 714
 715   ;; (exwm-input-set-key
 716   ;;  (kbd "<XF86AudioPrev>")
 717   ;;  (lambda ()
 718   ;;    (interactive)
 719   ;;    (start-process-shell-command "mpc" nil "mpc prev")))
 720
 721   ;; (exwm-input-set-key
 722   ;;  (kbd "<XF86AudioNext>")
 723   ;;  (lambda ()
 724   ;;    (interactive)
 725   ;;    (start-process-shell-command "mpc" nil "mpv next")))
 726
 727   (defun ab--exwm-pasystray ()
 728     "A command used to start pasystray."
 729     (interactive)
 730     (if (executable-find "pasystray")
 731         (progn
 732           (message "EXWM: starting pasystray ...")
 733           (start-process-shell-command "pasystray" nil "pasystray --notify=all"))
 734       (message "EXWM: pasystray is not installed, abort!")))
 735
 736   (add-hook 'exwm-init-hook #'ab--exwm-pasystray)
 737
 738   (exwm-input-set-key
 739    (kbd "s-t")
 740    (lambda ()
 741      (interactive)
 742      (exwm-floating-toggle-floating)))
 743
 744   (exwm-input-set-key
 745    (kbd "s-f")
 746    (lambda ()
 747      (interactive)
 748      (exwm-layout-toggle-fullscreen)))
 749
 750   (exwm-input-set-key
 751    (kbd "s-w")
 752    (lambda ()
 753      (interactive)
 754      (kill-buffer (current-buffer))))
 755
 756   (exwm-input-set-key
 757    (kbd "s-q")
 758    (lambda ()
 759      (interactive)
 760      (exwm-manage--kill-client))))
 761 #+end_src
 762
 763 **** sxhkdrc
 764 :PROPERTIES:
 765 :header-args+: :tangle ~/.config/sxhkd/sxhkdrc :mkdirp yes
 766 :END:
 767
 768 #+begin_src conf :tangle no
 769 # terminal emulator
 770 super + Return
 771         urxvt
 772
 773 # program launcher
 774 super + space
 775         rofi -show run -display-run '> ' -display-window ' 🗔 '
 776
 777 # window finder
 778 super + slash
 779         rofi -show window  -display-run '> ' -display-window ' 🗔 '
 780
 781 # password manager
 782 alt + space
 783         rofi-pass
 784
 785 # make sxhkd reload its configuration files:
 786 super + Escape
 787         pkill -USR1 -x sxhkd
 788
 789 # volume {up,down}
 790 XF86Audio{Raise,Lower}Volume
 791         pamixer --allow-boost --{in,de}crease 5
 792
 793 # mute
 794 XF86AudioMute
 795         pamixer --toggle-mute
 796
 797 # playback control
 798 XF86Audio{Play,Prev,Next}
 799         mpc {toggle,prev,next}
 800
 801 # Toggle keyboard layout
 802 # super + F7
 803 #       toggle-layout
 804
 805 # Toggle Xfce presentation mode
 806 # XF86LaunchB
 807 #       toggle-presentation-mode
 808
 809 # monitor brightness
 810 XF86MonBrightness{Up,Down}
 811         light -{A,U} 5
 812
 813 super + apostrophe
 814         rofi-light
 815 #+end_src
 816
 817 *** [[https://orgmode.org/][Org mode]]
 818
 819 #+begin_quote
 820 Org mode is for keeping notes, maintaining TODO lists, planning
 821 projects, and authoring documents with a fast and effective plain-text
 822 system.
 823 #+end_quote
 824
 825 In short, my favourite way of life.
 826
 827 #+begin_src emacs-lisp
 828 (setq org-src-tab-acts-natively t
 829       org-src-preserve-indentation nil
 830       org-edit-src-content-indentation 0)
 831 #+end_src
 832
 833 *** [[https://magit.vc/][Magit]]
 834
 835 #+begin_quote
 836 It's Magit! A Git porcelain inside Emacs.
 837 #+end_quote
 838
 839 Not just how I do git, but /the/ way to do git.
 840
 841 #+begin_src emacs-lisp
 842 (use-package magit
 843   :defer t
 844   :bind (("s-g"     . magit-status)
 845          ("C-x g"   . magit-status)
 846          ("C-x M-g" . magit-dispatch-popup))
 847   :config
 848   (magit-add-section-hook 'magit-status-sections-hook
 849                           'magit-insert-modules
 850                           'magit-insert-stashes
 851                           'append))
 852 #+end_src
 853
 854 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 855
 856 #+begin_quote
 857 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 858 an overview, and more. Oh, man!
 859 #+end_quote
 860
 861 There's no way I could top that, so I won't attempt to.
 862
 863 **** Ivy
 864
 865 #+begin_src emacs-lisp
 866 (use-package ivy
 867   :bind
 868   (:map ivy-minibuffer-map
 869         ([escape] . keyboard-escape-quit)
 870         ;; ("C-j"    . ivy-next-line)
 871         ;; ("C-k"    . ivy-previous-line)
 872         ([S-up]   . ivy-previous-history-element)
 873         ([S-down] . ivy-next-history-element)
 874         ("DEL"    . ivy-backward-delete-char))
 875   :config
 876   (setq ivy-wrap t)
 877   (ivy-mode 1))
 878 #+end_src
 879
 880 **** Swiper
 881
 882 #+begin_src emacs-lisp
 883 (use-package swiper
 884   :bind (([remap isearch-forward]  . swiper)
 885          ([remap isearch-backward] . swiper)))
 886 #+end_src
 887
 888 **** Counsel
 889
 890 #+begin_src emacs-lisp
 891 (use-package counsel
 892   :defer 1
 893   :bind (([remap execute-extended-command] . counsel-M-x)
 894          ([remap find-file] . counsel-find-file)
 895          ("s-r"     . counsel-recentf)
 896          :map minibuffer-local-map
 897          ("C-r" . counsel-minibuffer-history))
 898   :config
 899   (counsel-mode 1)
 900   (defalias 'locate #'counsel-locate))
 901 #+end_src
 902
 903 * Borg's =layer/essentials=
 904
 905 TODO: break this giant source block down into individual org sections.
 906
 907 #+begin_src emacs-lisp
 908 (use-package dash
 909   :config (dash-enable-font-lock))
 910
 911 (use-package diff-hl
 912   :config
 913   (setq diff-hl-draw-borders nil)
 914   (global-diff-hl-mode)
 915   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 916
 917 (use-package dired
 918   :defer t
 919   :config (setq dired-listing-switches "-alh"))
 920
 921 (use-package eldoc
 922   :when (version< "25" emacs-version)
 923   :config (global-eldoc-mode))
 924
 925 (use-package help
 926   :defer t
 927   :config (temp-buffer-resize-mode))
 928
 929 (progn ;    `isearch'
 930   (setq isearch-allow-scroll t))
 931
 932 (use-package lisp-mode
 933   :config
 934   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 935   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 936   (defun indent-spaces-mode ()
 937     (setq indent-tabs-mode nil))
 938   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 939
 940 (use-package man
 941   :defer t
 942   :config (setq Man-width 80))
 943
 944 (use-package paren
 945   :config (show-paren-mode))
 946
 947 (use-package prog-mode
 948   :config (global-prettify-symbols-mode)
 949   (defun indicate-buffer-boundaries-left ()
 950     (setq indicate-buffer-boundaries 'left))
 951   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 952
 953 (use-package recentf
 954   :demand t
 955   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 956
 957 (use-package savehist
 958   :config (savehist-mode))
 959
 960 (use-package saveplace
 961   :when (version< "25" emacs-version)
 962   :config (save-place-mode))
 963
 964 (use-package simple
 965   :config (column-number-mode))
 966
 967 (progn ;    `text-mode'
 968   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 969
 970 (use-package tramp
 971   :defer t
 972   :config
 973   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 974   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 975   (add-to-list 'tramp-default-proxies-alist
 976                (list (regexp-quote (system-name)) nil nil)))
 977
 978 (use-package undo-tree
 979   :config
 980   (global-undo-tree-mode)
 981   (setq undo-tree-mode-lighter ""))
 982 #+end_src
 983
 984 * Editing
 985
 986 ** Company
 987
 988 #+begin_src emacs-lisp
 989 (use-package company
 990   :defer 5
 991   :bind
 992   (:map company-active-map
 993         ([tab] . company-complete-common-or-cycle))
 994   :custom
 995   (company-idle-delay 0.3)
 996   (company-minimum-prefix-length 1)
 997   (company-selection-wrap-around t)
 998   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 999   :config
1000   (global-company-mode t))
1001 #+end_src
1002
1003 * Syntax and spell checking
1004 #+begin_src emacs-lisp
1005 (use-package flycheck
1006   :hook (prog-mode . flycheck-mode)
1007   :config
1008   ;; Use the load-path from running Emacs when checking elisp files
1009   (setq flycheck-emacs-lisp-load-path 'inherit)
1010
1011   ;; Only flycheck when I actually save the buffer
1012   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1013 #+end_src
1014 * Programming modes
1015
1016 ** [[https://github.com/leanprover/lean-mode][Lean]]
1017
1018 #+begin_src emacs-lisp
1019 (use-package lean-mode
1020   :bind (:map lean-mode-map
1021               ("S-SPC" . company-complete)))
1022 #+end_src
1023
1024 ** Haskell
1025
1026 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1027
1028 #+begin_src emacs-lisp
1029 (use-package haskell-mode
1030   :config
1031   (setq haskell-indentation-layout-offset 4
1032         haskell-indentation-left-offset 4
1033         flycheck-checker 'haskell-hlint
1034         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1035 #+end_src
1036
1037 *** [[https://github.com/jyp/dante][dante]]
1038
1039 #+begin_src emacs-lisp
1040 (use-package dante
1041   :after haskell-mode
1042   :commands dante-mode
1043   :hook (haskell-mode . dante-mode))
1044 #+end_src
1045
1046 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1047
1048 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1049 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1050
1051 #+begin_src emacs-lisp
1052 (use-package hlint-refactor
1053   :bind (:map hlint-refactor-mode-map
1054               ("C-c l b" . hlint-refactor-refactor-buffer)
1055               ("C-c l r" . hlint-refactor-refactor-at-point))
1056   :hook (haskell-mode . hlint-refactor-mode))
1057 #+end_src
1058
1059 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1060
1061 #+begin_src emacs-lisp
1062 (use-package flycheck-haskell)
1063 #+end_src
1064
1065 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1066 :PROPERTIES:
1067 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1068 :END:
1069
1070 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1071 instead.
1072
1073 #+begin_src emacs-lisp :tangle no
1074 ;;; hs-lint.el --- minor mode for HLint code checking
1075
1076 ;; Copyright 2009 (C) Alex Ott
1077 ;;
1078 ;; Author: Alex Ott <alexott@gmail.com>
1079 ;; Keywords: haskell, lint, HLint
1080 ;; Requirements:
1081 ;; Status: distributed under terms of GPL2 or above
1082
1083 ;; Typical message from HLint looks like:
1084 ;;
1085 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1086 ;; Found:
1087 ;;   count1 p l = length (filter p l)
1088 ;; Why not:
1089 ;;   count1 p = length . filter p
1090
1091
1092 (require 'compile)
1093
1094 (defgroup hs-lint nil
1095   "Run HLint as inferior of Emacs, parse error messages."
1096   :group 'tools
1097   :group 'haskell)
1098
1099 (defcustom hs-lint-command "hlint"
1100   "The default hs-lint command for \\[hlint]."
1101   :type 'string
1102   :group 'hs-lint)
1103
1104 (defcustom hs-lint-save-files t
1105   "Save modified files when run HLint or no (ask user)"
1106   :type 'boolean
1107   :group 'hs-lint)
1108
1109 (defcustom hs-lint-replace-with-suggestions nil
1110   "Replace user's code with suggested replacements"
1111   :type 'boolean
1112   :group 'hs-lint)
1113
1114 (defcustom hs-lint-replace-without-ask nil
1115   "Replace user's code with suggested replacements automatically"
1116   :type 'boolean
1117   :group 'hs-lint)
1118
1119 (defun hs-lint-process-setup ()
1120   "Setup compilation variables and buffer for `hlint'."
1121   (run-hooks 'hs-lint-setup-hook))
1122
1123 ;; regex for replace suggestions
1124 ;;
1125 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1126 ;; Found:
1127 ;; \s +\(.*\)
1128 ;; Why not:
1129 ;; \s +\(.*\)
1130
1131 (defvar hs-lint-regex
1132   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1133   "Regex for HLint messages")
1134
1135 (defun make-short-string (str maxlen)
1136   (if (< (length str) maxlen)
1137       str
1138     (concat (substring str 0 (- maxlen 3)) "...")))
1139
1140 (defun hs-lint-replace-suggestions ()
1141   "Perform actual replacement of suggestions"
1142   (goto-char (point-min))
1143   (while (re-search-forward hs-lint-regex nil t)
1144     (let* ((fname (match-string 1))
1145           (fline (string-to-number (match-string 2)))
1146           (old-code (match-string 4))
1147           (new-code (match-string 5))
1148           (msg (concat "Replace '" (make-short-string old-code 30)
1149                        "' with '" (make-short-string new-code 30) "'"))
1150           (bline 0)
1151           (eline 0)
1152           (spos 0)
1153           (new-old-code ""))
1154       (save-excursion
1155         (switch-to-buffer (get-file-buffer fname))
1156         (goto-char (point-min))
1157         (forward-line (1- fline))
1158         (beginning-of-line)
1159         (setf bline (point))
1160         (when (or hs-lint-replace-without-ask
1161                   (yes-or-no-p msg))
1162           (end-of-line)
1163           (setf eline (point))
1164           (beginning-of-line)
1165           (setf old-code (regexp-quote old-code))
1166           (while (string-match "\\\\ " old-code spos)
1167             (setf new-old-code (concat new-old-code
1168                                  (substring old-code spos (match-beginning 0))
1169                                  "\\ *"))
1170             (setf spos (match-end 0)))
1171           (setf new-old-code (concat new-old-code (substring old-code spos)))
1172           (remove-text-properties bline eline '(composition nil))
1173           (when (re-search-forward new-old-code eline t)
1174             (replace-match new-code nil t)))))))
1175
1176 (defun hs-lint-finish-hook (buf msg)
1177   "Function, that is executed at the end of HLint execution"
1178   (if hs-lint-replace-with-suggestions
1179       (hs-lint-replace-suggestions)
1180       (next-error 1 t)))
1181
1182 (define-compilation-mode hs-lint-mode "HLint"
1183   "Mode for check Haskell source code."
1184   (set (make-local-variable 'compilation-process-setup-function)
1185        'hs-lint-process-setup)
1186   (set (make-local-variable 'compilation-disable-input) t)
1187   (set (make-local-variable 'compilation-scroll-output) nil)
1188   (set (make-local-variable 'compilation-finish-functions)
1189        (list 'hs-lint-finish-hook))
1190   )
1191
1192 (defun hs-lint ()
1193   "Run HLint for current buffer with haskell source"
1194   (interactive)
1195   (save-some-buffers hs-lint-save-files)
1196   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1197                      'hs-lint-mode))
1198
1199 (provide 'hs-lint)
1200 ;;; hs-lint.el ends here
1201 #+end_src
1202
1203 #+begin_src emacs-lisp :tangle no
1204 (use-package hs-lint
1205   :load-path "lisp/"
1206   :bind (:map haskell-mode-map
1207               ("C-c l l" . hs-lint)))
1208 #+end_src
1209 * Emacs Enhancements
1210
1211 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1212
1213 #+begin_quote
1214 Emacs package that displays available keybindings in popup
1215 #+end_quote
1216
1217 #+begin_src emacs-lisp
1218 (use-package which-key
1219   :defer 1
1220   :config (which-key-mode))
1221 #+end_src
1222 * Email
1223 ** notmuch
1224
1225 #+begin_src emacs-lisp
1226 (defun ab/notmuch ()
1227   "Delete other windows, then launch `notmuch'."
1228   (interactive)
1229   (require 'notmuch)
1230   (delete-other-windows)
1231   (notmuch))
1232
1233 ;; (map!
1234 ;;  :leader
1235 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1236 ;;  (:desc "search" :prefix "/"
1237 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1238 #+end_src
1239
1240 #+begin_src emacs-lisp
1241 (defvar ab-maildir "~/mail")
1242
1243 (use-package sendmail
1244   ;; :ensure nil
1245   :config
1246   (setq sendmail-program "/usr/bin/msmtp"
1247         mail-specify-envelope-from t
1248         mail-envelope-from 'header))
1249
1250 (use-package message
1251   ;; :ensure nil
1252   :config
1253   (setq message-kill-buffer-on-exit t
1254         message-send-mail-function 'message-send-mail-with-sendmail
1255         message-sendmail-envelope-from 'header
1256         message-directory "drafts"
1257         message-user-fqdn "aminb.org")
1258   (add-hook 'message-mode-hook
1259             (lambda () (setq fill-column 65
1260                         message-fill-column 65)))
1261   (add-hook 'message-mode-hook
1262             #'flyspell-mode)
1263   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1264   ;; TODO: is there a way to only run this when replying and not composing?
1265   (add-hook 'notmuch-message-mode-hook
1266             (lambda () (progn
1267                     (newline)
1268                     (newline)
1269                     (forward-line -1)
1270                     (forward-line -1))))
1271   ;; (add-hook 'message-setup-hook
1272   ;;           #'mml-secure-message-sign-pgpmime)
1273   )
1274
1275 (after! mml-sec
1276   (setq mml-secure-openpgp-encrypt-to-self t
1277         mml-secure-openpgp-sign-with-sender t))
1278
1279 (use-package notmuch
1280   :config
1281   (setq notmuch-hello-sections
1282         '(notmuch-hello-insert-header
1283           notmuch-hello-insert-saved-searches
1284           ;; notmuch-hello-insert-search
1285           notmuch-hello-insert-alltags)
1286         notmuch-search-oldest-first nil
1287         notmuch-show-all-tags-list t
1288         notmuch-hello-thousands-separator ","
1289         notmuch-fcc-dirs
1290         '(("amin@aminb.org"            . "amin/Sent")
1291           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1292           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1293           ("aminb@gnu.org"             . "gnu/Sent")
1294           (".*"                        . "sent")))
1295   ;; (add-hook 'visual-fill-column-mode-hook
1296   ;;           (lambda ()
1297   ;;             (when (string= major-mode 'notmuch-message-mode)
1298   ;;               (setq visual-fill-column-width 70))))
1299   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1300   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1301   ;;             :override #'kill-this-buffer)
1302   :bind
1303   (:map notmuch-hello-mode-map
1304         ("g" . notmuch-poll-and-refresh-this-buffer)
1305         ("i" . (lambda ()
1306                  "Search for `inbox' tagged messages"
1307                  (interactive)
1308                  (notmuch-hello-search "tag:inbox")))
1309         ("u" . (lambda ()
1310                  "Search for `unread' tagged messages"
1311                  (interactive)
1312                  (notmuch-hello-search "tag:unread")))
1313         ("M" . (lambda ()
1314                  "Compose new mail and prompt for sender"
1315                  (interactive)
1316                  (let ((current-prefix-arg t))
1317                    (call-interactively #'notmuch-mua-new-mail)))))
1318   (:map notmuch-search-mode-map
1319         ("g" . notmuch-poll-and-refresh-this-buffer)
1320         ("k" . (lambda ()
1321                  "Mark message read"
1322                  (interactive)
1323                  (notmuch-search-tag '("-unread"))
1324                  ;; (notmuch-search-archive-thread)
1325                  (notmuch-search-next-thread)))
1326         ("u" . (lambda ()
1327                  "Mark message unread"
1328                  (interactive)
1329                  (notmuch-search-tag '("+unread"))
1330                  (notmuch-search-next-thread)))
1331         ("K" . (lambda ()
1332                  "Mark message deleted"
1333                  (interactive)
1334                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1335                  (notmuch-search-archive-thread)))
1336         ("S" . (lambda ()
1337                  "Mark message as spam"
1338                  (interactive)
1339                  (notmuch-search-tag '("-unread" "-inbox" "+spam"))
1340                  (notmuch-search-archive-thread))))
1341   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1342         ("S" . (lambda ()
1343                  "Mark message as spam"
1344                  (interactive)
1345                  (notmuch-tree-tag '("-unread" "-inbox" "+spam"))
1346                  (notmuch-tree-archive-thread))))
1347 )
1348
1349 ;; (use-package counsel-notmuch
1350 ;;   :commands counsel-notmuch)
1351
1352 (after! notmuch-crypto
1353   (setq notmuch-crypto-process-mime t))
1354
1355 ;; (after! evil
1356 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1357 ;;         '((notmuch-hello-mode . emacs)
1358 ;;           (notmuch-search-mode . emacs)
1359 ;;           (notmuch-tree-mode . emacs))))
1360
1361 (after! recentf
1362   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1363 #+end_src
1364
1365 * Post initialization
1366 :PROPERTIES:
1367 :CUSTOM_ID: post-initialization
1368 :END:
1369
1370 Display how long it took to load the init file.
1371
1372 #+begin_src emacs-lisp
1373 (message "Loading %s...done (%.3fs)" user-init-file
1374          (float-time (time-subtract (current-time)
1375                                     ab--before-user-init-time)))
1376 #+end_src
1377
1378 * Footer
1379 :PROPERTIES:
1380 :CUSTOM_ID: footer
1381 :END:
1382
1383 #+begin_src emacs-lisp :comments none
1384 ;;; init.el ends here
1385 #+end_src