git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** Package management
 192
 193 *** No =package.el=
 194
 195 I can do all my package management things with Borg, and don't need
 196 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 197 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 198
 199 #+begin_src emacs-lisp :tangle early-init.el
 200 (setq package-enable-at-startup nil)
 201 #+end_src
 202
 203 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 204 right now), and even when released it'll be long before most distros
 205 ship in their repos, I'll still put the old workaround with the
 206 commented call to ~package-initialize~ here anyway.
 207
 208 #+begin_src emacs-lisp
 209 (setq package-enable-at-startup nil)
 210 ;; (package-initialize)
 211 #+end_src
 212
 213 *** Borg
 214
 215 #+begin_quote
 216 Assimilate Emacs packages as Git submodules
 217 #+end_quote
 218
 219 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 220 short, it creates a git submodule in =lib/= for each package, which
 221 can then be managed with the help of Magit or other tools.
 222
 223 #+begin_src emacs-lisp
 224 (setq user-init-file (or load-file-name buffer-file-name)
 225       user-emacs-directory (file-name-directory user-init-file))
 226 (add-to-list 'load-path
 227              (expand-file-name "lib/borg" user-emacs-directory))
 228 (require 'borg)
 229 (borg-initialize)
 230 #+end_src
 231
 232 *** =use-package=
 233
 234 #+begin_quote
 235 A use-package declaration for simplifying your .emacs
 236 #+end_quote
 237
 238 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 239 packages (in our case especially the latter) in a neatly organized way
 240 and without compromising on performance.
 241
 242 #+begin_src emacs-lisp
 243 (require 'use-package)
 244 (if nil                             ; set to t when need to debug init
 245     (setq use-package-verbose t
 246           use-package-expand-minimally nil
 247           use-package-compute-statistics t
 248           debug-on-error t)
 249   (setq use-package-verbose nil
 250         use-package-expand-minimally t))
 251 #+end_src
 252
 253 *** Epkg
 254
 255 #+begin_quote
 256 Browse the Emacsmirror package database
 257 #+end_quote
 258
 259 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 260 database, low-level functions for querying the database, and a
 261 =package.el=-like user interface for browsing the available packages.
 262
 263 #+begin_src emacs-lisp
 264 (use-package epkg
 265   :defer t)
 266 #+end_src
 267
 268 ** No littering in =~/.emacs.d=
 269
 270 #+begin_quote
 271 Help keeping ~/.emacs.d clean
 272 #+end_quote
 273
 274 By default, even for Emacs' built-in packages, the configuration files
 275 and persistent data are all over the place. Use =no-littering= to help
 276 contain the mess.
 277
 278 #+begin_src emacs-lisp
 279 (use-package no-littering
 280   :demand t
 281   :config
 282   (savehist-mode 1)
 283   (add-to-list 'savehist-additional-variables 'kill-ring)
 284   (save-place-mode 1)
 285   (setq auto-save-file-name-transforms
 286         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 287 #+end_src
 288
 289 ** Custom file (=custom.el=)
 290
 291 I'm not planning on using the custom file much, but even so, I
 292 definitely don't want it mixing with =init.el=. So, here; let's give
 293 it it's own file. While at it, treat themes as safe.
 294
 295 #+begin_src emacs-lisp
 296 (use-package custom
 297   :no-require t
 298   :config
 299   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 300   (when (file-exists-p custom-file)
 301     (load custom-file))
 302   (setf custom-safe-themes t))
 303 #+end_src
 304
 305 ** Better =$PATH= handling
 306
 307 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 308 in my shell.
 309
 310 #+begin_src emacs-lisp
 311 (use-package exec-path-from-shell
 312   :defer 1
 313   :init
 314   (setq exec-path-from-shell-check-startup-files nil)
 315   :config
 316   (exec-path-from-shell-initialize)
 317   ;; while we're at it, let's fix access to our running ssh-agent
 318   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 319   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 320 #+end_src
 321
 322 ** Only one custom theme at a time
 323
 324 #+begin_src emacs-lisp
 325 (defadvice load-theme (before clear-previous-themes activate)
 326   "Clear existing theme settings instead of layering them"
 327   (mapc #'disable-theme custom-enabled-themes))
 328 #+end_src
 329
 330 ** Server
 331
 332 Start server if not already running. Alternatively, can be done by
 333 issuing =emacs --daemon= in the terminal, which can be automated with
 334 a systemd service or using =brew services start emacs= on macOS. I use
 335 Emacs as my window manager (via EXWM), so I always start Emacs on
 336 login; so starting the server from inside Emacs is good enough for me.
 337
 338 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 339
 340 #+begin_src emacs-lisp
 341 (use-package server
 342   :config (or (server-running-p) (server-mode)))
 343 #+end_src
 344
 345 ** Unicode support
 346
 347 Font stack with better unicode support, around =Ubuntu Mono= and
 348 =Hack=.
 349
 350 #+begin_src emacs-lisp
 351 (dolist (ft (fontset-list))
 352   (set-fontset-font
 353    ft
 354    'unicode
 355    (font-spec :name "Ubuntu Mono"))
 356   (set-fontset-font
 357    ft
 358    'unicode
 359    (font-spec :name "DejaVu Sans Mono")
 360    nil
 361    'append)
 362   ;; (set-fontset-font
 363   ;;  ft
 364   ;;  'unicode
 365   ;;  (font-spec
 366   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 367   ;;  nil
 368   ;;  'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  #x2115  ; ℕ
 372   ;;  (font-spec :name "DejaVu Sans Mono")
 373   ;;  nil
 374   ;;  'append)
 375   (set-fontset-font
 376    ft
 377    (cons ?Α ?ω)
 378    (font-spec :name "DejaVu Sans Mono" :size 14)
 379    nil
 380    'prepend))
 381 #+end_src
 382
 383 ** Libraries
 384
 385 #+begin_src emacs-lisp
 386 (require 'cl-lib)
 387 (require 'subr-x)
 388 #+end_src
 389
 390 ** Useful utilities
 391
 392 #+begin_src emacs-lisp
 393 (defun ab-enlist (exp)
 394   "Return EXP wrapped in a list, or as-is if already a list."
 395 (if (listp exp) exp (list exp)))
 396
 397 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 398 (defmacro after! (features &rest body)
 399   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 400 compilation."
 401   (declare (indent defun) (debug t))
 402   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 403                 (dolist (next (ab-enlist features))
 404                   (if (symbolp next)
 405                       (require next nil :no-error)
 406                     (load next :no-message :no-error))))
 407             #'progn
 408           #'with-no-warnings)
 409         (cond ((symbolp features)
 410                `(eval-after-load ',features '(progn ,@body)))
 411               ((and (consp features)
 412                     (memq (car features) '(:or :any)))
 413                `(progn
 414                   ,@(cl-loop for next in (cdr features)
 415                              collect `(after! ,next ,@body))))
 416               ((and (consp features)
 417                     (memq (car features) '(:and :all)))
 418                (dolist (next (cdr features))
 419                  (setq body `(after! ,next ,@body)))
 420                body)
 421               ((listp features)
 422                `(after! (:all ,@features) ,@body)))))
 423 #+end_src
 424
 425 * Core
 426 :PROPERTIES:
 427 :CUSTOM_ID: core
 428 :END:
 429
 430 ** Defaults
 431
 432 *** Time and battery in mode-line
 433
 434 Enable displaying time and battery in the mode-line, since I'm not
 435 using the Xfce panel anymore. Also, I don't need to see the load
 436 average on a regular basis, so disable that.
 437
 438 #+begin_src emacs-lisp
 439 (use-package time
 440   :ensure nil
 441   :init
 442   (setq display-time-default-load-average nil)
 443   :config
 444   (display-time-mode))
 445
 446 (use-package battery
 447   :ensure nil
 448   :config
 449   (display-battery-mode))
 450 #+end_src
 451
 452 *** Smaller fringe
 453
 454 Might want to set the fringe to a smaller value, especially if using
 455 EXWM. I'm fine with the default for now.
 456
 457 #+begin_src emacs-lisp
 458 ;; (fringe-mode '(3 . 1))
 459 (fringe-mode nil)
 460 #+end_src
 461
 462 *** Disable disabled commands
 463
 464 Emacs disables some commands by default that could persumably be
 465 confusing for novice users. Let's disable that.
 466
 467 #+begin_src emacs-lisp
 468 (setq disabled-command-function nil)
 469 #+end_src
 470
 471 *** Kill-ring
 472
 473 Save what I copy into clipboard from other applications into Emacs'
 474 kill-ring, which would allow me to still be able to easily access it
 475 in case I kill (cut or copy) something else inside Emacs before
 476 yanking (pasting) what I'd originally intended to.
 477
 478 #+begin_src emacs-lisp
 479 (setq save-interprogram-paste-before-kill t)
 480 #+end_src
 481
 482 *** Minibuffer
 483
 484 #+begin_src emacs-lisp
 485 (setq enable-recursive-minibuffers t
 486       resize-mini-windows t)
 487 #+end_src
 488
 489 *** Lazy-person-friendly yes/no prompts
 490
 491 Lazy people would prefer to type fewer keystrokes, especially for yes
 492 or no questions. I'm lazy.
 493
 494 #+begin_src emacs-lisp
 495 (defalias 'yes-or-no-p #'y-or-n-p)
 496 #+end_src
 497
 498 *** Startup screen and =*scratch*=
 499
 500 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 501 startup buffer.
 502
 503 #+begin_src emacs-lisp
 504 (setq initial-buffer-choice t)
 505 #+end_src
 506
 507 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 508 need the default hint.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-scratch-message nil)
 512 #+end_src
 513
 514 Also, let's use Text mode as the major mode, in case I want to
 515 customize it (=*scratch*='s default major mode, Fundamental mode,
 516 can't really be customized).
 517
 518 #+begin_src emacs-lisp
 519 (setq initial-major-mode 'text-mode)
 520 #+end_src
 521
 522 Inhibit the buffer list when more than 2 files are loaded.
 523
 524 #+begin_src emacs-lisp
 525 (setq inhibit-startup-buffer-menu t)
 526 #+end_src
 527
 528 I don't really need to see the startup screen or echo area message
 529 either.
 530
 531 #+begin_src emacs-lisp
 532 (advice-add #'display-startup-echo-area-message :override #'ignore)
 533 (setq inhibit-startup-screen t
 534       inhibit-startup-echo-area-message user-login-name)
 535 #+end_src
 536
 537 *** More useful frame titles
 538
 539 Show either the file name or the buffer name (in case the buffer isn't
 540 visiting a file). Borrowed from Emacs Prelude.
 541
 542 #+begin_src emacs-lisp
 543 (setq frame-title-format
 544       '("" invocation-name " - "
 545         (:eval (if (buffer-file-name)
 546                    (abbreviate-file-name (buffer-file-name))
 547                  "%b"))))
 548 #+end_src
 549
 550 *** Backups
 551
 552 Emacs' default backup settings aren't that great. Let's use more
 553 sensible options. See documentation for the ~make-backup-file~
 554 variable.
 555
 556 #+begin_src emacs-lisp
 557 (setq backup-by-copying t
 558       version-control t)
 559 #+end_src
 560
 561 ** Packages
 562
 563 The packages in this section are absolutely essential to my everyday
 564 workflow, and they play key roles in how I do my computing. They
 565 immensely enhance the Emacs experience for me; both using Emacs, and
 566 customizing it.
 567
 568 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 569
 570 #+begin_src emacs-lisp
 571 (use-package auto-compile
 572   :demand t
 573   :config
 574   (auto-compile-on-load-mode)
 575   (auto-compile-on-save-mode)
 576   (setq auto-compile-display-buffer               nil
 577         auto-compile-mode-line-counter            t
 578         auto-compile-source-recreate-deletes-dest t
 579         auto-compile-toggle-deletes-nonlib-dest   t
 580         auto-compile-update-autoloads             t)
 581   (add-hook 'auto-compile-inhibit-compile-hook
 582             'auto-compile-inhibit-compile-detached-git-head))
 583 #+end_src
 584
 585 *** [[https://github.com/noctuid/general.el][general]]
 586
 587 #+begin_quote
 588 Roll your own modal mode
 589 #+end_quote
 590
 591 #+begin_src emacs-lisp
 592 (use-package general
 593   :demand t
 594   :config
 595   (general-evil-setup t)
 596
 597   (general-override-mode)
 598
 599   (general-create-definer
 600     ab--mode-leader-keys
 601     :keymaps 'override
 602     :states '(emacs normal visual motion insert)
 603     :non-normal-prefix "C-,"
 604     :prefix ",")
 605
 606   (general-create-definer
 607     ab--leader-keys
 608     :keymaps 'override
 609     :states '(emacs normal visual motion insert)
 610     :non-normal-prefix "M-m"
 611     :prefix "SPC"))
 612 #+end_src
 613
 614 *** evil
 615
 616 #+begin_src emacs-lisp
 617 (use-package evil
 618   :demand t
 619   :hook (view-mode . evil-motion-state)
 620   :config (evil-mode 1))
 621 #+end_src
 622
 623 #+begin_src emacs-lisp
 624 (use-package evil-escape
 625   :demand t
 626   :init
 627   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 628         evil-escape-excluded-major-modes '(neotree-mode)
 629         evil-escape-key-sequence "jk"
 630         evil-escape-delay 0.25)
 631   :general
 632   (:states '(insert replace visual operator)
 633     "C-g" #'evil-escape)
 634   :config
 635   (evil-escape-mode 1)
 636   ;; no `evil-escape' in minibuffer
 637   (push #'minibufferp evil-escape-inhibit-functions))
 638 #+end_src
 639
 640 *** [[https://github.com/ch11ng/exwm][EXWM]] (window manager)
 641
 642 #+begin_src emacs-lisp :tangle no
 643 (use-package exwm
 644   :demand t
 645   :config
 646   (require 'exwm-config)
 647
 648   ;; Set the initial workspace number.
 649   (setq exwm-workspace-number 4)
 650
 651   ;; Make class name the buffer name, truncating beyond 50 characters
 652   (defun exwm-rename-buffer ()
 653     (interactive)
 654     (exwm-workspace-rename-buffer
 655      (concat exwm-class-name ":"
 656              (if (<= (length exwm-title) 50) exwm-title
 657                (concat (substring exwm-title 0 49) "...")))))
 658   (add-hook 'exwm-update-class-hook 'exwm-rename-buffer)
 659   (add-hook 'exwm-update-title-hook 'exwm-rename-buffer)
 660
 661   ;; 's-R': Reset
 662   (exwm-input-set-key (kbd "s-R") #'exwm-reset)
 663   ;; 's-\': Switch workspace
 664   (exwm-input-set-key (kbd "s-\\") #'exwm-workspace-switch)
 665   ;; 's-N': Switch to certain workspace
 666   (dotimes (i 10)
 667     (exwm-input-set-key (kbd (format "s-%d" i))
 668                         (lambda ()
 669                           (interactive)
 670                           (exwm-workspace-switch-create i))))
 671   ;; 's-SPC': Launch application
 672   ;; (exwm-input-set-key
 673   ;;  (kbd "s-SPC")
 674   ;;  (lambda (command)
 675   ;;    (interactive (list (read-shell-command "➜ ")))
 676   ;;    (start-process-shell-command command nil command)))
 677
 678   (exwm-input-set-key (kbd "M-s-SPC") #'counsel-linux-app)
 679
 680   ;; Shorten 'C-c C-q' to 'C-q'
 681   (define-key exwm-mode-map [?\C-q] #'exwm-input-send-next-key)
 682
 683   ;; Line-editing shortcuts
 684   (setq exwm-input-simulation-keys
 685         '(;; movement
 686           ([?\C-b] . [left])
 687           ([?\M-b] . [C-left])
 688           ([?\C-f] . [right])
 689           ([?\M-f] . [C-right])
 690           ([?\C-p] . [up])
 691           ([?\C-n] . [down])
 692           ([?\C-a] . [home])
 693           ([?\C-e] . [end])
 694           ([?\M-v] . [prior])
 695           ([?\C-v] . [next])
 696           ([?\C-d] . [delete])
 697           ([?\C-k] . [S-end delete])
 698           ;; cut/copy/paste
 699           ;; ([?\C-w] . [?\C-x])
 700           ([?\M-w] . [?\C-c])
 701           ([?\C-y] . [?\C-v])
 702           ;; search
 703           ([?\C-s] . [?\C-f])))
 704
 705   ;; Enable EXWM
 706   (exwm-enable)
 707
 708   (add-hook 'exwm-init-hook #'exwm-config--fix/ido-buffer-window-other-frame)
 709
 710   (require 'exwm-systemtray)
 711   (exwm-systemtray-enable)
 712
 713   (require 'exwm-randr)
 714   (exwm-randr-enable)
 715
 716   ;; (exwm-input-set-key
 717   ;;  (kbd "s-<return>")
 718   ;;  (lambda ()
 719   ;;    (interactive)
 720   ;;    (start-process "urxvt" nil "urxvt")))
 721
 722   ;; (exwm-input-set-key
 723   ;;  (kbd "s-SPC")  ;; rofi doesn't properly launch programs when started from emacs
 724   ;;  (lambda ()
 725   ;;    (interactive)
 726   ;;    (start-process-shell-command "rofi-run" nil "rofi -show run -display-run '> ' -display-window ' 🗔 '")))
 727
 728   ;; (exwm-input-set-key
 729   ;;  (kbd "s-/")
 730   ;;  (lambda ()
 731   ;;    (interactive)
 732   ;;    (start-process-shell-command "rofi-win" nil "rofi -show window  -display-run '> ' -display-window ' 🗔 '")))
 733
 734   ;; (exwm-input-set-key
 735   ;;  (kbd "M-SPC")
 736   ;;  (lambda ()
 737   ;;    (interactive)
 738   ;;    (start-process "rofi-pass" nil "rofi-pass")))
 739
 740   ;; (exwm-input-set-key
 741   ;;  (kbd "<XF86AudioMute>")
 742   ;;  (lambda ()
 743   ;;    (interactive)
 744   ;;    (start-process-shell-command "pamixer" nil "pamixer --toggle-mute")))
 745
 746   ;; (exwm-input-set-key
 747   ;;  (kbd "<XF86AudioLowerVolume>")
 748   ;;  (lambda ()
 749   ;;    (interactive)
 750   ;;    (start-process-shell-command "pamixer" nil "pamixer --allow-boost --decrease 5")))
 751
 752   ;; (exwm-input-set-key
 753   ;;  (kbd "<XF86AudioRaiseVolume>")
 754   ;;  (lambda ()
 755   ;;    (interactive)
 756   ;;    (start-process-shell-command "pamixer" nil "pamixer --allow-boost --increase 5")))
 757
 758   ;; (exwm-input-set-key
 759   ;;  (kbd "<XF86AudioPlay>")
 760   ;;  (lambda ()
 761   ;;    (interactive)
 762   ;;    (start-process-shell-command "mpc" nil "mpc toggle")))
 763
 764   ;; (exwm-input-set-key
 765   ;;  (kbd "<XF86AudioPrev>")
 766   ;;  (lambda ()
 767   ;;    (interactive)
 768   ;;    (start-process-shell-command "mpc" nil "mpc prev")))
 769
 770   ;; (exwm-input-set-key
 771   ;;  (kbd "<XF86AudioNext>")
 772   ;;  (lambda ()
 773   ;;    (interactive)
 774   ;;    (start-process-shell-command "mpc" nil "mpv next")))
 775
 776   (defun ab--exwm-pasystray ()
 777     "A command used to start pasystray."
 778     (interactive)
 779     (if (executable-find "pasystray")
 780         (progn
 781           (message "EXWM: starting pasystray ...")
 782           (start-process-shell-command "pasystray" nil "pasystray --notify=all"))
 783       (message "EXWM: pasystray is not installed, abort!")))
 784
 785   (add-hook 'exwm-init-hook #'ab--exwm-pasystray)
 786
 787   (exwm-input-set-key
 788    (kbd "s-t")
 789    (lambda ()
 790      (interactive)
 791      (exwm-floating-toggle-floating)))
 792
 793   (exwm-input-set-key
 794    (kbd "s-f")
 795    (lambda ()
 796      (interactive)
 797      (exwm-layout-toggle-fullscreen)))
 798
 799   (exwm-input-set-key
 800    (kbd "s-w")
 801    (lambda ()
 802      (interactive)
 803      (kill-buffer (current-buffer))))
 804
 805   (exwm-input-set-key
 806    (kbd "s-q")
 807    (lambda ()
 808      (interactive)
 809      (exwm-manage--kill-client))))
 810 #+end_src
 811
 812 **** sxhkdrc
 813 :PROPERTIES:
 814 :header-args+: :tangle ~/.config/sxhkd/sxhkdrc :mkdirp yes
 815 :END:
 816
 817 #+begin_src conf :tangle no
 818 # terminal emulator
 819 super + Return
 820         urxvt
 821
 822 # program launcher
 823 super + space
 824         rofi -show run -display-run '> ' -display-window ' 🗔 '
 825
 826 # window finder
 827 super + slash
 828         rofi -show window  -display-run '> ' -display-window ' 🗔 '
 829
 830 # password manager
 831 alt + space
 832         rofi-pass
 833
 834 # make sxhkd reload its configuration files:
 835 super + Escape
 836         pkill -USR1 -x sxhkd
 837
 838 # volume {up,down}
 839 XF86Audio{Raise,Lower}Volume
 840         pamixer --allow-boost --{in,de}crease 5
 841
 842 # mute
 843 XF86AudioMute
 844         pamixer --toggle-mute
 845
 846 # playback control
 847 XF86Audio{Play,Prev,Next}
 848         mpc {toggle,prev,next}
 849
 850 # Toggle keyboard layout
 851 # super + F7
 852 #       toggle-layout
 853
 854 # Toggle Xfce presentation mode
 855 # XF86LaunchB
 856 #       toggle-presentation-mode
 857
 858 # monitor brightness
 859 XF86MonBrightness{Up,Down}
 860         light -{A,U} 5
 861
 862 super + apostrophe
 863         rofi-light
 864 #+end_src
 865
 866 *** [[https://orgmode.org/][Org mode]]
 867
 868 #+begin_quote
 869 Org mode is for keeping notes, maintaining TODO lists, planning
 870 projects, and authoring documents with a fast and effective plain-text
 871 system.
 872 #+end_quote
 873
 874 In short, my favourite way of life.
 875
 876 #+begin_src emacs-lisp
 877 (setq org-src-tab-acts-natively t
 878       org-src-preserve-indentation nil
 879       org-edit-src-content-indentation 0
 880       org-html-doctype "html5"
 881       org-html-html5-fancy t)
 882 (add-hook 'org-mode-hook 'org-indent-mode)
 883 (use-package htmlize)
 884 #+end_src
 885
 886 *** [[https://magit.vc/][Magit]]
 887
 888 #+begin_quote
 889 It's Magit! A Git porcelain inside Emacs.
 890 #+end_quote
 891
 892 Not just how I do git, but /the/ way to do git.
 893
 894 #+begin_src emacs-lisp
 895 (use-package magit
 896   :general (ab--leader-keys "g s" 'magit-status)
 897   :defer t
 898   :bind (("s-g"     . magit-status)
 899          ("C-x g"   . magit-status)
 900          ("C-x M-g" . magit-dispatch-popup))
 901   :config
 902   (magit-add-section-hook 'magit-status-sections-hook
 903                           'magit-insert-modules
 904                           'magit-insert-stashes
 905                           'append))
 906 #+end_src
 907
 908 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 909
 910 #+begin_quote
 911 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 912 an overview, and more. Oh, man!
 913 #+end_quote
 914
 915 There's no way I could top that, so I won't attempt to.
 916
 917 **** Ivy
 918
 919 #+begin_src emacs-lisp
 920 (use-package ivy
 921   :defer 1
 922   :bind
 923   (:map ivy-minibuffer-map
 924         ([escape] . keyboard-escape-quit)
 925         ;; ("C-j"    . ivy-next-line)
 926         ;; ("C-k"    . ivy-previous-line)
 927         ([S-up]   . ivy-previous-history-element)
 928         ([S-down] . ivy-next-history-element)
 929         ("DEL"    . ivy-backward-delete-char))
 930   :config
 931   (setq ivy-wrap t)
 932   (ivy-mode 1))
 933 #+end_src
 934
 935 **** Swiper
 936
 937 #+begin_src emacs-lisp
 938 (use-package swiper
 939   :general (:states 'normal "/" 'swiper)
 940   :bind (([remap isearch-forward]  . swiper)
 941          ([remap isearch-backward] . swiper)))
 942 #+end_src
 943
 944 **** Counsel
 945
 946 #+begin_src emacs-lisp
 947 (use-package counsel
 948   :defer 1
 949   :general (ab--leader-keys
 950     "f r" 'counsel-recentf
 951     "SPC" 'counsel-M-x
 952     "."   'counsel-find-file)
 953   :bind (([remap execute-extended-command] . counsel-M-x)
 954          ([remap find-file] . counsel-find-file)
 955          ("s-r"     . counsel-recentf)
 956          :map minibuffer-local-map
 957          ("C-r" . counsel-minibuffer-history))
 958   :config
 959   (counsel-mode 1)
 960   (defalias 'locate #'counsel-locate))
 961 #+end_src
 962
 963 * Borg's =layer/essentials=
 964
 965 TODO: break this giant source block down into individual org sections.
 966
 967 #+begin_src emacs-lisp
 968 (use-package dash
 969   :config (dash-enable-font-lock))
 970
 971 (use-package diff-hl
 972   :config
 973   (setq diff-hl-draw-borders nil)
 974   (global-diff-hl-mode)
 975   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 976
 977 (use-package dired
 978   :defer t
 979   :config (setq dired-listing-switches "-alh"))
 980
 981 (use-package eldoc
 982   :when (version< "25" emacs-version)
 983   :config (global-eldoc-mode))
 984
 985 (use-package help
 986   :defer t
 987   :config (temp-buffer-resize-mode))
 988
 989 (progn ;    `isearch'
 990   (setq isearch-allow-scroll t))
 991
 992 (use-package lisp-mode
 993   :config
 994   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 995   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 996   (defun indent-spaces-mode ()
 997     (setq indent-tabs-mode nil))
 998   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 999
1000 (use-package man
1001   :defer t
1002   :config (setq Man-width 80))
1003
1004 (use-package paren
1005   :config (show-paren-mode))
1006
1007 (use-package prog-mode
1008   :config (global-prettify-symbols-mode)
1009   (defun indicate-buffer-boundaries-left ()
1010     (setq indicate-buffer-boundaries 'left))
1011   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1012
1013 (use-package recentf
1014   :demand t
1015   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
1016
1017 (use-package savehist
1018   :config (savehist-mode))
1019
1020 (use-package saveplace
1021   :when (version< "25" emacs-version)
1022   :config (save-place-mode))
1023
1024 (use-package simple
1025   :config (column-number-mode))
1026
1027 (progn ;    `text-mode'
1028   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1029
1030 (use-package tramp
1031   :defer t
1032   :config
1033   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1034   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1035   (add-to-list 'tramp-default-proxies-alist
1036                (list (regexp-quote (system-name)) nil nil)))
1037
1038 (use-package undo-tree
1039   :config
1040   (global-undo-tree-mode)
1041   (setq undo-tree-mode-lighter ""))
1042 #+end_src
1043
1044 * Editing
1045
1046 ** Company
1047
1048 #+begin_src emacs-lisp
1049 (use-package company
1050   :defer 5
1051   :bind
1052   (:map company-active-map
1053         ([tab] . company-complete-common-or-cycle))
1054   :custom
1055   (company-idle-delay 0.3)
1056   (company-minimum-prefix-length 1)
1057   (company-selection-wrap-around t)
1058   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1059   :config
1060   (global-company-mode t))
1061 #+end_src
1062
1063 ** Customizations
1064
1065 #+begin_src emacs-lisp
1066 (ab--leader-keys
1067   "b s" 'save-buffer
1068   "b b" 'ivy-switch-buffer
1069   ","   'ivy-switch-buffer
1070   "b k" 'kill-this-buffer
1071   "q q" 'evil-save-and-quit)
1072 #+end_src
1073
1074 * Syntax and spell checking
1075 #+begin_src emacs-lisp
1076 (use-package flycheck
1077   :hook (prog-mode . flycheck-mode)
1078   :config
1079   ;; Use the load-path from running Emacs when checking elisp files
1080   (setq flycheck-emacs-lisp-load-path 'inherit)
1081
1082   ;; Only flycheck when I actually save the buffer
1083   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1084 #+end_src
1085 * Programming modes
1086
1087 ** [[https://github.com/leanprover/lean-mode][Lean]]
1088
1089 #+begin_src emacs-lisp
1090 (use-package lean-mode
1091   :bind (:map lean-mode-map
1092               ("S-SPC" . company-complete)))
1093 #+end_src
1094
1095 ** Haskell
1096
1097 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1098
1099 #+begin_src emacs-lisp
1100 (use-package haskell-mode
1101   :config
1102   (setq haskell-indentation-layout-offset 4
1103         haskell-indentation-left-offset 4
1104         flycheck-checker 'haskell-hlint
1105         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1106 #+end_src
1107
1108 *** [[https://github.com/jyp/dante][dante]]
1109
1110 #+begin_src emacs-lisp
1111 (use-package dante
1112   :after haskell-mode
1113   :commands dante-mode
1114   :hook (haskell-mode . dante-mode))
1115 #+end_src
1116
1117 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1118
1119 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1120 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1121
1122 #+begin_src emacs-lisp
1123 (use-package hlint-refactor
1124   :bind (:map hlint-refactor-mode-map
1125               ("C-c l b" . hlint-refactor-refactor-buffer)
1126               ("C-c l r" . hlint-refactor-refactor-at-point))
1127   :hook (haskell-mode . hlint-refactor-mode))
1128 #+end_src
1129
1130 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1131
1132 #+begin_src emacs-lisp
1133 (use-package flycheck-haskell)
1134 #+end_src
1135
1136 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1137 :PROPERTIES:
1138 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1139 :END:
1140
1141 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1142 instead.
1143
1144 #+begin_src emacs-lisp :tangle no
1145 ;;; hs-lint.el --- minor mode for HLint code checking
1146
1147 ;; Copyright 2009 (C) Alex Ott
1148 ;;
1149 ;; Author: Alex Ott <alexott@gmail.com>
1150 ;; Keywords: haskell, lint, HLint
1151 ;; Requirements:
1152 ;; Status: distributed under terms of GPL2 or above
1153
1154 ;; Typical message from HLint looks like:
1155 ;;
1156 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1157 ;; Found:
1158 ;;   count1 p l = length (filter p l)
1159 ;; Why not:
1160 ;;   count1 p = length . filter p
1161
1162
1163 (require 'compile)
1164
1165 (defgroup hs-lint nil
1166   "Run HLint as inferior of Emacs, parse error messages."
1167   :group 'tools
1168   :group 'haskell)
1169
1170 (defcustom hs-lint-command "hlint"
1171   "The default hs-lint command for \\[hlint]."
1172   :type 'string
1173   :group 'hs-lint)
1174
1175 (defcustom hs-lint-save-files t
1176   "Save modified files when run HLint or no (ask user)"
1177   :type 'boolean
1178   :group 'hs-lint)
1179
1180 (defcustom hs-lint-replace-with-suggestions nil
1181   "Replace user's code with suggested replacements"
1182   :type 'boolean
1183   :group 'hs-lint)
1184
1185 (defcustom hs-lint-replace-without-ask nil
1186   "Replace user's code with suggested replacements automatically"
1187   :type 'boolean
1188   :group 'hs-lint)
1189
1190 (defun hs-lint-process-setup ()
1191   "Setup compilation variables and buffer for `hlint'."
1192   (run-hooks 'hs-lint-setup-hook))
1193
1194 ;; regex for replace suggestions
1195 ;;
1196 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1197 ;; Found:
1198 ;; \s +\(.*\)
1199 ;; Why not:
1200 ;; \s +\(.*\)
1201
1202 (defvar hs-lint-regex
1203   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1204   "Regex for HLint messages")
1205
1206 (defun make-short-string (str maxlen)
1207   (if (< (length str) maxlen)
1208       str
1209     (concat (substring str 0 (- maxlen 3)) "...")))
1210
1211 (defun hs-lint-replace-suggestions ()
1212   "Perform actual replacement of suggestions"
1213   (goto-char (point-min))
1214   (while (re-search-forward hs-lint-regex nil t)
1215     (let* ((fname (match-string 1))
1216           (fline (string-to-number (match-string 2)))
1217           (old-code (match-string 4))
1218           (new-code (match-string 5))
1219           (msg (concat "Replace '" (make-short-string old-code 30)
1220                        "' with '" (make-short-string new-code 30) "'"))
1221           (bline 0)
1222           (eline 0)
1223           (spos 0)
1224           (new-old-code ""))
1225       (save-excursion
1226         (switch-to-buffer (get-file-buffer fname))
1227         (goto-char (point-min))
1228         (forward-line (1- fline))
1229         (beginning-of-line)
1230         (setf bline (point))
1231         (when (or hs-lint-replace-without-ask
1232                   (yes-or-no-p msg))
1233           (end-of-line)
1234           (setf eline (point))
1235           (beginning-of-line)
1236           (setf old-code (regexp-quote old-code))
1237           (while (string-match "\\\\ " old-code spos)
1238             (setf new-old-code (concat new-old-code
1239                                  (substring old-code spos (match-beginning 0))
1240                                  "\\ *"))
1241             (setf spos (match-end 0)))
1242           (setf new-old-code (concat new-old-code (substring old-code spos)))
1243           (remove-text-properties bline eline '(composition nil))
1244           (when (re-search-forward new-old-code eline t)
1245             (replace-match new-code nil t)))))))
1246
1247 (defun hs-lint-finish-hook (buf msg)
1248   "Function, that is executed at the end of HLint execution"
1249   (if hs-lint-replace-with-suggestions
1250       (hs-lint-replace-suggestions)
1251       (next-error 1 t)))
1252
1253 (define-compilation-mode hs-lint-mode "HLint"
1254   "Mode for check Haskell source code."
1255   (set (make-local-variable 'compilation-process-setup-function)
1256        'hs-lint-process-setup)
1257   (set (make-local-variable 'compilation-disable-input) t)
1258   (set (make-local-variable 'compilation-scroll-output) nil)
1259   (set (make-local-variable 'compilation-finish-functions)
1260        (list 'hs-lint-finish-hook))
1261   )
1262
1263 (defun hs-lint ()
1264   "Run HLint for current buffer with haskell source"
1265   (interactive)
1266   (save-some-buffers hs-lint-save-files)
1267   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1268                      'hs-lint-mode))
1269
1270 (provide 'hs-lint)
1271 ;;; hs-lint.el ends here
1272 #+end_src
1273
1274 #+begin_src emacs-lisp :tangle no
1275 (use-package hs-lint
1276   :load-path "lisp/"
1277   :bind (:map haskell-mode-map
1278               ("C-c l l" . hs-lint)))
1279 #+end_src
1280 * Emacs Enhancements
1281
1282 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1283
1284 #+begin_quote
1285 Emacs package that displays available keybindings in popup
1286 #+end_quote
1287
1288 #+begin_src emacs-lisp
1289 (use-package which-key
1290   :defer 1
1291   :config (which-key-mode))
1292 #+end_src
1293 * Email
1294 ** notmuch
1295
1296 #+begin_src emacs-lisp
1297 (defun ab/notmuch ()
1298   "Delete other windows, then launch `notmuch'."
1299   (interactive)
1300   (require 'notmuch)
1301   (delete-other-windows)
1302   (notmuch))
1303
1304 ;; (ab--leader-keys
1305 ;;   "m"   'ab/notmuch
1306 ;;   "s"   'save-buffer
1307 ;;   "SPC" 'counsel-M-x)
1308
1309 ;; (map!
1310 ;;  :leader
1311 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1312 ;;  (:desc "search" :prefix "/"
1313 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1314 #+end_src
1315
1316 #+begin_src emacs-lisp
1317 (defvar ab-maildir "~/mail")
1318
1319 (use-package sendmail
1320   ;; :ensure nil
1321   :config
1322   (setq sendmail-program "/usr/bin/msmtp"
1323         mail-specify-envelope-from t
1324         mail-envelope-from 'header))
1325
1326 (use-package message
1327   ;; :ensure nil
1328   :config
1329   (setq message-kill-buffer-on-exit t
1330         message-send-mail-function 'message-send-mail-with-sendmail
1331         message-sendmail-envelope-from 'header
1332         message-directory "drafts"
1333         message-user-fqdn "fencepost.gnu.org")
1334   (add-hook 'message-mode-hook
1335             (lambda () (setq fill-column 65
1336                         message-fill-column 65)))
1337   (add-hook 'message-mode-hook
1338             #'flyspell-mode)
1339   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1340   ;; TODO: is there a way to only run this when replying and not composing?
1341   (add-hook 'notmuch-message-mode-hook
1342             (lambda () (progn
1343                     (newline)
1344                     (newline)
1345                     (forward-line -1)
1346                     (forward-line -1))))
1347   ;; (add-hook 'message-setup-hook
1348   ;;           #'mml-secure-message-sign-pgpmime)
1349   )
1350
1351 (after! mml-sec
1352   (setq mml-secure-openpgp-encrypt-to-self t
1353         mml-secure-openpgp-sign-with-sender t))
1354
1355 (use-package notmuch
1356   :general (ab--leader-keys "m" 'ab/notmuch)
1357   :config
1358   (setq notmuch-hello-sections
1359         '(notmuch-hello-insert-header
1360           notmuch-hello-insert-saved-searches
1361           ;; notmuch-hello-insert-search
1362           notmuch-hello-insert-alltags)
1363         notmuch-search-oldest-first nil
1364         notmuch-show-all-tags-list t
1365         notmuch-hello-thousands-separator ","
1366         notmuch-fcc-dirs
1367         '(("amin@aminb.org"            . "amin/Sent")
1368           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1369           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1370           ("aminb@gnu.org"             . "gnu/Sent")
1371           (".*"                        . "sent")))
1372   ;; (add-hook 'visual-fill-column-mode-hook
1373   ;;           (lambda ()
1374   ;;             (when (string= major-mode 'notmuch-message-mode)
1375   ;;               (setq visual-fill-column-width 70))))
1376   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1377   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1378   ;;             :override #'kill-this-buffer)
1379   :bind
1380   (:map notmuch-hello-mode-map
1381         ("g" . notmuch-poll-and-refresh-this-buffer)
1382         ("i" . (lambda ()
1383                  "Search for `inbox' tagged messages"
1384                  (interactive)
1385                  (notmuch-hello-search "tag:inbox")))
1386         ("u" . (lambda ()
1387                  "Search for `unread' tagged messages"
1388                  (interactive)
1389                  (notmuch-hello-search "tag:unread")))
1390         ("M" . (lambda ()
1391                  "Compose new mail and prompt for sender"
1392                  (interactive)
1393                  (let ((current-prefix-arg t))
1394                    (call-interactively #'notmuch-mua-new-mail)))))
1395   (:map notmuch-search-mode-map
1396         ("g" . notmuch-poll-and-refresh-this-buffer)
1397         ("k" . (lambda ()
1398                  "Mark message read"
1399                  (interactive)
1400                  (notmuch-search-tag '("-unread"))
1401                  ;; (notmuch-search-archive-thread)
1402                  (notmuch-search-next-thread)))
1403         ("u" . (lambda ()
1404                  "Mark message unread"
1405                  (interactive)
1406                  (notmuch-search-tag '("+unread"))
1407                  (notmuch-search-next-thread)))
1408         ("K" . (lambda ()
1409                  "Mark message deleted"
1410                  (interactive)
1411                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1412                  (notmuch-search-archive-thread)))
1413         ("S" . (lambda ()
1414                  "Mark message as spam"
1415                  (interactive)
1416                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1417                  (notmuch-search-archive-thread))))
1418   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1419         ("S" . (lambda ()
1420                  "Mark message as spam"
1421                  (interactive)
1422                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1423                  (notmuch-tree-archive-thread))))
1424 )
1425
1426 ;; (use-package counsel-notmuch
1427 ;;   :commands counsel-notmuch)
1428
1429 (after! notmuch-crypto
1430   (setq notmuch-crypto-process-mime t))
1431
1432 ;; (after! evil
1433 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1434 ;;         '((notmuch-hello-mode . emacs)
1435 ;;           (notmuch-search-mode . emacs)
1436 ;;           (notmuch-tree-mode . emacs))))
1437
1438 (after! recentf
1439   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1440 #+end_src
1441
1442 * Post initialization
1443 :PROPERTIES:
1444 :CUSTOM_ID: post-initialization
1445 :END:
1446
1447 Display how long it took to load the init file.
1448
1449 #+begin_src emacs-lisp
1450 (message "Loading %s...done (%.3fs)" user-init-file
1451          (float-time (time-subtract (current-time)
1452                                     ab--before-user-init-time)))
1453 #+end_src
1454
1455 * Footer
1456 :PROPERTIES:
1457 :CUSTOM_ID: footer
1458 :END:
1459
1460 #+begin_src emacs-lisp :comments none
1461 ;;; init.el ends here
1462 #+end_src