git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236 #+end_src
 237
 238 *** =use-package=
 239
 240 #+begin_quote
 241 A use-package declaration for simplifying your .emacs
 242 #+end_quote
 243
 244 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 245 packages (in our case especially the latter) in a neatly organized way
 246 and without compromising on performance.
 247
 248 #+begin_src emacs-lisp
 249 (require 'use-package)
 250 (if nil  ; set to t when need to debug init
 251     (setq use-package-verbose t
 252           use-package-expand-minimally nil
 253           use-package-compute-statistics t
 254           debug-on-error t)
 255   (setq use-package-verbose nil
 256         use-package-expand-minimally t))
 257 #+end_src
 258
 259 *** Epkg
 260
 261 #+begin_quote
 262 Browse the Emacsmirror package database
 263 #+end_quote
 264
 265 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 266 database, low-level functions for querying the database, and a
 267 =package.el=-like user interface for browsing the available packages.
 268
 269 #+begin_src emacs-lisp
 270 (use-package epkg
 271   :defer t)
 272 #+end_src
 273
 274 ** No littering in =~/.emacs.d=
 275
 276 #+begin_quote
 277 Help keeping ~/.emacs.d clean
 278 #+end_quote
 279
 280 By default, even for Emacs' built-in packages, the configuration files
 281 and persistent data are all over the place. Use =no-littering= to help
 282 contain the mess.
 283
 284 #+begin_src emacs-lisp
 285 (use-package no-littering
 286   :demand t
 287   :config
 288   (savehist-mode 1)
 289   (add-to-list 'savehist-additional-variables 'kill-ring)
 290   (save-place-mode 1)
 291   (setq auto-save-file-name-transforms
 292         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 293 #+end_src
 294
 295 ** Custom file (=custom.el=)
 296
 297 I'm not planning on using the custom file much, but even so, I
 298 definitely don't want it mixing with =init.el=. So, here; let's give
 299 it it's own file. While at it, treat themes as safe.
 300
 301 #+begin_src emacs-lisp
 302 (use-package custom
 303   :no-require t
 304   :config
 305   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 306   (when (file-exists-p custom-file)
 307     (load custom-file))
 308   (setf custom-safe-themes t))
 309 #+end_src
 310
 311 ** Better =$PATH= handling
 312
 313 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 314 in my shell.
 315
 316 #+begin_src emacs-lisp
 317 (use-package exec-path-from-shell
 318   :defer 1
 319   :init
 320   (setq exec-path-from-shell-check-startup-files nil)
 321   :config
 322   (exec-path-from-shell-initialize)
 323   ;; while we're at it, let's fix access to our running ssh-agent
 324   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 325   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 326 #+end_src
 327
 328 ** Only one custom theme at a time
 329
 330 #+begin_src emacs-lisp
 331 (defadvice load-theme (before clear-previous-themes activate)
 332   "Clear existing theme settings instead of layering them"
 333   (mapc #'disable-theme custom-enabled-themes))
 334 #+end_src
 335
 336 ** Server
 337
 338 Start server if not already running. Alternatively, can be done by
 339 issuing =emacs --daemon= in the terminal, which can be automated with
 340 a systemd service or using =brew services start emacs= on macOS. I use
 341 Emacs as my window manager (via EXWM), so I always start Emacs on
 342 login; so starting the server from inside Emacs is good enough for me.
 343
 344 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 345
 346 #+begin_src emacs-lisp
 347 (use-package server
 348   :config (or (server-running-p) (server-mode)))
 349 #+end_src
 350
 351 ** Unicode support
 352
 353 Font stack with better unicode support, around =Ubuntu Mono= and
 354 =Hack=.
 355
 356 #+begin_src emacs-lisp
 357 (dolist (ft (fontset-list))
 358   (set-fontset-font
 359    ft
 360    'unicode
 361    (font-spec :name "Ubuntu Mono"))
 362   (set-fontset-font
 363    ft
 364    'unicode
 365    (font-spec :name "DejaVu Sans Mono")
 366    nil
 367    'append)
 368   ;; (set-fontset-font
 369   ;;  ft
 370   ;;  'unicode
 371   ;;  (font-spec
 372   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 373   ;;  nil
 374   ;;  'append)
 375   ;; (set-fontset-font
 376   ;;  ft
 377   ;;  #x2115  ; ℕ
 378   ;;  (font-spec :name "DejaVu Sans Mono")
 379   ;;  nil
 380   ;;  'append)
 381   (set-fontset-font
 382    ft
 383    (cons ?Α ?ω)
 384    (font-spec :name "DejaVu Sans Mono" :size 14)
 385    nil
 386    'prepend))
 387 #+end_src
 388
 389 ** Libraries
 390
 391 #+begin_src emacs-lisp
 392 (require 'cl-lib)
 393 (require 'subr-x)
 394 #+end_src
 395
 396 ** Useful utilities
 397
 398 #+begin_src emacs-lisp
 399 (defun amin-enlist (exp)
 400   "Return EXP wrapped in a list, or as-is if already a list."
 401 (if (listp exp) exp (list exp)))
 402
 403 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 404 (defmacro after! (features &rest body)
 405   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 406 compilation."
 407   (declare (indent defun) (debug t))
 408   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 409                 (dolist (next (amin-enlist features))
 410                   (if (symbolp next)
 411                       (require next nil :no-error)
 412                     (load next :no-message :no-error))))
 413             #'progn
 414           #'with-no-warnings)
 415         (cond ((symbolp features)
 416                `(eval-after-load ',features '(progn ,@body)))
 417               ((and (consp features)
 418                     (memq (car features) '(:or :any)))
 419                `(progn
 420                   ,@(cl-loop for next in (cdr features)
 421                              collect `(after! ,next ,@body))))
 422               ((and (consp features)
 423                     (memq (car features) '(:and :all)))
 424                (dolist (next (cdr features))
 425                  (setq body `(after! ,next ,@body)))
 426                body)
 427               ((listp features)
 428                `(after! (:all ,@features) ,@body)))))
 429 #+end_src
 430
 431 * Core
 432 :PROPERTIES:
 433 :CUSTOM_ID: core
 434 :END:
 435
 436 ** Defaults
 437
 438 *** Time and battery in mode-line
 439
 440 Enable displaying time and battery in the mode-line, since I'm not
 441 using the Xfce panel anymore. Also, I don't need to see the load
 442 average on a regular basis, so disable that.
 443
 444 Note: using =i3status= on sway at the moment, so disabling this.
 445
 446 #+begin_src emacs-lisp :tangle no
 447 (use-package time
 448   :ensure nil
 449   :init
 450   (setq display-time-default-load-average nil)
 451   :config
 452   (display-time-mode))
 453
 454 (use-package battery
 455   :ensure nil
 456   :config
 457   (display-battery-mode))
 458 #+end_src
 459
 460 *** Smaller fringe
 461
 462 Might want to set the fringe to a smaller value, especially if using
 463 EXWM. I'm fine with the default for now.
 464
 465 #+begin_src emacs-lisp
 466 ;; (fringe-mode '(3 . 1))
 467 (fringe-mode nil)
 468 #+end_src
 469
 470 *** Disable disabled commands
 471
 472 Emacs disables some commands by default that could persumably be
 473 confusing for novice users. Let's disable that.
 474
 475 #+begin_src emacs-lisp
 476 (setq disabled-command-function nil)
 477 #+end_src
 478
 479 *** Kill-ring
 480
 481 Save what I copy into clipboard from other applications into Emacs'
 482 kill-ring, which would allow me to still be able to easily access it
 483 in case I kill (cut or copy) something else inside Emacs before
 484 yanking (pasting) what I'd originally intended to.
 485
 486 #+begin_src emacs-lisp
 487 (setq save-interprogram-paste-before-kill t)
 488 #+end_src
 489
 490 *** Minibuffer
 491
 492 #+begin_src emacs-lisp
 493 (setq enable-recursive-minibuffers t
 494       resize-mini-windows t)
 495 #+end_src
 496
 497 *** Lazy-person-friendly yes/no prompts
 498
 499 Lazy people would prefer to type fewer keystrokes, especially for yes
 500 or no questions. I'm lazy.
 501
 502 #+begin_src emacs-lisp
 503 (defalias 'yes-or-no-p #'y-or-n-p)
 504 #+end_src
 505
 506 *** Startup screen and =*scratch*=
 507
 508 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 509 startup buffer.
 510
 511 #+begin_src emacs-lisp
 512 (setq initial-buffer-choice t)
 513 #+end_src
 514
 515 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 516 need the default hint.
 517
 518 #+begin_src emacs-lisp
 519 (setq initial-scratch-message nil)
 520 #+end_src
 521
 522 Also, let's use Text mode as the major mode, in case I want to
 523 customize it (=*scratch*='s default major mode, Fundamental mode,
 524 can't really be customized).
 525
 526 #+begin_src emacs-lisp
 527 (setq initial-major-mode 'text-mode)
 528 #+end_src
 529
 530 Inhibit the buffer list when more than 2 files are loaded.
 531
 532 #+begin_src emacs-lisp
 533 (setq inhibit-startup-buffer-menu t)
 534 #+end_src
 535
 536 I don't really need to see the startup screen or echo area message
 537 either.
 538
 539 #+begin_src emacs-lisp
 540 (advice-add #'display-startup-echo-area-message :override #'ignore)
 541 (setq inhibit-startup-screen t
 542       inhibit-startup-echo-area-message user-login-name)
 543 #+end_src
 544
 545 *** More useful frame titles
 546
 547 Show either the file name or the buffer name (in case the buffer isn't
 548 visiting a file). Borrowed from Emacs Prelude.
 549
 550 #+begin_src emacs-lisp
 551 (setq frame-title-format
 552       '("" invocation-name " - "
 553         (:eval (if (buffer-file-name)
 554                    (abbreviate-file-name (buffer-file-name))
 555                  "%b"))))
 556 #+end_src
 557
 558 *** Backups
 559
 560 Emacs' default backup settings aren't that great. Let's use more
 561 sensible options. See documentation for the ~make-backup-file~
 562 variable.
 563
 564 #+begin_src emacs-lisp
 565 (setq backup-by-copying t
 566       version-control t)
 567 #+end_src
 568
 569 *** Auto revert
 570
 571 Enable automatic reloading of changed buffers and files.
 572
 573 #+begin_src emacs-lisp
 574 (global-auto-revert-mode 1)
 575 (setq auto-revert-verbose nil
 576       global-auto-revert-non-file-buffers t)
 577 #+end_src
 578
 579 *** Always use space for indentation
 580
 581 #+begin_src emacs-lisp
 582 (setq-default
 583  indent-tabs-mode nil
 584  require-final-newline t
 585  tab-width 4)
 586 #+end_src
 587
 588 ** Packages
 589
 590 The packages in this section are absolutely essential to my everyday
 591 workflow, and they play key roles in how I do my computing. They
 592 immensely enhance the Emacs experience for me; both using Emacs, and
 593 customizing it.
 594
 595 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 596
 597 #+begin_src emacs-lisp
 598 (use-package auto-compile
 599   :demand t
 600   :config
 601   (auto-compile-on-load-mode)
 602   (auto-compile-on-save-mode)
 603   (setq auto-compile-display-buffer               nil
 604         auto-compile-mode-line-counter            t
 605         auto-compile-source-recreate-deletes-dest t
 606         auto-compile-toggle-deletes-nonlib-dest   t
 607         auto-compile-update-autoloads             t)
 608   (add-hook 'auto-compile-inhibit-compile-hook
 609             'auto-compile-inhibit-compile-detached-git-head))
 610 #+end_src
 611
 612 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 613
 614 #+begin_quote
 615 Roll your own modal mode
 616 #+end_quote
 617
 618 #+begin_src emacs-lisp
 619 (use-package ryo-modal
 620   :commands ryo-modal-mode
 621   :bind ("M-m" . ryo-modal-mode)
 622   :after which-key
 623   :config
 624   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 625   (ryo-modal-keys
 626    ("," ryo-modal-repeat)
 627    ("b" backward-char)
 628    ("n" next-line)
 629    ("p" previous-line)
 630    ("f" forward-char)
 631    ("/" undo)
 632    ("i" ryo-modal-mode)
 633    ("l" recenter-top-bottom)
 634    ("v" scroll-up-command)
 635    ("V" scroll-down-command)
 636    ("x" delete-forward-char)
 637    ("SPC" (("b" (("b" ibuffer-list-buffers)
 638                  ("k" kill-this-buffer)
 639                  ("o" other-window)
 640                  ("s" save-buffer)))
 641            ("B" (("A" borg-activate)
 642                  ("a" borg-assimilate)
 643                  ("b" borg-build)
 644                  ("c" borg-clone)
 645                  ("r" borg-remove)))
 646            ("h" (("c" describe-char)
 647                  ("f" describe-function)
 648                  ("F" describe-face)
 649                  ("i" info)
 650                  ("k" describe-key)
 651                  ("l" view-lossage)
 652                  ("v" describe-variable)))
 653            ("q" (("q" save-buffers-kill-terminal)))))
 654    ("d" (("w" kill-word)
 655          ("b" backward-kill-word)))
 656    ("c w" kill-word :exit t))
 657
 658   (ryo-modal-keys
 659    ;; First argyment to ryo-modal-keys may be a list of keywords.
 660    ;; These keywords will be applied to all keybindings.
 661    (:norepeat t)
 662    ("0" "M-0")
 663    ("1" "M-1")
 664    ("2" "M-2")
 665    ("3" "M-3")
 666    ("4" "M-4")
 667    ("5" "M-5")
 668    ("6" "M-6")
 669    ("7" "M-7")
 670    ("8" "M-8")
 671    ("9" "M-9"))
 672   :hook ((text-mode . ryo-modal-mode)
 673          (prog-mode . ryo-modal-mode)))
 674 #+end_src
 675
 676 *** [[https://orgmode.org/][Org mode]]
 677
 678 #+begin_quote
 679 Org mode is for keeping notes, maintaining TODO lists, planning
 680 projects, and authoring documents with a fast and effective plain-text
 681 system.
 682 #+end_quote
 683
 684 In short, my favourite way of life.
 685
 686 #+begin_src emacs-lisp
 687 (use-package org
 688   :ryo ("SPC b t" org-babel-tangle)
 689   :config
 690   (setq org-src-tab-acts-natively t
 691         org-src-preserve-indentation nil
 692         org-edit-src-content-indentation 0)
 693   :hook (org-mode . org-indent-mode))
 694 (use-package org-notmuch
 695   :after (:any org notmuch))
 696 #+end_src
 697
 698 *** [[https://magit.vc/][Magit]]
 699
 700 #+begin_quote
 701 It's Magit! A Git porcelain inside Emacs.
 702 #+end_quote
 703
 704 Not just how I do git, but /the/ way to do git.
 705
 706 #+begin_src emacs-lisp
 707 (use-package magit
 708   :ryo ("SPC" (("g s" magit-status)))
 709   :defer t
 710   :bind (("s-g"     . magit-status)
 711          ("C-x g"   . magit-status)
 712          ("C-x M-g" . magit-dispatch-popup))
 713   :config
 714   (magit-add-section-hook 'magit-status-sections-hook
 715                           'magit-insert-modules
 716                           'magit-insert-stashes
 717                           'append))
 718 #+end_src
 719
 720 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 721
 722 #+begin_quote
 723 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 724 an overview, and more. Oh, man!
 725 #+end_quote
 726
 727 There's no way I could top that, so I won't attempt to.
 728
 729 **** Ivy
 730
 731 #+begin_src emacs-lisp
 732 (use-package ivy
 733   :defer 1
 734   :bind
 735   (:map ivy-minibuffer-map
 736         ([escape] . keyboard-escape-quit)
 737         ;; ("C-j"    . ivy-next-line)
 738         ;; ("C-k"    . ivy-previous-line)
 739         ([S-up]   . ivy-previous-history-element)
 740         ([S-down] . ivy-next-history-element)
 741         ("DEL"    . ivy-backward-delete-char))
 742   :ryo ("SPC ," ivy-switch-buffer)
 743   :config
 744   (setq ivy-wrap t)
 745   (ivy-mode 1))
 746 #+end_src
 747
 748 **** Swiper
 749
 750 #+begin_src emacs-lisp
 751 (use-package swiper
 752   :ryo
 753   ("SPC /" swiper)
 754   ("s" swiper)
 755   :bind (([remap isearch-forward]  . swiper)
 756          ([remap isearch-backward] . swiper)))
 757 #+end_src
 758
 759 **** Counsel
 760
 761 #+begin_src emacs-lisp
 762 (use-package counsel
 763   :defer 1
 764   :ryo
 765   ("SPC" (("f r" counsel-recentf)
 766           ("SPC" counsel-M-x)
 767           ("."   counsel-find-file)))
 768   :bind (([remap execute-extended-command] . counsel-M-x)
 769          ([remap find-file] . counsel-find-file)
 770          ("s-r"     . counsel-recentf)
 771          :map minibuffer-local-map
 772          ("C-r" . counsel-minibuffer-history))
 773   :config
 774   (counsel-mode 1)
 775   (defalias 'locate #'counsel-locate))
 776 #+end_src
 777
 778 * Borg's =layer/essentials=
 779
 780 TODO: break this giant source block down into individual org sections.
 781
 782 #+begin_src emacs-lisp
 783 (use-package dash
 784   :config (dash-enable-font-lock))
 785
 786 (use-package diff-hl
 787   :config
 788   (setq diff-hl-draw-borders nil)
 789   (global-diff-hl-mode)
 790   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 791
 792 (use-package dired
 793   :defer t
 794   :config (setq dired-listing-switches "-alh"))
 795
 796 (use-package eldoc
 797   :when (version< "25" emacs-version)
 798   :config (global-eldoc-mode))
 799
 800 (use-package help
 801   :defer t
 802   :config (temp-buffer-resize-mode))
 803
 804 (progn ;    `isearch'
 805   (setq isearch-allow-scroll t))
 806
 807 (use-package lisp-mode
 808   :config
 809   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 810   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 811   (defun indent-spaces-mode ()
 812     (setq indent-tabs-mode nil))
 813   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 814
 815 (use-package man
 816   :defer t
 817   :config (setq Man-width 80))
 818
 819 (use-package paren
 820   :config (show-paren-mode))
 821
 822 (use-package prog-mode
 823   :config (global-prettify-symbols-mode)
 824   (defun indicate-buffer-boundaries-left ()
 825     (setq indicate-buffer-boundaries 'left))
 826   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 827
 828 (use-package recentf
 829   :demand t
 830   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 831
 832 (use-package savehist
 833   :config (savehist-mode))
 834
 835 (use-package saveplace
 836   :when (version< "25" emacs-version)
 837   :config (save-place-mode))
 838
 839 (use-package simple
 840   :config (column-number-mode))
 841
 842 (progn ;    `text-mode'
 843   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 844
 845 (use-package tramp
 846   :defer t
 847   :config
 848   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 849   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 850   (add-to-list 'tramp-default-proxies-alist
 851                (list (regexp-quote (system-name)) nil nil)))
 852
 853 (use-package undo-tree
 854   :ryo
 855   ("?" undo-tree-undo)
 856   ("_" undo-tree-redo)
 857   :bind (("C-?" . undo-tree-undo)
 858          ("M-_" . undo-tree-redo))
 859   :config
 860   (global-undo-tree-mode)
 861   (setq undo-tree-mode-lighter ""
 862         undo-tree-auto-save-history t))
 863 #+end_src
 864
 865 * Editing
 866
 867 ** Company
 868
 869 #+begin_src emacs-lisp
 870 (use-package company
 871   :defer 5
 872   :bind
 873   (:map company-active-map
 874         ([tab] . company-complete-common-or-cycle))
 875   :custom
 876   (company-idle-delay 0.3)
 877   (company-minimum-prefix-length 1)
 878   (company-selection-wrap-around t)
 879   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 880   :config
 881   (global-company-mode t))
 882 #+end_src
 883
 884 * Syntax and spell checking
 885 #+begin_src emacs-lisp
 886 (use-package flycheck
 887   :hook (prog-mode . flycheck-mode)
 888   :config
 889   ;; Use the load-path from running Emacs when checking elisp files
 890   (setq flycheck-emacs-lisp-load-path 'inherit)
 891
 892   ;; Only flycheck when I actually save the buffer
 893   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 894 #+end_src
 895 * Programming modes
 896
 897 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 898
 899 #+begin_src emacs-lisp
 900 (use-package alloy-mode
 901   :config (setq alloy-basic-offset 2))
 902 #+end_src
 903
 904 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 905
 906 #+begin_src emacs-lisp
 907 (use-package proof-site  ; Proof General
 908   :load-path "lib/proof-site/generic/")
 909 #+end_src
 910
 911 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 912
 913 #+begin_src emacs-lisp
 914 (use-package lean-mode
 915   :bind (:map lean-mode-map
 916               ("S-SPC" . company-complete)))
 917 #+end_src
 918
 919 ** Haskell
 920
 921 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 922
 923 #+begin_src emacs-lisp
 924 (use-package haskell-mode
 925   :config
 926   (setq haskell-indentation-layout-offset 4
 927         haskell-indentation-left-offset 4
 928         flycheck-checker 'haskell-hlint
 929         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 930 #+end_src
 931
 932 *** [[https://github.com/jyp/dante][dante]]
 933
 934 #+begin_src emacs-lisp
 935 (use-package dante
 936   :after haskell-mode
 937   :commands dante-mode
 938   :hook (haskell-mode . dante-mode))
 939 #+end_src
 940
 941 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 942
 943 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 944 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 945
 946 #+begin_src emacs-lisp
 947 (use-package hlint-refactor
 948   :bind (:map hlint-refactor-mode-map
 949               ("C-c l b" . hlint-refactor-refactor-buffer)
 950               ("C-c l r" . hlint-refactor-refactor-at-point))
 951   :hook (haskell-mode . hlint-refactor-mode))
 952 #+end_src
 953
 954 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 955
 956 #+begin_src emacs-lisp
 957 (use-package flycheck-haskell)
 958 #+end_src
 959
 960 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 961 :PROPERTIES:
 962 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 963 :END:
 964
 965 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 966 instead.
 967
 968 #+begin_src emacs-lisp :tangle no
 969 ;;; hs-lint.el --- minor mode for HLint code checking
 970
 971 ;; Copyright 2009 (C) Alex Ott
 972 ;;
 973 ;; Author: Alex Ott <alexott@gmail.com>
 974 ;; Keywords: haskell, lint, HLint
 975 ;; Requirements:
 976 ;; Status: distributed under terms of GPL2 or above
 977
 978 ;; Typical message from HLint looks like:
 979 ;;
 980 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 981 ;; Found:
 982 ;;   count1 p l = length (filter p l)
 983 ;; Why not:
 984 ;;   count1 p = length . filter p
 985
 986
 987 (require 'compile)
 988
 989 (defgroup hs-lint nil
 990   "Run HLint as inferior of Emacs, parse error messages."
 991   :group 'tools
 992   :group 'haskell)
 993
 994 (defcustom hs-lint-command "hlint"
 995   "The default hs-lint command for \\[hlint]."
 996   :type 'string
 997   :group 'hs-lint)
 998
 999 (defcustom hs-lint-save-files t
1000   "Save modified files when run HLint or no (ask user)"
1001   :type 'boolean
1002   :group 'hs-lint)
1003
1004 (defcustom hs-lint-replace-with-suggestions nil
1005   "Replace user's code with suggested replacements"
1006   :type 'boolean
1007   :group 'hs-lint)
1008
1009 (defcustom hs-lint-replace-without-ask nil
1010   "Replace user's code with suggested replacements automatically"
1011   :type 'boolean
1012   :group 'hs-lint)
1013
1014 (defun hs-lint-process-setup ()
1015   "Setup compilation variables and buffer for `hlint'."
1016   (run-hooks 'hs-lint-setup-hook))
1017
1018 ;; regex for replace suggestions
1019 ;;
1020 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1021 ;; Found:
1022 ;; \s +\(.*\)
1023 ;; Why not:
1024 ;; \s +\(.*\)
1025
1026 (defvar hs-lint-regex
1027   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1028   "Regex for HLint messages")
1029
1030 (defun make-short-string (str maxlen)
1031   (if (< (length str) maxlen)
1032       str
1033     (concat (substring str 0 (- maxlen 3)) "...")))
1034
1035 (defun hs-lint-replace-suggestions ()
1036   "Perform actual replacement of suggestions"
1037   (goto-char (point-min))
1038   (while (re-search-forward hs-lint-regex nil t)
1039     (let* ((fname (match-string 1))
1040           (fline (string-to-number (match-string 2)))
1041           (old-code (match-string 4))
1042           (new-code (match-string 5))
1043           (msg (concat "Replace '" (make-short-string old-code 30)
1044                        "' with '" (make-short-string new-code 30) "'"))
1045           (bline 0)
1046           (eline 0)
1047           (spos 0)
1048           (new-old-code ""))
1049       (save-excursion
1050         (switch-to-buffer (get-file-buffer fname))
1051         (goto-char (point-min))
1052         (forward-line (1- fline))
1053         (beginning-of-line)
1054         (setf bline (point))
1055         (when (or hs-lint-replace-without-ask
1056                   (yes-or-no-p msg))
1057           (end-of-line)
1058           (setf eline (point))
1059           (beginning-of-line)
1060           (setf old-code (regexp-quote old-code))
1061           (while (string-match "\\\\ " old-code spos)
1062             (setf new-old-code (concat new-old-code
1063                                  (substring old-code spos (match-beginning 0))
1064                                  "\\ *"))
1065             (setf spos (match-end 0)))
1066           (setf new-old-code (concat new-old-code (substring old-code spos)))
1067           (remove-text-properties bline eline '(composition nil))
1068           (when (re-search-forward new-old-code eline t)
1069             (replace-match new-code nil t)))))))
1070
1071 (defun hs-lint-finish-hook (buf msg)
1072   "Function, that is executed at the end of HLint execution"
1073   (if hs-lint-replace-with-suggestions
1074       (hs-lint-replace-suggestions)
1075       (next-error 1 t)))
1076
1077 (define-compilation-mode hs-lint-mode "HLint"
1078   "Mode for check Haskell source code."
1079   (set (make-local-variable 'compilation-process-setup-function)
1080        'hs-lint-process-setup)
1081   (set (make-local-variable 'compilation-disable-input) t)
1082   (set (make-local-variable 'compilation-scroll-output) nil)
1083   (set (make-local-variable 'compilation-finish-functions)
1084        (list 'hs-lint-finish-hook))
1085   )
1086
1087 (defun hs-lint ()
1088   "Run HLint for current buffer with haskell source"
1089   (interactive)
1090   (save-some-buffers hs-lint-save-files)
1091   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1092                      'hs-lint-mode))
1093
1094 (provide 'hs-lint)
1095 ;;; hs-lint.el ends here
1096 #+end_src
1097
1098 #+begin_src emacs-lisp :tangle no
1099 (use-package hs-lint
1100   :load-path "lisp/"
1101   :bind (:map haskell-mode-map
1102               ("C-c l l" . hs-lint)))
1103 #+end_src
1104 * Emacs Enhancements
1105
1106 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1107
1108 #+begin_quote
1109 Emacs package that displays available keybindings in popup
1110 #+end_quote
1111
1112 #+begin_src emacs-lisp
1113 (use-package which-key
1114   :defer 1
1115   :config (which-key-mode))
1116 #+end_src
1117
1118 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1119
1120 #+begin_src emacs-lisp
1121 (use-package doom-modeline
1122   :demand t
1123   :config (setq doom-modeline-height 32)
1124   :hook (after-init . doom-modeline-init))
1125 #+end_src
1126
1127 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1128
1129 #+begin_src emacs-lisp :tangle no
1130 (use-package tao-theme
1131   :demand t
1132   :config (load-theme 'tao-yang t))
1133 #+end_src
1134
1135 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1136
1137 #+begin_src emacs-lisp
1138 (load-theme 'eink t)
1139 #+end_src
1140
1141 ** [[https://github.com/bbatsov/crux][crux]]
1142
1143 #+begin_src emacs-lisp
1144 (use-package crux
1145   :bind (("C-c d"    . crux-duplicate-current-line-or-region)
1146          ("C-c M-d"  . crux-duplicate-and-comment-current-line-or-region))
1147   :ryo
1148   ("o" crux-smart-open-line :exit t)
1149   ("O" crux-smart-open-line-above :exit t)
1150   ("SPC b K" crux-kill-other-buffers)
1151   ("d d" crux-kill-whole-line)
1152   ("c c" crux-kill-whole-line :then '(crux-smart-open-line-above) :exit t)
1153   ("SPC f" (("c" crux-copy-file-preserve-attributes)
1154             ("D" crux-delete-file-and-buffer)
1155             ("R" crux-rename-file-and-buffer))))
1156 #+end_src
1157
1158 ** [[https://github.com/alezost/mwim.el][mwim]]
1159
1160 #+begin_src emacs-lisp
1161 (use-package mwim
1162   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1163          ("C-e"    . mwim-end-of-code-or-line)
1164          ("<home>" . mwim-beginning-of-line-or-code)
1165          ("<end>"  . mwim-end-of-line-or-code))
1166   :ryo
1167   ("a" mwim-beginning-of-code-or-line)
1168   ("e" mwim-end-of-code-or-line))
1169 #+end_src
1170
1171 ** [[https://www.emacswiki.org/emacs/KeyChord][key-chord]]
1172
1173 #+begin_src emacs-lisp
1174 (use-package key-chord
1175   :demand t
1176   :config
1177   (key-chord-mode 1)
1178   (key-chord-define-global "jk" 'ryo-modal-mode)
1179   (setq key-chord-one-key-delay 0 ; i don't need one-key chords for now
1180         key-chord-two-keys-delay 0.005))
1181 #+end_src
1182
1183 * Email
1184 ** [[https://notmuchmail.org][notmuch]]
1185
1186 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1187
1188 #+begin_src emacs-lisp
1189 (defun amin/notmuch ()
1190   "Delete other windows, then launch `notmuch'."
1191   (interactive)
1192   (require 'notmuch)
1193   (delete-other-windows)
1194   (notmuch))
1195
1196 ;; (map!
1197 ;;  :leader
1198 ;;  :desc "notmuch" :n "m" #'amin/notmuch
1199 ;;  (:desc "search" :prefix "/"
1200 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1201 #+end_src
1202
1203 #+begin_src emacs-lisp
1204 (defvar amin-maildir "~/mail")
1205
1206 (use-package sendmail
1207   ;; :ensure nil
1208   :config
1209   (setq sendmail-program "/usr/bin/msmtp"
1210         ; message-sendmail-extra-arguments '("-v" "-d")
1211         mail-specify-envelope-from t
1212         mail-envelope-from 'header))
1213
1214 (use-package message
1215   ;; :ensure nil
1216   :config
1217   (setq message-kill-buffer-on-exit t
1218         message-send-mail-function 'message-send-mail-with-sendmail
1219         message-sendmail-envelope-from 'header
1220         message-directory "drafts"
1221         message-user-fqdn "aminb.org")
1222   (add-hook 'message-mode-hook
1223             (lambda () (setq fill-column 65
1224                         message-fill-column 65)))
1225   (add-hook 'message-mode-hook
1226             #'flyspell-mode)
1227   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1228   ;; TODO: is there a way to only run this when replying and not composing?
1229   ;; (add-hook 'notmuch-message-mode-hook
1230   ;;           (lambda () (progn
1231   ;;                   (newline)
1232   ;;                   (newline)
1233   ;;                   (forward-line -1)
1234   ;;                   (forward-line -1))))
1235   ;; (add-hook 'message-setup-hook
1236   ;;           #'mml-secure-message-sign-pgpmime)
1237   )
1238
1239 (after! mml-sec
1240   (setq mml-secure-openpgp-encrypt-to-self t
1241         mml-secure-openpgp-sign-with-sender t))
1242
1243 (use-package notmuch
1244   :ryo ("SPC m" amin/notmuch)
1245   :config
1246   (setq notmuch-hello-sections
1247         '(notmuch-hello-insert-header
1248           notmuch-hello-insert-saved-searches
1249           ;; notmuch-hello-insert-search
1250           notmuch-hello-insert-alltags)
1251         notmuch-search-oldest-first nil
1252         notmuch-show-all-tags-list t
1253         notmuch-message-headers  ; see bug follow-up above
1254         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1255         notmuch-hello-thousands-separator ","
1256         notmuch-fcc-dirs
1257         '(("amin@aminb.org"            . "amin/Sent")
1258           ("amin@gnu.org"              . "gnu/Sent")
1259           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1260           ("mab@gnu.org"               . "gnu/Sent")
1261           ("aminb@gnu.org"             . "gnu/Sent")
1262           (".*"                        . "sent"))
1263         notmuch-search-result-format
1264         '(("date" . "%12s ")
1265           ("count" . "%-7s ")
1266           ("authors" . "%-40s ")
1267           ("subject" . "%s ")
1268           ("tags" . "(%s)")))
1269   ;; (add-hook 'visual-fill-column-mode-hook
1270   ;;           (lambda ()
1271   ;;             (when (string= major-mode 'notmuch-message-mode)
1272   ;;               (setq visual-fill-column-width 70))))
1273   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1274   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1275   ;;             :override #'kill-this-buffer)
1276   :bind
1277   (:map notmuch-hello-mode-map
1278         ("g" . notmuch-poll-and-refresh-this-buffer)
1279         ("u" . (lambda ()
1280                  "Search for `unread' tagged messages"
1281                  (interactive)
1282                  (notmuch-hello-search "tag:unread")))
1283         ("i" . (lambda ()
1284                  "Search for `inbox' tagged messages"
1285                  (interactive)
1286                  (notmuch-hello-search "tag:inbox")))
1287         ("l" . (lambda ()
1288                  "Search for `latest' tagged messages"
1289                  (interactive)
1290                  (notmuch-hello-search "tag:latest")))
1291         ("e" . (lambda ()
1292                  "Search for `encrypted' tagged messages"
1293                  (interactive)
1294                  (notmuch-hello-search "tag:encrypted")))
1295         ("M" . (lambda ()
1296                  "Compose new mail and prompt for sender"
1297                  (interactive)
1298                  (let ((current-prefix-arg t))
1299                    (call-interactively #'notmuch-mua-new-mail)))))
1300   (:map notmuch-search-mode-map
1301         ("g" . notmuch-poll-and-refresh-this-buffer)
1302         ("k" . (lambda ()
1303                  "Mark message read"
1304                  (interactive)
1305                  (notmuch-search-tag '("-unread"))
1306                  ;; (notmuch-search-archive-thread)
1307                  (notmuch-search-next-thread)))
1308         ("u" . (lambda ()
1309                  "Mark message unread"
1310                  (interactive)
1311                  (notmuch-search-tag '("+unread"))
1312                  (notmuch-search-next-thread)))
1313         ("K" . (lambda ()
1314                  "Mark message deleted"
1315                  (interactive)
1316                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1317                  (notmuch-search-archive-thread)))
1318         ("S" . (lambda ()
1319                  "Mark message as spam"
1320                  (interactive)
1321                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1322                  (notmuch-search-archive-thread))))
1323   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1324         ("S" . (lambda ()
1325                  "Mark message as spam"
1326                  (interactive)
1327                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1328                  (notmuch-tree-archive-thread))))
1329 )
1330
1331 ;; (use-package counsel-notmuch
1332 ;;   :commands counsel-notmuch)
1333
1334 (after! notmuch-crypto
1335   (setq notmuch-crypto-process-mime t))
1336
1337 ;; (after! evil
1338 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1339 ;;         '((notmuch-hello-mode . emacs)
1340 ;;           (notmuch-search-mode . emacs)
1341 ;;           (notmuch-tree-mode . emacs))))
1342
1343 (after! recentf
1344   (add-to-list 'recentf-exclude (expand-file-name amin-maildir)))
1345 #+end_src
1346
1347 ** supercite
1348
1349 #+begin_src emacs-lisp :tangle no
1350 (use-package supercite
1351   :commands sc-cite-original
1352   :init
1353   (add-hook 'mail-citation-hook 'sc-cite-original)
1354
1355   (defun sc-remove-existing-signature ()
1356     (save-excursion
1357       (goto-char (region-beginning))
1358       (when (re-search-forward message-signature-separator (region-end) t)
1359         (delete-region (match-beginning 0) (region-end)))))
1360
1361   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1362
1363   (defun sc-remove-if-not-mailing-list ()
1364     (unless (assoc "list-id" sc-mail-info)
1365       (setq attribution sc-default-attribution
1366             citation (concat sc-citation-delimiter
1367                              sc-citation-separator))))
1368
1369   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1370
1371   :config
1372   (defun sc-fill-if-different (&optional prefix)
1373     "Fill the region bounded by `sc-fill-begin' and point.
1374 Only fill if optional PREFIX is different than
1375 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1376 fill region.  If PREFIX is not supplied, initialize fill
1377 variables.  This is useful for a regi `begin' frame-entry."
1378     (if (not prefix)
1379         (setq sc-fill-line-prefix ""
1380               sc-fill-begin (line-beginning-position))
1381       (if (and sc-auto-fill-region-p
1382                (not (string= prefix sc-fill-line-prefix)))
1383           (let ((fill-prefix sc-fill-line-prefix))
1384             (unless (or (string= fill-prefix "")
1385                         (save-excursion
1386                           (goto-char sc-fill-begin)
1387                           (or (looking-at ">+  +")
1388                               (< (length
1389                                   (buffer-substring (point)
1390                                                     (line-end-position)))
1391                                  65))))
1392               (fill-region sc-fill-begin (line-beginning-position)))
1393             (setq sc-fill-line-prefix prefix
1394                   sc-fill-begin (line-beginning-position)))))
1395 nil))
1396 #+end_src
1397
1398 * Blogging
1399 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1400
1401 #+begin_src emacs-lisp
1402 (use-package ox-hugo
1403   :after ox)
1404 #+end_src
1405
1406 * Post initialization
1407 :PROPERTIES:
1408 :CUSTOM_ID: post-initialization
1409 :END:
1410
1411 Display how long it took to load the init file.
1412
1413 #+begin_src emacs-lisp
1414 (message "Loading %s...done (%.3fs)" user-init-file
1415          (float-time (time-subtract (current-time)
1416                                     amin--before-user-init-time)))
1417 #+end_src
1418
1419 * Footer
1420 :PROPERTIES:
1421 :CUSTOM_ID: footer
1422 :END:
1423
1424 #+begin_src emacs-lisp :comments none
1425 ;;; init.el ends here
1426 #+end_src