git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#borg-essentials][Borg's =layer/essentials=]]
  58 - [[#editing][Editing]]
  59 - [[#syntax-spell-checking][Syntax and spell checking]]
  60 - [[#programming-modes][Programming modes]]
  61 - [[#emacs-enhancements][Emacs enhancements]]
  62 - [[#email][Email]]
  63 - [[#blogging][Blogging]]
  64 - [[#post-initialization][Post initialization]]
  65 - [[#footer][Footer]]
  66
  67 * Header
  68 :PROPERTIES:
  69 :CUSTOM_ID: header
  70 :END:
  71
  72 ** First line
  73
  74 #+begin_src emacs-lisp :comments none
  75 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t; eval: (view-mode 1) -*-
  76 #+end_src
  77
  78 Enable =view-mode=, which both makes the file read-only (as a reminder
  79 that =init.el= is an auto-generated file, not supposed to be edited),
  80 and provides some convenient key bindings for browsing through the
  81 file.
  82
  83 ** License
  84
  85 #+begin_src emacs-lisp :comments none
  86 ;; Copyright (C) 2018  Amin Bandali <bandali@gnu.org>
  87
  88 ;; This program is free software: you can redistribute it and/or modify
  89 ;; it under the terms of the GNU General Public License as published by
  90 ;; the Free Software Foundation, either version 3 of the License, or
  91 ;; (at your option) any later version.
  92
  93 ;; This program is distributed in the hope that it will be useful,
  94 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  95 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  96 ;; GNU General Public License for more details.
  97
  98 ;; You should have received a copy of the GNU General Public License
  99 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
 100 #+end_src
 101
 102 ** Commentary
 103
 104 #+begin_src emacs-lisp :comments none
 105 ;;; Commentary:
 106
 107 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 108 ;; programmer.
 109
 110 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 111 #+end_src
 112
 113 ** Naming conventions
 114
 115 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 116
 117 #+begin_src emacs-lisp :comments none
 118 ;; Naming conventions:
 119 ;;
 120 ;;   amin-...   public variables or non-interactive functions
 121 ;;   amin--...  private anything (non-interactive), not safe for direct use
 122 ;;   amin/...   an interactive function; safe for M-x or keybinding
 123 ;;   amin|...   a hook function
 124 ;;   amin*...   an advising function
 125 ;;   amin@...   a hydra command
 126 ;;   ...!       a macro
 127 #+end_src
 128
 129 * Initial setup
 130 :PROPERTIES:
 131 :CUSTOM_ID: initial-setup
 132 :END:
 133
 134 ** Emacs initialization
 135
 136 I'd like to do a couple of measurements of Emacs' startup time. First,
 137 let's see how long Emacs takes to start up, before even loading
 138 =init.el=, i.e. =user-init-file=:
 139
 140 #+begin_src emacs-lisp
 141 (defvar amin--before-user-init-time (current-time)
 142   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 143 (message "Loading Emacs...done (%.3fs)"
 144          (float-time (time-subtract amin--before-user-init-time
 145                                     before-init-time)))
 146 #+end_src
 147
 148 Also, temporarily increase ~gc-cons-threshhold~ and
 149 ~gc-cons-percentage~ during startup to reduce garbage collection
 150 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 151 startup time as well.
 152
 153 #+begin_src emacs-lisp
 154 (defvar amin--gc-cons-threshold gc-cons-threshold)
 155 (defvar amin--gc-cons-percentage gc-cons-percentage)
 156 (defvar amin--file-name-handler-alist file-name-handler-alist)
 157 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 158       gc-cons-percentage 0.6
 159       file-name-handler-alist nil
 160       ;; sidesteps a bug when profiling with esup
 161       esup-child-profile-require-level 0)
 162 #+end_src
 163
 164 Of course, we'd like to set them back to their defaults once we're
 165 done initializing.
 166
 167 #+begin_src emacs-lisp
 168 (add-hook
 169  'after-init-hook
 170  (lambda ()
 171    (setq gc-cons-threshold amin--gc-cons-threshold
 172          gc-cons-percentage amin--gc-cons-percentage
 173          file-name-handler-alist amin--file-name-handler-alist)))
 174 #+end_src
 175
 176 Increase the number of lines kept in message logs (the =*Messages*=
 177 buffer).
 178
 179 #+begin_src emacs-lisp
 180 (setq message-log-max 20000)
 181 #+end_src
 182
 183 Optionally, we could suppress some byte compiler warnings like below,
 184 but for now I've decided to keep them enabled. See documentation for
 185 ~byte-compile-warnings~ for more details.
 186
 187 #+begin_src emacs-lisp
 188 ;; (setq byte-compile-warnings
 189 ;;       '(not free-vars unresolved noruntime lexical make-local))
 190 #+end_src
 191
 192 ** whoami
 193
 194 #+begin_src emacs-lisp
 195 (setq user-full-name "Amin Bandali"
 196       user-mail-address "amin@aminb.org")
 197 #+end_src
 198
 199 ** Package management
 200
 201 *** No =package.el=
 202
 203 I can do all my package management things with Borg, and don't need
 204 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 205 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 206
 207 #+begin_src emacs-lisp :tangle early-init.el
 208 (setq package-enable-at-startup nil)
 209 #+end_src
 210
 211 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 212 right now), and even when released it'll be long before most distros
 213 ship in their repos, I'll still put the old workaround with the
 214 commented call to ~package-initialize~ here anyway.
 215
 216 #+begin_src emacs-lisp
 217 (setq package-enable-at-startup nil)
 218 ;; (package-initialize)
 219 #+end_src
 220
 221 *** Borg
 222
 223 #+begin_quote
 224 Assimilate Emacs packages as Git submodules
 225 #+end_quote
 226
 227 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 228 short, it creates a git submodule in =lib/= for each package, which
 229 can then be managed with the help of Magit or other tools.
 230
 231 #+begin_src emacs-lisp
 232 (setq user-init-file (or load-file-name buffer-file-name)
 233       user-emacs-directory (file-name-directory user-init-file))
 234 (add-to-list 'load-path
 235              (expand-file-name "lib/borg" user-emacs-directory))
 236 (require 'borg)
 237 (borg-initialize)
 238
 239 ;; (require 'borg-nix-shell)
 240 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 241
 242 (with-eval-after-load 'bind-key
 243   (bind-keys
 244    :package borg
 245    ("C-c b A" . borg-activate)
 246    ("C-c b a" . borg-assimilate)
 247    ("C-c b b" . borg-build)
 248    ("C-c b c" . borg-clone)
 249    ("C-c b r" . borg-remove)))
 250 #+end_src
 251
 252 *** =use-package=
 253
 254 #+begin_quote
 255 A use-package declaration for simplifying your .emacs
 256 #+end_quote
 257
 258 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 259 packages (in our case especially the latter) in a neatly organized way
 260 and without compromising on performance.
 261
 262 #+begin_src emacs-lisp
 263 (require 'use-package)
 264 (if nil  ; set to t when need to debug init
 265     (setq use-package-verbose t
 266           use-package-expand-minimally nil
 267           use-package-compute-statistics t
 268           debug-on-error t)
 269   (setq use-package-verbose nil
 270         use-package-expand-minimally t))
 271 #+end_src
 272
 273 *** Epkg
 274
 275 #+begin_quote
 276 Browse the Emacsmirror package database
 277 #+end_quote
 278
 279 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 280 database, low-level functions for querying the database, and a
 281 =package.el=-like user interface for browsing the available packages.
 282
 283 #+begin_src emacs-lisp
 284 (use-package epkg
 285   :defer t
 286   :bind
 287   (("C-c b d" . epkg-describe-package)
 288    ("C-c b p" . epkg-list-packages)
 289    ("C-c b u" . epkg-update)))
 290 #+end_src
 291
 292 ** No littering in =~/.emacs.d=
 293
 294 #+begin_quote
 295 Help keeping ~/.emacs.d clean
 296 #+end_quote
 297
 298 By default, even for Emacs' built-in packages, the configuration files
 299 and persistent data are all over the place. Use =no-littering= to help
 300 contain the mess.
 301
 302 #+begin_src emacs-lisp
 303 (use-package no-littering
 304   :demand t
 305   :config
 306   (savehist-mode 1)
 307   (add-to-list 'savehist-additional-variables 'kill-ring)
 308   (save-place-mode 1)
 309   (setq auto-save-file-name-transforms
 310         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 311 #+end_src
 312
 313 ** Custom file (=custom.el=)
 314
 315 I'm not planning on using the custom file much, but even so, I
 316 definitely don't want it mixing with =init.el=. So, here; let's give
 317 it it's own file. While at it, treat themes as safe.
 318
 319 #+begin_src emacs-lisp
 320 (use-package custom
 321   :no-require t
 322   :config
 323   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 324   (when (file-exists-p custom-file)
 325     (load custom-file))
 326   (setf custom-safe-themes t))
 327 #+end_src
 328
 329 ** Secrets file
 330
 331 Load the secrets file if it exists, otherwise show a warning.
 332
 333 #+begin_src emacs-lisp
 334 (with-demoted-errors
 335     (load (no-littering-expand-etc-file-name "secrets")))
 336 #+end_src
 337
 338 ** Better =$PATH= handling
 339
 340 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 341 in my shell.
 342
 343 #+begin_src emacs-lisp
 344 (use-package exec-path-from-shell
 345   :defer 1
 346   :init
 347   (setq exec-path-from-shell-check-startup-files nil)
 348   :config
 349   (exec-path-from-shell-initialize)
 350   ;; while we're at it, let's fix access to our running ssh-agent
 351   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 352   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 353 #+end_src
 354
 355 ** COMMENT Only one custom theme at a time
 356
 357 #+begin_src emacs-lisp
 358 (defadvice load-theme (before clear-previous-themes activate)
 359   "Clear existing theme settings instead of layering them"
 360   (mapc #'disable-theme custom-enabled-themes))
 361 #+end_src
 362
 363 ** Server
 364
 365 Start server if not already running. Alternatively, can be done by
 366 issuing =emacs --daemon= in the terminal, which can be automated with
 367 a systemd service or using =brew services start emacs= on macOS. I use
 368 Emacs as my window manager (via EXWM), so I always start Emacs on
 369 login; so starting the server from inside Emacs is good enough for me.
 370
 371 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 372
 373 #+begin_src emacs-lisp
 374 (use-package server
 375   :defer 1
 376   :config (or (server-running-p) (server-mode)))
 377 #+end_src
 378
 379 ** COMMENT Unicode support
 380
 381 Font stack with better unicode support, around =Ubuntu Mono= and
 382 =Hack=.
 383
 384 #+begin_src emacs-lisp
 385 (dolist (ft (fontset-list))
 386   (set-fontset-font
 387    ft
 388    'unicode
 389    (font-spec :name "Source Code Pro" :size 14))
 390   (set-fontset-font
 391    ft
 392    'unicode
 393    (font-spec :name "DejaVu Sans Mono")
 394    nil
 395    'append)
 396   ;; (set-fontset-font
 397   ;;  ft
 398   ;;  'unicode
 399   ;;  (font-spec
 400   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 401   ;;  nil
 402   ;;  'append)
 403   ;; (set-fontset-font
 404   ;;  ft
 405   ;;  #x2115  ; ℕ
 406   ;;  (font-spec :name "DejaVu Sans Mono")
 407   ;;  nil
 408   ;;  'append)
 409   (set-fontset-font
 410    ft
 411    (cons ?Α ?ω)
 412    (font-spec :name "DejaVu Sans Mono" :size 14)
 413    nil
 414    'prepend))
 415 #+end_src
 416
 417 ** Gentler font resizing
 418
 419 #+begin_src emacs-lisp
 420 (setq text-scale-mode-step 1.05)
 421 #+end_src
 422
 423 ** Focus follows mouse
 424
 425 I’d like focus to follow the mouse when I move the cursor from one
 426 window to the next.
 427
 428 #+begin_src emacs-lisp
 429 (setq mouse-autoselect-window t)
 430 #+end_src
 431
 432 Let’s define a function to conveniently disable this for certain
 433 buffers and/or modes.
 434
 435 #+begin_src emacs-lisp
 436 (defun amin--no-mouse-autoselect-window ()
 437   (make-local-variable 'mouse-autoselect-window)
 438   (setq mouse-autoselect-window nil))
 439 #+end_src
 440
 441 ** Libraries
 442
 443 #+begin_src emacs-lisp
 444 (require 'cl-lib)
 445 (require 'subr-x)
 446 #+end_src
 447
 448 ** Useful utilities
 449
 450 #+begin_src emacs-lisp
 451 (defun amin-enlist (exp)
 452   "Return EXP wrapped in a list, or as-is if already a list."
 453 (if (listp exp) exp (list exp)))
 454
 455 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 456 (defmacro after! (features &rest body)
 457   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 458 compilation."
 459   (declare (indent defun) (debug t))
 460   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 461                 (dolist (next (amin-enlist features))
 462                   (if (symbolp next)
 463                       (require next nil :no-error)
 464                     (load next :no-message :no-error))))
 465             #'progn
 466           #'with-no-warnings)
 467         (cond ((symbolp features)
 468                `(eval-after-load ',features '(progn ,@body)))
 469               ((and (consp features)
 470                     (memq (car features) '(:or :any)))
 471                `(progn
 472                   ,@(cl-loop for next in (cdr features)
 473                              collect `(after! ,next ,@body))))
 474               ((and (consp features)
 475                     (memq (car features) '(:and :all)))
 476                (dolist (next (cdr features))
 477                  (setq body `(after! ,next ,@body)))
 478                body)
 479               ((listp features)
 480                `(after! (:all ,@features) ,@body)))))
 481 #+end_src
 482
 483 Convenience macro for =setq='ing multiple variables to the same value:
 484
 485 #+begin_src emacs-lisp
 486 (defmacro setq-every! (value &rest vars)
 487   "Set all the variables from VARS to value VALUE."
 488   (declare (indent defun) (debug t))
 489   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 490 #+end_src
 491
 492 * Core
 493 :PROPERTIES:
 494 :CUSTOM_ID: core
 495 :END:
 496
 497 ** Defaults
 498
 499 *** Time and battery in mode-line
 500
 501 Enable displaying time and battery in the mode-line, since I'm not
 502 using the Xfce panel anymore. Also, I don't need to see the load
 503 average on a regular basis, so disable that.
 504
 505 Note: using =i3status= on sway at the moment, so disabling this.
 506
 507 #+begin_src emacs-lisp :tangle no
 508 (use-package time
 509   :init
 510   (setq display-time-default-load-average nil)
 511   :config
 512   (display-time-mode))
 513
 514 (use-package battery
 515   :config
 516   (display-battery-mode))
 517 #+end_src
 518
 519 *** Smaller fringe
 520
 521 Might want to set the fringe to a smaller value, especially if using
 522 EXWM. I'm fine with the default for now.
 523
 524 #+begin_src emacs-lisp
 525 ;; (fringe-mode '(3 . 1))
 526 (fringe-mode nil)
 527 #+end_src
 528
 529 *** Disable disabled commands
 530
 531 Emacs disables some commands by default that could persumably be
 532 confusing for novice users. Let's disable that.
 533
 534 #+begin_src emacs-lisp
 535 (setq disabled-command-function nil)
 536 #+end_src
 537
 538 *** Kill-ring
 539
 540 Save what I copy into clipboard from other applications into Emacs'
 541 kill-ring, which would allow me to still be able to easily access it
 542 in case I kill (cut or copy) something else inside Emacs before
 543 yanking (pasting) what I'd originally intended to.
 544
 545 #+begin_src emacs-lisp
 546 (setq save-interprogram-paste-before-kill t)
 547 #+end_src
 548
 549 *** Minibuffer
 550
 551 #+begin_src emacs-lisp
 552 (setq enable-recursive-minibuffers t
 553       resize-mini-windows t)
 554 #+end_src
 555
 556 *** Lazy-person-friendly yes/no prompts
 557
 558 Lazy people would prefer to type fewer keystrokes, especially for yes
 559 or no questions. I'm lazy.
 560
 561 #+begin_src emacs-lisp
 562 (defalias 'yes-or-no-p #'y-or-n-p)
 563 #+end_src
 564
 565 *** Startup screen and =*scratch*=
 566
 567 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 568 startup buffer.
 569
 570 #+begin_src emacs-lisp
 571 (setq initial-buffer-choice t)
 572 #+end_src
 573
 574 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 575 need the default hint.
 576
 577 #+begin_src emacs-lisp
 578 (setq initial-scratch-message nil)
 579 #+end_src
 580
 581 Also, let's use Text mode as the major mode, in case I want to
 582 customize it (=*scratch*='s default major mode, Fundamental mode,
 583 can't really be customized).
 584
 585 #+begin_src emacs-lisp
 586 (setq initial-major-mode 'text-mode)
 587 #+end_src
 588
 589 Inhibit the buffer list when more than 2 files are loaded.
 590
 591 #+begin_src emacs-lisp
 592 (setq inhibit-startup-buffer-menu t)
 593 #+end_src
 594
 595 I don't really need to see the startup screen or echo area message
 596 either.
 597
 598 #+begin_src emacs-lisp
 599 (advice-add #'display-startup-echo-area-message :override #'ignore)
 600 (setq inhibit-startup-screen t
 601       inhibit-startup-echo-area-message user-login-name)
 602 #+end_src
 603
 604 *** More useful frame titles
 605
 606 Show either the file name or the buffer name (in case the buffer isn't
 607 visiting a file). Borrowed from Emacs Prelude.
 608
 609 #+begin_src emacs-lisp
 610 (setq frame-title-format
 611       '("" invocation-name " - "
 612         (:eval (if (buffer-file-name)
 613                    (abbreviate-file-name (buffer-file-name))
 614                  "%b"))))
 615 #+end_src
 616
 617 *** Backups
 618
 619 Emacs' default backup settings aren't that great. Let's use more
 620 sensible options. See documentation for the ~make-backup-file~
 621 variable.
 622
 623 #+begin_src emacs-lisp
 624 (setq backup-by-copying t
 625       version-control t
 626       delete-old-versions t)
 627 #+end_src
 628
 629 *** Auto revert
 630
 631 Enable automatic reloading of changed buffers and files.
 632
 633 #+begin_src emacs-lisp
 634 (global-auto-revert-mode 1)
 635 (setq auto-revert-verbose nil
 636       global-auto-revert-non-file-buffers nil)
 637 #+end_src
 638
 639 *** Always use space for indentation
 640
 641 #+begin_src emacs-lisp
 642 (setq-default
 643  indent-tabs-mode nil
 644  require-final-newline t
 645  tab-width 4)
 646 #+end_src
 647
 648 *** Winner mode
 649
 650 Enable =winner-mode=.
 651
 652 #+begin_src emacs-lisp
 653 (winner-mode 1)
 654 #+end_src
 655
 656 *** Don’t display =*compilation*= on success
 657
 658 Based on https://stackoverflow.com/a/17788551, with changes to use
 659 =cl-letf= instead of the now obsolete =flet=.
 660
 661 #+begin_src emacs-lisp
 662 (use-package compile
 663   :config
 664   (defun amin--compilation-finish-function (buffer outstr)
 665     (unless (string-match "finished" outstr)
 666       (switch-to-buffer-other-window buffer))
 667     t)
 668
 669   (setq compilation-finish-functions #'amin--compilation-finish-function)
 670
 671   (require 'cl-macs)
 672
 673   (defadvice compilation-start
 674       (around inhibit-display
 675               (command &optional mode name-function highlight-regexp))
 676     (if (not (string-match "^\\(find\\|grep\\)" command))
 677         (cl-letf (((symbol-function 'display-buffer) #'ignore))
 678           (save-window-excursion ad-do-it))
 679       ad-do-it))
 680   (ad-activate 'compilation-start))
 681 #+end_src
 682
 683 *** Search for non-ASCII characters
 684
 685 I’d like non-ASCII characters such as ‘’“”«»‹›áⓐ𝒶 to be selected when
 686 I search for their ASCII counterpart.  Shoutout to [[http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html][endlessparentheses]]
 687 for this.
 688
 689 #+begin_src emacs-lisp
 690 (setq search-default-mode #'char-fold-to-regexp)
 691
 692 ;; uncomment to extend this behaviour to query-replace
 693 ;; (setq replace-char-fold t)
 694 #+end_src
 695
 696 ** Bindings
 697
 698 #+begin_src emacs-lisp
 699 (bind-keys
 700  ("C-c a i" . ielm)
 701
 702  ("C-c e b" . eval-buffer)
 703  ("C-c e r" . eval-region)
 704
 705  ("C-c F m" . make-frame-command)
 706  ("C-c F d" . delete-frame)
 707  ("C-c F D" . delete-other-frames)
 708
 709  ("C-c o"   . other-window)
 710
 711  ("C-c Q"   . save-buffers-kill-terminal)
 712
 713  ("C-S-h C" . describe-char)
 714  ("C-S-h F" . describe-face)
 715
 716  ("C-x K"   . kill-this-buffer)
 717
 718  ("s-p"     . beginning-of-buffer)
 719  ("s-n"     . end-of-buffer))
 720 #+end_src
 721
 722 ** Packages
 723
 724 The packages in this section are absolutely essential to my everyday
 725 workflow, and they play key roles in how I do my computing. They
 726 immensely enhance the Emacs experience for me; both using Emacs, and
 727 customizing it.
 728
 729 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 730
 731 #+begin_src emacs-lisp
 732 (use-package auto-compile
 733   :demand t
 734   :config
 735   (auto-compile-on-load-mode)
 736   (auto-compile-on-save-mode)
 737   (setq auto-compile-display-buffer               nil
 738         auto-compile-mode-line-counter            t
 739         auto-compile-source-recreate-deletes-dest t
 740         auto-compile-toggle-deletes-nonlib-dest   t
 741         auto-compile-update-autoloads             t)
 742   (add-hook 'auto-compile-inhibit-compile-hook
 743             'auto-compile-inhibit-compile-detached-git-head))
 744 #+end_src
 745
 746 *** [[https://orgmode.org/][Org mode]]
 747
 748 #+begin_quote
 749 Org mode is for keeping notes, maintaining TODO lists, planning
 750 projects, and authoring documents with a fast and effective plain-text
 751 system.
 752 #+end_quote
 753
 754 In short, my favourite way of life.
 755
 756 #+begin_src emacs-lisp
 757 (use-package org
 758   :defer 1
 759   :config
 760   (setq org-src-tab-acts-natively t
 761         org-src-preserve-indentation nil
 762         org-edit-src-content-indentation 0
 763         org-email-link-description-format "Email %c: %s" ; %.30s
 764         org-highlight-latex-and-related '(entities)
 765         org-use-speed-commands t
 766         org-startup-folded 'content
 767         org-catch-invisible-edits 'show-and-error
 768         org-log-done 'time)
 769   (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
 770   (font-lock-add-keywords
 771    'org-mode
 772    '(("[ \t]*\\(#\\+\\(BEGIN\\|END\\|begin\\|end\\)_\\(\\S-+\\)\\)[ \t]*\\([^\n:]*\\)"
 773       (1 '(:foreground "#5a5b5a" :background "#292b2b") t) ; directive
 774       (3 '(:foreground "#81a2be" :background "#292b2b") t) ; kind
 775       (4 '(:foreground "#c5c8c6") t))) ; title
 776    t)
 777   :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
 778   :hook ((org-mode . org-indent-mode)
 779          (org-mode . auto-fill-mode)
 780          (org-mode . flyspell-mode))
 781   :custom
 782   (org-latex-packages-alist '(("" "listings") ("" "color")))
 783   :custom-face
 784   '(org-block-begin-line ((t (:foreground "#5a5b5a" :background "#1d1f21"))))
 785   '(org-block ((t (:background "#1d1f21"))))
 786   '(org-latex-and-related ((t (:foreground "#b294bb")))))
 787
 788 (use-package ox-latex
 789   :after ox
 790   :config
 791   (setq org-latex-listings 'listings
 792         ;; org-latex-prefer-user-labels t
 793         )
 794   (add-to-list 'org-latex-packages-alist '("" "listings"))
 795   (add-to-list 'org-latex-packages-alist '("" "color"))
 796   (add-to-list 'org-latex-classes
 797                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 798                  ("\\section{%s}" . "\\section*{%s}")
 799                  ("\\subsection{%s}" . "\\subsection*{%s}")
 800                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 801                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 802                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 803                t))
 804
 805 (use-package ox-beamer
 806   :after ox)
 807
 808 (use-package orgalist
 809   :after message
 810   :hook (message-mode . orgalist-mode))
 811 #+end_src
 812
 813 **** asynchronous tangle
 814
 815 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 816 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 817 file.
 818
 819 #+begin_src emacs-lisp
 820 (after! org
 821   (defvar amin-show-async-tangle-results nil
 822     "Keep *emacs* async buffers around for later inspection.")
 823
 824   (defvar amin-show-async-tangle-time nil
 825     "Show the time spent tangling the file.")
 826
 827   (defvar amin-async-tangle-post-compile "make ti"
 828     "If non-nil, pass to `compile' after successful tangle.")
 829
 830   (defun amin/async-babel-tangle ()
 831     "Tangle org file asynchronously."
 832     (interactive)
 833     (let* ((file-tangle-start-time (current-time))
 834            (file (buffer-file-name))
 835            (file-nodir (file-name-nondirectory file))
 836            ;; (async-quiet-switch "-q")
 837            )
 838       (async-start
 839        `(lambda ()
 840           (require 'org)
 841           (org-babel-tangle-file ,file))
 842        (unless amin-show-async-tangle-results
 843          `(lambda (result)
 844             (if result
 845                 (progn
 846                   (message "Tangled %s%s"
 847                            ,file-nodir
 848                            (if amin-show-async-tangle-time
 849                                (format " (%.3fs)"
 850                                        (float-time (time-subtract (current-time)
 851                                                                   ',file-tangle-start-time)))
 852                              ""))
 853                   (when amin-async-tangle-post-compile
 854                     (compile amin-async-tangle-post-compile)))
 855               (message "Tangling %s failed" ,file-nodir))))))))
 856
 857 (add-to-list
 858  'safe-local-variable-values
 859  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 860 #+end_src
 861
 862 *** [[https://magit.vc/][Magit]]
 863
 864 #+begin_quote
 865 It's Magit! A Git porcelain inside Emacs.
 866 #+end_quote
 867
 868 Not just how I do git, but /the/ way to do git.
 869
 870 #+begin_src emacs-lisp
 871 (use-package magit
 872   :defer 1
 873   :bind (("C-x g" . magit-status)
 874          ("s-g s" . magit-status)
 875          ("s-g l" . magit-log-buffer-file))
 876   :config
 877   (magit-add-section-hook 'magit-status-sections-hook
 878                           'magit-insert-modules
 879                           'magit-insert-stashes
 880                           'append)
 881   (setq
 882    magit-repository-directories '(("~/.emacs.d/" . 0)
 883                                   ("~/src/git/" . 1)))
 884   (nconc magit-section-initial-visibility-alist
 885          '(([unpulled status] . show)
 886            ([unpushed status] . show)))
 887   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 888 #+end_src
 889
 890 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 891
 892 #+begin_quote
 893 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 894 an overview, and more. Oh, man!
 895 #+end_quote
 896
 897 There's no way I could top that, so I won't attempt to.
 898
 899 **** Ivy
 900
 901 #+begin_src emacs-lisp
 902 (use-package ivy
 903   :defer 1
 904   :bind
 905   (:map ivy-minibuffer-map
 906    ([escape] . keyboard-escape-quit)
 907    ([S-up]   . ivy-previous-history-element)
 908    ([S-down] . ivy-next-history-element)
 909    ("DEL"    . ivy-backward-delete-char))
 910   :config
 911   (setq ivy-wrap t)
 912   (ivy-mode 1)
 913   ;; :custom-face
 914   ;; (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 915   ;; (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 916   ;; (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold))))
 917 )
 918 #+end_src
 919
 920 **** Swiper
 921
 922 #+begin_src emacs-lisp
 923 (use-package swiper
 924   :bind (("C-s"   . swiper)
 925          ("C-r"   . swiper)
 926          ("C-S-s" . isearch-forward)))
 927 #+end_src
 928
 929 **** Counsel
 930
 931 #+begin_src emacs-lisp
 932 (use-package counsel
 933   :defer 1
 934   :bind (([remap execute-extended-command] . counsel-M-x)
 935          ([remap find-file]                . counsel-find-file)
 936          ("s-r"                            . counsel-recentf)
 937          ("C-c x"                          . counsel-M-x)
 938          ("C-c f ."                        . counsel-find-file)
 939          :map minibuffer-local-map
 940          ("C-r" . counsel-minibuffer-history))
 941   :config
 942   (counsel-mode 1)
 943   (defalias 'locate #'counsel-locate))
 944 #+end_src
 945
 946 *** eshell
 947
 948 #+begin_src emacs-lisp
 949 (use-package eshell
 950   :defer 1
 951   :commands eshell
 952   :bind ("C-c a s e" . eshell)
 953   :config
 954   (eval-when-compile (defvar eshell-prompt-regexp))
 955   (defun amin/eshell-quit-or-delete-char (arg)
 956     (interactive "p")
 957     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 958         (eshell-life-is-too-much)
 959       (delete-char arg)))
 960
 961   (defun amin/eshell-clear ()
 962     (interactive)
 963     (let ((inhibit-read-only t))
 964       (erase-buffer))
 965     (eshell-send-input))
 966
 967   (defun amin|eshell-setup ()
 968     (make-local-variable 'company-idle-delay)
 969     (defvar company-idle-delay nil)
 970     (bind-keys :map eshell-mode-map
 971                ("C-d"   . amin/eshell-quit-or-delete-char)
 972                ("C-S-l" . amin/eshell-clear)
 973                ("M-r"   . counsel-esh-history)
 974                ([tab]   . company-complete)))
 975
 976   :hook (eshell-mode . amin|eshell-setup)
 977   :custom
 978   (eshell-hist-ignoredups t)
 979   (eshell-input-filter 'eshell-input-filter-initial-space))
 980 #+end_src
 981
 982 *** Ibuffer
 983
 984 #+begin_src emacs-lisp
 985 (use-package ibuffer
 986   :defer t
 987   :bind
 988   (("C-x C-b" . ibuffer-other-window)
 989    :map ibuffer-mode-map
 990    ("P"   . ibuffer-backward-filter-group)
 991    ("N"   . ibuffer-forward-filter-group)
 992    ("M-p" . ibuffer-do-print)
 993    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 994   :config
 995   ;; Use human readable Size column instead of original one
 996   (define-ibuffer-column size-h
 997     (:name "Size" :inline t)
 998     (cond
 999      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
1000      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
1001      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
1002      (t (format "%8d" (buffer-size)))))
1003   :custom
1004   (ibuffer-saved-filter-groups
1005    '(("default"
1006       ("dired" (mode . dired-mode))
1007       ("org"   (mode . org-mode))
1008       ("gnus"
1009        (or
1010         (mode . gnus-group-mode)
1011         (mode . gnus-summary-mode)
1012         (mode . gnus-article-mode)
1013         ;; not really, but...
1014         (mode . message-mode)))
1015       ("web"
1016        (or
1017         (mode . web-mode)
1018         (mode . css-mode)
1019         (mode . scss-mode)
1020         (mode . js2-mode)))
1021       ("shell"
1022        (or
1023         (mode . eshell-mode)
1024         (mode . shell-mode)
1025         (mode . term-mode)))
1026       ("programming"
1027        (or
1028         (mode . python-mode)
1029         (mode . c-mode)
1030         (mode . c++-mode)
1031         (mode . emacs-lisp-mode)
1032         (mode . scheme-mode)
1033         (mode . haskell-mode)
1034         (mode . lean-mode)))
1035       ("emacs"
1036        (or
1037         (name . "^\\*scratch\\*$")
1038         (name . "^\\*Messages\\*$"))))))
1039   (ibuffer-formats
1040    '((mark modified read-only locked " "
1041            (name 18 18 :left :elide)
1042            " "
1043            (size-h 9 -1 :right)
1044            " "
1045            (mode 16 16 :left :elide)
1046            " " filename-and-process)
1047      (mark " "
1048            (name 16 -1)
1049            " " filename)))
1050   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
1051 #+end_src
1052
1053 *** Outline
1054
1055 #+begin_src emacs-lisp
1056 (use-package outline
1057   :defer t
1058   :hook (prog-mode . outline-minor-mode)
1059   :bind
1060   (:map
1061    outline-minor-mode-map
1062    ("<s-tab>"  . outline-toggle-children)
1063    ("M-p"      . outline-previous-visible-heading)
1064    ("M-n"      . outline-next-visible-heading)
1065    :prefix-map amin--outline-prefix-map
1066    :prefix "s-o"
1067    ("TAB" . outline-toggle-children)
1068    ("a"   . outline-hide-body)
1069    ("H"   . outline-hide-body)
1070    ("S"   . outline-show-all)
1071    ("h"   . outline-hide-subtree)
1072    ("s"   . outline-show-subtree)))
1073 #+end_src
1074
1075 * Borg's =layer/essentials=
1076 :PROPERTIES:
1077 :CUSTOM_ID: borg-essentials
1078 :END:
1079
1080 TODO: break this giant source block down into individual org sections.
1081
1082 #+begin_src emacs-lisp
1083 (use-package dash
1084   :config (dash-enable-font-lock))
1085
1086 (use-package diff-hl
1087   :config
1088   (setq diff-hl-draw-borders nil)
1089   (global-diff-hl-mode)
1090   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
1091
1092 (use-package dired
1093   :defer t
1094   :config (setq dired-listing-switches "-alh"))
1095
1096 (use-package eldoc
1097   :when (version< "25" emacs-version)
1098   :config (global-eldoc-mode))
1099
1100 (use-package help
1101   :defer t
1102   :config
1103   (temp-buffer-resize-mode)
1104   (setq help-window-select t))
1105
1106 (progn ;    `isearch'
1107   (setq isearch-allow-scroll t))
1108
1109 (use-package lisp-mode
1110   :config
1111   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1112   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1113   (defun indent-spaces-mode ()
1114     (setq indent-tabs-mode nil))
1115   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1116
1117 (use-package man
1118   :defer t
1119   :config (setq Man-width 80))
1120
1121 (use-package paren
1122   :config (show-paren-mode))
1123
1124 (use-package prog-mode
1125   :config (global-prettify-symbols-mode)
1126   (defun indicate-buffer-boundaries-left ()
1127     (setq indicate-buffer-boundaries 'left))
1128   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1129
1130 (use-package recentf
1131   :defer 0.5
1132   :config
1133   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1134   (setq recentf-max-saved-items 40))
1135
1136 (use-package savehist
1137   :config (savehist-mode))
1138
1139 (use-package saveplace
1140   :when (version< "25" emacs-version)
1141   :config (save-place-mode))
1142
1143 (use-package simple
1144   :config (column-number-mode))
1145
1146 (progn ;    `text-mode'
1147   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left)
1148   (add-hook 'text-mode-hook #'abbrev-mode))
1149
1150 (use-package tramp
1151   :defer t
1152   :config
1153   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1154   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1155   (add-to-list 'tramp-default-proxies-alist
1156                (list (regexp-quote (system-name)) nil nil)))
1157
1158 #+end_src
1159
1160 * Editing
1161 :PROPERTIES:
1162 :CUSTOM_ID: editing
1163 :END:
1164
1165 ** Company
1166
1167 #+begin_src emacs-lisp
1168 (use-package company
1169   :defer 1
1170   :bind
1171   (:map company-active-map
1172         ([tab]    . company-complete-common-or-cycle)
1173         ([escape] . company-abort))
1174   :custom
1175   (company-minimum-prefix-length 1)
1176   (company-selection-wrap-around t)
1177   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1178   (company-dabbrev-downcase nil)
1179   (company-dabbrev-ignore-case nil)
1180   :config
1181   (global-company-mode t))
1182 #+end_src
1183
1184 * Syntax and spell checking
1185 :PROPERTIES:
1186 :CUSTOM_ID: syntax-spell-checking
1187 :END:
1188
1189 #+begin_src emacs-lisp
1190 (use-package flycheck
1191   :defer 3
1192   :hook (prog-mode . flycheck-mode)
1193   :bind
1194   (:map flycheck-mode-map
1195         ("M-P" . flycheck-previous-error)
1196         ("M-N" . flycheck-next-error))
1197   :config
1198   ;; Use the load-path from running Emacs when checking elisp files
1199   (setq flycheck-emacs-lisp-load-path 'inherit)
1200
1201   ;; Only flycheck when I actually save the buffer
1202   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1203
1204 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1205 (use-package ispell
1206   :defer 3
1207   :config
1208   ;; ’ can be part of a word
1209   (setq ispell-local-dictionary-alist
1210         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1211                "['\x2019]" nil ("-B") nil utf-8)))
1212   ;; don't send ’ to the subprocess
1213   (defun endless/replace-apostrophe (args)
1214     (cons (replace-regexp-in-string
1215            "’" "'" (car args))
1216           (cdr args)))
1217   (advice-add #'ispell-send-string :filter-args
1218               #'endless/replace-apostrophe)
1219
1220   ;; convert ' back to ’ from the subprocess
1221   (defun endless/replace-quote (args)
1222     (if (not (derived-mode-p 'org-mode))
1223         args
1224       (cons (replace-regexp-in-string
1225              "'" "’" (car args))
1226             (cdr args))))
1227   (advice-add #'ispell-parse-output :filter-args
1228               #'endless/replace-quote))
1229 #+end_src
1230
1231 * Programming modes
1232 :PROPERTIES:
1233 :CUSTOM_ID: programming-modes
1234 :END:
1235
1236 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1237
1238 #+begin_src emacs-lisp
1239 (use-package alloy-mode
1240   :defer t
1241   :config (setq alloy-basic-offset 2))
1242 #+end_src
1243
1244 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1245
1246 #+begin_src emacs-lisp
1247 (use-package proof-site  ; Proof General
1248   :defer t
1249   :load-path "lib/proof-site/generic/")
1250 #+end_src
1251
1252 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1253
1254 #+begin_src emacs-lisp
1255 (eval-when-compile (defvar lean-mode-map))
1256 (use-package lean-mode
1257   :defer 1
1258   :bind (:map lean-mode-map
1259               ("S-SPC" . company-complete))
1260   :config
1261   (require 'lean-input)
1262   (setq default-input-method "Lean"
1263         lean-input-tweak-all '(lean-input-compose
1264                                (lean-input-prepend "/")
1265                                (lean-input-nonempty))
1266         lean-input-user-translations '(("/" "/")))
1267   (lean-input-setup))
1268   #+end_src
1269
1270 ** Haskell
1271
1272 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1273
1274 #+begin_src emacs-lisp
1275 (use-package haskell-mode
1276   :defer t
1277   :config
1278   (setq haskell-indentation-layout-offset 4
1279         haskell-indentation-left-offset 4
1280         flycheck-checker 'haskell-hlint
1281         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1282 #+end_src
1283
1284 *** [[https://github.com/jyp/dante][dante]]
1285
1286 #+begin_src emacs-lisp
1287 (use-package dante
1288   :after haskell-mode
1289   :commands dante-mode
1290   :hook (haskell-mode . dante-mode))
1291 #+end_src
1292
1293 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1294
1295 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1296 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1297
1298 #+begin_src emacs-lisp
1299 (use-package hlint-refactor
1300   :after haskell-mode
1301   :bind (:map hlint-refactor-mode-map
1302               ("C-c l b" . hlint-refactor-refactor-buffer)
1303               ("C-c l r" . hlint-refactor-refactor-at-point))
1304   :hook (haskell-mode . hlint-refactor-mode))
1305 #+end_src
1306
1307 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1308
1309 #+begin_src emacs-lisp
1310 (use-package flycheck-haskell
1311   :after haskell-mode)
1312 #+end_src
1313
1314 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1315 :PROPERTIES:
1316 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1317 :END:
1318
1319 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1320 instead.
1321
1322 #+begin_src emacs-lisp :tangle no
1323 ;;; hs-lint.el --- minor mode for HLint code checking
1324
1325 ;; Copyright 2009 (C) Alex Ott
1326 ;;
1327 ;; Author: Alex Ott <alexott@gmail.com>
1328 ;; Keywords: haskell, lint, HLint
1329 ;; Requirements:
1330 ;; Status: distributed under terms of GPL2 or above
1331
1332 ;; Typical message from HLint looks like:
1333 ;;
1334 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1335 ;; Found:
1336 ;;   count1 p l = length (filter p l)
1337 ;; Why not:
1338 ;;   count1 p = length . filter p
1339
1340
1341 (require 'compile)
1342
1343 (defgroup hs-lint nil
1344   "Run HLint as inferior of Emacs, parse error messages."
1345   :group 'tools
1346   :group 'haskell)
1347
1348 (defcustom hs-lint-command "hlint"
1349   "The default hs-lint command for \\[hlint]."
1350   :type 'string
1351   :group 'hs-lint)
1352
1353 (defcustom hs-lint-save-files t
1354   "Save modified files when run HLint or no (ask user)"
1355   :type 'boolean
1356   :group 'hs-lint)
1357
1358 (defcustom hs-lint-replace-with-suggestions nil
1359   "Replace user's code with suggested replacements"
1360   :type 'boolean
1361   :group 'hs-lint)
1362
1363 (defcustom hs-lint-replace-without-ask nil
1364   "Replace user's code with suggested replacements automatically"
1365   :type 'boolean
1366   :group 'hs-lint)
1367
1368 (defun hs-lint-process-setup ()
1369   "Setup compilation variables and buffer for `hlint'."
1370   (run-hooks 'hs-lint-setup-hook))
1371
1372 ;; regex for replace suggestions
1373 ;;
1374 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1375 ;; Found:
1376 ;; \s +\(.*\)
1377 ;; Why not:
1378 ;; \s +\(.*\)
1379
1380 (defvar hs-lint-regex
1381   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1382   "Regex for HLint messages")
1383
1384 (defun make-short-string (str maxlen)
1385   (if (< (length str) maxlen)
1386       str
1387     (concat (substring str 0 (- maxlen 3)) "...")))
1388
1389 (defun hs-lint-replace-suggestions ()
1390   "Perform actual replacement of suggestions"
1391   (goto-char (point-min))
1392   (while (re-search-forward hs-lint-regex nil t)
1393     (let* ((fname (match-string 1))
1394           (fline (string-to-number (match-string 2)))
1395           (old-code (match-string 4))
1396           (new-code (match-string 5))
1397           (msg (concat "Replace '" (make-short-string old-code 30)
1398                        "' with '" (make-short-string new-code 30) "'"))
1399           (bline 0)
1400           (eline 0)
1401           (spos 0)
1402           (new-old-code ""))
1403       (save-excursion
1404         (switch-to-buffer (get-file-buffer fname))
1405         (goto-char (point-min))
1406         (forward-line (1- fline))
1407         (beginning-of-line)
1408         (setf bline (point))
1409         (when (or hs-lint-replace-without-ask
1410                   (yes-or-no-p msg))
1411           (end-of-line)
1412           (setf eline (point))
1413           (beginning-of-line)
1414           (setf old-code (regexp-quote old-code))
1415           (while (string-match "\\\\ " old-code spos)
1416             (setf new-old-code (concat new-old-code
1417                                  (substring old-code spos (match-beginning 0))
1418                                  "\\ *"))
1419             (setf spos (match-end 0)))
1420           (setf new-old-code (concat new-old-code (substring old-code spos)))
1421           (remove-text-properties bline eline '(composition nil))
1422           (when (re-search-forward new-old-code eline t)
1423             (replace-match new-code nil t)))))))
1424
1425 (defun hs-lint-finish-hook (buf msg)
1426   "Function, that is executed at the end of HLint execution"
1427   (if hs-lint-replace-with-suggestions
1428       (hs-lint-replace-suggestions)
1429       (next-error 1 t)))
1430
1431 (define-compilation-mode hs-lint-mode "HLint"
1432   "Mode for check Haskell source code."
1433   (set (make-local-variable 'compilation-process-setup-function)
1434        'hs-lint-process-setup)
1435   (set (make-local-variable 'compilation-disable-input) t)
1436   (set (make-local-variable 'compilation-scroll-output) nil)
1437   (set (make-local-variable 'compilation-finish-functions)
1438        (list 'hs-lint-finish-hook))
1439   )
1440
1441 (defun hs-lint ()
1442   "Run HLint for current buffer with haskell source"
1443   (interactive)
1444   (save-some-buffers hs-lint-save-files)
1445   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1446                      'hs-lint-mode))
1447
1448 (provide 'hs-lint)
1449 ;;; hs-lint.el ends here
1450 #+end_src
1451
1452 #+begin_src emacs-lisp :tangle no
1453 (use-package hs-lint
1454   :load-path "lisp/"
1455   :bind (:map haskell-mode-map
1456               ("C-c l l" . hs-lint)))
1457 #+end_src
1458
1459 ** Web dev
1460
1461 *** SGML and HTML
1462
1463 #+begin_src emacs-lisp
1464 (use-package sgml-mode
1465   :defer t
1466   :config
1467   (setq sgml-basic-offset 2))
1468 #+end_src
1469
1470 *** CSS and SCSS
1471
1472 #+begin_src emacs-lisp
1473 (use-package css-mode
1474   :defer t
1475   :config
1476   (setq css-indent-offset 2))
1477 #+end_src
1478
1479 *** Web mode
1480
1481 #+begin_src emacs-lisp
1482 (use-package web-mode
1483   :defer t
1484   :mode "\\.html\\'"
1485   :config
1486   (setq-every! 2
1487     web-mode-code-indent-offset
1488     web-mode-css-indent-offset
1489     web-mode-markup-indent-offset))
1490 #+end_src
1491
1492 *** Emmet mode
1493
1494 #+begin_src emacs-lisp
1495 (use-package emmet-mode
1496   :after (:any web-mode css-mode sgml-mode)
1497   :bind* (("C-)" . emmet-next-edit-point)
1498           ("C-(" . emmet-prev-edit-point))
1499   :config
1500   (unbind-key "C-j" emmet-mode-keymap)
1501   (setq emmet-move-cursor-between-quotes t)
1502   :hook (web-mode css-mode html-mode sgml-mode))
1503 #+end_src
1504
1505 ** COMMENT Java
1506
1507 *** meghanada
1508
1509 #+begin_src emacs-lisp
1510 (use-package meghanada
1511   :bind
1512   (:map meghanada-mode-map
1513         (("C-M-o" . meghanada-optimize-import)
1514          ("C-M-t" . meghanada-import-all)))
1515   :hook (java-mode . meghanada-mode))
1516 #+end_src
1517
1518 *** lsp-java
1519
1520 #+begin_comment
1521 dependencies:
1522
1523 ace-window
1524 avy
1525 bui
1526 company-lsp
1527 dap-mode
1528 lsp-java
1529 lsp-mode
1530 lsp-ui
1531 pfuture
1532 tree-mode
1533 treemacs
1534 #+end_comment
1535
1536 #+begin_src emacs-lisp
1537 (use-package treemacs
1538   :config (setq treemacs-never-persist t))
1539
1540 (use-package yasnippet
1541   :config
1542   ;; (yas-global-mode)
1543   )
1544
1545 (use-package lsp-mode
1546   :init (setq lsp-eldoc-render-all nil
1547               lsp-highlight-symbol-at-point nil)
1548   )
1549
1550 (use-package hydra)
1551
1552 (use-package company-lsp
1553   :after  company
1554   :config
1555   (setq company-lsp-cache-candidates t
1556         company-lsp-async t))
1557
1558 (use-package lsp-ui
1559   :config
1560   (setq lsp-ui-sideline-update-mode 'point))
1561
1562 (use-package lsp-java
1563   :config
1564   (add-hook 'java-mode-hook
1565             (lambda ()
1566               (setq-local company-backends (list 'company-lsp))))
1567
1568   (add-hook 'java-mode-hook 'lsp-java-enable)
1569   (add-hook 'java-mode-hook 'flycheck-mode)
1570   (add-hook 'java-mode-hook 'company-mode)
1571   (add-hook 'java-mode-hook 'lsp-ui-mode))
1572
1573 (use-package dap-mode
1574   :after lsp-mode
1575   :config
1576   (dap-mode t)
1577   (dap-ui-mode t))
1578
1579 (use-package dap-java
1580   :after (lsp-java))
1581
1582 (use-package lsp-java-treemacs
1583   :after (treemacs))
1584 #+end_src
1585
1586 ** geiser
1587
1588 #+begin_src emacs-lisp
1589 (use-package geiser)
1590
1591 (use-package geiser-guile
1592   :config
1593   (setq geiser-guile-load-path "~/src/git/guix"))
1594 #+end_src
1595
1596 ** guix
1597
1598 #+begin_src emacs-lisp
1599 (use-package guix
1600   :load-path "lib/guix/elisp")
1601 #+end_src
1602
1603 * Emacs enhancements
1604 :PROPERTIES:
1605 :CUSTOM_ID: emacs-enhancements
1606 :END:
1607
1608 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1609
1610 #+begin_quote
1611 Emacs package that displays available keybindings in popup
1612 #+end_quote
1613
1614 #+begin_src emacs-lisp
1615 (use-package which-key
1616   :defer 1
1617   :config (which-key-mode))
1618 #+end_src
1619
1620 ** theme
1621
1622 #+begin_src emacs-lisp
1623 (add-to-list 'custom-theme-load-path "~/.emacs.d/lisp")
1624 (load-theme 'tangomod t)
1625 #+end_src
1626
1627 ** smart-mode-line
1628
1629 #+begin_src emacs-lisp
1630 (use-package smart-mode-line
1631   :config
1632   (sml/setup))
1633 #+end_src
1634
1635 ** doom-themes
1636
1637 #+begin_src emacs-lisp
1638 (use-package doom-themes)
1639 #+end_src
1640
1641 ** theme helper functions
1642
1643 #+begin_src emacs-lisp
1644 (defun amin/lights-on ()
1645   "Enable my favourite light theme."
1646   (interactive)
1647   (mapc #'disable-theme custom-enabled-themes)
1648   (load-theme 'tangomod t)
1649   (sml/apply-theme 'automatic))
1650
1651 (defun amin/lights-off ()
1652   "Go dark."
1653   (interactive)
1654   (mapc #'disable-theme custom-enabled-themes)
1655   (load-theme 'doom-tomorrow-night t)
1656   (sml/apply-theme 'automatic))
1657
1658 (bind-keys
1659  ("s-t d" . amin/lights-off)
1660  ("s-t l" . amin/lights-on))
1661 #+end_src
1662
1663 ** [[https://github.com/bbatsov/crux][crux]]
1664
1665 #+begin_src emacs-lisp
1666 (use-package crux
1667   :defer 1
1668   :bind (("C-c b k" . crux-kill-other-buffers)
1669          ("C-c d"   . crux-duplicate-current-line-or-region)
1670          ("C-c D"   . crux-duplicate-and-comment-current-line-or-region)
1671          ("C-c f c" . crux-copy-file-preserve-attributes)
1672          ("C-c f d" . crux-delete-file-and-buffer)
1673          ("C-c f r" . crux-rename-file-and-buffer)
1674          ("C-c j"   . crux-top-join-line)
1675          ("C-S-j"   . crux-top-join-line)))
1676 #+end_src
1677
1678 ** [[https://github.com/alezost/mwim.el][mwim]]
1679
1680 #+begin_src emacs-lisp
1681 (use-package mwim
1682   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1683          ("C-e"    . mwim-end-of-code-or-line)
1684          ("<home>" . mwim-beginning-of-line-or-code)
1685          ("<end>"  . mwim-end-of-line-or-code)))
1686 #+end_src
1687
1688 ** projectile
1689
1690 #+begin_src emacs-lisp
1691 (use-package projectile
1692   :defer t
1693   :bind-keymap ("C-c p" . projectile-command-map)
1694   :config
1695   (projectile-mode)
1696
1697   (defun my-projectile-invalidate-cache (&rest _args)
1698     ;; ignore the args to `magit-checkout'
1699     (projectile-invalidate-cache nil))
1700
1701   (eval-after-load 'magit-branch
1702     '(progn
1703        (advice-add 'magit-checkout
1704                    :after #'my-projectile-invalidate-cache)
1705        (advice-add 'magit-branch-and-checkout
1706                    :after #'my-projectile-invalidate-cache)))
1707   :custom (projectile-completion-system 'ivy))
1708 #+end_src
1709
1710 ** [[https://github.com/Wilfred/helpful][helpful]]
1711
1712 #+begin_src emacs-lisp
1713 (use-package helpful
1714   :defer 1
1715   :bind
1716   (("C-S-h c" . helpful-command)
1717    ("C-S-h f" . helpful-callable)        ; helpful-function
1718    ("C-S-h v" . helpful-variable)
1719    ("C-S-h k" . helpful-key)
1720    ("C-S-h p" . helpful-at-point)))
1721 #+end_src
1722
1723 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1724
1725 Make =*scratch*= and =*Messages*= unkillable.
1726
1727 #+begin_src emacs-lisp
1728 (use-package unkillable-scratch
1729   :defer 3
1730   :config
1731   (unkillable-scratch 1)
1732   :custom
1733   (unkillable-scratch-behavior 'do-nothing)
1734   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1735 #+end_src
1736
1737 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1738
1739 #+begin_example
1740 ,----
1741 | make pretty boxed quotes like this
1742 `----
1743 #+end_example
1744
1745 #+begin_src emacs-lisp
1746 (use-package boxquote
1747   :defer 3
1748   :bind
1749   (:prefix-map amin--boxquote-prefix-map
1750    :prefix "C-c q"
1751    ("b"   . boxquote-buffer)
1752    ("B"   . boxquote-insert-buffer)
1753    ("d"   . boxquote-defun)
1754    ("F"   . boxquote-insert-file)
1755    ("hf"  . boxquote-describe-function)
1756    ("hk"  . boxquote-describe-key)
1757    ("hv"  . boxquote-describe-variable)
1758    ("hw"  . boxquote-where-is)
1759    ("k"   . boxquote-kill)
1760    ("p"   . boxquote-paragraph)
1761    ("q"   . boxquote-boxquote)
1762    ("r"   . boxquote-region)
1763    ("s"   . boxquote-shell-command)
1764    ("t"   . boxquote-text)
1765    ("T"   . boxquote-title)
1766    ("u"   . boxquote-unbox)
1767    ("U"   . boxquote-unbox-region)
1768    ("y"   . boxquote-yank)
1769    ("M-q" . boxquote-fill-paragraph)
1770    ("M-w" . boxquote-kill-ring-save)))
1771 #+end_src
1772
1773 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1774
1775 ** typo.el
1776
1777 #+begin_src emacs-lisp
1778 (use-package typo
1779   :defer 2
1780   :config
1781   (typo-global-mode 1)
1782   :hook (text-mode . typo-mode))
1783 #+end_src
1784
1785 ** hl-todo
1786
1787 #+begin_src emacs-lisp
1788 (use-package hl-todo
1789   :defer 4
1790   :config
1791   (global-hl-todo-mode))
1792 #+end_src
1793
1794 ** shrink-path
1795
1796 #+begin_src emacs-lisp
1797 (use-package shrink-path
1798   :after eshell
1799   :config
1800   (setq eshell-prompt-regexp "\\(.*\n\\)*λ "
1801         eshell-prompt-function #'+eshell/prompt)
1802
1803   (defun +eshell/prompt ()
1804     (let ((base/dir (shrink-path-prompt default-directory)))
1805       (concat (propertize (car base/dir)
1806                           'face 'font-lock-comment-face)
1807               (propertize (cdr base/dir)
1808                           'face 'font-lock-constant-face)
1809               (propertize (+eshell--current-git-branch)
1810                           'face 'font-lock-function-name-face)
1811               "\n"
1812               (propertize "λ" 'face 'eshell-prompt-face)
1813               ;; needed for the input text to not have prompt face
1814               (propertize " " 'face 'default))))
1815
1816   (defun +eshell--current-git-branch ()
1817     (let ((branch (car (loop for match in (split-string (shell-command-to-string "git branch") "\n")
1818                              when (string-match "^\*" match)
1819                              collect match))))
1820       (if (not (eq branch nil))
1821           (concat " " (substring branch 2))
1822         ""))))
1823 #+end_src
1824
1825 ** [[https://github.com/peterwvj/eshell-up][eshell-up]]
1826
1827 #+begin_src emacs-lisp
1828 (use-package eshell-up
1829   :after eshell)
1830 #+end_src
1831
1832 ** multi-term
1833
1834 #+begin_src emacs-lisp
1835 (use-package multi-term
1836   :defer 1
1837   :bind (("C-c a s m m" . multi-term)
1838          ("C-c a s m p" . multi-term-dedicated-toggle)
1839          :map term-mode-map
1840          ("C-c C-j" . term-char-mode)
1841          :map term-raw-map
1842          ("C-c C-j" . term-line-mode))
1843   :config
1844   (setq multi-term-program "/bin/screen"
1845         ;; TODO: add separate bindings for connecting to existing
1846         ;; session vs. always creating a new one
1847         multi-term-dedicated-select-after-open-p t
1848         multi-term-dedicated-window-height 20
1849         multi-term-dedicated-max-window-height 30
1850         term-bind-key-alist
1851         '(("C-c C-c" . term-interrupt-subjob)
1852           ("C-c C-e" . term-send-esc)
1853           ("C-k" . kill-line)
1854           ("C-y" . term-paste)
1855           ("M-f" . term-send-forward-word)
1856           ("M-b" . term-send-backward-word)
1857           ("M-p" . term-send-up)
1858           ("M-n" . term-send-down)
1859           ("<C-backspace>" . term-send-backward-kill-word)
1860           ("<M-DEL>" . term-send-backward-kill-word)
1861           ("M-d" . term-send-delete-word)
1862           ("M-," . term-send-raw)
1863           ("M-." . comint-dynamic-complete))
1864         term-unbind-key-alist
1865         '("C-z" "C-x" "C-c" "C-h" "C-y" "<ESC>")))
1866 #+end_src
1867
1868 ** page-break-lines
1869
1870 #+begin_src emacs-lisp
1871 (use-package page-break-lines
1872   :config
1873   (global-page-break-lines-mode))
1874 #+end_src
1875
1876 ** expand-region
1877
1878 #+begin_src emacs-lisp
1879 (use-package expand-region
1880   :bind ("C-=" . er/expand-region))
1881 #+end_src
1882
1883 * Email
1884 :PROPERTIES:
1885 :CUSTOM_ID: email
1886 :END:
1887
1888 #+begin_src emacs-lisp
1889 (defvar amin-maildir (expand-file-name "~/mail/"))
1890 (after! recentf
1891   (add-to-list 'recentf-exclude amin-maildir))
1892 #+end_src
1893
1894 ** Gnus
1895
1896 #+begin_src emacs-lisp
1897 (setq
1898  amin-gnus-init-file (no-littering-expand-etc-file-name "gnus")
1899  mail-user-agent     'gnus-user-agent
1900  read-mail-command   'gnus)
1901
1902 (use-package gnus
1903   :bind (("C-c m" . gnus)
1904          ("C-c M" . gnus-unplugged)
1905          ("s-m"   . gnus)
1906          ("s-M"   . gnus-unplugged))
1907   :init
1908   (setq
1909    gnus-select-method '(nnnil "")
1910    gnus-secondary-select-methods
1911    '((nnimap "amin"
1912             (nnimap-stream plain)
1913             (nnimap-address "127.0.0.1")
1914             (nnimap-server-port 143)
1915             (nnimap-authenticator plain)
1916             (nnimap-user "amin@aminb.org"))
1917      (nnimap "uwaterloo"
1918              (nnimap-stream plain)
1919              (nnimap-address "127.0.0.1")
1920              (nnimap-server-port 143)
1921              (nnimap-authenticator plain)
1922              (nnimap-user "abandali@uwaterloo.ca")))
1923    gnus-message-archive-group "nnimap+amin:Sent"
1924    gnus-parameters
1925    '(("gnu.*"
1926       (gcc-self . t)))
1927    gnus-large-newsgroup  50
1928    gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
1929    gnus-directory        (concat gnus-home-directory "news/")
1930    message-directory     (concat gnus-home-directory "mail/")
1931    nndraft-directory     (concat gnus-home-directory "drafts/")
1932    gnus-save-newsrc-file nil
1933    gnus-read-newsrc-file nil
1934    gnus-interactive-exit nil
1935    gnus-gcc-mark-as-read t))
1936
1937 (use-package gnus-art
1938   :config
1939   (setq
1940    gnus-visible-headers
1941    (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
1942    gnus-sorted-header-list
1943    '("^From:" "^Subject:" "^Summary:" "^Keywords:"
1944      "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
1945      "^Newsgroups:" "List-Id:" "^Organization:"
1946      "^User-Agent:" "^Date:")
1947   ;; local-lapsed article dates
1948   ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
1949   gnus-article-date-headers '(user-defined)
1950   gnus-article-time-format
1951   (lambda (time)
1952     (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
1953            (local (article-make-date-line date 'local))
1954            (combined-lapsed (article-make-date-line date
1955                                                     'combined-lapsed))
1956            (lapsed (progn
1957                      (string-match " (.+" combined-lapsed)
1958                      (match-string 0 combined-lapsed))))
1959       (concat local lapsed))))
1960   (bind-keys
1961    :map gnus-article-mode-map
1962    ("r"   . gnus-article-reply-with-original)
1963    ("R"   . gnus-article-wide-reply-with-original)
1964    ("M-L" . org-store-link)))
1965
1966 (use-package gnus-sum
1967   :bind (:map gnus-summary-mode-map
1968               :prefix-map amin--gnus-summary-prefix-map
1969               :prefix "v"
1970               ("r" . gnus-summary-reply)
1971               ("w" . gnus-summary-wide-reply)
1972               ("v" . gnus-summary-show-raw-article))
1973   :config
1974   (bind-keys
1975    :map gnus-summary-mode-map
1976    ("r"   . gnus-summary-reply-with-original)
1977    ("R"   . gnus-summary-wide-reply-with-original)
1978    ("M-L" . org-store-link))
1979   :hook (gnus-summary-mode . amin--no-mouse-autoselect-window))
1980
1981 (use-package gnus-msg
1982   :config
1983   (setq gnus-posting-styles
1984         '((".*"
1985            (address "amin@aminb.org")
1986            (body "\nBest,\namin\n")
1987            (eval (setq amin--message-cite-say-hi t)))
1988           ("gnu.*"
1989            (address "bandali@gnu.org"))
1990           ((header "subject" "ThankCRM")
1991            (to "webmasters-comment@gnu.org")
1992            (body "\nAdded  to 2018supporters.html.\n\nMoving to campaigns.\n\n-amin\n")
1993            (eval (setq amin--message-cite-say-hi nil)))
1994           ("nnimap\\+uwaterloo:.*"
1995            (address "abandali@uwaterloo.ca")
1996            (gcc "\"nnimap+uwaterloo:Sent Items\"")))))
1997
1998 (use-package gnus-topic
1999   :hook (gnus-group-mode . gnus-topic-mode))
2000
2001 (use-package gnus-agent
2002   :config
2003   (setq gnus-agent-synchronize-flags 'ask)
2004   :hook (gnus-group-mode . gnus-agent-mode))
2005
2006 (use-package gnus-group
2007   :config
2008   (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))
2009
2010 (use-package mm-decode
2011   :config
2012   (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
2013 #+end_src
2014
2015 ** sendmail
2016
2017 #+begin_src emacs-lisp
2018 (use-package sendmail
2019   :config
2020   (setq sendmail-program "/usr/bin/msmtp"
2021         ;; message-sendmail-extra-arguments '("-v" "-d")
2022         mail-specify-envelope-from t
2023         mail-envelope-from 'header))
2024 #+end_src
2025
2026 ** message
2027
2028 #+begin_src emacs-lisp
2029 (use-package message
2030   :config
2031   (defconst amin--message-cite-style-format "On %Y-%m-%d %l:%M %p, %N wrote:")
2032   (defconst message-cite-style-bandali
2033     '((message-cite-function  'message-cite-original)
2034       (message-citation-line-function  'message-insert-formatted-citation-line)
2035       (message-cite-reply-position 'traditional)
2036       (message-yank-prefix  "> ")
2037       (message-yank-cited-prefix  ">")
2038       (message-yank-empty-prefix  ">")
2039       (message-citation-line-format
2040        (if amin--message-cite-say-hi
2041            (concat "Hi %F,\n\n" amin--message-cite-style-format)
2042          amin--message-cite-style-format)))
2043     "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
2044   (setq message-cite-style 'message-cite-style-bandali
2045         message-kill-buffer-on-exit t
2046         message-send-mail-function 'message-send-mail-with-sendmail
2047         message-sendmail-envelope-from 'header
2048         message-dont-reply-to-names
2049         "\\(\\(.*@aminb\\.org\\)\\|\\(amin@bandali\\.me\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
2050         message-user-fqdn "aminb.org")
2051   :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
2052          (message-mode . flyspell-mode)
2053          (message-mode . (lambda ()
2054                            ;; (setq fill-column 65
2055                            ;;       message-fill-column 65)
2056                            (make-local-variable 'company-idle-delay)
2057                            (setq company-idle-delay 0.2))))
2058   ;; :custom-face
2059   ;; (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
2060   ;; (message-header-to      ((t (:foreground "#111" :weight normal))))
2061   ;; (message-header-cc      ((t (:foreground "#333" :weight normal))))
2062   )
2063
2064 (after! mml-sec
2065   (setq mml-secure-openpgp-encrypt-to-self t
2066         mml-secure-openpgp-sign-with-sender t))
2067 #+end_src
2068
2069 ** footnote
2070
2071 Convenient footnotes in =message-mode=.
2072
2073 #+begin_src emacs-lisp
2074 (use-package footnote
2075   :after message
2076   :bind
2077   (:map message-mode-map
2078         :prefix-map amin--footnote-prefix-map
2079         :prefix "C-c f"
2080         ("a" . footnote-add-footnote)
2081         ("b" . footnote-back-to-message)
2082         ("c" . footnote-cycle-style)
2083         ("d" . footnote-delete-footnote)
2084         ("g" . footnote-goto-footnote)
2085         ("r" . footnote-renumber-footnotes)
2086         ("s" . footnote-set-style))
2087   :config
2088   (setq footnote-start-tag ""
2089         footnote-end-tag   ""
2090         footnote-style     'unicode))
2091 #+end_src
2092
2093 ** ebdb
2094
2095 #+begin_src emacs-lisp
2096 (use-package ebdb
2097   :defer 1
2098   :bind (:map gnus-group-mode-map ("e" . ebdb))
2099   :config
2100   (setq ebdb-sources (no-littering-expand-var-file-name "ebdb"))
2101   (after! swiper
2102     (add-to-list 'swiper-font-lock-exclude 'ebdb-mode t)))
2103
2104 (use-package ebdb-com
2105   :after ebdb)
2106
2107 ;; (use-package ebdb-complete
2108 ;;   :after ebdb
2109 ;;   :config
2110 ;;   (ebdb-complete-enable))
2111
2112 (use-package company-ebdb
2113   :after (:all company message)
2114   :config
2115   (defun company-ebdb--post-complete (_) nil)
2116   :hook
2117   (message-mode . (lambda ()
2118                     (add-to-list (make-local-variable 'company-backends)
2119                                  'company-ebdb))))
2120
2121 (use-package ebdb-gnus
2122   :after ebdb
2123   :custom
2124   (ebdb-gnus-window-configuration
2125    '(article
2126      (vertical 1.0
2127                (summary 0.25 point)
2128                (horizontal 1.0
2129                            (article 1.0)
2130                            (ebdb-gnus 0.3))))))
2131
2132 (use-package ebdb-mua
2133   :after ebdb
2134   ;; :custom (ebdb-mua-pop-up nil)
2135   )
2136
2137 ;; (use-package ebdb-message
2138 ;;   :after ebdb)
2139
2140
2141 ;; (use-package ebdb-vcard
2142 ;;   :after ebdb)
2143 #+end_src
2144
2145 ** COMMENT message-x
2146
2147 #+begin_src emacs-lisp
2148 (use-package message-x
2149   :custom
2150   (message-x-completion-alist
2151    (quote
2152     (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
2153      ((if
2154           (boundp
2155            (quote message-newgroups-header-regexp))
2156           message-newgroups-header-regexp message-newsgroups-header-regexp)
2157       . message-expand-group)))))
2158 #+end_src
2159
2160 ** COMMENT gnus-harvest
2161
2162 #+begin_src emacs-lisp
2163 (use-package gnus-harvest
2164   :commands gnus-harvest-install
2165   :demand t
2166   :config
2167   (if (featurep 'message-x)
2168       (gnus-harvest-install 'message-x)
2169     (gnus-harvest-install)))
2170 #+end_src
2171
2172 * Blogging
2173 :PROPERTIES:
2174 :CUSTOM_ID: blogging
2175 :END:
2176
2177 ** [[https://ox-hugo.scripter.co][ox-hugo]]
2178
2179 #+begin_src emacs-lisp
2180 (use-package ox-hugo
2181   :after ox)
2182
2183 (use-package ox-hugo-auto-export
2184   :load-path "lib/ox-hugo")
2185 #+end_src
2186
2187 * Post initialization
2188 :PROPERTIES:
2189 :CUSTOM_ID: post-initialization
2190 :END:
2191
2192 Display how long it took to load the init file.
2193
2194 #+begin_src emacs-lisp
2195 (message "Loading %s...done (%.3fs)" user-init-file
2196          (float-time (time-subtract (current-time)
2197                                     amin--before-user-init-time)))
2198 #+end_src
2199
2200 * Footer
2201 :PROPERTIES:
2202 :CUSTOM_ID: footer
2203 :END:
2204
2205 #+begin_src emacs-lisp :comments none
2206 ;;; init.el ends here
2207 #+end_src
2208
2209 * COMMENT Local Variables                                           :ARCHIVE:
2210 # Local Variables:
2211 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
2212 # eval: (typo-mode -1)
2213 # End: