git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 ** Packages
 569
 570 The packages in this section are absolutely essential to my everyday
 571 workflow, and they play key roles in how I do my computing. They
 572 immensely enhance the Emacs experience for me; both using Emacs, and
 573 customizing it.
 574
 575 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 576
 577 #+begin_src emacs-lisp
 578 (use-package auto-compile
 579   :demand t
 580   :config
 581   (auto-compile-on-load-mode)
 582   (auto-compile-on-save-mode)
 583   (setq auto-compile-display-buffer               nil
 584         auto-compile-mode-line-counter            t
 585         auto-compile-source-recreate-deletes-dest t
 586         auto-compile-toggle-deletes-nonlib-dest   t
 587         auto-compile-update-autoloads             t)
 588   (add-hook 'auto-compile-inhibit-compile-hook
 589             'auto-compile-inhibit-compile-detached-git-head))
 590 #+end_src
 591
 592 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 593
 594 #+begin_quote
 595 Roll your own modal mode
 596 #+end_quote
 597
 598 #+begin_src emacs-lisp
 599 (use-package ryo-modal
 600   :commands ryo-modal-mode
 601   :bind ("M-m" . ryo-modal-mode)
 602   :after which-key
 603   :config
 604   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 605   (ryo-modal-keys
 606    ("," ryo-modal-repeat)
 607    ("b" backward-char)
 608    ("n" next-line)
 609    ("p" previous-line)
 610    ("f" forward-char)
 611    ("a" move-beginning-of-line)
 612    ("e" move-end-of-line)
 613    ("SPC" (("b" (("b" ibuffer-list-buffers)
 614                  ("k" kill-this-buffer)
 615                  ("o" other-window)
 616                  ("s" save-buffer)))
 617            ("h" (("c" describe-char)
 618                  ("f" describe-function)
 619                  ("F" describe-face)
 620                  ("i" info)
 621                  ("k" describe-key)
 622                  ("l" view-lossage)
 623                  ("v" describe-variable)))
 624            ("q" (("q" save-buffers-kill-terminal)))))
 625    ("d" (("w" kill-word)
 626          ("d" kill-whole-line)
 627          ("b" backward-kill-word)))
 628    ("c" (("w" kill-word :exit t)
 629          ("c" kill-whole-line :exit t))))
 630
 631   (ryo-modal-keys
 632    ;; First argyment to ryo-modal-keys may be a list of keywords.
 633    ;; These keywords will be applied to all keybindings.
 634    (:norepeat t)
 635    ("0" "M-0")
 636    ("1" "M-1")
 637    ("2" "M-2")
 638    ("3" "M-3")
 639    ("4" "M-4")
 640    ("5" "M-5")
 641    ("6" "M-6")
 642    ("7" "M-7")
 643    ("8" "M-8")
 644    ("9" "M-9"))
 645   :hook ((text-mode . ryo-modal-mode)
 646          (prog-mode . ryo-modal-mode)))
 647 #+end_src
 648
 649 *** [[https://orgmode.org/][Org mode]]
 650
 651 #+begin_quote
 652 Org mode is for keeping notes, maintaining TODO lists, planning
 653 projects, and authoring documents with a fast and effective plain-text
 654 system.
 655 #+end_quote
 656
 657 In short, my favourite way of life.
 658
 659 #+begin_src emacs-lisp
 660 (use-package org
 661   :ryo ("SPC b t" org-babel-tangle)
 662   :config
 663   (setq org-src-tab-acts-natively t
 664         org-src-preserve-indentation nil
 665         org-edit-src-content-indentation 0
 666         org-html-divs '((preamble  "header" "preamble")
 667                         (content   "main"   "content")
 668                         (postamble "footer" "postamble"))
 669         org-html-doctype "html5"
 670         org-html-html5-fancy t
 671         org-html-postamble nil)
 672   :hook (org-mode . org-indent-mode))
 673 (use-package htmlize
 674   :after org)
 675 (use-package org-notmuch
 676   :after (:any org notmuch))
 677 #+end_src
 678
 679 *** [[https://magit.vc/][Magit]]
 680
 681 #+begin_quote
 682 It's Magit! A Git porcelain inside Emacs.
 683 #+end_quote
 684
 685 Not just how I do git, but /the/ way to do git.
 686
 687 #+begin_src emacs-lisp
 688 (use-package magit
 689   :ryo ("SPC" (("g s" magit-status)))
 690   :defer t
 691   :bind (("s-g"     . magit-status)
 692          ("C-x g"   . magit-status)
 693          ("C-x M-g" . magit-dispatch-popup))
 694   :config
 695   (magit-add-section-hook 'magit-status-sections-hook
 696                           'magit-insert-modules
 697                           'magit-insert-stashes
 698                           'append))
 699 #+end_src
 700
 701 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 702
 703 #+begin_quote
 704 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 705 an overview, and more. Oh, man!
 706 #+end_quote
 707
 708 There's no way I could top that, so I won't attempt to.
 709
 710 **** Ivy
 711
 712 #+begin_src emacs-lisp
 713 (use-package ivy
 714   :defer 1
 715   :bind
 716   (:map ivy-minibuffer-map
 717         ([escape] . keyboard-escape-quit)
 718         ;; ("C-j"    . ivy-next-line)
 719         ;; ("C-k"    . ivy-previous-line)
 720         ([S-up]   . ivy-previous-history-element)
 721         ([S-down] . ivy-next-history-element)
 722         ("DEL"    . ivy-backward-delete-char))
 723   :ryo ("SPC ," ivy-switch-buffer)
 724   :config
 725   (setq ivy-wrap t)
 726   (ivy-mode 1))
 727 #+end_src
 728
 729 **** Swiper
 730
 731 #+begin_src emacs-lisp
 732 (use-package swiper
 733   :ryo
 734   ("SPC /" swiper)
 735   ("s" swiper)
 736   :bind (([remap isearch-forward]  . swiper)
 737          ([remap isearch-backward] . swiper)))
 738 #+end_src
 739
 740 **** Counsel
 741
 742 #+begin_src emacs-lisp
 743 (use-package counsel
 744   :defer 1
 745   :ryo
 746   ("SPC" (("f r" counsel-recentf)
 747           ("SPC" counsel-M-x)
 748           ("."   counsel-find-file)))
 749   :bind (([remap execute-extended-command] . counsel-M-x)
 750          ([remap find-file] . counsel-find-file)
 751          ("s-r"     . counsel-recentf)
 752          :map minibuffer-local-map
 753          ("C-r" . counsel-minibuffer-history))
 754   :config
 755   (counsel-mode 1)
 756   (defalias 'locate #'counsel-locate))
 757 #+end_src
 758
 759 * Borg's =layer/essentials=
 760
 761 TODO: break this giant source block down into individual org sections.
 762
 763 #+begin_src emacs-lisp
 764 (use-package dash
 765   :config (dash-enable-font-lock))
 766
 767 (use-package diff-hl
 768   :config
 769   (setq diff-hl-draw-borders nil)
 770   (global-diff-hl-mode)
 771   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 772
 773 (use-package dired
 774   :defer t
 775   :config (setq dired-listing-switches "-alh"))
 776
 777 (use-package eldoc
 778   :when (version< "25" emacs-version)
 779   :config (global-eldoc-mode))
 780
 781 (use-package help
 782   :defer t
 783   :config (temp-buffer-resize-mode))
 784
 785 (progn ;    `isearch'
 786   (setq isearch-allow-scroll t))
 787
 788 (use-package lisp-mode
 789   :config
 790   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 791   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 792   (defun indent-spaces-mode ()
 793     (setq indent-tabs-mode nil))
 794   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 795
 796 (use-package man
 797   :defer t
 798   :config (setq Man-width 80))
 799
 800 (use-package paren
 801   :config (show-paren-mode))
 802
 803 (use-package prog-mode
 804   :config (global-prettify-symbols-mode)
 805   (defun indicate-buffer-boundaries-left ()
 806     (setq indicate-buffer-boundaries 'left))
 807   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 808
 809 (use-package recentf
 810   :demand t
 811   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 812
 813 (use-package savehist
 814   :config (savehist-mode))
 815
 816 (use-package saveplace
 817   :when (version< "25" emacs-version)
 818   :config (save-place-mode))
 819
 820 (use-package simple
 821   :config (column-number-mode))
 822
 823 (progn ;    `text-mode'
 824   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 825
 826 (use-package tramp
 827   :defer t
 828   :config
 829   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 830   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 831   (add-to-list 'tramp-default-proxies-alist
 832                (list (regexp-quote (system-name)) nil nil)))
 833
 834 (use-package undo-tree
 835   :ryo
 836   ("/" undo-tree-undo)
 837   ("_" undo-tree-redo)
 838   :bind (("C-/" . undo-tree-undo)
 839          ("M-_" . undo-tree-redo))
 840   :config
 841   (global-undo-tree-mode)
 842   (setq undo-tree-mode-lighter ""))
 843 #+end_src
 844
 845 * Editing
 846
 847 ** Company
 848
 849 #+begin_src emacs-lisp
 850 (use-package company
 851   :defer 5
 852   :bind
 853   (:map company-active-map
 854         ([tab] . company-complete-common-or-cycle))
 855   :custom
 856   (company-idle-delay 0.3)
 857   (company-minimum-prefix-length 1)
 858   (company-selection-wrap-around t)
 859   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 860   :config
 861   (global-company-mode t))
 862 #+end_src
 863
 864 * Syntax and spell checking
 865 #+begin_src emacs-lisp
 866 (use-package flycheck
 867   :hook (prog-mode . flycheck-mode)
 868   :config
 869   ;; Use the load-path from running Emacs when checking elisp files
 870   (setq flycheck-emacs-lisp-load-path 'inherit)
 871
 872   ;; Only flycheck when I actually save the buffer
 873   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 874 #+end_src
 875 * Programming modes
 876
 877 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 878
 879 #+begin_src emacs-lisp
 880 (use-package alloy-mode
 881   :config (setq alloy-basic-offset 2))
 882 #+end_src
 883
 884 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 885
 886 #+begin_src emacs-lisp
 887 (use-package proof-site  ; Proof General
 888   :load-path "lib/proof-site/generic/")
 889 #+end_src
 890
 891 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 892
 893 #+begin_src emacs-lisp
 894 (use-package lean-mode
 895   :bind (:map lean-mode-map
 896               ("S-SPC" . company-complete)))
 897 #+end_src
 898
 899 ** Haskell
 900
 901 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 902
 903 #+begin_src emacs-lisp
 904 (use-package haskell-mode
 905   :config
 906   (setq haskell-indentation-layout-offset 4
 907         haskell-indentation-left-offset 4
 908         flycheck-checker 'haskell-hlint
 909         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 910 #+end_src
 911
 912 *** [[https://github.com/jyp/dante][dante]]
 913
 914 #+begin_src emacs-lisp
 915 (use-package dante
 916   :after haskell-mode
 917   :commands dante-mode
 918   :hook (haskell-mode . dante-mode))
 919 #+end_src
 920
 921 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 922
 923 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 924 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 925
 926 #+begin_src emacs-lisp
 927 (use-package hlint-refactor
 928   :bind (:map hlint-refactor-mode-map
 929               ("C-c l b" . hlint-refactor-refactor-buffer)
 930               ("C-c l r" . hlint-refactor-refactor-at-point))
 931   :hook (haskell-mode . hlint-refactor-mode))
 932 #+end_src
 933
 934 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 935
 936 #+begin_src emacs-lisp
 937 (use-package flycheck-haskell)
 938 #+end_src
 939
 940 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 941 :PROPERTIES:
 942 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 943 :END:
 944
 945 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 946 instead.
 947
 948 #+begin_src emacs-lisp :tangle no
 949 ;;; hs-lint.el --- minor mode for HLint code checking
 950
 951 ;; Copyright 2009 (C) Alex Ott
 952 ;;
 953 ;; Author: Alex Ott <alexott@gmail.com>
 954 ;; Keywords: haskell, lint, HLint
 955 ;; Requirements:
 956 ;; Status: distributed under terms of GPL2 or above
 957
 958 ;; Typical message from HLint looks like:
 959 ;;
 960 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 961 ;; Found:
 962 ;;   count1 p l = length (filter p l)
 963 ;; Why not:
 964 ;;   count1 p = length . filter p
 965
 966
 967 (require 'compile)
 968
 969 (defgroup hs-lint nil
 970   "Run HLint as inferior of Emacs, parse error messages."
 971   :group 'tools
 972   :group 'haskell)
 973
 974 (defcustom hs-lint-command "hlint"
 975   "The default hs-lint command for \\[hlint]."
 976   :type 'string
 977   :group 'hs-lint)
 978
 979 (defcustom hs-lint-save-files t
 980   "Save modified files when run HLint or no (ask user)"
 981   :type 'boolean
 982   :group 'hs-lint)
 983
 984 (defcustom hs-lint-replace-with-suggestions nil
 985   "Replace user's code with suggested replacements"
 986   :type 'boolean
 987   :group 'hs-lint)
 988
 989 (defcustom hs-lint-replace-without-ask nil
 990   "Replace user's code with suggested replacements automatically"
 991   :type 'boolean
 992   :group 'hs-lint)
 993
 994 (defun hs-lint-process-setup ()
 995   "Setup compilation variables and buffer for `hlint'."
 996   (run-hooks 'hs-lint-setup-hook))
 997
 998 ;; regex for replace suggestions
 999 ;;
1000 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1001 ;; Found:
1002 ;; \s +\(.*\)
1003 ;; Why not:
1004 ;; \s +\(.*\)
1005
1006 (defvar hs-lint-regex
1007   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1008   "Regex for HLint messages")
1009
1010 (defun make-short-string (str maxlen)
1011   (if (< (length str) maxlen)
1012       str
1013     (concat (substring str 0 (- maxlen 3)) "...")))
1014
1015 (defun hs-lint-replace-suggestions ()
1016   "Perform actual replacement of suggestions"
1017   (goto-char (point-min))
1018   (while (re-search-forward hs-lint-regex nil t)
1019     (let* ((fname (match-string 1))
1020           (fline (string-to-number (match-string 2)))
1021           (old-code (match-string 4))
1022           (new-code (match-string 5))
1023           (msg (concat "Replace '" (make-short-string old-code 30)
1024                        "' with '" (make-short-string new-code 30) "'"))
1025           (bline 0)
1026           (eline 0)
1027           (spos 0)
1028           (new-old-code ""))
1029       (save-excursion
1030         (switch-to-buffer (get-file-buffer fname))
1031         (goto-char (point-min))
1032         (forward-line (1- fline))
1033         (beginning-of-line)
1034         (setf bline (point))
1035         (when (or hs-lint-replace-without-ask
1036                   (yes-or-no-p msg))
1037           (end-of-line)
1038           (setf eline (point))
1039           (beginning-of-line)
1040           (setf old-code (regexp-quote old-code))
1041           (while (string-match "\\\\ " old-code spos)
1042             (setf new-old-code (concat new-old-code
1043                                  (substring old-code spos (match-beginning 0))
1044                                  "\\ *"))
1045             (setf spos (match-end 0)))
1046           (setf new-old-code (concat new-old-code (substring old-code spos)))
1047           (remove-text-properties bline eline '(composition nil))
1048           (when (re-search-forward new-old-code eline t)
1049             (replace-match new-code nil t)))))))
1050
1051 (defun hs-lint-finish-hook (buf msg)
1052   "Function, that is executed at the end of HLint execution"
1053   (if hs-lint-replace-with-suggestions
1054       (hs-lint-replace-suggestions)
1055       (next-error 1 t)))
1056
1057 (define-compilation-mode hs-lint-mode "HLint"
1058   "Mode for check Haskell source code."
1059   (set (make-local-variable 'compilation-process-setup-function)
1060        'hs-lint-process-setup)
1061   (set (make-local-variable 'compilation-disable-input) t)
1062   (set (make-local-variable 'compilation-scroll-output) nil)
1063   (set (make-local-variable 'compilation-finish-functions)
1064        (list 'hs-lint-finish-hook))
1065   )
1066
1067 (defun hs-lint ()
1068   "Run HLint for current buffer with haskell source"
1069   (interactive)
1070   (save-some-buffers hs-lint-save-files)
1071   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1072                      'hs-lint-mode))
1073
1074 (provide 'hs-lint)
1075 ;;; hs-lint.el ends here
1076 #+end_src
1077
1078 #+begin_src emacs-lisp :tangle no
1079 (use-package hs-lint
1080   :load-path "lisp/"
1081   :bind (:map haskell-mode-map
1082               ("C-c l l" . hs-lint)))
1083 #+end_src
1084 * Emacs Enhancements
1085
1086 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1087
1088 #+begin_quote
1089 Emacs package that displays available keybindings in popup
1090 #+end_quote
1091
1092 #+begin_src emacs-lisp
1093 (use-package which-key
1094   :defer 1
1095   :config (which-key-mode))
1096 #+end_src
1097
1098 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1099
1100 #+begin_src emacs-lisp
1101 (use-package doom-modeline
1102   :demand t
1103   :config (setq doom-modeline-height 32)
1104   :hook (after-init . doom-modeline-init))
1105 #+end_src
1106
1107 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1108
1109 #+begin_src emacs-lisp :tangle no
1110 (use-package tao-theme
1111   :demand t
1112   :config (load-theme 'tao-yang t))
1113 #+end_src
1114
1115 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1116
1117 #+begin_src emacs-lisp
1118 (load-theme 'eink t)
1119 #+end_src
1120
1121 * Email
1122 ** [[https://notmuchmail.org][notmuch]]
1123
1124 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1125
1126 #+begin_src emacs-lisp
1127 (defun ab/notmuch ()
1128   "Delete other windows, then launch `notmuch'."
1129   (interactive)
1130   (require 'notmuch)
1131   (delete-other-windows)
1132   (notmuch))
1133
1134 ;; (map!
1135 ;;  :leader
1136 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1137 ;;  (:desc "search" :prefix "/"
1138 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1139 #+end_src
1140
1141 #+begin_src emacs-lisp
1142 (defvar ab-maildir "~/mail")
1143
1144 (use-package sendmail
1145   ;; :ensure nil
1146   :config
1147   (setq sendmail-program "/usr/bin/msmtp"
1148         mail-specify-envelope-from t
1149         mail-envelope-from 'header))
1150
1151 (use-package message
1152   ;; :ensure nil
1153   :config
1154   (setq message-kill-buffer-on-exit t
1155         message-send-mail-function 'message-send-mail-with-sendmail
1156         message-sendmail-envelope-from 'header
1157         message-directory "drafts"
1158         message-user-fqdn "aminb.org")
1159   (add-hook 'message-mode-hook
1160             (lambda () (setq fill-column 65
1161                         message-fill-column 65)))
1162   (add-hook 'message-mode-hook
1163             #'flyspell-mode)
1164   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1165   ;; TODO: is there a way to only run this when replying and not composing?
1166   ;; (add-hook 'notmuch-message-mode-hook
1167   ;;           (lambda () (progn
1168   ;;                   (newline)
1169   ;;                   (newline)
1170   ;;                   (forward-line -1)
1171   ;;                   (forward-line -1))))
1172   ;; (add-hook 'message-setup-hook
1173   ;;           #'mml-secure-message-sign-pgpmime)
1174   )
1175
1176 (after! mml-sec
1177   (setq mml-secure-openpgp-encrypt-to-self t
1178         mml-secure-openpgp-sign-with-sender t))
1179
1180 (use-package notmuch
1181   :ryo ("SPC m" ab/notmuch)
1182   :config
1183   (setq notmuch-hello-sections
1184         '(notmuch-hello-insert-header
1185           notmuch-hello-insert-saved-searches
1186           ;; notmuch-hello-insert-search
1187           notmuch-hello-insert-alltags)
1188         notmuch-search-oldest-first nil
1189         notmuch-show-all-tags-list t
1190         notmuch-message-headers  ; see bug follow-up above
1191         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1192         notmuch-hello-thousands-separator ","
1193         notmuch-fcc-dirs
1194         '(("amin@aminb.org"            . "amin/Sent")
1195           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1196           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1197           ("aminb@gnu.org"             . "gnu/Sent")
1198           (".*"                        . "sent"))
1199         notmuch-search-result-format
1200         '(("date" . "%12s ")
1201           ("count" . "%-7s ")
1202           ("authors" . "%-40s ")
1203           ("subject" . "%s ")
1204           ("tags" . "(%s)")))
1205   ;; (add-hook 'visual-fill-column-mode-hook
1206   ;;           (lambda ()
1207   ;;             (when (string= major-mode 'notmuch-message-mode)
1208   ;;               (setq visual-fill-column-width 70))))
1209   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1210   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1211   ;;             :override #'kill-this-buffer)
1212   :bind
1213   (:map notmuch-hello-mode-map
1214         ("g" . notmuch-poll-and-refresh-this-buffer)
1215         ("i" . (lambda ()
1216                  "Search for `inbox' tagged messages"
1217                  (interactive)
1218                  (notmuch-hello-search "tag:inbox")))
1219         ("u" . (lambda ()
1220                  "Search for `unread' tagged messages"
1221                  (interactive)
1222                  (notmuch-hello-search "tag:unread")))
1223         ("l" . (lambda ()
1224                  "Search for `latest tagged messages"
1225                  (interactive)
1226                  (notmuch-hello-search "tag:latest")))
1227         ("M" . (lambda ()
1228                  "Compose new mail and prompt for sender"
1229                  (interactive)
1230                  (let ((current-prefix-arg t))
1231                    (call-interactively #'notmuch-mua-new-mail)))))
1232   (:map notmuch-search-mode-map
1233         ("g" . notmuch-poll-and-refresh-this-buffer)
1234         ("k" . (lambda ()
1235                  "Mark message read"
1236                  (interactive)
1237                  (notmuch-search-tag '("-unread"))
1238                  ;; (notmuch-search-archive-thread)
1239                  (notmuch-search-next-thread)))
1240         ("u" . (lambda ()
1241                  "Mark message unread"
1242                  (interactive)
1243                  (notmuch-search-tag '("+unread"))
1244                  (notmuch-search-next-thread)))
1245         ("K" . (lambda ()
1246                  "Mark message deleted"
1247                  (interactive)
1248                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1249                  (notmuch-search-archive-thread)))
1250         ("S" . (lambda ()
1251                  "Mark message as spam"
1252                  (interactive)
1253                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1254                  (notmuch-search-archive-thread))))
1255   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1256         ("S" . (lambda ()
1257                  "Mark message as spam"
1258                  (interactive)
1259                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1260                  (notmuch-tree-archive-thread))))
1261 )
1262
1263 ;; (use-package counsel-notmuch
1264 ;;   :commands counsel-notmuch)
1265
1266 (after! notmuch-crypto
1267   (setq notmuch-crypto-process-mime t))
1268
1269 ;; (after! evil
1270 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1271 ;;         '((notmuch-hello-mode . emacs)
1272 ;;           (notmuch-search-mode . emacs)
1273 ;;           (notmuch-tree-mode . emacs))))
1274
1275 (after! recentf
1276   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1277 #+end_src
1278
1279 ** supercite
1280
1281 #+begin_src emacs-lisp :tangle no
1282 (use-package supercite
1283   :commands sc-cite-original
1284   :init
1285   (add-hook 'mail-citation-hook 'sc-cite-original)
1286
1287   (defun sc-remove-existing-signature ()
1288     (save-excursion
1289       (goto-char (region-beginning))
1290       (when (re-search-forward message-signature-separator (region-end) t)
1291         (delete-region (match-beginning 0) (region-end)))))
1292
1293   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1294
1295   (defun sc-remove-if-not-mailing-list ()
1296     (unless (assoc "list-id" sc-mail-info)
1297       (setq attribution sc-default-attribution
1298             citation (concat sc-citation-delimiter
1299                              sc-citation-separator))))
1300
1301   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1302
1303   :config
1304   (defun sc-fill-if-different (&optional prefix)
1305     "Fill the region bounded by `sc-fill-begin' and point.
1306 Only fill if optional PREFIX is different than
1307 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1308 fill region.  If PREFIX is not supplied, initialize fill
1309 variables.  This is useful for a regi `begin' frame-entry."
1310     (if (not prefix)
1311         (setq sc-fill-line-prefix ""
1312               sc-fill-begin (line-beginning-position))
1313       (if (and sc-auto-fill-region-p
1314                (not (string= prefix sc-fill-line-prefix)))
1315           (let ((fill-prefix sc-fill-line-prefix))
1316             (unless (or (string= fill-prefix "")
1317                         (save-excursion
1318                           (goto-char sc-fill-begin)
1319                           (or (looking-at ">+  +")
1320                               (< (length
1321                                   (buffer-substring (point)
1322                                                     (line-end-position)))
1323                                  65))))
1324               (fill-region sc-fill-begin (line-beginning-position)))
1325             (setq sc-fill-line-prefix prefix
1326                   sc-fill-begin (line-beginning-position)))))
1327 nil))
1328 #+end_src
1329
1330 * Blogging
1331 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1332
1333 #+begin_src emacs-lisp
1334 (use-package ox-hugo
1335   :after ox)
1336 #+end_src
1337
1338 * Post initialization
1339 :PROPERTIES:
1340 :CUSTOM_ID: post-initialization
1341 :END:
1342
1343 Display how long it took to load the init file.
1344
1345 #+begin_src emacs-lisp
1346 (message "Loading %s...done (%.3fs)" user-init-file
1347          (float-time (time-subtract (current-time)
1348                                     ab--before-user-init-time)))
1349 #+end_src
1350
1351 * Footer
1352 :PROPERTIES:
1353 :CUSTOM_ID: footer
1354 :END:
1355
1356 #+begin_src emacs-lisp :comments none
1357 ;;; init.el ends here
1358 #+end_src