git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 *** Auto revert
 569
 570 Enable automatic reloading of changed buffers and files.
 571
 572 #+begin_src emacs-lisp
 573 (global-auto-revert-mode 1)
 574 (setq auto-revert-verbose nil
 575       global-auto-revert-non-file-buffers t)
 576 #+end_src
 577
 578 *** Always use space for indentation
 579
 580 #+begin_src emacs-lisp
 581 (setq-default
 582  indent-tabs-mode nil
 583  require-final-newline t
 584  tab-width 4)
 585 #+end_src
 586
 587 ** Packages
 588
 589 The packages in this section are absolutely essential to my everyday
 590 workflow, and they play key roles in how I do my computing. They
 591 immensely enhance the Emacs experience for me; both using Emacs, and
 592 customizing it.
 593
 594 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 595
 596 #+begin_src emacs-lisp
 597 (use-package auto-compile
 598   :demand t
 599   :config
 600   (auto-compile-on-load-mode)
 601   (auto-compile-on-save-mode)
 602   (setq auto-compile-display-buffer               nil
 603         auto-compile-mode-line-counter            t
 604         auto-compile-source-recreate-deletes-dest t
 605         auto-compile-toggle-deletes-nonlib-dest   t
 606         auto-compile-update-autoloads             t)
 607   (add-hook 'auto-compile-inhibit-compile-hook
 608             'auto-compile-inhibit-compile-detached-git-head))
 609 #+end_src
 610
 611 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 612
 613 #+begin_quote
 614 Roll your own modal mode
 615 #+end_quote
 616
 617 #+begin_src emacs-lisp
 618 (use-package ryo-modal
 619   :commands ryo-modal-mode
 620   :bind ("M-m" . ryo-modal-mode)
 621   :after which-key
 622   :config
 623   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 624   (ryo-modal-keys
 625    ("," ryo-modal-repeat)
 626    ("b" backward-char)
 627    ("n" next-line)
 628    ("p" previous-line)
 629    ("f" forward-char)
 630    ("SPC" (("b" (("b" ibuffer-list-buffers)
 631                  ("k" kill-this-buffer)
 632                  ("o" other-window)
 633                  ("s" save-buffer)))
 634            ("h" (("c" describe-char)
 635                  ("f" describe-function)
 636                  ("F" describe-face)
 637                  ("i" info)
 638                  ("k" describe-key)
 639                  ("l" view-lossage)
 640                  ("v" describe-variable)))
 641            ("q" (("q" save-buffers-kill-terminal)))))
 642    ("d" (("w" kill-word)
 643          ("b" backward-kill-word)))
 644    ("c w" kill-word :exit t))
 645
 646   (ryo-modal-keys
 647    ;; First argyment to ryo-modal-keys may be a list of keywords.
 648    ;; These keywords will be applied to all keybindings.
 649    (:norepeat t)
 650    ("0" "M-0")
 651    ("1" "M-1")
 652    ("2" "M-2")
 653    ("3" "M-3")
 654    ("4" "M-4")
 655    ("5" "M-5")
 656    ("6" "M-6")
 657    ("7" "M-7")
 658    ("8" "M-8")
 659    ("9" "M-9"))
 660   :hook ((text-mode . ryo-modal-mode)
 661          (prog-mode . ryo-modal-mode)))
 662 #+end_src
 663
 664 *** [[https://orgmode.org/][Org mode]]
 665
 666 #+begin_quote
 667 Org mode is for keeping notes, maintaining TODO lists, planning
 668 projects, and authoring documents with a fast and effective plain-text
 669 system.
 670 #+end_quote
 671
 672 In short, my favourite way of life.
 673
 674 #+begin_src emacs-lisp
 675 (use-package org
 676   :ryo ("SPC b t" org-babel-tangle)
 677   :config
 678   (setq org-src-tab-acts-natively t
 679         org-src-preserve-indentation nil
 680         org-edit-src-content-indentation 0
 681         org-html-divs '((preamble  "header" "preamble")
 682                         (content   "main"   "content")
 683                         (postamble "footer" "postamble"))
 684         org-html-doctype "html5"
 685         org-html-html5-fancy t
 686         org-html-postamble nil)
 687   :hook (org-mode . org-indent-mode))
 688 (use-package htmlize
 689   :after org)
 690 (use-package org-notmuch
 691   :after (:any org notmuch))
 692 #+end_src
 693
 694 *** [[https://magit.vc/][Magit]]
 695
 696 #+begin_quote
 697 It's Magit! A Git porcelain inside Emacs.
 698 #+end_quote
 699
 700 Not just how I do git, but /the/ way to do git.
 701
 702 #+begin_src emacs-lisp
 703 (use-package magit
 704   :ryo ("SPC" (("g s" magit-status)))
 705   :defer t
 706   :bind (("s-g"     . magit-status)
 707          ("C-x g"   . magit-status)
 708          ("C-x M-g" . magit-dispatch-popup))
 709   :config
 710   (magit-add-section-hook 'magit-status-sections-hook
 711                           'magit-insert-modules
 712                           'magit-insert-stashes
 713                           'append))
 714 #+end_src
 715
 716 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 717
 718 #+begin_quote
 719 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 720 an overview, and more. Oh, man!
 721 #+end_quote
 722
 723 There's no way I could top that, so I won't attempt to.
 724
 725 **** Ivy
 726
 727 #+begin_src emacs-lisp
 728 (use-package ivy
 729   :defer 1
 730   :bind
 731   (:map ivy-minibuffer-map
 732         ([escape] . keyboard-escape-quit)
 733         ;; ("C-j"    . ivy-next-line)
 734         ;; ("C-k"    . ivy-previous-line)
 735         ([S-up]   . ivy-previous-history-element)
 736         ([S-down] . ivy-next-history-element)
 737         ("DEL"    . ivy-backward-delete-char))
 738   :ryo ("SPC ," ivy-switch-buffer)
 739   :config
 740   (setq ivy-wrap t)
 741   (ivy-mode 1))
 742 #+end_src
 743
 744 **** Swiper
 745
 746 #+begin_src emacs-lisp
 747 (use-package swiper
 748   :ryo
 749   ("SPC /" swiper)
 750   ("s" swiper)
 751   :bind (([remap isearch-forward]  . swiper)
 752          ([remap isearch-backward] . swiper)))
 753 #+end_src
 754
 755 **** Counsel
 756
 757 #+begin_src emacs-lisp
 758 (use-package counsel
 759   :defer 1
 760   :ryo
 761   ("SPC" (("f r" counsel-recentf)
 762           ("SPC" counsel-M-x)
 763           ("."   counsel-find-file)))
 764   :bind (([remap execute-extended-command] . counsel-M-x)
 765          ([remap find-file] . counsel-find-file)
 766          ("s-r"     . counsel-recentf)
 767          :map minibuffer-local-map
 768          ("C-r" . counsel-minibuffer-history))
 769   :config
 770   (counsel-mode 1)
 771   (defalias 'locate #'counsel-locate))
 772 #+end_src
 773
 774 * Borg's =layer/essentials=
 775
 776 TODO: break this giant source block down into individual org sections.
 777
 778 #+begin_src emacs-lisp
 779 (use-package dash
 780   :config (dash-enable-font-lock))
 781
 782 (use-package diff-hl
 783   :config
 784   (setq diff-hl-draw-borders nil)
 785   (global-diff-hl-mode)
 786   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 787
 788 (use-package dired
 789   :defer t
 790   :config (setq dired-listing-switches "-alh"))
 791
 792 (use-package eldoc
 793   :when (version< "25" emacs-version)
 794   :config (global-eldoc-mode))
 795
 796 (use-package help
 797   :defer t
 798   :config (temp-buffer-resize-mode))
 799
 800 (progn ;    `isearch'
 801   (setq isearch-allow-scroll t))
 802
 803 (use-package lisp-mode
 804   :config
 805   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 806   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 807   (defun indent-spaces-mode ()
 808     (setq indent-tabs-mode nil))
 809   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 810
 811 (use-package man
 812   :defer t
 813   :config (setq Man-width 80))
 814
 815 (use-package paren
 816   :config (show-paren-mode))
 817
 818 (use-package prog-mode
 819   :config (global-prettify-symbols-mode)
 820   (defun indicate-buffer-boundaries-left ()
 821     (setq indicate-buffer-boundaries 'left))
 822   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 823
 824 (use-package recentf
 825   :demand t
 826   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 827
 828 (use-package savehist
 829   :config (savehist-mode))
 830
 831 (use-package saveplace
 832   :when (version< "25" emacs-version)
 833   :config (save-place-mode))
 834
 835 (use-package simple
 836   :config (column-number-mode))
 837
 838 (progn ;    `text-mode'
 839   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 840
 841 (use-package tramp
 842   :defer t
 843   :config
 844   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 845   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 846   (add-to-list 'tramp-default-proxies-alist
 847                (list (regexp-quote (system-name)) nil nil)))
 848
 849 (use-package undo-tree
 850   :ryo
 851   ("/" undo-tree-undo)
 852   ("_" undo-tree-redo)
 853   :bind (("C-/" . undo-tree-undo)
 854          ("M-_" . undo-tree-redo))
 855   :config
 856   (global-undo-tree-mode)
 857   (setq undo-tree-mode-lighter ""))
 858 #+end_src
 859
 860 * Editing
 861
 862 ** Company
 863
 864 #+begin_src emacs-lisp
 865 (use-package company
 866   :defer 5
 867   :bind
 868   (:map company-active-map
 869         ([tab] . company-complete-common-or-cycle))
 870   :custom
 871   (company-idle-delay 0.3)
 872   (company-minimum-prefix-length 1)
 873   (company-selection-wrap-around t)
 874   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 875   :config
 876   (global-company-mode t))
 877 #+end_src
 878
 879 * Syntax and spell checking
 880 #+begin_src emacs-lisp
 881 (use-package flycheck
 882   :hook (prog-mode . flycheck-mode)
 883   :config
 884   ;; Use the load-path from running Emacs when checking elisp files
 885   (setq flycheck-emacs-lisp-load-path 'inherit)
 886
 887   ;; Only flycheck when I actually save the buffer
 888   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 889 #+end_src
 890 * Programming modes
 891
 892 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 893
 894 #+begin_src emacs-lisp
 895 (use-package alloy-mode
 896   :config (setq alloy-basic-offset 2))
 897 #+end_src
 898
 899 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 900
 901 #+begin_src emacs-lisp
 902 (use-package proof-site  ; Proof General
 903   :load-path "lib/proof-site/generic/")
 904 #+end_src
 905
 906 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 907
 908 #+begin_src emacs-lisp
 909 (use-package lean-mode
 910   :bind (:map lean-mode-map
 911               ("S-SPC" . company-complete)))
 912 #+end_src
 913
 914 ** Haskell
 915
 916 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 917
 918 #+begin_src emacs-lisp
 919 (use-package haskell-mode
 920   :config
 921   (setq haskell-indentation-layout-offset 4
 922         haskell-indentation-left-offset 4
 923         flycheck-checker 'haskell-hlint
 924         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 925 #+end_src
 926
 927 *** [[https://github.com/jyp/dante][dante]]
 928
 929 #+begin_src emacs-lisp
 930 (use-package dante
 931   :after haskell-mode
 932   :commands dante-mode
 933   :hook (haskell-mode . dante-mode))
 934 #+end_src
 935
 936 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 937
 938 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 939 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 940
 941 #+begin_src emacs-lisp
 942 (use-package hlint-refactor
 943   :bind (:map hlint-refactor-mode-map
 944               ("C-c l b" . hlint-refactor-refactor-buffer)
 945               ("C-c l r" . hlint-refactor-refactor-at-point))
 946   :hook (haskell-mode . hlint-refactor-mode))
 947 #+end_src
 948
 949 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 950
 951 #+begin_src emacs-lisp
 952 (use-package flycheck-haskell)
 953 #+end_src
 954
 955 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 956 :PROPERTIES:
 957 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 958 :END:
 959
 960 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 961 instead.
 962
 963 #+begin_src emacs-lisp :tangle no
 964 ;;; hs-lint.el --- minor mode for HLint code checking
 965
 966 ;; Copyright 2009 (C) Alex Ott
 967 ;;
 968 ;; Author: Alex Ott <alexott@gmail.com>
 969 ;; Keywords: haskell, lint, HLint
 970 ;; Requirements:
 971 ;; Status: distributed under terms of GPL2 or above
 972
 973 ;; Typical message from HLint looks like:
 974 ;;
 975 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 976 ;; Found:
 977 ;;   count1 p l = length (filter p l)
 978 ;; Why not:
 979 ;;   count1 p = length . filter p
 980
 981
 982 (require 'compile)
 983
 984 (defgroup hs-lint nil
 985   "Run HLint as inferior of Emacs, parse error messages."
 986   :group 'tools
 987   :group 'haskell)
 988
 989 (defcustom hs-lint-command "hlint"
 990   "The default hs-lint command for \\[hlint]."
 991   :type 'string
 992   :group 'hs-lint)
 993
 994 (defcustom hs-lint-save-files t
 995   "Save modified files when run HLint or no (ask user)"
 996   :type 'boolean
 997   :group 'hs-lint)
 998
 999 (defcustom hs-lint-replace-with-suggestions nil
1000   "Replace user's code with suggested replacements"
1001   :type 'boolean
1002   :group 'hs-lint)
1003
1004 (defcustom hs-lint-replace-without-ask nil
1005   "Replace user's code with suggested replacements automatically"
1006   :type 'boolean
1007   :group 'hs-lint)
1008
1009 (defun hs-lint-process-setup ()
1010   "Setup compilation variables and buffer for `hlint'."
1011   (run-hooks 'hs-lint-setup-hook))
1012
1013 ;; regex for replace suggestions
1014 ;;
1015 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1016 ;; Found:
1017 ;; \s +\(.*\)
1018 ;; Why not:
1019 ;; \s +\(.*\)
1020
1021 (defvar hs-lint-regex
1022   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1023   "Regex for HLint messages")
1024
1025 (defun make-short-string (str maxlen)
1026   (if (< (length str) maxlen)
1027       str
1028     (concat (substring str 0 (- maxlen 3)) "...")))
1029
1030 (defun hs-lint-replace-suggestions ()
1031   "Perform actual replacement of suggestions"
1032   (goto-char (point-min))
1033   (while (re-search-forward hs-lint-regex nil t)
1034     (let* ((fname (match-string 1))
1035           (fline (string-to-number (match-string 2)))
1036           (old-code (match-string 4))
1037           (new-code (match-string 5))
1038           (msg (concat "Replace '" (make-short-string old-code 30)
1039                        "' with '" (make-short-string new-code 30) "'"))
1040           (bline 0)
1041           (eline 0)
1042           (spos 0)
1043           (new-old-code ""))
1044       (save-excursion
1045         (switch-to-buffer (get-file-buffer fname))
1046         (goto-char (point-min))
1047         (forward-line (1- fline))
1048         (beginning-of-line)
1049         (setf bline (point))
1050         (when (or hs-lint-replace-without-ask
1051                   (yes-or-no-p msg))
1052           (end-of-line)
1053           (setf eline (point))
1054           (beginning-of-line)
1055           (setf old-code (regexp-quote old-code))
1056           (while (string-match "\\\\ " old-code spos)
1057             (setf new-old-code (concat new-old-code
1058                                  (substring old-code spos (match-beginning 0))
1059                                  "\\ *"))
1060             (setf spos (match-end 0)))
1061           (setf new-old-code (concat new-old-code (substring old-code spos)))
1062           (remove-text-properties bline eline '(composition nil))
1063           (when (re-search-forward new-old-code eline t)
1064             (replace-match new-code nil t)))))))
1065
1066 (defun hs-lint-finish-hook (buf msg)
1067   "Function, that is executed at the end of HLint execution"
1068   (if hs-lint-replace-with-suggestions
1069       (hs-lint-replace-suggestions)
1070       (next-error 1 t)))
1071
1072 (define-compilation-mode hs-lint-mode "HLint"
1073   "Mode for check Haskell source code."
1074   (set (make-local-variable 'compilation-process-setup-function)
1075        'hs-lint-process-setup)
1076   (set (make-local-variable 'compilation-disable-input) t)
1077   (set (make-local-variable 'compilation-scroll-output) nil)
1078   (set (make-local-variable 'compilation-finish-functions)
1079        (list 'hs-lint-finish-hook))
1080   )
1081
1082 (defun hs-lint ()
1083   "Run HLint for current buffer with haskell source"
1084   (interactive)
1085   (save-some-buffers hs-lint-save-files)
1086   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1087                      'hs-lint-mode))
1088
1089 (provide 'hs-lint)
1090 ;;; hs-lint.el ends here
1091 #+end_src
1092
1093 #+begin_src emacs-lisp :tangle no
1094 (use-package hs-lint
1095   :load-path "lisp/"
1096   :bind (:map haskell-mode-map
1097               ("C-c l l" . hs-lint)))
1098 #+end_src
1099 * Emacs Enhancements
1100
1101 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1102
1103 #+begin_quote
1104 Emacs package that displays available keybindings in popup
1105 #+end_quote
1106
1107 #+begin_src emacs-lisp
1108 (use-package which-key
1109   :defer 1
1110   :config (which-key-mode))
1111 #+end_src
1112
1113 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1114
1115 #+begin_src emacs-lisp
1116 (use-package doom-modeline
1117   :demand t
1118   :config (setq doom-modeline-height 32)
1119   :hook (after-init . doom-modeline-init))
1120 #+end_src
1121
1122 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1123
1124 #+begin_src emacs-lisp :tangle no
1125 (use-package tao-theme
1126   :demand t
1127   :config (load-theme 'tao-yang t))
1128 #+end_src
1129
1130 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1131
1132 #+begin_src emacs-lisp
1133 (load-theme 'eink t)
1134 #+end_src
1135
1136 ** [[https://github.com/bbatsov/crux][crux]]
1137
1138 #+begin_src emacs-lisp
1139 (use-package crux
1140   :bind (("C-c d"    . crux-duplicate-current-line-or-region)
1141          ("C-c M-d"  . crux-duplicate-and-comment-current-line-or-region))
1142   :ryo
1143   ("o" crux-smart-open-line :exit t)
1144   ("O" crux-smart-open-line-above :exit t)
1145   ("SPC b K" crux-kill-other-buffers)
1146   ("d d" crux-kill-whole-line)
1147   ("c c" crux-kill-whole-line :then '(crux-smart-open-line-above) :exit t)
1148   ("SPC f" (("c" crux-copy-file-preserve-attributes)
1149             ("D" crux-delete-file-and-buffer)
1150             ("R" crux-rename-file-and-buffer))))
1151 #+end_src
1152
1153 ** [[https://github.com/alezost/mwim.el][mwim]]
1154
1155 #+begin_src emacs-lisp
1156 (use-package mwim
1157   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1158          ("C-e"    . mwim-end-of-code-or-line)
1159          ("<home>" . mwim-beginning-of-line-or-code)
1160          ("<end>"  . mwim-end-of-line-or-code))
1161   :ryo
1162   ("a" mwim-beginning-of-code-or-line)
1163   ("e" mwim-end-of-code-or-line))
1164 #+end_src
1165
1166 * Email
1167 ** [[https://notmuchmail.org][notmuch]]
1168
1169 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1170
1171 #+begin_src emacs-lisp
1172 (defun ab/notmuch ()
1173   "Delete other windows, then launch `notmuch'."
1174   (interactive)
1175   (require 'notmuch)
1176   (delete-other-windows)
1177   (notmuch))
1178
1179 ;; (map!
1180 ;;  :leader
1181 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1182 ;;  (:desc "search" :prefix "/"
1183 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1184 #+end_src
1185
1186 #+begin_src emacs-lisp
1187 (defvar ab-maildir "~/mail")
1188
1189 (use-package sendmail
1190   ;; :ensure nil
1191   :config
1192   (setq sendmail-program "/usr/bin/msmtp"
1193         mail-specify-envelope-from t
1194         mail-envelope-from 'header))
1195
1196 (use-package message
1197   ;; :ensure nil
1198   :config
1199   (setq message-kill-buffer-on-exit t
1200         message-send-mail-function 'message-send-mail-with-sendmail
1201         message-sendmail-envelope-from 'header
1202         message-directory "drafts"
1203         message-user-fqdn "aminb.org")
1204   (add-hook 'message-mode-hook
1205             (lambda () (setq fill-column 65
1206                         message-fill-column 65)))
1207   (add-hook 'message-mode-hook
1208             #'flyspell-mode)
1209   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1210   ;; TODO: is there a way to only run this when replying and not composing?
1211   ;; (add-hook 'notmuch-message-mode-hook
1212   ;;           (lambda () (progn
1213   ;;                   (newline)
1214   ;;                   (newline)
1215   ;;                   (forward-line -1)
1216   ;;                   (forward-line -1))))
1217   ;; (add-hook 'message-setup-hook
1218   ;;           #'mml-secure-message-sign-pgpmime)
1219   )
1220
1221 (after! mml-sec
1222   (setq mml-secure-openpgp-encrypt-to-self t
1223         mml-secure-openpgp-sign-with-sender t))
1224
1225 (use-package notmuch
1226   :ryo ("SPC m" ab/notmuch)
1227   :config
1228   (setq notmuch-hello-sections
1229         '(notmuch-hello-insert-header
1230           notmuch-hello-insert-saved-searches
1231           ;; notmuch-hello-insert-search
1232           notmuch-hello-insert-alltags)
1233         notmuch-search-oldest-first nil
1234         notmuch-show-all-tags-list t
1235         notmuch-message-headers  ; see bug follow-up above
1236         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1237         notmuch-hello-thousands-separator ","
1238         notmuch-fcc-dirs
1239         '(("amin@aminb.org"            . "amin/Sent")
1240           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1241           ("amin.bandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1242           ("aminb@gnu.org"             . "gnu/Sent")
1243           (".*"                        . "sent"))
1244         notmuch-search-result-format
1245         '(("date" . "%12s ")
1246           ("count" . "%-7s ")
1247           ("authors" . "%-40s ")
1248           ("subject" . "%s ")
1249           ("tags" . "(%s)")))
1250   ;; (add-hook 'visual-fill-column-mode-hook
1251   ;;           (lambda ()
1252   ;;             (when (string= major-mode 'notmuch-message-mode)
1253   ;;               (setq visual-fill-column-width 70))))
1254   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1255   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1256   ;;             :override #'kill-this-buffer)
1257   :bind
1258   (:map notmuch-hello-mode-map
1259         ("g" . notmuch-poll-and-refresh-this-buffer)
1260         ("i" . (lambda ()
1261                  "Search for `inbox' tagged messages"
1262                  (interactive)
1263                  (notmuch-hello-search "tag:inbox")))
1264         ("u" . (lambda ()
1265                  "Search for `unread' tagged messages"
1266                  (interactive)
1267                  (notmuch-hello-search "tag:unread")))
1268         ("l" . (lambda ()
1269                  "Search for `latest tagged messages"
1270                  (interactive)
1271                  (notmuch-hello-search "tag:latest")))
1272         ("M" . (lambda ()
1273                  "Compose new mail and prompt for sender"
1274                  (interactive)
1275                  (let ((current-prefix-arg t))
1276                    (call-interactively #'notmuch-mua-new-mail)))))
1277   (:map notmuch-search-mode-map
1278         ("g" . notmuch-poll-and-refresh-this-buffer)
1279         ("k" . (lambda ()
1280                  "Mark message read"
1281                  (interactive)
1282                  (notmuch-search-tag '("-unread"))
1283                  ;; (notmuch-search-archive-thread)
1284                  (notmuch-search-next-thread)))
1285         ("u" . (lambda ()
1286                  "Mark message unread"
1287                  (interactive)
1288                  (notmuch-search-tag '("+unread"))
1289                  (notmuch-search-next-thread)))
1290         ("K" . (lambda ()
1291                  "Mark message deleted"
1292                  (interactive)
1293                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1294                  (notmuch-search-archive-thread)))
1295         ("S" . (lambda ()
1296                  "Mark message as spam"
1297                  (interactive)
1298                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1299                  (notmuch-search-archive-thread))))
1300   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1301         ("S" . (lambda ()
1302                  "Mark message as spam"
1303                  (interactive)
1304                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1305                  (notmuch-tree-archive-thread))))
1306 )
1307
1308 ;; (use-package counsel-notmuch
1309 ;;   :commands counsel-notmuch)
1310
1311 (after! notmuch-crypto
1312   (setq notmuch-crypto-process-mime t))
1313
1314 ;; (after! evil
1315 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1316 ;;         '((notmuch-hello-mode . emacs)
1317 ;;           (notmuch-search-mode . emacs)
1318 ;;           (notmuch-tree-mode . emacs))))
1319
1320 (after! recentf
1321   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1322 #+end_src
1323
1324 ** supercite
1325
1326 #+begin_src emacs-lisp :tangle no
1327 (use-package supercite
1328   :commands sc-cite-original
1329   :init
1330   (add-hook 'mail-citation-hook 'sc-cite-original)
1331
1332   (defun sc-remove-existing-signature ()
1333     (save-excursion
1334       (goto-char (region-beginning))
1335       (when (re-search-forward message-signature-separator (region-end) t)
1336         (delete-region (match-beginning 0) (region-end)))))
1337
1338   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1339
1340   (defun sc-remove-if-not-mailing-list ()
1341     (unless (assoc "list-id" sc-mail-info)
1342       (setq attribution sc-default-attribution
1343             citation (concat sc-citation-delimiter
1344                              sc-citation-separator))))
1345
1346   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1347
1348   :config
1349   (defun sc-fill-if-different (&optional prefix)
1350     "Fill the region bounded by `sc-fill-begin' and point.
1351 Only fill if optional PREFIX is different than
1352 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1353 fill region.  If PREFIX is not supplied, initialize fill
1354 variables.  This is useful for a regi `begin' frame-entry."
1355     (if (not prefix)
1356         (setq sc-fill-line-prefix ""
1357               sc-fill-begin (line-beginning-position))
1358       (if (and sc-auto-fill-region-p
1359                (not (string= prefix sc-fill-line-prefix)))
1360           (let ((fill-prefix sc-fill-line-prefix))
1361             (unless (or (string= fill-prefix "")
1362                         (save-excursion
1363                           (goto-char sc-fill-begin)
1364                           (or (looking-at ">+  +")
1365                               (< (length
1366                                   (buffer-substring (point)
1367                                                     (line-end-position)))
1368                                  65))))
1369               (fill-region sc-fill-begin (line-beginning-position)))
1370             (setq sc-fill-line-prefix prefix
1371                   sc-fill-begin (line-beginning-position)))))
1372 nil))
1373 #+end_src
1374
1375 * Blogging
1376 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1377
1378 #+begin_src emacs-lisp
1379 (use-package ox-hugo
1380   :after ox)
1381 #+end_src
1382
1383 * Post initialization
1384 :PROPERTIES:
1385 :CUSTOM_ID: post-initialization
1386 :END:
1387
1388 Display how long it took to load the init file.
1389
1390 #+begin_src emacs-lisp
1391 (message "Loading %s...done (%.3fs)" user-init-file
1392          (float-time (time-subtract (current-time)
1393                                     ab--before-user-init-time)))
1394 #+end_src
1395
1396 * Footer
1397 :PROPERTIES:
1398 :CUSTOM_ID: footer
1399 :END:
1400
1401 #+begin_src emacs-lisp :comments none
1402 ;;; init.el ends here
1403 #+end_src