git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 ** Packages
 569
 570 The packages in this section are absolutely essential to my everyday
 571 workflow, and they play key roles in how I do my computing. They
 572 immensely enhance the Emacs experience for me; both using Emacs, and
 573 customizing it.
 574
 575 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 576
 577 #+begin_src emacs-lisp
 578 (use-package auto-compile
 579   :demand t
 580   :config
 581   (auto-compile-on-load-mode)
 582   (auto-compile-on-save-mode)
 583   (setq auto-compile-display-buffer               nil
 584         auto-compile-mode-line-counter            t
 585         auto-compile-source-recreate-deletes-dest t
 586         auto-compile-toggle-deletes-nonlib-dest   t
 587         auto-compile-update-autoloads             t)
 588   (add-hook 'auto-compile-inhibit-compile-hook
 589             'auto-compile-inhibit-compile-detached-git-head))
 590 #+end_src
 591
 592 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 593
 594 #+begin_quote
 595 Roll your own modal mode
 596 #+end_quote
 597
 598 #+begin_src emacs-lisp
 599 (use-package ryo-modal
 600   :commands ryo-modal-mode
 601   :bind ("M-m" . ryo-modal-mode)
 602   :after which-key
 603   :config
 604   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 605   (ryo-modal-keys
 606    ("," ryo-modal-repeat)
 607    ("q" ryo-modal-mode)
 608    ("b" backward-char)
 609    ("n" next-line)
 610    ("p" previous-line)
 611    ("f" forward-char))
 612
 613   (ryo-modal-keys
 614    ;; First argyment to ryo-modal-keys may be a list of keywords.
 615    ;; These keywords will be applied to all keybindings.
 616    (:norepeat t)
 617    ("0" "M-0")
 618    ("1" "M-1")
 619    ("2" "M-2")
 620    ("3" "M-3")
 621    ("4" "M-4")
 622    ("5" "M-5")
 623    ("6" "M-6")
 624    ("7" "M-7")
 625    ("8" "M-8")
 626    ("9" "M-9"))
 627   :hook ((text-mode . ryo-modal-mode)
 628          (prog-mode . ryo-modal-mode)))
 629 #+end_src
 630
 631 *** [[https://orgmode.org/][Org mode]]
 632
 633 #+begin_quote
 634 Org mode is for keeping notes, maintaining TODO lists, planning
 635 projects, and authoring documents with a fast and effective plain-text
 636 system.
 637 #+end_quote
 638
 639 In short, my favourite way of life.
 640
 641 #+begin_src emacs-lisp
 642 (setq org-src-tab-acts-natively t
 643       org-src-preserve-indentation nil
 644       org-edit-src-content-indentation 0
 645       org-html-divs '((preamble  "header" "preamble")
 646                       (content   "main"   "content")
 647                       (postamble "footer" "postamble"))
 648       org-html-doctype "html5"
 649       org-html-html5-fancy t
 650       org-html-postamble nil)
 651 (add-hook 'org-mode-hook 'org-indent-mode)
 652 (use-package htmlize)
 653 (use-package org-notmuch
 654   :after (:any org notmuch))
 655 #+end_src
 656
 657 *** [[https://magit.vc/][Magit]]
 658
 659 #+begin_quote
 660 It's Magit! A Git porcelain inside Emacs.
 661 #+end_quote
 662
 663 Not just how I do git, but /the/ way to do git.
 664
 665 #+begin_src emacs-lisp
 666 (use-package magit
 667   :ryo ("SPC" (("g s" magit-status)))
 668   :defer t
 669   :bind (("s-g"     . magit-status)
 670          ("C-x g"   . magit-status)
 671          ("C-x M-g" . magit-dispatch-popup))
 672   :config
 673   (magit-add-section-hook 'magit-status-sections-hook
 674                           'magit-insert-modules
 675                           'magit-insert-stashes
 676                           'append))
 677 #+end_src
 678
 679 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 680
 681 #+begin_quote
 682 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 683 an overview, and more. Oh, man!
 684 #+end_quote
 685
 686 There's no way I could top that, so I won't attempt to.
 687
 688 **** Ivy
 689
 690 #+begin_src emacs-lisp
 691 (use-package ivy
 692   :defer 1
 693   :bind
 694   (:map ivy-minibuffer-map
 695         ([escape] . keyboard-escape-quit)
 696         ;; ("C-j"    . ivy-next-line)
 697         ;; ("C-k"    . ivy-previous-line)
 698         ([S-up]   . ivy-previous-history-element)
 699         ([S-down] . ivy-next-history-element)
 700         ("DEL"    . ivy-backward-delete-char))
 701   :ryo ("SPC ," ivy-switch-buffer)
 702   :config
 703   (setq ivy-wrap t)
 704   (ivy-mode 1))
 705 #+end_src
 706
 707 **** Swiper
 708
 709 #+begin_src emacs-lisp
 710 (use-package swiper
 711   :ryo ("/" swiper)
 712   :bind (([remap isearch-forward]  . swiper)
 713          ([remap isearch-backward] . swiper)))
 714 #+end_src
 715
 716 **** Counsel
 717
 718 #+begin_src emacs-lisp
 719 (use-package counsel
 720   :defer 1
 721   :ryo
 722   ("SPC" (("f r" counsel-recentf)
 723           ("SPC" counsel-M-x)
 724           ("."   counsel-find-file)))
 725   :bind (([remap execute-extended-command] . counsel-M-x)
 726          ([remap find-file] . counsel-find-file)
 727          ("s-r"     . counsel-recentf)
 728          :map minibuffer-local-map
 729          ("C-r" . counsel-minibuffer-history))
 730   :config
 731   (counsel-mode 1)
 732   (defalias 'locate #'counsel-locate))
 733 #+end_src
 734
 735 * Borg's =layer/essentials=
 736
 737 TODO: break this giant source block down into individual org sections.
 738
 739 #+begin_src emacs-lisp
 740 (use-package dash
 741   :config (dash-enable-font-lock))
 742
 743 (use-package diff-hl
 744   :config
 745   (setq diff-hl-draw-borders nil)
 746   (global-diff-hl-mode)
 747   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 748
 749 (use-package dired
 750   :defer t
 751   :config (setq dired-listing-switches "-alh"))
 752
 753 (use-package eldoc
 754   :when (version< "25" emacs-version)
 755   :config (global-eldoc-mode))
 756
 757 (use-package help
 758   :defer t
 759   :config (temp-buffer-resize-mode))
 760
 761 (progn ;    `isearch'
 762   (setq isearch-allow-scroll t))
 763
 764 (use-package lisp-mode
 765   :config
 766   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 767   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 768   (defun indent-spaces-mode ()
 769     (setq indent-tabs-mode nil))
 770   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 771
 772 (use-package man
 773   :defer t
 774   :config (setq Man-width 80))
 775
 776 (use-package paren
 777   :config (show-paren-mode))
 778
 779 (use-package prog-mode
 780   :config (global-prettify-symbols-mode)
 781   (defun indicate-buffer-boundaries-left ()
 782     (setq indicate-buffer-boundaries 'left))
 783   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 784
 785 (use-package recentf
 786   :demand t
 787   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 788
 789 (use-package savehist
 790   :config (savehist-mode))
 791
 792 (use-package saveplace
 793   :when (version< "25" emacs-version)
 794   :config (save-place-mode))
 795
 796 (use-package simple
 797   :config (column-number-mode))
 798
 799 (progn ;    `text-mode'
 800   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 801
 802 (use-package tramp
 803   :defer t
 804   :config
 805   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 806   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 807   (add-to-list 'tramp-default-proxies-alist
 808                (list (regexp-quote (system-name)) nil nil)))
 809
 810 (use-package undo-tree
 811   :config
 812   (global-undo-tree-mode)
 813   (setq undo-tree-mode-lighter ""))
 814 #+end_src
 815
 816 * Editing
 817
 818 ** Company
 819
 820 #+begin_src emacs-lisp
 821 (use-package company
 822   :defer 5
 823   :bind
 824   (:map company-active-map
 825         ([tab] . company-complete-common-or-cycle))
 826   :custom
 827   (company-idle-delay 0.3)
 828   (company-minimum-prefix-length 1)
 829   (company-selection-wrap-around t)
 830   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 831   :config
 832   (global-company-mode t))
 833 #+end_src
 834
 835 ** Customizations
 836
 837 #+begin_src emacs-lisp
 838 (ryo-modal-key
 839  "SPC" '(("b b" ibuffer-list-buffers)
 840          ("b k" kill-this-buffer)
 841          ("b s" save-buffer)
 842          ("q q" save-buffers-kill-terminal)))
 843 #+end_src
 844
 845 * Syntax and spell checking
 846 #+begin_src emacs-lisp
 847 (use-package flycheck
 848   :hook (prog-mode . flycheck-mode)
 849   :config
 850   ;; Use the load-path from running Emacs when checking elisp files
 851   (setq flycheck-emacs-lisp-load-path 'inherit)
 852
 853   ;; Only flycheck when I actually save the buffer
 854   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 855 #+end_src
 856 * Programming modes
 857
 858 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 859
 860 #+begin_src emacs-lisp
 861 (use-package alloy-mode
 862   :config (setq alloy-basic-offset 2))
 863 #+end_src
 864
 865 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 866
 867 #+begin_src emacs-lisp
 868 (use-package proof-site  ; Proof General
 869   :load-path "lib/proof-site/generic/")
 870 #+end_src
 871
 872 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 873
 874 #+begin_src emacs-lisp
 875 (use-package lean-mode
 876   :bind (:map lean-mode-map
 877               ("S-SPC" . company-complete)))
 878 #+end_src
 879
 880 ** Haskell
 881
 882 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 883
 884 #+begin_src emacs-lisp
 885 (use-package haskell-mode
 886   :config
 887   (setq haskell-indentation-layout-offset 4
 888         haskell-indentation-left-offset 4
 889         flycheck-checker 'haskell-hlint
 890         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 891 #+end_src
 892
 893 *** [[https://github.com/jyp/dante][dante]]
 894
 895 #+begin_src emacs-lisp
 896 (use-package dante
 897   :after haskell-mode
 898   :commands dante-mode
 899   :hook (haskell-mode . dante-mode))
 900 #+end_src
 901
 902 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 903
 904 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 905 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 906
 907 #+begin_src emacs-lisp
 908 (use-package hlint-refactor
 909   :bind (:map hlint-refactor-mode-map
 910               ("C-c l b" . hlint-refactor-refactor-buffer)
 911               ("C-c l r" . hlint-refactor-refactor-at-point))
 912   :hook (haskell-mode . hlint-refactor-mode))
 913 #+end_src
 914
 915 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 916
 917 #+begin_src emacs-lisp
 918 (use-package flycheck-haskell)
 919 #+end_src
 920
 921 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 922 :PROPERTIES:
 923 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 924 :END:
 925
 926 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 927 instead.
 928
 929 #+begin_src emacs-lisp :tangle no
 930 ;;; hs-lint.el --- minor mode for HLint code checking
 931
 932 ;; Copyright 2009 (C) Alex Ott
 933 ;;
 934 ;; Author: Alex Ott <alexott@gmail.com>
 935 ;; Keywords: haskell, lint, HLint
 936 ;; Requirements:
 937 ;; Status: distributed under terms of GPL2 or above
 938
 939 ;; Typical message from HLint looks like:
 940 ;;
 941 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 942 ;; Found:
 943 ;;   count1 p l = length (filter p l)
 944 ;; Why not:
 945 ;;   count1 p = length . filter p
 946
 947
 948 (require 'compile)
 949
 950 (defgroup hs-lint nil
 951   "Run HLint as inferior of Emacs, parse error messages."
 952   :group 'tools
 953   :group 'haskell)
 954
 955 (defcustom hs-lint-command "hlint"
 956   "The default hs-lint command for \\[hlint]."
 957   :type 'string
 958   :group 'hs-lint)
 959
 960 (defcustom hs-lint-save-files t
 961   "Save modified files when run HLint or no (ask user)"
 962   :type 'boolean
 963   :group 'hs-lint)
 964
 965 (defcustom hs-lint-replace-with-suggestions nil
 966   "Replace user's code with suggested replacements"
 967   :type 'boolean
 968   :group 'hs-lint)
 969
 970 (defcustom hs-lint-replace-without-ask nil
 971   "Replace user's code with suggested replacements automatically"
 972   :type 'boolean
 973   :group 'hs-lint)
 974
 975 (defun hs-lint-process-setup ()
 976   "Setup compilation variables and buffer for `hlint'."
 977   (run-hooks 'hs-lint-setup-hook))
 978
 979 ;; regex for replace suggestions
 980 ;;
 981 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 982 ;; Found:
 983 ;; \s +\(.*\)
 984 ;; Why not:
 985 ;; \s +\(.*\)
 986
 987 (defvar hs-lint-regex
 988   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
 989   "Regex for HLint messages")
 990
 991 (defun make-short-string (str maxlen)
 992   (if (< (length str) maxlen)
 993       str
 994     (concat (substring str 0 (- maxlen 3)) "...")))
 995
 996 (defun hs-lint-replace-suggestions ()
 997   "Perform actual replacement of suggestions"
 998   (goto-char (point-min))
 999   (while (re-search-forward hs-lint-regex nil t)
1000     (let* ((fname (match-string 1))
1001           (fline (string-to-number (match-string 2)))
1002           (old-code (match-string 4))
1003           (new-code (match-string 5))
1004           (msg (concat "Replace '" (make-short-string old-code 30)
1005                        "' with '" (make-short-string new-code 30) "'"))
1006           (bline 0)
1007           (eline 0)
1008           (spos 0)
1009           (new-old-code ""))
1010       (save-excursion
1011         (switch-to-buffer (get-file-buffer fname))
1012         (goto-char (point-min))
1013         (forward-line (1- fline))
1014         (beginning-of-line)
1015         (setf bline (point))
1016         (when (or hs-lint-replace-without-ask
1017                   (yes-or-no-p msg))
1018           (end-of-line)
1019           (setf eline (point))
1020           (beginning-of-line)
1021           (setf old-code (regexp-quote old-code))
1022           (while (string-match "\\\\ " old-code spos)
1023             (setf new-old-code (concat new-old-code
1024                                  (substring old-code spos (match-beginning 0))
1025                                  "\\ *"))
1026             (setf spos (match-end 0)))
1027           (setf new-old-code (concat new-old-code (substring old-code spos)))
1028           (remove-text-properties bline eline '(composition nil))
1029           (when (re-search-forward new-old-code eline t)
1030             (replace-match new-code nil t)))))))
1031
1032 (defun hs-lint-finish-hook (buf msg)
1033   "Function, that is executed at the end of HLint execution"
1034   (if hs-lint-replace-with-suggestions
1035       (hs-lint-replace-suggestions)
1036       (next-error 1 t)))
1037
1038 (define-compilation-mode hs-lint-mode "HLint"
1039   "Mode for check Haskell source code."
1040   (set (make-local-variable 'compilation-process-setup-function)
1041        'hs-lint-process-setup)
1042   (set (make-local-variable 'compilation-disable-input) t)
1043   (set (make-local-variable 'compilation-scroll-output) nil)
1044   (set (make-local-variable 'compilation-finish-functions)
1045        (list 'hs-lint-finish-hook))
1046   )
1047
1048 (defun hs-lint ()
1049   "Run HLint for current buffer with haskell source"
1050   (interactive)
1051   (save-some-buffers hs-lint-save-files)
1052   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1053                      'hs-lint-mode))
1054
1055 (provide 'hs-lint)
1056 ;;; hs-lint.el ends here
1057 #+end_src
1058
1059 #+begin_src emacs-lisp :tangle no
1060 (use-package hs-lint
1061   :load-path "lisp/"
1062   :bind (:map haskell-mode-map
1063               ("C-c l l" . hs-lint)))
1064 #+end_src
1065 * Emacs Enhancements
1066
1067 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1068
1069 #+begin_quote
1070 Emacs package that displays available keybindings in popup
1071 #+end_quote
1072
1073 #+begin_src emacs-lisp
1074 (use-package which-key
1075   :defer 1
1076   :config (which-key-mode))
1077 #+end_src
1078
1079 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1080
1081 #+begin_src emacs-lisp
1082 (use-package doom-modeline
1083   :demand t
1084   :config (setq doom-modeline-height 32)
1085   :hook (after-init . doom-modeline-init))
1086 #+end_src
1087
1088 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1089
1090 #+begin_src emacs-lisp :tangle no
1091 (use-package tao-theme
1092   :demand t
1093   :config (load-theme 'tao-yang t))
1094 #+end_src
1095
1096 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1097
1098 #+begin_src emacs-lisp
1099 (load-theme 'eink t)
1100 #+end_src
1101
1102 * Email
1103 ** [[https://notmuchmail.org][notmuch]]
1104
1105 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1106
1107 #+begin_src emacs-lisp
1108 (defun ab/notmuch ()
1109   "Delete other windows, then launch `notmuch'."
1110   (interactive)
1111   (require 'notmuch)
1112   (delete-other-windows)
1113   (notmuch))
1114
1115 ;; (map!
1116 ;;  :leader
1117 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1118 ;;  (:desc "search" :prefix "/"
1119 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1120 #+end_src
1121
1122 #+begin_src emacs-lisp
1123 (defvar ab-maildir "~/mail")
1124
1125 (use-package sendmail
1126   ;; :ensure nil
1127   :config
1128   (setq sendmail-program "/usr/bin/msmtp"
1129         mail-specify-envelope-from t
1130         mail-envelope-from 'header))
1131
1132 (use-package message
1133   ;; :ensure nil
1134   :config
1135   (setq message-kill-buffer-on-exit t
1136         message-send-mail-function 'message-send-mail-with-sendmail
1137         message-sendmail-envelope-from 'header
1138         message-directory "drafts"
1139         message-user-fqdn "aminb.org")
1140   (add-hook 'message-mode-hook
1141             (lambda () (setq fill-column 65
1142                         message-fill-column 65)))
1143   (add-hook 'message-mode-hook
1144             #'flyspell-mode)
1145   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1146   ;; TODO: is there a way to only run this when replying and not composing?
1147   ;; (add-hook 'notmuch-message-mode-hook
1148   ;;           (lambda () (progn
1149   ;;                   (newline)
1150   ;;                   (newline)
1151   ;;                   (forward-line -1)
1152   ;;                   (forward-line -1))))
1153   ;; (add-hook 'message-setup-hook
1154   ;;           #'mml-secure-message-sign-pgpmime)
1155   )
1156
1157 (after! mml-sec
1158   (setq mml-secure-openpgp-encrypt-to-self t
1159         mml-secure-openpgp-sign-with-sender t))
1160
1161 (use-package notmuch
1162   :ryo ("SPC m" ab/notmuch)
1163   :config
1164   (setq notmuch-hello-sections
1165         '(notmuch-hello-insert-header
1166           notmuch-hello-insert-saved-searches
1167           ;; notmuch-hello-insert-search
1168           notmuch-hello-insert-alltags)
1169         notmuch-search-oldest-first nil
1170         notmuch-show-all-tags-list t
1171         notmuch-message-headers  ; see bug follow-up above
1172         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1173         notmuch-hello-thousands-separator ","
1174         notmuch-fcc-dirs
1175         '(("amin@aminb.org"            . "amin/Sent")
1176           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1177           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1178           ("aminb@gnu.org"             . "gnu/Sent")
1179           (".*"                        . "sent"))
1180         notmuch-search-result-format
1181         '(("date" . "%12s ")
1182           ("count" . "%-7s ")
1183           ("authors" . "%-40s ")
1184           ("subject" . "%s ")
1185           ("tags" . "(%s)")))
1186   ;; (add-hook 'visual-fill-column-mode-hook
1187   ;;           (lambda ()
1188   ;;             (when (string= major-mode 'notmuch-message-mode)
1189   ;;               (setq visual-fill-column-width 70))))
1190   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1191   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1192   ;;             :override #'kill-this-buffer)
1193   :bind
1194   (:map notmuch-hello-mode-map
1195         ("g" . notmuch-poll-and-refresh-this-buffer)
1196         ("i" . (lambda ()
1197                  "Search for `inbox' tagged messages"
1198                  (interactive)
1199                  (notmuch-hello-search "tag:inbox")))
1200         ("u" . (lambda ()
1201                  "Search for `unread' tagged messages"
1202                  (interactive)
1203                  (notmuch-hello-search "tag:unread")))
1204         ("l" . (lambda ()
1205                  "Search for `latest tagged messages"
1206                  (interactive)
1207                  (notmuch-hello-search "tag:latest")))
1208         ("M" . (lambda ()
1209                  "Compose new mail and prompt for sender"
1210                  (interactive)
1211                  (let ((current-prefix-arg t))
1212                    (call-interactively #'notmuch-mua-new-mail)))))
1213   (:map notmuch-search-mode-map
1214         ("g" . notmuch-poll-and-refresh-this-buffer)
1215         ("k" . (lambda ()
1216                  "Mark message read"
1217                  (interactive)
1218                  (notmuch-search-tag '("-unread"))
1219                  ;; (notmuch-search-archive-thread)
1220                  (notmuch-search-next-thread)))
1221         ("u" . (lambda ()
1222                  "Mark message unread"
1223                  (interactive)
1224                  (notmuch-search-tag '("+unread"))
1225                  (notmuch-search-next-thread)))
1226         ("K" . (lambda ()
1227                  "Mark message deleted"
1228                  (interactive)
1229                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1230                  (notmuch-search-archive-thread)))
1231         ("S" . (lambda ()
1232                  "Mark message as spam"
1233                  (interactive)
1234                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1235                  (notmuch-search-archive-thread))))
1236   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1237         ("S" . (lambda ()
1238                  "Mark message as spam"
1239                  (interactive)
1240                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1241                  (notmuch-tree-archive-thread))))
1242 )
1243
1244 ;; (use-package counsel-notmuch
1245 ;;   :commands counsel-notmuch)
1246
1247 (after! notmuch-crypto
1248   (setq notmuch-crypto-process-mime t))
1249
1250 ;; (after! evil
1251 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1252 ;;         '((notmuch-hello-mode . emacs)
1253 ;;           (notmuch-search-mode . emacs)
1254 ;;           (notmuch-tree-mode . emacs))))
1255
1256 (after! recentf
1257   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1258 #+end_src
1259
1260 ** supercite
1261
1262 #+begin_src emacs-lisp :tangle no
1263 (use-package supercite
1264   :commands sc-cite-original
1265   :init
1266   (add-hook 'mail-citation-hook 'sc-cite-original)
1267
1268   (defun sc-remove-existing-signature ()
1269     (save-excursion
1270       (goto-char (region-beginning))
1271       (when (re-search-forward message-signature-separator (region-end) t)
1272         (delete-region (match-beginning 0) (region-end)))))
1273
1274   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1275
1276   (defun sc-remove-if-not-mailing-list ()
1277     (unless (assoc "list-id" sc-mail-info)
1278       (setq attribution sc-default-attribution
1279             citation (concat sc-citation-delimiter
1280                              sc-citation-separator))))
1281
1282   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1283
1284   :config
1285   (defun sc-fill-if-different (&optional prefix)
1286     "Fill the region bounded by `sc-fill-begin' and point.
1287 Only fill if optional PREFIX is different than
1288 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1289 fill region.  If PREFIX is not supplied, initialize fill
1290 variables.  This is useful for a regi `begin' frame-entry."
1291     (if (not prefix)
1292         (setq sc-fill-line-prefix ""
1293               sc-fill-begin (line-beginning-position))
1294       (if (and sc-auto-fill-region-p
1295                (not (string= prefix sc-fill-line-prefix)))
1296           (let ((fill-prefix sc-fill-line-prefix))
1297             (unless (or (string= fill-prefix "")
1298                         (save-excursion
1299                           (goto-char sc-fill-begin)
1300                           (or (looking-at ">+  +")
1301                               (< (length
1302                                   (buffer-substring (point)
1303                                                     (line-end-position)))
1304                                  65))))
1305               (fill-region sc-fill-begin (line-beginning-position)))
1306             (setq sc-fill-line-prefix prefix
1307                   sc-fill-begin (line-beginning-position)))))
1308 nil))
1309 #+end_src
1310
1311 * Blogging
1312 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1313
1314 #+begin_src emacs-lisp
1315 (use-package ox-hugo
1316   :after ox)
1317 #+end_src
1318
1319 * Post initialization
1320 :PROPERTIES:
1321 :CUSTOM_ID: post-initialization
1322 :END:
1323
1324 Display how long it took to load the init file.
1325
1326 #+begin_src emacs-lisp
1327 (message "Loading %s...done (%.3fs)" user-init-file
1328          (float-time (time-subtract (current-time)
1329                                     ab--before-user-init-time)))
1330 #+end_src
1331
1332 * Footer
1333 :PROPERTIES:
1334 :CUSTOM_ID: footer
1335 :END:
1336
1337 #+begin_src emacs-lisp :comments none
1338 ;;; init.el ends here
1339 #+end_src