git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil                             ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 ** Packages
 569
 570 The packages in this section are absolutely essential to my everyday
 571 workflow, and they play key roles in how I do my computing. They
 572 immensely enhance the Emacs experience for me; both using Emacs, and
 573 customizing it.
 574
 575 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 576
 577 #+begin_src emacs-lisp
 578 (use-package auto-compile
 579   :demand t
 580   :config
 581   (auto-compile-on-load-mode)
 582   (auto-compile-on-save-mode)
 583   (setq auto-compile-display-buffer               nil
 584         auto-compile-mode-line-counter            t
 585         auto-compile-source-recreate-deletes-dest t
 586         auto-compile-toggle-deletes-nonlib-dest   t
 587         auto-compile-update-autoloads             t)
 588   (add-hook 'auto-compile-inhibit-compile-hook
 589             'auto-compile-inhibit-compile-detached-git-head))
 590 #+end_src
 591
 592 *** [[https://github.com/noctuid/general.el][general]]
 593
 594 #+begin_quote
 595 Roll your own modal mode
 596 #+end_quote
 597
 598 #+begin_src emacs-lisp
 599 (use-package general
 600   :demand t
 601   :config
 602   (general-evil-setup t)
 603
 604   (general-override-mode)
 605
 606   (general-create-definer
 607     ab--mode-leader-keys
 608     :keymaps 'override
 609     :states '(emacs normal visual motion insert)
 610     :non-normal-prefix "C-,"
 611     :prefix ",")
 612
 613   (general-create-definer
 614     ab--leader-keys
 615     :keymaps 'override
 616     :states '(emacs normal visual motion insert)
 617     :non-normal-prefix "M-m"
 618     :prefix "SPC"))
 619 #+end_src
 620
 621 *** evil
 622
 623 #+begin_src emacs-lisp
 624 (use-package evil
 625   :demand t
 626   :hook (view-mode . evil-motion-state)
 627   :config (evil-mode 1))
 628 #+end_src
 629
 630 #+begin_src emacs-lisp
 631 (use-package evil-escape
 632   :demand t
 633   :init
 634   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 635         evil-escape-excluded-major-modes '(neotree-mode)
 636         evil-escape-key-sequence "jk"
 637         evil-escape-delay 0.25)
 638   :general
 639   (:states '(insert replace visual operator)
 640     "C-g" #'evil-escape)
 641   :config
 642   (evil-escape-mode 1)
 643   ;; no `evil-escape' in minibuffer
 644   (push #'minibufferp evil-escape-inhibit-functions))
 645 #+end_src
 646
 647 *** [[https://orgmode.org/][Org mode]]
 648
 649 #+begin_quote
 650 Org mode is for keeping notes, maintaining TODO lists, planning
 651 projects, and authoring documents with a fast and effective plain-text
 652 system.
 653 #+end_quote
 654
 655 In short, my favourite way of life.
 656
 657 #+begin_src emacs-lisp
 658 (setq org-src-tab-acts-natively t
 659       org-src-preserve-indentation nil
 660       org-edit-src-content-indentation 0
 661       org-html-divs '((preamble  "header" "preamble")
 662                       (content   "main"   "content")
 663                       (postamble "footer" "postamble"))
 664       org-html-doctype "html5"
 665       org-html-html5-fancy t
 666       org-html-postamble nil)
 667 (add-hook 'org-mode-hook 'org-indent-mode)
 668 (use-package htmlize)
 669 (use-package org-notmuch
 670   :after (:any org notmuch))
 671 #+end_src
 672
 673 *** [[https://magit.vc/][Magit]]
 674
 675 #+begin_quote
 676 It's Magit! A Git porcelain inside Emacs.
 677 #+end_quote
 678
 679 Not just how I do git, but /the/ way to do git.
 680
 681 #+begin_src emacs-lisp
 682 (use-package magit
 683   :general (ab--leader-keys "g s" 'magit-status)
 684   :defer t
 685   :bind (("s-g"     . magit-status)
 686          ("C-x g"   . magit-status)
 687          ("C-x M-g" . magit-dispatch-popup))
 688   :config
 689   (magit-add-section-hook 'magit-status-sections-hook
 690                           'magit-insert-modules
 691                           'magit-insert-stashes
 692                           'append))
 693 #+end_src
 694
 695 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 696
 697 #+begin_quote
 698 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 699 an overview, and more. Oh, man!
 700 #+end_quote
 701
 702 There's no way I could top that, so I won't attempt to.
 703
 704 **** Ivy
 705
 706 #+begin_src emacs-lisp
 707 (use-package ivy
 708   :defer 1
 709   :bind
 710   (:map ivy-minibuffer-map
 711         ([escape] . keyboard-escape-quit)
 712         ;; ("C-j"    . ivy-next-line)
 713         ;; ("C-k"    . ivy-previous-line)
 714         ([S-up]   . ivy-previous-history-element)
 715         ([S-down] . ivy-next-history-element)
 716         ("DEL"    . ivy-backward-delete-char))
 717   :config
 718   (setq ivy-wrap t)
 719   (ivy-mode 1))
 720 #+end_src
 721
 722 **** Swiper
 723
 724 #+begin_src emacs-lisp
 725 (use-package swiper
 726   :general (:states 'normal "/" 'swiper)
 727   :bind (([remap isearch-forward]  . swiper)
 728          ([remap isearch-backward] . swiper)))
 729 #+end_src
 730
 731 **** Counsel
 732
 733 #+begin_src emacs-lisp
 734 (use-package counsel
 735   :defer 1
 736   :general (ab--leader-keys
 737     "f r" 'counsel-recentf
 738     "SPC" 'counsel-M-x
 739     "."   'counsel-find-file)
 740   :bind (([remap execute-extended-command] . counsel-M-x)
 741          ([remap find-file] . counsel-find-file)
 742          ("s-r"     . counsel-recentf)
 743          :map minibuffer-local-map
 744          ("C-r" . counsel-minibuffer-history))
 745   :config
 746   (counsel-mode 1)
 747   (defalias 'locate #'counsel-locate))
 748 #+end_src
 749
 750 * Borg's =layer/essentials=
 751
 752 TODO: break this giant source block down into individual org sections.
 753
 754 #+begin_src emacs-lisp
 755 (use-package dash
 756   :config (dash-enable-font-lock))
 757
 758 (use-package diff-hl
 759   :config
 760   (setq diff-hl-draw-borders nil)
 761   (global-diff-hl-mode)
 762   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 763
 764 (use-package dired
 765   :defer t
 766   :config (setq dired-listing-switches "-alh"))
 767
 768 (use-package eldoc
 769   :when (version< "25" emacs-version)
 770   :config (global-eldoc-mode))
 771
 772 (use-package help
 773   :defer t
 774   :config (temp-buffer-resize-mode))
 775
 776 (progn ;    `isearch'
 777   (setq isearch-allow-scroll t))
 778
 779 (use-package lisp-mode
 780   :config
 781   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 782   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 783   (defun indent-spaces-mode ()
 784     (setq indent-tabs-mode nil))
 785   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 786
 787 (use-package man
 788   :defer t
 789   :config (setq Man-width 80))
 790
 791 (use-package paren
 792   :config (show-paren-mode))
 793
 794 (use-package prog-mode
 795   :config (global-prettify-symbols-mode)
 796   (defun indicate-buffer-boundaries-left ()
 797     (setq indicate-buffer-boundaries 'left))
 798   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 799
 800 (use-package recentf
 801   :demand t
 802   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 803
 804 (use-package savehist
 805   :config (savehist-mode))
 806
 807 (use-package saveplace
 808   :when (version< "25" emacs-version)
 809   :config (save-place-mode))
 810
 811 (use-package simple
 812   :config (column-number-mode))
 813
 814 (progn ;    `text-mode'
 815   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 816
 817 (use-package tramp
 818   :defer t
 819   :config
 820   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 821   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 822   (add-to-list 'tramp-default-proxies-alist
 823                (list (regexp-quote (system-name)) nil nil)))
 824
 825 (use-package undo-tree
 826   :config
 827   (global-undo-tree-mode)
 828   (setq undo-tree-mode-lighter ""))
 829 #+end_src
 830
 831 * Editing
 832
 833 ** Company
 834
 835 #+begin_src emacs-lisp
 836 (use-package company
 837   :defer 5
 838   :bind
 839   (:map company-active-map
 840         ([tab] . company-complete-common-or-cycle))
 841   :custom
 842   (company-idle-delay 0.3)
 843   (company-minimum-prefix-length 1)
 844   (company-selection-wrap-around t)
 845   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 846   :config
 847   (global-company-mode t))
 848 #+end_src
 849
 850 ** Customizations
 851
 852 #+begin_src emacs-lisp
 853 (ab--leader-keys
 854   "b s" 'save-buffer
 855   "b b" 'ivy-switch-buffer
 856   ","   'ivy-switch-buffer
 857   "b k" 'kill-this-buffer
 858   "q q" 'evil-save-and-quit)
 859 #+end_src
 860
 861 * Syntax and spell checking
 862 #+begin_src emacs-lisp
 863 (use-package flycheck
 864   :hook (prog-mode . flycheck-mode)
 865   :config
 866   ;; Use the load-path from running Emacs when checking elisp files
 867   (setq flycheck-emacs-lisp-load-path 'inherit)
 868
 869   ;; Only flycheck when I actually save the buffer
 870   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 871 #+end_src
 872 * Programming modes
 873
 874 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 875
 876 #+begin_src emacs-lisp
 877 (use-package alloy-mode
 878   :config (setq alloy-basic-offset 2))
 879 #+end_src
 880
 881 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 882
 883 #+begin_src emacs-lisp
 884 (use-package proof-site  ; Proof General
 885   :load-path "lib/proof-site/generic/")
 886 #+end_src
 887
 888 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 889
 890 #+begin_src emacs-lisp
 891 (use-package lean-mode
 892   :bind (:map lean-mode-map
 893               ("S-SPC" . company-complete)))
 894 #+end_src
 895
 896 ** Haskell
 897
 898 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 899
 900 #+begin_src emacs-lisp
 901 (use-package haskell-mode
 902   :config
 903   (setq haskell-indentation-layout-offset 4
 904         haskell-indentation-left-offset 4
 905         flycheck-checker 'haskell-hlint
 906         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 907 #+end_src
 908
 909 *** [[https://github.com/jyp/dante][dante]]
 910
 911 #+begin_src emacs-lisp
 912 (use-package dante
 913   :after haskell-mode
 914   :commands dante-mode
 915   :hook (haskell-mode . dante-mode))
 916 #+end_src
 917
 918 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 919
 920 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 921 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 922
 923 #+begin_src emacs-lisp
 924 (use-package hlint-refactor
 925   :bind (:map hlint-refactor-mode-map
 926               ("C-c l b" . hlint-refactor-refactor-buffer)
 927               ("C-c l r" . hlint-refactor-refactor-at-point))
 928   :hook (haskell-mode . hlint-refactor-mode))
 929 #+end_src
 930
 931 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 932
 933 #+begin_src emacs-lisp
 934 (use-package flycheck-haskell)
 935 #+end_src
 936
 937 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 938 :PROPERTIES:
 939 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 940 :END:
 941
 942 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 943 instead.
 944
 945 #+begin_src emacs-lisp :tangle no
 946 ;;; hs-lint.el --- minor mode for HLint code checking
 947
 948 ;; Copyright 2009 (C) Alex Ott
 949 ;;
 950 ;; Author: Alex Ott <alexott@gmail.com>
 951 ;; Keywords: haskell, lint, HLint
 952 ;; Requirements:
 953 ;; Status: distributed under terms of GPL2 or above
 954
 955 ;; Typical message from HLint looks like:
 956 ;;
 957 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 958 ;; Found:
 959 ;;   count1 p l = length (filter p l)
 960 ;; Why not:
 961 ;;   count1 p = length . filter p
 962
 963
 964 (require 'compile)
 965
 966 (defgroup hs-lint nil
 967   "Run HLint as inferior of Emacs, parse error messages."
 968   :group 'tools
 969   :group 'haskell)
 970
 971 (defcustom hs-lint-command "hlint"
 972   "The default hs-lint command for \\[hlint]."
 973   :type 'string
 974   :group 'hs-lint)
 975
 976 (defcustom hs-lint-save-files t
 977   "Save modified files when run HLint or no (ask user)"
 978   :type 'boolean
 979   :group 'hs-lint)
 980
 981 (defcustom hs-lint-replace-with-suggestions nil
 982   "Replace user's code with suggested replacements"
 983   :type 'boolean
 984   :group 'hs-lint)
 985
 986 (defcustom hs-lint-replace-without-ask nil
 987   "Replace user's code with suggested replacements automatically"
 988   :type 'boolean
 989   :group 'hs-lint)
 990
 991 (defun hs-lint-process-setup ()
 992   "Setup compilation variables and buffer for `hlint'."
 993   (run-hooks 'hs-lint-setup-hook))
 994
 995 ;; regex for replace suggestions
 996 ;;
 997 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 998 ;; Found:
 999 ;; \s +\(.*\)
1000 ;; Why not:
1001 ;; \s +\(.*\)
1002
1003 (defvar hs-lint-regex
1004   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1005   "Regex for HLint messages")
1006
1007 (defun make-short-string (str maxlen)
1008   (if (< (length str) maxlen)
1009       str
1010     (concat (substring str 0 (- maxlen 3)) "...")))
1011
1012 (defun hs-lint-replace-suggestions ()
1013   "Perform actual replacement of suggestions"
1014   (goto-char (point-min))
1015   (while (re-search-forward hs-lint-regex nil t)
1016     (let* ((fname (match-string 1))
1017           (fline (string-to-number (match-string 2)))
1018           (old-code (match-string 4))
1019           (new-code (match-string 5))
1020           (msg (concat "Replace '" (make-short-string old-code 30)
1021                        "' with '" (make-short-string new-code 30) "'"))
1022           (bline 0)
1023           (eline 0)
1024           (spos 0)
1025           (new-old-code ""))
1026       (save-excursion
1027         (switch-to-buffer (get-file-buffer fname))
1028         (goto-char (point-min))
1029         (forward-line (1- fline))
1030         (beginning-of-line)
1031         (setf bline (point))
1032         (when (or hs-lint-replace-without-ask
1033                   (yes-or-no-p msg))
1034           (end-of-line)
1035           (setf eline (point))
1036           (beginning-of-line)
1037           (setf old-code (regexp-quote old-code))
1038           (while (string-match "\\\\ " old-code spos)
1039             (setf new-old-code (concat new-old-code
1040                                  (substring old-code spos (match-beginning 0))
1041                                  "\\ *"))
1042             (setf spos (match-end 0)))
1043           (setf new-old-code (concat new-old-code (substring old-code spos)))
1044           (remove-text-properties bline eline '(composition nil))
1045           (when (re-search-forward new-old-code eline t)
1046             (replace-match new-code nil t)))))))
1047
1048 (defun hs-lint-finish-hook (buf msg)
1049   "Function, that is executed at the end of HLint execution"
1050   (if hs-lint-replace-with-suggestions
1051       (hs-lint-replace-suggestions)
1052       (next-error 1 t)))
1053
1054 (define-compilation-mode hs-lint-mode "HLint"
1055   "Mode for check Haskell source code."
1056   (set (make-local-variable 'compilation-process-setup-function)
1057        'hs-lint-process-setup)
1058   (set (make-local-variable 'compilation-disable-input) t)
1059   (set (make-local-variable 'compilation-scroll-output) nil)
1060   (set (make-local-variable 'compilation-finish-functions)
1061        (list 'hs-lint-finish-hook))
1062   )
1063
1064 (defun hs-lint ()
1065   "Run HLint for current buffer with haskell source"
1066   (interactive)
1067   (save-some-buffers hs-lint-save-files)
1068   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1069                      'hs-lint-mode))
1070
1071 (provide 'hs-lint)
1072 ;;; hs-lint.el ends here
1073 #+end_src
1074
1075 #+begin_src emacs-lisp :tangle no
1076 (use-package hs-lint
1077   :load-path "lisp/"
1078   :bind (:map haskell-mode-map
1079               ("C-c l l" . hs-lint)))
1080 #+end_src
1081 * Emacs Enhancements
1082
1083 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1084
1085 #+begin_quote
1086 Emacs package that displays available keybindings in popup
1087 #+end_quote
1088
1089 #+begin_src emacs-lisp
1090 (use-package which-key
1091   :defer 1
1092   :config (which-key-mode))
1093 #+end_src
1094
1095 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1096
1097 #+begin_src emacs-lisp
1098 (use-package doom-modeline
1099   :demand t
1100   :config (setq doom-modeline-height 32)
1101   :hook (after-init . doom-modeline-init))
1102 #+end_src
1103
1104 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1105
1106 #+begin_src emacs-lisp :tangle no
1107 (use-package tao-theme
1108   :demand t
1109   :config (load-theme 'tao-yang t))
1110 #+end_src
1111
1112 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1113
1114 #+begin_src emacs-lisp
1115 (load-theme 'eink t)
1116 #+end_src
1117
1118 * Email
1119 ** [[https://notmuchmail.org][notmuch]]
1120
1121 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1122
1123 #+begin_src emacs-lisp
1124 (defun ab/notmuch ()
1125   "Delete other windows, then launch `notmuch'."
1126   (interactive)
1127   (require 'notmuch)
1128   (delete-other-windows)
1129   (notmuch))
1130
1131 ;; (ab--leader-keys
1132 ;;   "m"   'ab/notmuch
1133 ;;   "s"   'save-buffer
1134 ;;   "SPC" 'counsel-M-x)
1135
1136 ;; (map!
1137 ;;  :leader
1138 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1139 ;;  (:desc "search" :prefix "/"
1140 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1141 #+end_src
1142
1143 #+begin_src emacs-lisp
1144 (defvar ab-maildir "~/mail")
1145
1146 (use-package sendmail
1147   ;; :ensure nil
1148   :config
1149   (setq sendmail-program "/usr/bin/msmtp"
1150         mail-specify-envelope-from t
1151         mail-envelope-from 'header))
1152
1153 (use-package message
1154   ;; :ensure nil
1155   :config
1156   (setq message-kill-buffer-on-exit t
1157         message-send-mail-function 'message-send-mail-with-sendmail
1158         message-sendmail-envelope-from 'header
1159         message-directory "drafts"
1160         message-user-fqdn "aminb.org")
1161   (add-hook 'message-mode-hook
1162             (lambda () (setq fill-column 65
1163                         message-fill-column 65)))
1164   (add-hook 'message-mode-hook
1165             #'flyspell-mode)
1166   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1167   ;; TODO: is there a way to only run this when replying and not composing?
1168   ;; (add-hook 'notmuch-message-mode-hook
1169   ;;           (lambda () (progn
1170   ;;                   (newline)
1171   ;;                   (newline)
1172   ;;                   (forward-line -1)
1173   ;;                   (forward-line -1))))
1174   ;; (add-hook 'message-setup-hook
1175   ;;           #'mml-secure-message-sign-pgpmime)
1176   )
1177
1178 (after! mml-sec
1179   (setq mml-secure-openpgp-encrypt-to-self t
1180         mml-secure-openpgp-sign-with-sender t))
1181
1182 (use-package notmuch
1183   :general (ab--leader-keys "m" 'ab/notmuch)
1184   :config
1185   (setq notmuch-hello-sections
1186         '(notmuch-hello-insert-header
1187           notmuch-hello-insert-saved-searches
1188           ;; notmuch-hello-insert-search
1189           notmuch-hello-insert-alltags)
1190         notmuch-search-oldest-first nil
1191         notmuch-show-all-tags-list t
1192         notmuch-message-headers  ; see bug follow-up above
1193         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1194         notmuch-hello-thousands-separator ","
1195         notmuch-fcc-dirs
1196         '(("amin@aminb.org"            . "amin/Sent")
1197           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1198           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1199           ("aminb@gnu.org"             . "gnu/Sent")
1200           (".*"                        . "sent"))
1201         notmuch-search-result-format
1202         '(("date" . "%12s ")
1203           ("count" . "%-7s ")
1204           ("authors" . "%-40s ")
1205           ("subject" . "%s ")
1206           ("tags" . "(%s)")))
1207   ;; (add-hook 'visual-fill-column-mode-hook
1208   ;;           (lambda ()
1209   ;;             (when (string= major-mode 'notmuch-message-mode)
1210   ;;               (setq visual-fill-column-width 70))))
1211   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1212   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1213   ;;             :override #'kill-this-buffer)
1214   :bind
1215   (:map notmuch-hello-mode-map
1216         ("g" . notmuch-poll-and-refresh-this-buffer)
1217         ("i" . (lambda ()
1218                  "Search for `inbox' tagged messages"
1219                  (interactive)
1220                  (notmuch-hello-search "tag:inbox")))
1221         ("u" . (lambda ()
1222                  "Search for `unread' tagged messages"
1223                  (interactive)
1224                  (notmuch-hello-search "tag:unread")))
1225         ("l" . (lambda ()
1226                  "Search for `latest tagged messages"
1227                  (interactive)
1228                  (notmuch-hello-search "tag:latest")))
1229         ("M" . (lambda ()
1230                  "Compose new mail and prompt for sender"
1231                  (interactive)
1232                  (let ((current-prefix-arg t))
1233                    (call-interactively #'notmuch-mua-new-mail)))))
1234   (:map notmuch-search-mode-map
1235         ("g" . notmuch-poll-and-refresh-this-buffer)
1236         ("k" . (lambda ()
1237                  "Mark message read"
1238                  (interactive)
1239                  (notmuch-search-tag '("-unread"))
1240                  ;; (notmuch-search-archive-thread)
1241                  (notmuch-search-next-thread)))
1242         ("u" . (lambda ()
1243                  "Mark message unread"
1244                  (interactive)
1245                  (notmuch-search-tag '("+unread"))
1246                  (notmuch-search-next-thread)))
1247         ("K" . (lambda ()
1248                  "Mark message deleted"
1249                  (interactive)
1250                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1251                  (notmuch-search-archive-thread)))
1252         ("S" . (lambda ()
1253                  "Mark message as spam"
1254                  (interactive)
1255                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1256                  (notmuch-search-archive-thread))))
1257   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1258         ("S" . (lambda ()
1259                  "Mark message as spam"
1260                  (interactive)
1261                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1262                  (notmuch-tree-archive-thread))))
1263 )
1264
1265 ;; (use-package counsel-notmuch
1266 ;;   :commands counsel-notmuch)
1267
1268 (after! notmuch-crypto
1269   (setq notmuch-crypto-process-mime t))
1270
1271 ;; (after! evil
1272 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1273 ;;         '((notmuch-hello-mode . emacs)
1274 ;;           (notmuch-search-mode . emacs)
1275 ;;           (notmuch-tree-mode . emacs))))
1276
1277 (after! recentf
1278   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1279 #+end_src
1280
1281 ** supercite
1282
1283 #+begin_src emacs-lisp :tangle no
1284 (use-package supercite
1285   :commands sc-cite-original
1286   :init
1287   (add-hook 'mail-citation-hook 'sc-cite-original)
1288
1289   (defun sc-remove-existing-signature ()
1290     (save-excursion
1291       (goto-char (region-beginning))
1292       (when (re-search-forward message-signature-separator (region-end) t)
1293         (delete-region (match-beginning 0) (region-end)))))
1294
1295   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1296
1297   (defun sc-remove-if-not-mailing-list ()
1298     (unless (assoc "list-id" sc-mail-info)
1299       (setq attribution sc-default-attribution
1300             citation (concat sc-citation-delimiter
1301                              sc-citation-separator))))
1302
1303   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1304
1305   :config
1306   (defun sc-fill-if-different (&optional prefix)
1307     "Fill the region bounded by `sc-fill-begin' and point.
1308 Only fill if optional PREFIX is different than
1309 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1310 fill region.  If PREFIX is not supplied, initialize fill
1311 variables.  This is useful for a regi `begin' frame-entry."
1312     (if (not prefix)
1313         (setq sc-fill-line-prefix ""
1314               sc-fill-begin (line-beginning-position))
1315       (if (and sc-auto-fill-region-p
1316                (not (string= prefix sc-fill-line-prefix)))
1317           (let ((fill-prefix sc-fill-line-prefix))
1318             (unless (or (string= fill-prefix "")
1319                         (save-excursion
1320                           (goto-char sc-fill-begin)
1321                           (or (looking-at ">+  +")
1322                               (< (length
1323                                   (buffer-substring (point)
1324                                                     (line-end-position)))
1325                                  65))))
1326               (fill-region sc-fill-begin (line-beginning-position)))
1327             (setq sc-fill-line-prefix prefix
1328                   sc-fill-begin (line-beginning-position)))))
1329 nil))
1330 #+end_src
1331
1332 * Blogging
1333 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1334
1335 #+begin_src emacs-lisp
1336 (use-package ox-hugo
1337   :after ox)
1338 #+end_src
1339
1340 * Post initialization
1341 :PROPERTIES:
1342 :CUSTOM_ID: post-initialization
1343 :END:
1344
1345 Display how long it took to load the init file.
1346
1347 #+begin_src emacs-lisp
1348 (message "Loading %s...done (%.3fs)" user-init-file
1349          (float-time (time-subtract (current-time)
1350                                     ab--before-user-init-time)))
1351 #+end_src
1352
1353 * Footer
1354 :PROPERTIES:
1355 :CUSTOM_ID: footer
1356 :END:
1357
1358 #+begin_src emacs-lisp :comments none
1359 ;;; init.el ends here
1360 #+end_src