git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 ;; (require 'borg-nix-shell)
 238 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c b A" . borg-activate)
 244    ("C-c b a" . borg-assimilate)
 245    ("C-c b b" . borg-build)
 246    ("C-c b c" . borg-clone)
 247    ("C-c b m" . borg-insert-update-message)
 248    ("C-c b r" . borg-remove)))
 249 #+end_src
 250
 251 *** =use-package=
 252
 253 #+begin_quote
 254 A use-package declaration for simplifying your .emacs
 255 #+end_quote
 256
 257 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 258 packages (in our case especially the latter) in a neatly organized way
 259 and without compromising on performance.
 260
 261 #+begin_src emacs-lisp
 262 (require 'use-package)
 263 (if nil  ; set to t when need to debug init
 264     (setq use-package-verbose t
 265           use-package-expand-minimally nil
 266           use-package-compute-statistics t
 267           debug-on-error t)
 268   (setq use-package-verbose nil
 269         use-package-expand-minimally t))
 270 #+end_src
 271
 272 *** Epkg
 273
 274 #+begin_quote
 275 Browse the Emacsmirror package database
 276 #+end_quote
 277
 278 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 279 database, low-level functions for querying the database, and a
 280 =package.el=-like user interface for browsing the available packages.
 281
 282 #+begin_src emacs-lisp
 283 (use-package epkg
 284   :defer t
 285   :bind
 286   (("C-c b d" . epkg-describe-package)
 287    ("C-c b p" . epkg-list-packages)
 288    ("C-c b u" . epkg-update)))
 289 #+end_src
 290
 291 ** No littering in =~/.emacs.d=
 292
 293 #+begin_quote
 294 Help keeping ~/.emacs.d clean
 295 #+end_quote
 296
 297 By default, even for Emacs' built-in packages, the configuration files
 298 and persistent data are all over the place. Use =no-littering= to help
 299 contain the mess.
 300
 301 #+begin_src emacs-lisp
 302 (use-package no-littering
 303   :demand t
 304   :config
 305   (savehist-mode 1)
 306   (add-to-list 'savehist-additional-variables 'kill-ring)
 307   (save-place-mode 1)
 308   (setq auto-save-file-name-transforms
 309         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 310 #+end_src
 311
 312 ** Custom file (=custom.el=)
 313
 314 I'm not planning on using the custom file much, but even so, I
 315 definitely don't want it mixing with =init.el=. So, here; let's give
 316 it it's own file. While at it, treat themes as safe.
 317
 318 #+begin_src emacs-lisp
 319 (use-package custom
 320   :no-require t
 321   :config
 322   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 323   (when (file-exists-p custom-file)
 324     (load custom-file))
 325   (setf custom-safe-themes t))
 326 #+end_src
 327
 328 ** Secrets file
 329
 330 #+begin_src emacs-lisp
 331 (load (no-littering-expand-etc-file-name "secrets"))
 332 #+end_src
 333
 334 ** Better =$PATH= handling
 335
 336 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 337 in my shell.
 338
 339 #+begin_src emacs-lisp
 340 (use-package exec-path-from-shell
 341   :defer 1
 342   :init
 343   (setq exec-path-from-shell-check-startup-files nil)
 344   :config
 345   (exec-path-from-shell-initialize)
 346   ;; while we're at it, let's fix access to our running ssh-agent
 347   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 348   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 349 #+end_src
 350
 351 ** COMMENT Only one custom theme at a time
 352
 353 #+begin_src emacs-lisp
 354 (defadvice load-theme (before clear-previous-themes activate)
 355   "Clear existing theme settings instead of layering them"
 356   (mapc #'disable-theme custom-enabled-themes))
 357 #+end_src
 358
 359 ** Server
 360
 361 Start server if not already running. Alternatively, can be done by
 362 issuing =emacs --daemon= in the terminal, which can be automated with
 363 a systemd service or using =brew services start emacs= on macOS. I use
 364 Emacs as my window manager (via EXWM), so I always start Emacs on
 365 login; so starting the server from inside Emacs is good enough for me.
 366
 367 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 368
 369 #+begin_src emacs-lisp
 370 (use-package server
 371   :defer 1
 372   :config (or (server-running-p) (server-mode)))
 373 #+end_src
 374
 375 ** COMMENT Unicode support
 376
 377 Font stack with better unicode support, around =Ubuntu Mono= and
 378 =Hack=.
 379
 380 #+begin_src emacs-lisp :tangle no
 381 (dolist (ft (fontset-list))
 382   (set-fontset-font
 383    ft
 384    'unicode
 385    (font-spec :name "Source Code Pro" :size 14))
 386   (set-fontset-font
 387    ft
 388    'unicode
 389    (font-spec :name "DejaVu Sans Mono")
 390    nil
 391    'append)
 392   ;; (set-fontset-font
 393   ;;  ft
 394   ;;  'unicode
 395   ;;  (font-spec
 396   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 397   ;;  nil
 398   ;;  'append)
 399   ;; (set-fontset-font
 400   ;;  ft
 401   ;;  #x2115  ; ℕ
 402   ;;  (font-spec :name "DejaVu Sans Mono")
 403   ;;  nil
 404   ;;  'append)
 405   (set-fontset-font
 406    ft
 407    (cons ?Α ?ω)
 408    (font-spec :name "DejaVu Sans Mono" :size 14)
 409    nil
 410    'prepend))
 411 #+end_src
 412
 413 ** Gentler font resizing
 414
 415 #+begin_src emacs-lisp
 416 (setq text-scale-mode-step 1.05)
 417 #+end_src
 418
 419 ** Libraries
 420
 421 #+begin_src emacs-lisp
 422 (require 'cl-lib)
 423 (require 'subr-x)
 424 #+end_src
 425
 426 ** Useful utilities
 427
 428 #+begin_src emacs-lisp
 429 (defun amin-enlist (exp)
 430   "Return EXP wrapped in a list, or as-is if already a list."
 431 (if (listp exp) exp (list exp)))
 432
 433 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 434 (defmacro after! (features &rest body)
 435   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 436 compilation."
 437   (declare (indent defun) (debug t))
 438   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 439                 (dolist (next (amin-enlist features))
 440                   (if (symbolp next)
 441                       (require next nil :no-error)
 442                     (load next :no-message :no-error))))
 443             #'progn
 444           #'with-no-warnings)
 445         (cond ((symbolp features)
 446                `(eval-after-load ',features '(progn ,@body)))
 447               ((and (consp features)
 448                     (memq (car features) '(:or :any)))
 449                `(progn
 450                   ,@(cl-loop for next in (cdr features)
 451                              collect `(after! ,next ,@body))))
 452               ((and (consp features)
 453                     (memq (car features) '(:and :all)))
 454                (dolist (next (cdr features))
 455                  (setq body `(after! ,next ,@body)))
 456                body)
 457               ((listp features)
 458                `(after! (:all ,@features) ,@body)))))
 459 #+end_src
 460
 461 Convenience macro for =setq='ing multiple variables to the same value:
 462
 463 #+begin_src emacs-lisp
 464 (defmacro setq-every! (value &rest vars)
 465   "Set all the variables from VARS to value VALUE."
 466   (declare (indent defun) (debug t))
 467   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 468 #+end_src
 469
 470 * Core
 471 :PROPERTIES:
 472 :CUSTOM_ID: core
 473 :END:
 474
 475 ** Defaults
 476
 477 *** Time and battery in mode-line
 478
 479 Enable displaying time and battery in the mode-line, since I'm not
 480 using the Xfce panel anymore. Also, I don't need to see the load
 481 average on a regular basis, so disable that.
 482
 483 Note: using =i3status= on sway at the moment, so disabling this.
 484
 485 #+begin_src emacs-lisp :tangle no
 486 (use-package time
 487   :init
 488   (setq display-time-default-load-average nil)
 489   :config
 490   (display-time-mode))
 491
 492 (use-package battery
 493   :config
 494   (display-battery-mode))
 495 #+end_src
 496
 497 *** Smaller fringe
 498
 499 Might want to set the fringe to a smaller value, especially if using
 500 EXWM. I'm fine with the default for now.
 501
 502 #+begin_src emacs-lisp
 503 ;; (fringe-mode '(3 . 1))
 504 (fringe-mode nil)
 505 #+end_src
 506
 507 *** Disable disabled commands
 508
 509 Emacs disables some commands by default that could persumably be
 510 confusing for novice users. Let's disable that.
 511
 512 #+begin_src emacs-lisp
 513 (setq disabled-command-function nil)
 514 #+end_src
 515
 516 *** Kill-ring
 517
 518 Save what I copy into clipboard from other applications into Emacs'
 519 kill-ring, which would allow me to still be able to easily access it
 520 in case I kill (cut or copy) something else inside Emacs before
 521 yanking (pasting) what I'd originally intended to.
 522
 523 #+begin_src emacs-lisp
 524 (setq save-interprogram-paste-before-kill t)
 525 #+end_src
 526
 527 *** Minibuffer
 528
 529 #+begin_src emacs-lisp
 530 (setq enable-recursive-minibuffers t
 531       resize-mini-windows t)
 532 #+end_src
 533
 534 *** Lazy-person-friendly yes/no prompts
 535
 536 Lazy people would prefer to type fewer keystrokes, especially for yes
 537 or no questions. I'm lazy.
 538
 539 #+begin_src emacs-lisp
 540 (defalias 'yes-or-no-p #'y-or-n-p)
 541 #+end_src
 542
 543 *** Startup screen and =*scratch*=
 544
 545 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 546 startup buffer.
 547
 548 #+begin_src emacs-lisp
 549 (setq initial-buffer-choice t)
 550 #+end_src
 551
 552 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 553 need the default hint.
 554
 555 #+begin_src emacs-lisp
 556 (setq initial-scratch-message nil)
 557 #+end_src
 558
 559 Also, let's use Text mode as the major mode, in case I want to
 560 customize it (=*scratch*='s default major mode, Fundamental mode,
 561 can't really be customized).
 562
 563 #+begin_src emacs-lisp
 564 (setq initial-major-mode 'text-mode)
 565 #+end_src
 566
 567 Inhibit the buffer list when more than 2 files are loaded.
 568
 569 #+begin_src emacs-lisp
 570 (setq inhibit-startup-buffer-menu t)
 571 #+end_src
 572
 573 I don't really need to see the startup screen or echo area message
 574 either.
 575
 576 #+begin_src emacs-lisp
 577 (advice-add #'display-startup-echo-area-message :override #'ignore)
 578 (setq inhibit-startup-screen t
 579       inhibit-startup-echo-area-message user-login-name)
 580 #+end_src
 581
 582 *** More useful frame titles
 583
 584 Show either the file name or the buffer name (in case the buffer isn't
 585 visiting a file). Borrowed from Emacs Prelude.
 586
 587 #+begin_src emacs-lisp
 588 (setq frame-title-format
 589       '("" invocation-name " - "
 590         (:eval (if (buffer-file-name)
 591                    (abbreviate-file-name (buffer-file-name))
 592                  "%b"))))
 593 #+end_src
 594
 595 *** Backups
 596
 597 Emacs' default backup settings aren't that great. Let's use more
 598 sensible options. See documentation for the ~make-backup-file~
 599 variable.
 600
 601 #+begin_src emacs-lisp
 602 (setq backup-by-copying t
 603       version-control t
 604       delete-old-versions t)
 605 #+end_src
 606
 607 *** Auto revert
 608
 609 Enable automatic reloading of changed buffers and files.
 610
 611 #+begin_src emacs-lisp
 612 (global-auto-revert-mode 1)
 613 (setq auto-revert-verbose nil
 614       global-auto-revert-non-file-buffers nil)
 615 #+end_src
 616
 617 *** Always use space for indentation
 618
 619 #+begin_src emacs-lisp
 620 (setq-default
 621  indent-tabs-mode nil
 622  require-final-newline t
 623  tab-width 4)
 624 #+end_src
 625
 626 *** Winner mode
 627
 628 Enable =winner-mode=.
 629
 630 #+begin_src emacs-lisp
 631 (winner-mode 1)
 632 #+end_src
 633
 634 *** Close =*compilation*= on success
 635
 636 #+begin_src emacs-lisp
 637 (setq compilation-exit-message-function
 638       (lambda (status code msg)
 639         "Close the compilation window if successful."
 640         ;; if M-x compile exits with 0
 641          (when (and (eq status 'exit) (zerop code))
 642            (bury-buffer)
 643            (delete-window (get-buffer-window (get-buffer "*compilation*"))))
 644          ;; return the result of compilation-exit-message-function
 645          (cons msg code)))
 646 #+end_src
 647
 648 *** Search for non-ASCII characters
 649
 650 I’d like non-ASCII characters such as ‘’“”«»‹›áⓐ𝒶 to be selected when
 651 I search for their ASCII counterpart.  Shoutout to [[http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html][endlessparentheses]]
 652 for this.
 653
 654 #+begin_src emacs-lisp
 655 (setq search-default-mode #'char-fold-to-regexp)
 656
 657 ;; uncomment to extend this behaviour to query-replace
 658 ;; (setq replace-char-fold t)
 659 #+end_src
 660
 661 ** Bindings
 662
 663 #+begin_src emacs-lisp
 664 (bind-keys
 665  ("s-c e b" . eval-buffer)
 666  ("s-c e r" . eval-region)
 667
 668  ("s-p"     . beginning-of-buffer)
 669  ("s-n"     . end-of-buffer))
 670 #+end_src
 671
 672 ** Packages
 673
 674 The packages in this section are absolutely essential to my everyday
 675 workflow, and they play key roles in how I do my computing. They
 676 immensely enhance the Emacs experience for me; both using Emacs, and
 677 customizing it.
 678
 679 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 680
 681 #+begin_src emacs-lisp
 682 (use-package auto-compile
 683   :demand t
 684   :config
 685   (auto-compile-on-load-mode)
 686   (auto-compile-on-save-mode)
 687   (setq auto-compile-display-buffer               nil
 688         auto-compile-mode-line-counter            t
 689         auto-compile-source-recreate-deletes-dest t
 690         auto-compile-toggle-deletes-nonlib-dest   t
 691         auto-compile-update-autoloads             t)
 692   (add-hook 'auto-compile-inhibit-compile-hook
 693             'auto-compile-inhibit-compile-detached-git-head))
 694 #+end_src
 695
 696 *** [[https://github.com/noctuid/general.el][general]]
 697
 698 #+begin_src emacs-lisp
 699 (use-package general
 700   :demand t
 701   :config
 702   (general-evil-setup t)
 703   (general-override-mode)
 704
 705   (general-create-definer
 706    amin--leader-keys
 707    :keymaps 'override
 708    :states '(emacs normal visual motion insert)
 709    :non-normal-prefix "M-m"
 710    :prefix "SPC"))
 711 #+end_src
 712
 713 *** [[https://github.com/emacs-evil/evil][evil]]
 714
 715 #+begin_src emacs-lisp
 716 (use-package evil
 717   :demand t
 718   ;; :hook (org-src-mode . evil-motion-state)
 719   :config
 720   (evil-mode 1)
 721   (general-swap-key nil '(normal motion) ";" ":")
 722
 723   (setq evil-want-visual-char-semi-exclusive t)
 724
 725   ;; custom mode state mappings
 726   (dolist (mspair '((ebdb-mode    . emacs)
 727                     (helpful-mode . motion)
 728                     (view-mode    . motion)))
 729     (evil-set-initial-state (car mspair) (cdr mspair)))
 730
 731   ;; fix tab and indentation in src blocks inside org-mode buffer
 732   ;; also see https://git.sr.ht/~bandali/dotfiles/commit/0e2ffd584aafdd4cf256bcdf2473f01c3aaaed55
 733   (unbind-key "TAB" evil-motion-state-map)
 734
 735   (unbind-key "C-d" evil-insert-state-map)
 736   (unbind-key "C-v" evil-insert-state-map)
 737   (unbind-key "C-y" evil-insert-state-map)
 738   (unbind-key "C-a" evil-insert-state-map)
 739   (unbind-key "C-e" evil-insert-state-map)
 740   (unbind-key "C-p" evil-insert-state-map)
 741   (unbind-key "C-n" evil-insert-state-map)
 742   (unbind-key "C-k" evil-insert-state-map)
 743   (bind-keys
 744     :map evil-insert-state-map
 745     ("C-k"   . kill-line)
 746     ("C-S-k" . evil-insert-digraph)
 747     :map evil-motion-state-map
 748     ([down-mouse-1] . nil)))
 749 #+end_src
 750
 751 #+begin_src emacs-lisp
 752 (use-package evil-escape
 753   :after evil
 754   :init
 755   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 756         evil-escape-excluded-major-modes '(neotree-mode)
 757         evil-escape-key-sequence "jk"
 758         evil-escape-delay 0.25)
 759   ;; :general
 760   ;; (:states '(insert replace visual operator)
 761   ;;          "C-g" #'evil-escape)
 762   :config
 763   (evil-escape-mode 1)
 764   ;; no `evil-escape' in minibuffer
 765   (push #'minibufferp evil-escape-inhibit-functions))
 766 #+end_src
 767
 768 #+begin_src emacs-lisp
 769 (use-package evil-nerd-commenter
 770   :after evil
 771   :general
 772   (nmap
 773     "gc" 'evilnc-comment-operator
 774     "gy" 'evilnc-copy-and-comment-lines))
 775 #+end_src
 776
 777 #+begin_src emacs-lisp
 778 (use-package evil-surround
 779   :after evil
 780   :general
 781   (omap
 782     "s" 'evil-surround-edit
 783     "S" 'evil-Surround-edit)
 784   (vmap
 785     "S" 'evil-surround-region
 786     "gS" 'evil-Surround-region))
 787 #+end_src
 788
 789 #+begin_src emacs-lisp
 790 (amin--leader-keys
 791   "/"   '(:ignore t :wk "search")
 792
 793   "a"   '(:ignore t :wk "apps")
 794   "a i" 'ielm
 795
 796   "b"   '(:ignore t :wk "buffers")
 797   "b k" 'kill-this-buffer
 798   "b s" 'save-buffer
 799
 800   "e"   '(:ignore t :wk "eval")
 801   "e b" 'eval-buffer
 802   "e r" 'eval-region
 803
 804   "f"   '(:ignore t :wk "files")
 805
 806   "F"   '(:ignore t :wk "frames")
 807   "F m" 'make-frame-command
 808   "F d" 'delete-frame
 809   "F D" 'delete-other-frames
 810
 811   "h"   '(:ignore t :wk "help(ful)")
 812   "h c" 'describe-char
 813   "h f" 'describe-function
 814   "h F" 'describe-face
 815   "h H" 'view-hello-file
 816   "h i" 'info
 817   "h k" 'describe-key
 818   "h l" 'view-lossage
 819   "h v" 'describe-variable
 820
 821   "o"   'other-window
 822
 823   "w"   '(:ignore t :wk "window")
 824   "w o" 'other-window
 825   "w 0" 'delete-window
 826   "w 1" 'delete-other-windows
 827   "w 2" 'split-window-below
 828   "w 3" 'split-window-right
 829   "w u" 'winner-undo
 830   "w r" 'winner-redo
 831
 832   "q"   '(:ignore t :wk "quit")
 833   "q q" 'save-buffers-kill-terminal)
 834 #+end_src
 835
 836 *** [[https://orgmode.org/][Org mode]]
 837
 838 #+begin_quote
 839 Org mode is for keeping notes, maintaining TODO lists, planning
 840 projects, and authoring documents with a fast and effective plain-text
 841 system.
 842 #+end_quote
 843
 844 In short, my favourite way of life.
 845
 846 #+begin_src emacs-lisp
 847 (use-package org
 848   :defer 3
 849   :general
 850   (amin--leader-keys
 851     :states 'normal
 852     :keymaps 'org-mode-map
 853     "'" 'org-edit-special)
 854   (amin--leader-keys
 855     :definer 'minor-mode
 856     :states 'normal
 857     :keymaps 'org-src-mode
 858     "'" 'org-edit-src-exit
 859     "k" 'org-edit-src-abort)
 860   (general-define-key
 861    :definer 'minor-mode
 862    :states 'normal
 863    :keymaps 'org-src-mode
 864    "q" 'org-edit-src-exit)
 865   :config
 866   (setq org-src-tab-acts-natively t
 867         org-src-preserve-indentation nil
 868         org-edit-src-content-indentation 0
 869         org-email-link-description-format "Email %c: %s" ; %.30s
 870         org-highlight-latex-and-related '(entities)
 871         org-log-done 'time)
 872   (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
 873   (after! org-src
 874     (define-key org-src-mode-map [remap evil-write] 'org-edit-src-save)
 875     (define-key org-src-mode-map [remap evil-save-and-close]
 876       (lambda () (interactive)
 877         (org-edit-src-save)
 878         (org-edit-src-exit)))
 879     (define-key org-src-mode-map [remap evil-save-modified-and-close]
 880       (lambda () (interactive)
 881         (org-edit-src-save)
 882         (org-edit-src-exit)))
 883     (define-key org-src-mode-map [remap evil-quit] 'org-edit-src-abort))
 884   (font-lock-add-keywords
 885    'org-mode
 886    '(("[ \t]*\\(#\\+\\(BEGIN\\|END\\|begin\\|end\\)_\\(\\S-+\\)\\)[ \t]*\\([^\n:]*\\)"
 887       (1 '(:foreground "#5a5b5a" :background "#292b2b") t) ; directive
 888       (3 '(:foreground "#81a2be" :background "#292b2b") t) ; kind
 889       (4 '(:foreground "#c5c8c6") t))) ; title
 890    t)
 891   :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
 892   :hook ((org-mode . org-indent-mode)
 893          (org-mode . auto-fill-mode)
 894          (org-mode . flyspell-mode))
 895   :custom
 896   (org-latex-packages-alist '(("" "listings") ("" "color")))
 897   :custom-face
 898   '(org-block-begin-line ((t (:foreground "#5a5b5a" :background "#1d1f21"))))
 899   '(org-block ((t (:background "#1d1f21"))))
 900   '(org-latex-and-related ((t (:foreground "#b294bb")))))
 901
 902 (use-package ox-latex
 903   :after ox
 904   :config
 905   (setq org-latex-listings 'listings
 906         ;; org-latex-prefer-user-labels t
 907         )
 908   (add-to-list 'org-latex-packages-alist '("" "listings"))
 909   (add-to-list 'org-latex-packages-alist '("" "color"))
 910   (add-to-list 'org-latex-classes
 911                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 912                  ("\\section{%s}" . "\\section*{%s}")
 913                  ("\\subsection{%s}" . "\\subsection*{%s}")
 914                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 915                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 916                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 917                t))
 918
 919 (use-package ox-beamer
 920   :after ox)
 921
 922 (use-package ob-tangle
 923   :general
 924   (amin--leader-keys
 925     :states 'normal
 926     :keymaps 'org-mode-map
 927     "b t" 'org-babel-tangle))
 928
 929 (use-package orgalist
 930   :after message
 931   :hook (message-mode . orgalist-mode))
 932 #+end_src
 933
 934 **** asynchronous tangle
 935
 936 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 937 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 938 file.
 939
 940 #+begin_src emacs-lisp
 941 (after! org
 942   (defvar amin-show-async-tangle-results nil
 943     "Keep *emacs* async buffers around for later inspection.")
 944
 945   (defvar amin-show-async-tangle-time nil
 946     "Show the time spent tangling the file.")
 947
 948   (defvar amin-async-tangle-post-compile "make ti"
 949     "If non-nil, pass to `compile' after successful tangle.")
 950
 951   (defun amin/async-babel-tangle ()
 952     "Tangle org file asynchronously."
 953     (interactive)
 954     (let* ((file-tangle-start-time (current-time))
 955            (file (buffer-file-name))
 956            (file-nodir (file-name-nondirectory file))
 957            (async-quiet-switch "-q"))
 958       (async-start
 959        `(lambda ()
 960           (require 'org)
 961           (org-babel-tangle-file ,file))
 962        (unless amin-show-async-tangle-results
 963          `(lambda (result)
 964             (if result
 965                 (progn
 966                   (message "Tangled %s%s"
 967                            ,file-nodir
 968                            (if amin-show-async-tangle-time
 969                                (format " (%.3fs)"
 970                                        (float-time (time-subtract (current-time)
 971                                                                   ',file-tangle-start-time)))
 972                              ""))
 973                   (when amin-async-tangle-post-compile
 974                     (compile amin-async-tangle-post-compile)))
 975               (message "Tangling %s failed" ,file-nodir))))))))
 976
 977 (add-to-list
 978  'safe-local-variable-values
 979  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 980 #+end_src
 981
 982 *** [[https://magit.vc/][Magit]]
 983
 984 #+begin_quote
 985 It's Magit! A Git porcelain inside Emacs.
 986 #+end_quote
 987
 988 Not just how I do git, but /the/ way to do git.
 989
 990 #+begin_src emacs-lisp
 991 (use-package magit
 992   :defer 2
 993   :general (amin--leader-keys "g s" 'magit-status)
 994   :bind ("s-g" . magit-status)
 995   :config
 996   (magit-add-section-hook 'magit-status-sections-hook
 997                           'magit-insert-modules
 998                           'magit-insert-stashes
 999                           'append)
1000   (setq
1001    magit-repository-directories '(("~/.emacs.d/" . 0)
1002                                   ("~/src/git/" . 1)))
1003   (nconc magit-section-initial-visibility-alist
1004          '(([unpulled status] . show)
1005            ([unpushed status] . show)))
1006   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
1007 #+end_src
1008
1009 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
1010
1011 #+begin_quote
1012 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
1013 an overview, and more. Oh, man!
1014 #+end_quote
1015
1016 There's no way I could top that, so I won't attempt to.
1017
1018 **** Ivy
1019
1020 #+begin_src emacs-lisp
1021 (use-package ivy
1022   :defer 1
1023   :general (amin--leader-keys "," 'ivy-switch-buffer)
1024   :bind
1025   (:map ivy-minibuffer-map
1026    ([escape] . keyboard-escape-quit)
1027    ([S-up]   . ivy-previous-history-element)
1028    ([S-down] . ivy-next-history-element)
1029    ("DEL"    . ivy-backward-delete-char))
1030   :config
1031   (setq ivy-wrap t)
1032   (ivy-mode 1)
1033   ;; :custom-face
1034   ;; (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
1035   ;; (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
1036   ;; (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold))))
1037 )
1038 #+end_src
1039
1040 **** Swiper
1041
1042 #+begin_src emacs-lisp
1043 (use-package swiper
1044   :general (:states '(normal motion) "/" 'swiper)
1045   :bind (("C-s" . swiper)
1046          ("C-r" . swiper)))
1047 #+end_src
1048
1049 **** Counsel
1050
1051 #+begin_src emacs-lisp
1052 (use-package counsel
1053   :defer 1
1054   :general
1055   (amin--leader-keys
1056     "r" 'counsel-recentf
1057     "SPC" 'counsel-M-x
1058     "."   'counsel-find-file)
1059   :bind (([remap execute-extended-command] . counsel-M-x)
1060          ([remap find-file]                . counsel-find-file)
1061          ("s-r"                            . counsel-recentf)
1062          ("C-c x"                          . counsel-M-x)
1063          ("C-c f ."                        . counsel-find-file)
1064          :map minibuffer-local-map
1065          ("C-r" . counsel-minibuffer-history))
1066   :config
1067   (counsel-mode 1)
1068   (defalias 'locate #'counsel-locate))
1069 #+end_src
1070
1071 *** eshell
1072
1073 #+begin_src emacs-lisp
1074 (use-package eshell
1075   :defer 1
1076   :commands eshell
1077   :config
1078   (eval-when-compile (defvar eshell-prompt-regexp))
1079   (defun amin/eshell-quit-or-delete-char (arg)
1080     (interactive "p")
1081     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
1082         (eshell-life-is-too-much)
1083       (delete-char arg)))
1084
1085   (defun amin/eshell-clear ()
1086     (interactive)
1087     (let ((inhibit-read-only t))
1088       (erase-buffer))
1089     (eshell-send-input))
1090
1091   (defun amin|eshell-setup ()
1092     (bind-keys :map eshell-mode-map
1093                ("C-d" . amin/eshell-quit-or-delete-char)
1094                ("C-l" . amin/eshell-clear)))
1095
1096   :hook (eshell-mode . amin|eshell-setup))
1097 #+end_src
1098
1099 *** Ibuffer
1100
1101 #+begin_src emacs-lisp
1102 (use-package ibuffer
1103   :defer t
1104   :general (amin--leader-keys "b b" 'ibuffer-other-window)
1105   :bind
1106   (("C-x C-b" . ibuffer-other-window)
1107    :map ibuffer-mode-map
1108    ("P"   . ibuffer-backward-filter-group)
1109    ("N"   . ibuffer-forward-filter-group)
1110    ("M-p" . ibuffer-do-print)
1111    ("M-n" . ibuffer-do-shell-command-pipe-replace))
1112   :config
1113   ;; Use human readable Size column instead of original one
1114   (define-ibuffer-column size-h
1115     (:name "Size" :inline t)
1116     (cond
1117      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
1118      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
1119      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
1120      (t (format "%8d" (buffer-size)))))
1121   :custom
1122   (ibuffer-saved-filter-groups
1123    '(("default"
1124       ("dired" (mode . dired-mode))
1125       ("org"   (mode . org-mode))
1126       ("web"
1127        (or
1128         (mode . web-mode)
1129         (mode . css-mode)
1130         (mode . scss-mode)
1131         (mode . js2-mode)))
1132       ("shell"
1133        (or
1134         (mode . eshell-mode)
1135         (mode . shell-mode)))
1136       ("notmuch" (name . "\*notmuch\*"))
1137       ("programming"
1138        (or
1139         (mode . python-mode)
1140         (mode . c++-mode)
1141         (mode . emacs-lisp-mode)))
1142       ("emacs"
1143        (or
1144         (name . "^\\*scratch\\*$")
1145         (name . "^\\*Messages\\*$")))
1146       ("slack"
1147        (or
1148         (name . "^\\*Slack*"))))))
1149   (ibuffer-formats
1150    '((mark modified read-only locked " "
1151            (name 18 18 :left :elide)
1152            " "
1153            (size-h 9 -1 :right)
1154            " "
1155            (mode 16 16 :left :elide)
1156            " " filename-and-process)
1157      (mark " "
1158            (name 16 -1)
1159            " " filename)))
1160   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
1161 #+end_src
1162
1163 *** Outline
1164
1165 #+begin_src emacs-lisp
1166 (use-package outline
1167   :defer t
1168   :hook (prog-mode . outline-minor-mode)
1169   :bind
1170   (:map
1171    outline-minor-mode-map
1172    ("<s-tab>"  . outline-toggle-children)
1173    ("M-p"      . outline-previous-visible-heading)
1174    ("M-n"      . outline-next-visible-heading)
1175    :prefix-map amin--outline-prefix-map
1176    :prefix "s-o"
1177    ("TAB" . outline-toggle-children)
1178    ("a"   . outline-hide-body)
1179    ("H"   . outline-hide-body)
1180    ("S"   . outline-show-all)
1181    ("h"   . outline-hide-subtree)
1182    ("s"   . outline-show-subtree)))
1183 #+end_src
1184
1185 * Borg's =layer/essentials=
1186
1187 TODO: break this giant source block down into individual org sections.
1188
1189 #+begin_src emacs-lisp
1190 (use-package dash
1191   :config (dash-enable-font-lock))
1192
1193 (use-package diff-hl
1194   :config
1195   (setq diff-hl-draw-borders nil)
1196   (global-diff-hl-mode)
1197   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
1198
1199 (use-package dired
1200   :defer t
1201   :config (setq dired-listing-switches "-alh"))
1202
1203 (use-package eldoc
1204   :when (version< "25" emacs-version)
1205   :config (global-eldoc-mode))
1206
1207 (use-package help
1208   :defer t
1209   :config
1210   (temp-buffer-resize-mode)
1211   (setq help-window-select t))
1212
1213 (progn ;    `isearch'
1214   (setq isearch-allow-scroll t))
1215
1216 (use-package lisp-mode
1217   :config
1218   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1219   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1220   (defun indent-spaces-mode ()
1221     (setq indent-tabs-mode nil))
1222   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1223
1224 (use-package man
1225   :defer t
1226   :config (setq Man-width 80))
1227
1228 (use-package paren
1229   :config (show-paren-mode))
1230
1231 (use-package prog-mode
1232   :config (global-prettify-symbols-mode)
1233   (defun indicate-buffer-boundaries-left ()
1234     (setq indicate-buffer-boundaries 'left))
1235   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1236
1237 (use-package recentf
1238   :defer 0.5
1239   :config
1240   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1241   (setq recentf-max-saved-items 40))
1242
1243 (use-package savehist
1244   :config (savehist-mode))
1245
1246 (use-package saveplace
1247   :when (version< "25" emacs-version)
1248   :config (save-place-mode))
1249
1250 (use-package simple
1251   :config (column-number-mode))
1252
1253 (progn ;    `text-mode'
1254   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1255
1256 (use-package tramp
1257   :defer t
1258   :config
1259   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1260   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1261   (add-to-list 'tramp-default-proxies-alist
1262                (list (regexp-quote (system-name)) nil nil)))
1263
1264 (use-package undo-tree
1265   :config
1266   (global-undo-tree-mode -1))
1267   ;; :bind (("C-?" . undo-tree-undo)
1268   ;;        ("M-_" . undo-tree-redo))
1269   ;; :config
1270   ;; (global-undo-tree-mode)
1271   ;; (setq undo-tree-mode-lighter ""
1272   ;;       undo-tree-auto-save-history t))
1273 #+end_src
1274
1275 * Editing
1276
1277 ** Company
1278
1279 #+begin_src emacs-lisp
1280 (use-package company
1281   :defer 2
1282   :bind
1283   (:map company-active-map
1284         ([tab]    . company-complete-common-or-cycle)
1285         ([escape] . company-abort))
1286   :custom
1287   (company-idle-delay 0.3)
1288   (company-minimum-prefix-length 1)
1289   (company-selection-wrap-around t)
1290   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1291   (company-dabbrev-downcase nil)
1292   (company-dabbrev-ignore-case nil)
1293   :config
1294   (global-company-mode t))
1295 #+end_src
1296
1297 * Syntax and spell checking
1298 #+begin_src emacs-lisp
1299 (use-package flycheck
1300   :defer 3
1301   :hook (prog-mode . flycheck-mode)
1302   :bind
1303   (:map flycheck-mode-map
1304         ("M-P" . flycheck-previous-error)
1305         ("M-N" . flycheck-next-error))
1306   :config
1307   ;; Use the load-path from running Emacs when checking elisp files
1308   (setq flycheck-emacs-lisp-load-path 'inherit)
1309
1310   ;; Only flycheck when I actually save the buffer
1311   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1312
1313 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1314 (use-package ispell
1315   :defer 3
1316   :config
1317   ;; ’ can be part of a word
1318   (setq ispell-local-dictionary-alist
1319         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1320                "['\x2019]" nil ("-B") nil utf-8)))
1321   ;; don't send ’ to the subprocess
1322   (defun endless/replace-apostrophe (args)
1323     (cons (replace-regexp-in-string
1324            "’" "'" (car args))
1325           (cdr args)))
1326   (advice-add #'ispell-send-string :filter-args
1327               #'endless/replace-apostrophe)
1328
1329   ;; convert ' back to ’ from the subprocess
1330   (defun endless/replace-quote (args)
1331     (if (not (derived-mode-p 'org-mode))
1332         args
1333       (cons (replace-regexp-in-string
1334              "'" "’" (car args))
1335             (cdr args))))
1336   (advice-add #'ispell-parse-output :filter-args
1337               #'endless/replace-quote))
1338 #+end_src
1339 * Programming modes
1340
1341 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1342
1343 #+begin_src emacs-lisp
1344 (use-package alloy-mode
1345   :defer t
1346   :config (setq alloy-basic-offset 2))
1347 #+end_src
1348
1349 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1350
1351 #+begin_src emacs-lisp
1352 (use-package proof-site  ; Proof General
1353   :defer t
1354   :load-path "lib/proof-site/generic/")
1355 #+end_src
1356
1357 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1358
1359 #+begin_src emacs-lisp
1360 (eval-when-compile (defvar lean-mode-map))
1361 (use-package lean-mode
1362   :defer 1
1363   :bind (:map lean-mode-map
1364               ("S-SPC" . company-complete))
1365   :config
1366   (require 'lean-input)
1367   (setq default-input-method "Lean"
1368         lean-input-tweak-all '(lean-input-compose
1369                                (lean-input-prepend "/")
1370                                (lean-input-nonempty))
1371         lean-input-user-translations '(("/" "/")))
1372   (lean-input-setup))
1373   #+end_src
1374
1375 ** Haskell
1376
1377 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1378
1379 #+begin_src emacs-lisp
1380 (use-package haskell-mode
1381   :defer t
1382   :config
1383   (setq haskell-indentation-layout-offset 4
1384         haskell-indentation-left-offset 4
1385         flycheck-checker 'haskell-hlint
1386         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1387 #+end_src
1388
1389 *** [[https://github.com/jyp/dante][dante]]
1390
1391 #+begin_src emacs-lisp
1392 (use-package dante
1393   :after haskell-mode
1394   :commands dante-mode
1395   :hook (haskell-mode . dante-mode))
1396 #+end_src
1397
1398 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1399
1400 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1401 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1402
1403 #+begin_src emacs-lisp
1404 (use-package hlint-refactor
1405   :after haskell-mode
1406   :bind (:map hlint-refactor-mode-map
1407               ("C-c l b" . hlint-refactor-refactor-buffer)
1408               ("C-c l r" . hlint-refactor-refactor-at-point))
1409   :hook (haskell-mode . hlint-refactor-mode))
1410 #+end_src
1411
1412 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1413
1414 #+begin_src emacs-lisp
1415 (use-package flycheck-haskell
1416   :after haskell-mode)
1417 #+end_src
1418
1419 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1420 :PROPERTIES:
1421 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1422 :END:
1423
1424 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1425 instead.
1426
1427 #+begin_src emacs-lisp :tangle no
1428 ;;; hs-lint.el --- minor mode for HLint code checking
1429
1430 ;; Copyright 2009 (C) Alex Ott
1431 ;;
1432 ;; Author: Alex Ott <alexott@gmail.com>
1433 ;; Keywords: haskell, lint, HLint
1434 ;; Requirements:
1435 ;; Status: distributed under terms of GPL2 or above
1436
1437 ;; Typical message from HLint looks like:
1438 ;;
1439 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1440 ;; Found:
1441 ;;   count1 p l = length (filter p l)
1442 ;; Why not:
1443 ;;   count1 p = length . filter p
1444
1445
1446 (require 'compile)
1447
1448 (defgroup hs-lint nil
1449   "Run HLint as inferior of Emacs, parse error messages."
1450   :group 'tools
1451   :group 'haskell)
1452
1453 (defcustom hs-lint-command "hlint"
1454   "The default hs-lint command for \\[hlint]."
1455   :type 'string
1456   :group 'hs-lint)
1457
1458 (defcustom hs-lint-save-files t
1459   "Save modified files when run HLint or no (ask user)"
1460   :type 'boolean
1461   :group 'hs-lint)
1462
1463 (defcustom hs-lint-replace-with-suggestions nil
1464   "Replace user's code with suggested replacements"
1465   :type 'boolean
1466   :group 'hs-lint)
1467
1468 (defcustom hs-lint-replace-without-ask nil
1469   "Replace user's code with suggested replacements automatically"
1470   :type 'boolean
1471   :group 'hs-lint)
1472
1473 (defun hs-lint-process-setup ()
1474   "Setup compilation variables and buffer for `hlint'."
1475   (run-hooks 'hs-lint-setup-hook))
1476
1477 ;; regex for replace suggestions
1478 ;;
1479 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1480 ;; Found:
1481 ;; \s +\(.*\)
1482 ;; Why not:
1483 ;; \s +\(.*\)
1484
1485 (defvar hs-lint-regex
1486   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1487   "Regex for HLint messages")
1488
1489 (defun make-short-string (str maxlen)
1490   (if (< (length str) maxlen)
1491       str
1492     (concat (substring str 0 (- maxlen 3)) "...")))
1493
1494 (defun hs-lint-replace-suggestions ()
1495   "Perform actual replacement of suggestions"
1496   (goto-char (point-min))
1497   (while (re-search-forward hs-lint-regex nil t)
1498     (let* ((fname (match-string 1))
1499           (fline (string-to-number (match-string 2)))
1500           (old-code (match-string 4))
1501           (new-code (match-string 5))
1502           (msg (concat "Replace '" (make-short-string old-code 30)
1503                        "' with '" (make-short-string new-code 30) "'"))
1504           (bline 0)
1505           (eline 0)
1506           (spos 0)
1507           (new-old-code ""))
1508       (save-excursion
1509         (switch-to-buffer (get-file-buffer fname))
1510         (goto-char (point-min))
1511         (forward-line (1- fline))
1512         (beginning-of-line)
1513         (setf bline (point))
1514         (when (or hs-lint-replace-without-ask
1515                   (yes-or-no-p msg))
1516           (end-of-line)
1517           (setf eline (point))
1518           (beginning-of-line)
1519           (setf old-code (regexp-quote old-code))
1520           (while (string-match "\\\\ " old-code spos)
1521             (setf new-old-code (concat new-old-code
1522                                  (substring old-code spos (match-beginning 0))
1523                                  "\\ *"))
1524             (setf spos (match-end 0)))
1525           (setf new-old-code (concat new-old-code (substring old-code spos)))
1526           (remove-text-properties bline eline '(composition nil))
1527           (when (re-search-forward new-old-code eline t)
1528             (replace-match new-code nil t)))))))
1529
1530 (defun hs-lint-finish-hook (buf msg)
1531   "Function, that is executed at the end of HLint execution"
1532   (if hs-lint-replace-with-suggestions
1533       (hs-lint-replace-suggestions)
1534       (next-error 1 t)))
1535
1536 (define-compilation-mode hs-lint-mode "HLint"
1537   "Mode for check Haskell source code."
1538   (set (make-local-variable 'compilation-process-setup-function)
1539        'hs-lint-process-setup)
1540   (set (make-local-variable 'compilation-disable-input) t)
1541   (set (make-local-variable 'compilation-scroll-output) nil)
1542   (set (make-local-variable 'compilation-finish-functions)
1543        (list 'hs-lint-finish-hook))
1544   )
1545
1546 (defun hs-lint ()
1547   "Run HLint for current buffer with haskell source"
1548   (interactive)
1549   (save-some-buffers hs-lint-save-files)
1550   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1551                      'hs-lint-mode))
1552
1553 (provide 'hs-lint)
1554 ;;; hs-lint.el ends here
1555 #+end_src
1556
1557 #+begin_src emacs-lisp :tangle no
1558 (use-package hs-lint
1559   :load-path "lisp/"
1560   :bind (:map haskell-mode-map
1561               ("C-c l l" . hs-lint)))
1562 #+end_src
1563
1564 ** Web dev
1565
1566 *** SGML and HTML
1567
1568 #+begin_src emacs-lisp
1569 (use-package sgml-mode
1570   :defer t
1571   :config
1572   (setq sgml-basic-offset 2))
1573 #+end_src
1574
1575 *** CSS and SCSS
1576
1577 #+begin_src emacs-lisp
1578 (use-package css-mode
1579   :defer t
1580   :config
1581   (setq css-indent-offset 2))
1582 #+end_src
1583
1584 *** Web mode
1585
1586 #+begin_src emacs-lisp
1587 (use-package web-mode
1588   :defer t
1589   :mode "\\.html\\'"
1590   :config
1591   (setq-every! 2
1592     web-mode-code-indent-offset
1593     web-mode-css-indent-offset
1594     web-mode-markup-indent-offset))
1595 #+end_src
1596
1597 *** Emmet mode
1598
1599 #+begin_src emacs-lisp
1600 (use-package emmet-mode
1601   :after (:any web-mode css-mode sgml-mode)
1602   :bind* (("C-)" . emmet-next-edit-point)
1603           ("C-(" . emmet-prev-edit-point))
1604   :config
1605   (unbind-key "C-j" emmet-mode-keymap)
1606   (setq emmet-move-cursor-between-quotes t)
1607   :hook (web-mode css-mode html-mode sgml-mode))
1608 #+end_src
1609
1610 ** Nix
1611
1612 #+begin_src emacs-lisp
1613 (use-package nix-mode
1614   :defer t
1615   :mode "\\.nix\\'")
1616 #+end_src
1617
1618 ** Java
1619
1620 *** meghanada
1621
1622 #+begin_src emacs-lisp :tangle no
1623 (use-package meghanada
1624   :bind
1625   (:map meghanada-mode-map
1626         (("C-M-o" . meghanada-optimize-import)
1627          ("C-M-t" . meghanada-import-all)))
1628   :hook (java-mode . meghanada-mode))
1629 #+end_src
1630
1631 *** lsp-java
1632
1633 #+begin_comment
1634 dependencies:
1635
1636 ace-window
1637 avy
1638 bui
1639 company-lsp
1640 dap-mode
1641 lsp-java
1642 lsp-mode
1643 lsp-ui
1644 pfuture
1645 tree-mode
1646 treemacs
1647 #+end_comment
1648
1649 #+begin_src emacs-lisp :tangle no
1650 (use-package treemacs
1651   :config (setq treemacs-never-persist t))
1652
1653 (use-package yasnippet
1654   :config
1655   ;; (yas-global-mode)
1656   )
1657
1658 (use-package lsp-mode
1659   :init (setq lsp-eldoc-render-all nil
1660               lsp-highlight-symbol-at-point nil)
1661   )
1662
1663 (use-package hydra)
1664
1665 (use-package company-lsp
1666   :after  company
1667   :config
1668   (setq company-lsp-cache-candidates t
1669         company-lsp-async t))
1670
1671 (use-package lsp-ui
1672   :config
1673   (setq lsp-ui-sideline-update-mode 'point))
1674
1675 (use-package lsp-java
1676   :config
1677   (add-hook 'java-mode-hook
1678             (lambda ()
1679               (setq-local company-backends (list 'company-lsp))))
1680
1681   (add-hook 'java-mode-hook 'lsp-java-enable)
1682   (add-hook 'java-mode-hook 'flycheck-mode)
1683   (add-hook 'java-mode-hook 'company-mode)
1684   (add-hook 'java-mode-hook 'lsp-ui-mode))
1685
1686 (use-package dap-mode
1687   :after lsp-mode
1688   :config
1689   (dap-mode t)
1690   (dap-ui-mode t))
1691
1692 (use-package dap-java
1693   :after (lsp-java))
1694
1695 (use-package lsp-java-treemacs
1696   :after (treemacs))
1697 #+end_src
1698
1699 * Emacs Enhancements
1700
1701 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1702
1703 #+begin_quote
1704 Emacs package that displays available keybindings in popup
1705 #+end_quote
1706
1707 #+begin_src emacs-lisp
1708 (use-package which-key
1709   :defer 1
1710   :config (which-key-mode))
1711 #+end_src
1712
1713 ** theme
1714
1715 #+begin_src emacs-lisp
1716 (add-to-list 'custom-theme-load-path "~/.emacs.d/lisp")
1717 (load-theme 'tangomod t)
1718 #+end_src
1719
1720 ** COMMENT [[https://github.com/Malabarba/smart-mode-line][smart-mode-line]]
1721
1722 #+begin_src emacs-lisp
1723 (use-package smart-mode-line
1724   :config
1725   (sml/setup)
1726   (sml/apply-theme 'light)
1727   (remove-hook 'display-time-hook 'sml/propertize-time-string))
1728 #+end_src
1729
1730 ** doom-modeline
1731
1732 #+begin_src emacs-lisp
1733 (use-package doom-modeline
1734   :demand t
1735   :config (setq doom-modeline-height 32)
1736   :hook (after-init . doom-modeline-init))
1737 #+end_src
1738
1739 ** doom-themes
1740
1741 #+begin_src emacs-lisp
1742 (use-package doom-themes)
1743 #+end_src
1744
1745 ** theme helper functions
1746
1747 #+begin_src emacs-lisp
1748 (defun amin/lights-on ()
1749   "Enable my favourite light theme."
1750   (interactive)
1751   (progn
1752     (mapc #'disable-theme custom-enabled-themes)
1753     (load-theme 'tangomod t)))
1754
1755 (defun amin/lights-off ()
1756   "Go dark."
1757   (interactive)
1758   (progn
1759     (mapc #'disable-theme custom-enabled-themes)
1760     (load-theme 'doom-tomorrow-night t)))
1761
1762 (amin--leader-keys
1763   "t"   '(:ignore t :wk "theme")
1764   "t d" 'amin/lights-off
1765   "t l" 'amin/lights-on)
1766 #+end_src
1767
1768 ** [[https://github.com/bbatsov/crux][crux]]
1769
1770 #+begin_src emacs-lisp
1771 (use-package crux
1772   :defer 1
1773   :general
1774   (amin--leader-keys
1775     "b K" 'crux-kill-other-buffers
1776     "c d" 'crux-duplicate-current-line-or-region
1777     "c D" 'crux-duplicate-and-comment-current-line-or-region
1778     "f c" 'crux-copy-file-preserve-attributes
1779     "f d" 'crux-delete-file-and-buffer
1780     "f r" 'crux-rename-file-and-buffer)
1781   :bind (("C-c d" . crux-duplicate-current-line-or-region)
1782          ("C-c D" . crux-duplicate-and-comment-current-line-or-region)
1783          ("C-S-j" . crux-top-join-line)
1784          ("C-c j" . crux-top-join-line)))
1785 #+end_src
1786
1787 ** [[https://github.com/alezost/mwim.el][mwim]]
1788
1789 #+begin_src emacs-lisp
1790 (use-package mwim
1791   :general
1792   (:states '(normal visual)
1793            "0" 'mwim-beginning-of-code-or-line
1794            "$" 'mwim-end-of-code-or-line)
1795   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1796          ("C-e"    . mwim-end-of-code-or-line)
1797          ("<home>" . mwim-beginning-of-line-or-code)
1798          ("<end>"  . mwim-end-of-line-or-code)))
1799 #+end_src
1800
1801 ** projectile
1802
1803 #+begin_src emacs-lisp
1804 (use-package projectile
1805   :defer 2
1806   :bind-keymap ("C-c p" . projectile-command-map)
1807   :config
1808   (projectile-mode)
1809
1810   (defun my-projectile-invalidate-cache (&rest _args)
1811     ;; ignore the args to `magit-checkout'
1812     (projectile-invalidate-cache nil))
1813
1814   (eval-after-load 'magit-branch
1815     '(progn
1816        (advice-add 'magit-checkout
1817                    :after #'my-projectile-invalidate-cache)
1818        (advice-add 'magit-branch-and-checkout
1819                    :after #'my-projectile-invalidate-cache))))
1820 #+end_src
1821
1822 ** [[https://github.com/Wilfred/helpful][helpful]]
1823
1824 #+begin_src emacs-lisp
1825 (use-package helpful
1826   :defer 1
1827   :general
1828   (amin--leader-keys
1829     "h h"   '(:ignore t :wk "helpful")
1830     "h h c" 'helpful-command
1831     "h h f" 'helpful-callable           ; helpful-function
1832     "h h v" 'helpful-variable
1833     "h h k" 'helpful-key
1834     "h h p" 'helpful-at-point))
1835 #+end_src
1836
1837 ** [[https://github.com/knu/shell-toggle.el][shell-toggle]]
1838
1839 #+begin_src emacs-lisp
1840 (use-package shell-toggle
1841   :after eshell
1842   :general (amin--leader-keys "a s" 'amin/shell-toggle)
1843   :bind ("C-c e" . amin/shell-toggle)
1844   :config
1845   (defun amin/shell-toggle (make-cd)
1846     "Toggle between the shell buffer and whatever buffer you are editing.
1847 With a prefix argument MAKE-CD also insert a \"cd DIR\" command
1848 into the shell, where DIR is the directory of the current buffer.
1849
1850 When called in the shell buffer returns you to the buffer you were editing
1851 before calling this the first time.
1852
1853 Options: `shell-toggle-goto-eob'"
1854     (interactive "P")
1855     ;; Try to decide on one of three possibilities:
1856     ;; If not in shell-buffer, switch to it.
1857     ;; If in shell-buffer, return to state before going to the shell-buffer
1858     (if (eq (current-buffer) shell-toggle-shell-buffer)
1859         (shell-toggle-buffer-return-from-shell)
1860       (progn
1861         (shell-toggle-buffer-goto-shell make-cd)
1862         (if shell-toggle-full-screen-window-only (delete-other-windows)))))
1863
1864   ;; override to split horizontally instead
1865   (defun shell-toggle-buffer-switch-to-other-window ()
1866     "Switch to other window.
1867 If the current window is the only window in the current frame,
1868 create a new window and switch to it.
1869
1870 \(This is less intrusive to the current window configuration than
1871 `switch-buffer-other-window')"
1872     (let ((this-window (selected-window)))
1873       (other-window 1)
1874       ;; If we did not switch window then we only have one window and need to
1875       ;; create a new one.
1876       (if (eq this-window (selected-window))
1877               (progn
1878                 (split-window-horizontally)
1879             (other-window 1)))))
1880
1881   :custom
1882   (shell-toggle-launch-shell 'shell-toggle-eshell))
1883 #+end_src
1884
1885 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1886
1887 Make =*scratch*= and =*Messages*= unkillable.
1888
1889 #+begin_src emacs-lisp
1890 (use-package unkillable-scratch
1891   :defer 3
1892   :config
1893   (unkillable-scratch 1)
1894   :custom
1895   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1896 #+end_src
1897
1898 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1899
1900 #+begin_example
1901 ,----
1902 | make pretty boxed quotes like this
1903 `----
1904 #+end_example
1905
1906 #+begin_src emacs-lisp
1907 (use-package boxquote
1908   :defer 3
1909   :bind
1910   (:prefix-map amin--boxquote-prefix-map
1911    :prefix "C-c q"
1912    ("b"   . boxquote-buffer)
1913    ("B"   . boxquote-insert-buffer)
1914    ("d"   . boxquote-defun)
1915    ("F"   . boxquote-insert-file)
1916    ("hf"  . boxquote-describe-function)
1917    ("hk"  . boxquote-describe-key)
1918    ("hv"  . boxquote-describe-variable)
1919    ("hw"  . boxquote-where-is)
1920    ("k"   . boxquote-kill)
1921    ("p"   . boxquote-paragraph)
1922    ("q"   . boxquote-boxquote)
1923    ("r"   . boxquote-region)
1924    ("s"   . boxquote-shell-command)
1925    ("t"   . boxquote-text)
1926    ("T"   . boxquote-title)
1927    ("u"   . boxquote-unbox)
1928    ("U"   . boxquote-unbox-region)
1929    ("y"   . boxquote-yank)
1930    ("M-q" . boxquote-fill-paragraph)
1931    ("M-w" . boxquote-kill-ring-save)))
1932 #+end_src
1933
1934 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1935
1936 ** COMMENT [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]                                 :ARCHIVE:
1937
1938 #+begin_src emacs-lisp
1939 (use-package highlight-indent-guides
1940   :defer 3
1941   :hook ((prog-mode . highlight-indent-guides-mode)
1942          ;; (org-mode  . highlight-indent-guides-mode)
1943          )
1944   :config
1945   (setq highlight-indent-guides-character ?\|)
1946   (setq highlight-indent-guides-auto-enabled nil)
1947   (setq highlight-indent-guides-method 'character)
1948   (setq highlight-indent-guides-responsive 'top)
1949   (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
1950   (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
1951 #+end_src
1952
1953 ** pdf-tools
1954
1955 #+begin_src emacs-lisp
1956 (use-package pdf-tools
1957   :defer t
1958   :magic ("%PDF" . pdf-view-mode)
1959   :config
1960   (setq pdf-view-resize-factor 1.05)
1961   (pdf-tools-install)
1962   :bind
1963   (:map pdf-view-mode-map
1964         ("C-s" . isearch-forward)
1965         ("C-r" . isearch-backward)
1966         ("j"   . pdf-view-next-line-or-next-page)
1967         ("k"   . pdf-view-previous-line-or-previous-page)
1968         ("h"   . image-backward-hscroll)
1969         ("l"   . image-forward-hscroll)))
1970 #+end_src
1971
1972 ** anzu
1973
1974 #+begin_src emacs-lisp
1975 (use-package anzu)
1976 #+end_src
1977
1978 ** typo.el
1979
1980 #+begin_src emacs-lisp
1981 (use-package typo
1982   :defer 2
1983   :config
1984   (typo-global-mode 1)
1985   :hook (text-mode . typo-mode))
1986 #+end_src
1987
1988 ** slack
1989
1990 Hopefully temporary.
1991
1992 #+begin_src emacs-lisp
1993 (use-package slack
1994   :commands (slack-start)
1995   :init
1996   (eval-when-compile                    ; silence the byte-compiler
1997     (defvar url-http-data nil)
1998     (defvar url-http-extra-headers nil)
1999     (defvar url-http-method nil)
2000     (defvar url-callback-function nil)
2001     (defvar url-callback-arguments nil)
2002     (defvar oauth--token-data nil))
2003   (setq slack-buffer-emojify t
2004         slack-prefer-current-team t)
2005   :config
2006   (slack-register-team
2007    :name "uw-apv"
2008    :default t
2009    :client-id uw-apv-client-id
2010    :client-secret uw-apv-client-secret
2011    :token uw-apv-token
2012    :subscribed-channels '(general)
2013    :full-and-display-names t)
2014   (slack-register-team
2015    :name "watform"
2016    :default nil
2017    :client-id watform-client-id
2018    :client-secret watform-client-secret
2019    :token watform-token
2020    :subscribed-channels '(general)
2021    :full-and-display-names t)
2022   (add-to-list 'swiper-font-lock-exclude 'slack-message-buffer-mode t)
2023   (setq lui-time-stamp-format "[%Y-%m-%d %H:%M:%S]"
2024         lui-time-stamp-only-when-changed-p t
2025         lui-time-stamp-position 'right)
2026   :bind
2027   (("C-c s s" . slack-start)
2028    ("C-c s u" . slack-select-unread-rooms)
2029    ("C-c s b" . slack-select-rooms)
2030    ("C-c s t" . slack-change-current-team)
2031    ("C-c s c" . slack-ws-close)
2032    :map slack-mode-map
2033    ("M-p"     . slack-buffer-goto-prev-message)
2034    ("M-n"     . slack-buffer-goto-next-message)
2035    ("C-c e"   . slack-message-edit)
2036    ("C-c k"   . slack-message-delete)
2037    ("C-c C-k" . slack-channel-leave)
2038    ("C-c r a" . slack-message-add-reaction)
2039    ("C-c r r" . slack-message-remove-reaction)
2040    ("C-c r s" . slack-message-show-reaction-users)
2041    ("C-c p l" . slack-room-pins-list)
2042    ("C-c p a" . slack-message-pins-add)
2043    ("C-c p r" . slack-message-pins-remove)
2044    ("@"       . slack-message-embed-mention)
2045    ("#"       . slack-message-embed-channel)))
2046
2047 (use-package alert
2048   :commands (alert)
2049   :init
2050   (setq alert-default-style 'notifier))
2051 #+end_src
2052
2053 ** hl-todo
2054
2055 #+begin_src emacs-lisp
2056 (use-package hl-todo
2057   :defer 4
2058   :config
2059   (global-hl-todo-mode))
2060 #+end_src
2061
2062 ** shrink-path
2063
2064 #+begin_src emacs-lisp
2065 (use-package shrink-path
2066   :after eshell
2067   :config
2068   (setq eshell-prompt-regexp "\\(.*\n\\)*λ "
2069         eshell-prompt-function #'+eshell/prompt)
2070
2071   (defun +eshell/prompt ()
2072     (let ((base/dir (shrink-path-prompt default-directory)))
2073       (concat (propertize (car base/dir)
2074                           'face 'font-lock-comment-face)
2075               (propertize (cdr base/dir)
2076                           'face 'font-lock-constant-face)
2077               (propertize (+eshell--current-git-branch)
2078                           'face 'font-lock-function-name-face)
2079               "\n"
2080               (propertize "λ" 'face 'eshell-prompt-face)
2081               ;; needed for the input text to not have prompt face
2082               (propertize " " 'face 'default))))
2083
2084   (defun +eshell--current-git-branch ()
2085     (let ((branch (car (loop for match in (split-string (shell-command-to-string "git branch") "\n")
2086                              when (string-match "^\*" match)
2087                              collect match))))
2088       (if (not (eq branch nil))
2089           (concat " " (substring branch 2))
2090         ""))))
2091 #+end_src
2092
2093 ** magithub
2094
2095 For when I /have to/ use GH.
2096
2097 #+begin_src emacs-lisp
2098 (use-package magithub
2099   :after magit
2100   :config
2101   (magithub-feature-autoinject t)
2102   (setq magithub-clone-default-directory "~/src/git"))
2103 #+end_src
2104
2105 ** [[https://github.com/peterwvj/eshell-up][eshell-up]]
2106
2107 #+begin_src emacs-lisp
2108 (use-package eshell-up
2109   :after eshell)
2110 #+end_src
2111
2112 * Email
2113
2114 #+begin_src emacs-lisp
2115 (defvar amin-maildir (expand-file-name "~/mail/"))
2116 (after! recentf
2117   (add-to-list 'recentf-exclude amin-maildir))
2118 #+end_src
2119
2120 ** Gnus
2121
2122 #+begin_src emacs-lisp
2123 (setq
2124  amin-gnus-init-file (no-littering-expand-etc-file-name "gnus")
2125  mail-user-agent     'gnus-user-agent
2126  read-mail-command   'gnus)
2127
2128 (use-package gnus
2129   :general
2130   (amin--leader-keys
2131     "m" 'gnus
2132     "M" 'gnus-unplugged)
2133   :bind (("s-m" . gnus)
2134          ("s-M" . gnus-unplugged))
2135   :init
2136   (setq
2137    gnus-select-method '(nnnil "")
2138    gnus-secondary-select-methods
2139    '((nnimap "amin"
2140             (nnimap-stream plain)
2141             (nnimap-address "127.0.0.1")
2142             (nnimap-server-port 143)
2143             (nnimap-authenticator plain)
2144             (nnimap-user "amin@aminb.org"))
2145      (nnimap "uwaterloo"
2146              (nnimap-stream plain)
2147              (nnimap-address "127.0.0.1")
2148              (nnimap-server-port 143)
2149              (nnimap-authenticator plain)
2150              (nnimap-user "abandali@uwaterloo.ca")))
2151    gnus-message-archive-group "nnimap+amin:Sent"
2152    gnus-parameters
2153    '(("gnu.*"
2154       (gcc-self . t)))
2155    gnus-large-newsgroup  50
2156    gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
2157    gnus-directory        (concat gnus-home-directory "news/")
2158    message-directory     (concat gnus-home-directory "mail/")
2159    nndraft-directory     (concat gnus-home-directory "drafts/")
2160    gnus-save-newsrc-file nil
2161    gnus-read-newsrc-file nil
2162    gnus-interactive-exit nil
2163    gnus-gcc-mark-as-read t))
2164
2165 (use-package gnus-art
2166   :config
2167   (setq
2168    gnus-visible-headers
2169    (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
2170    gnus-sorted-header-list
2171    '("^From:" "^Subject:" "^Summary:" "^Keywords:"
2172      "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
2173      "^Newsgroups:" "List-Id:" "^Organization:"
2174      "^User-Agent:" "^Date:")
2175   ;; local-lapsed article dates
2176   ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
2177   gnus-article-date-headers '(user-defined)
2178   gnus-article-time-format
2179   (lambda (time)
2180     (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
2181            (local (article-make-date-line date 'local))
2182            (combined-lapsed (article-make-date-line date
2183                                                     'combined-lapsed))
2184            (lapsed (progn
2185                      (string-match " (.+" combined-lapsed)
2186                      (match-string 0 combined-lapsed))))
2187       (concat local lapsed))))
2188   (bind-keys
2189    :map gnus-article-mode-map
2190    ("r"   . gnus-article-reply-with-original)
2191    ("R"   . gnus-article-wide-reply-with-original)
2192    ("M-L" . org-store-link)))
2193
2194 (use-package gnus-sum
2195   :bind (:map gnus-summary-mode-map
2196               :prefix-map amin--gnus-summary-prefix-map
2197               :prefix "v"
2198               ("r" . gnus-summary-reply)
2199               ("w" . gnus-summary-wide-reply)
2200               ("v" . gnus-summary-show-raw-article))
2201   :config
2202   (bind-keys
2203    :map gnus-summary-mode-map
2204    ("r"   . gnus-summary-reply-with-original)
2205    ("R"   . gnus-summary-wide-reply-with-original)
2206    ("M-L" . org-store-link)))
2207
2208 (use-package gnus-msg
2209   :config
2210   (setq gnus-posting-styles
2211         '((".*"
2212            (address "amin@aminb.org")
2213            (body "\nBest,\namin\n"))
2214           ("gnu.*"
2215            (address "bandali@gnu.org"))
2216           ((header "subject" "ThankCRM")
2217            (to "webmasters-comment@gnu.org"))
2218           ("nnimap\\+uwaterloo:.*"
2219            (address "abandali@uwaterloo.ca")
2220            (gcc "\"nnimap+uwaterloo:Sent Items\"")))))
2221
2222 (use-package gnus-topic
2223   :hook (gnus-group-mode . gnus-topic-mode))
2224
2225 (use-package gnus-agent
2226   :config
2227   (setq gnus-agent-synchronize-flags 'ask)
2228   :hook (gnus-group-mode . gnus-agent-mode))
2229
2230 (use-package gnus-group
2231   :config
2232   (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))
2233
2234 (use-package mm-decode
2235   :config
2236   (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
2237 #+end_src
2238
2239 ** sendmail
2240
2241 #+begin_src emacs-lisp
2242 (use-package sendmail
2243   :config
2244   (setq sendmail-program "/usr/bin/msmtp"
2245         ;; message-sendmail-extra-arguments '("-v" "-d")
2246         mail-specify-envelope-from t
2247         mail-envelope-from 'header))
2248 #+end_src
2249
2250 ** message
2251
2252 #+begin_src emacs-lisp
2253 (use-package message
2254   :config
2255   (defconst message-cite-style-bandali
2256     '((message-cite-function  'message-cite-original)
2257       (message-citation-line-function  'message-insert-formatted-citation-line)
2258       (message-cite-reply-position 'traditional)
2259       (message-yank-prefix  "> ")
2260       (message-yank-cited-prefix  ">")
2261       (message-yank-empty-prefix  ">")
2262       (message-citation-line-format "Hi %F,\n\nOn %Y-%m-%d %l:%M %p, %N wrote:"))
2263     "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
2264   (setq message-cite-style 'message-cite-style-bandali
2265         message-kill-buffer-on-exit t
2266         message-send-mail-function 'message-send-mail-with-sendmail
2267         message-sendmail-envelope-from 'header
2268         message-dont-reply-to-names
2269         "\\(\\(.*@aminb\\.org\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
2270         message-user-fqdn "aminb.org")
2271   :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
2272          (message-mode . flyspell-mode)
2273          (message-mode . (lambda () (setq fill-column 65
2274                                      message-fill-column 65))))
2275   ;; :custom-face
2276   ;; (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
2277   ;; (message-header-to      ((t (:foreground "#111" :weight normal))))
2278   ;; (message-header-cc      ((t (:foreground "#333" :weight normal))))
2279   )
2280
2281 (after! mml-sec
2282   (setq mml-secure-openpgp-encrypt-to-self t
2283         mml-secure-openpgp-sign-with-sender t))
2284 #+end_src
2285
2286 ** footnote
2287
2288 Convenient footnotes in =message-mode=.
2289
2290 #+begin_src emacs-lisp
2291 (use-package footnote
2292   :after message
2293   :bind
2294   (:map message-mode-map
2295         :prefix-map amin--footnote-prefix-map
2296         :prefix "C-c f"
2297         ("a" . footnote-add-footnote)
2298         ("b" . footnote-back-to-message)
2299         ("c" . footnote-cycle-style)
2300         ("d" . footnote-delete-footnote)
2301         ("g" . footnote-goto-footnote)
2302         ("r" . footnote-renumber-footnotes)
2303         ("s" . footnote-set-style))
2304   :config
2305   (setq footnote-start-tag ""
2306         footnote-end-tag   ""
2307         footnote-style     'unicode))
2308 #+end_src
2309
2310 ** COMMENT supercite
2311
2312 #+begin_src emacs-lisp
2313 (use-package supercite
2314   :after message
2315   :init
2316   (setq sc-nested-citation-p t
2317         ;; sc-cite-blank-lines-p t
2318         sc-citation-leader ""
2319         sc-reference-tag-string ""
2320         sc-preferred-header-style 5     ; (sc-header-author-writes)
2321         sc-auto-fill-region-p nil
2322         sc-confirm-always-p nil)
2323   :config
2324   ;;   (defun amin--sc-header-on-wrote ()
2325   ;;     "\"On <date>, <sc-author> wrote:\" unless:
2326   ;; 1. the \"sc-author\" field cannot be found, in which case nothing is inserted;
2327   ;; 2. the \"date\" field is missing in which case only the from part is printed."
2328   ;;     (let ((sc-mumble "")
2329   ;;          (whofrom (sc-whofrom)))
2330   ;;       (if whofrom
2331   ;;          (insert sc-reference-tag-string
2332   ;;                      (sc-hdr "On " (sc-mail-field "date") ", ")
2333   ;;                      (sc-hdr "" (sc-mail-field "sc-author")) " wrote:\n"))))
2334   ;;   (defun amin--sc-header ()
2335   ;;     "Hi <firstname>,\n\n <from> writes:"
2336   ;;     (let ((sc-mumble "")
2337   ;;          (whofrom (sc-whofrom)))
2338   ;;       (if whofrom
2339   ;;          (insert (sc-hdr "Hi " (sc-mail-field "sc-firstname") ",\n\n")
2340   ;;                   sc-reference-tag-string
2341   ;;                      whofrom
2342   ;;                      " writes:\n"))))
2343   ;; (add-to-list 'sc-rewrite-header-list '(amin--sc-header) t)
2344   ;; (add-to-list 'sc-rewrite-header-list '(amin--sc-header-on-wrote) t)
2345   ;; (setq sc-preferred-header-style (1- (length sc-rewrite-header-list)))
2346   (add-hook 'mail-citation-hook 'sc-cite-original))
2347 #+end_src
2348
2349 ** ebdb
2350
2351 #+begin_src emacs-lisp
2352 (use-package ebdb
2353   :defer 1
2354   :bind (:map gnus-group-mode-map ("e" . ebdb))
2355   :config
2356   (setq ebdb-sources (no-littering-expand-var-file-name "ebdb")))
2357
2358 (use-package ebdb-com
2359   :after ebdb)
2360
2361 (use-package ebdb-complete
2362   :after ebdb
2363   :config
2364   (ebdb-complete-enable))
2365
2366 (use-package ebdb-gnus
2367   :after ebdb)
2368
2369 (use-package ebdb-message
2370   :after ebdb)
2371
2372 ;; (use-package ebdb-vcard
2373 ;;   :after ebdb)
2374 #+end_src
2375
2376 ** COMMENT bbdb
2377
2378 #+begin_comment
2379 [submodule "bbdb"]
2380         path = lib/bbdb
2381         url = https://git.savannah.nongnu.org/git/bbdb.git
2382         load-path = lisp/elisp
2383         info-path = doc
2384         build-step = ./autogen.sh
2385         build-step = ./configure --with-lispdir=elisp
2386         build-step = make
2387         build-step = make install
2388 #+end_comment
2389
2390 #+begin_src emacs-lisp
2391 (use-package bbdb
2392   :init
2393   (bbdb-mua-auto-update-init 'message)
2394   (setq bbdb-mua-auto-update-p 'query)
2395   (add-hook 'gnus-startup-hook 'bbdb-insinuate-gnus))
2396 #+end_src
2397
2398 ** COMMENT message-x
2399
2400 #+begin_src emacs-lisp
2401 (use-package message-x
2402   :custom
2403   (message-x-completion-alist
2404    (quote
2405     (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
2406      ((if
2407           (boundp
2408            (quote message-newgroups-header-regexp))
2409           message-newgroups-header-regexp message-newsgroups-header-regexp)
2410       . message-expand-group)))))
2411 #+end_src
2412
2413 ** COMMENT gnus-harvest
2414
2415 #+begin_src emacs-lisp
2416 (use-package gnus-harvest
2417   :commands gnus-harvest-install
2418   :demand t
2419   :config
2420   (if (featurep 'message-x)
2421       (gnus-harvest-install 'message-x)
2422     (gnus-harvest-install)))
2423 #+end_src
2424
2425 ** COMMENT gnus-alias                                              :ARCHIVE:
2426
2427 #+begin_src emacs-lisp
2428 (use-package gnus-alias
2429   :commands (gnus-alias-determine-identity
2430              gnus-alias-select-identity)
2431   :bind (:map  message-mode-map
2432                ("s-i" . gnus-alias-select-identity))
2433   :config
2434   (setq
2435    gnus-alias-default-identity "amin"
2436    gnus-alias-identity-alist
2437    '(("amin"
2438       nil   ;; Does not refer to any other identity
2439       "Amin Bandali <amin@aminb.org>"
2440       nil   ;; Organization
2441       nil   ;; extra headers
2442       nil   ;; extra body text
2443       nil)  ;; signature file
2444      ("gnu"
2445       nil
2446       "Amin Bandali <bandali@gnu.org>"
2447       nil
2448       nil
2449       nil
2450       nil)
2451      ("uw"
2452       nil
2453       "Amin Bandali <abandali@uwaterloo.ca>"
2454       nil
2455       (("Gcc" . "\"nnimap+uwaterloo:Sent Items\""))
2456       nil
2457       nil))
2458    gnus-alias-identity-rules
2459    '(("amin" ("Delivered-To" "<amin\\@aminb\\.org" both) "amin")
2460      ("gnu" ("Delivered-To" "<gnu\\@aminb\\.org" both) "gnu")
2461      ("uw" ("any" "<\\(.+\\)\\@uwaterloo\\.ca" both) "uw"))
2462    gnus-alias-override-user-mail-address t)
2463   :hook (message-setup . gnus-alias-determine-identity))
2464 #+end_src
2465
2466 ** COMMENT [[https://notmuchmail.org][notmuch]]                                                 :ARCHIVE:
2467
2468 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
2469
2470 #+begin_src emacs-lisp
2471 (defun amin/notmuch ()
2472   "Delete other windows, then launch `notmuch'."
2473   (interactive
2474    (when (equal current-prefix-arg nil)
2475      (delete-other-windows)))
2476   (notmuch))
2477
2478 (use-package notmuch
2479   :commands notmuch
2480   :bind ("C-c n" . amin/notmuch)
2481   :custom (notmuch-always-prompt-for-sender t)
2482   :config
2483   (setq notmuch-hello-sections
2484         '(notmuch-hello-insert-header
2485           notmuch-hello-insert-saved-searches
2486           ;; notmuch-hello-insert-search
2487           notmuch-hello-insert-alltags)
2488         notmuch-search-oldest-first nil
2489         notmuch-show-all-tags-list t
2490         notmuch-message-headers  ; see bug follow-up above
2491         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
2492         notmuch-hello-thousands-separator ","
2493         notmuch-fcc-dirs
2494         '(("amin@aminb.org"        . "amin/Sent")
2495           ("bandali@gnu.org"       . "gnu/Sent")
2496           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
2497           ("mab@gnu.org"           . "gnu/Sent")
2498           ("amin@gnu.org"          . "gnu/Sent")
2499           ("aminb@gnu.org"         . "gnu/Sent")
2500           (".*"                    . "sent"))
2501         notmuch-search-result-format
2502         '(("date"    . "%12s ")
2503           ("count"   . "%-7s ")
2504           ("authors" . "%-40s ")
2505           ("subject" . "%s ")
2506           ("tags"    . "(%s)"))
2507         notmuch-saved-searches
2508         '((:name "inbox"     :query "tag:inbox"     :key "i")
2509           (:name "unread"    :query "tag:unread"    :key "u")
2510           (:name "latest"    :query "tag:latest"    :key "l")
2511           (:name "encrypted" :query "tag:encrypted" :key "e")
2512           (:name "flagged"   :query "tag:flagged"   :key "f")
2513           (:name "sent"      :query "tag:sent"      :key "s")
2514           (:name "drafts"    :query "tag:draft"     :key "d")
2515           (:name "all mail"  :query "*"             :key "a")))
2516   ;; (add-hook 'visual-fill-column-mode-hook
2517   ;;           (lambda ()
2518   ;;             (when (string= major-mode 'notmuch-message-mode)
2519   ;;               (setq visual-fill-column-width 70))))
2520   ;; (set! :evil-state 'notmuch-message-mode 'insert)
2521   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
2522   ;;             :override #'kill-this-buffer)
2523   :hook (notmuch-message-mode . doom-modeline-set-special-modeline)
2524   :bind
2525   (:map notmuch-hello-mode-map
2526         ("u" . (lambda ()
2527                  "Search for `unread'-tagged messages"
2528                  (interactive)
2529                  (notmuch-hello-search "tag:unread")))
2530         ("i" . (lambda ()
2531                  "Search for `inbox'-tagged messages"
2532                  (interactive)
2533                  (notmuch-hello-search "tag:inbox")))
2534         ("l" . (lambda ()
2535                  "Search for `latest'-tagged messages"
2536                  (interactive)
2537                  (notmuch-hello-search "tag:latest")))
2538         ("e" . (lambda ()
2539                  "Search for `encrypted'-tagged messages"
2540                  (interactive)
2541                  (notmuch-hello-search "tag:encrypted"))))
2542   (:map notmuch-search-mode-map
2543         ("k" . (lambda ()
2544                  "Mark message read"
2545                  (interactive)
2546                  (notmuch-search-tag '("-unread"))
2547                  ;; (notmuch-search-archive-thread)
2548                  (notmuch-search-next-thread)))
2549         ("u" . (lambda ()
2550                  "Mark message unread"
2551                  (interactive)
2552                  (notmuch-search-tag '("+unread"))
2553                  (notmuch-search-next-thread)))
2554         ("K" . (lambda ()
2555                  "Mark message deleted"
2556                  (interactive)
2557                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
2558                  (notmuch-search-next-thread)))
2559         ("S" . (lambda ()
2560                  "Mark message as spam"
2561                  (interactive)
2562                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
2563                  (notmuch-search-next-thread))))
2564   (:map notmuch-tree-mode-map
2565         ("k" . (lambda ()
2566                  "Mark message read"
2567                  (interactive)
2568                  (notmuch-tree-tag '("-unread"))
2569                  ;; (notmuch-tree-archive-thread)
2570                  (notmuch-tree-next-message)))
2571         ("u" . (lambda ()
2572                  "Mark message unread"
2573                  (interactive)
2574                  (notmuch-tree-tag '("+unread"))
2575                  (notmuch-tree-next-message)))
2576         ("K" . (lambda ()
2577                  "Mark message deleted"
2578                  (interactive)
2579                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
2580                  (notmuch-tree-next-message)))
2581         ("S" . (lambda ()
2582                  "Mark message as spam"
2583                  (interactive)
2584                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
2585                  (notmuch-tree-next-message))))
2586   :custom-face
2587   (notmuch-search-unread-face ((t (:weight semi-bold))))
2588   (notmuch-tag-face ((t (:foreground "navy blue" :weight semi-bold)))))
2589
2590 (use-package counsel-notmuch
2591   :bind ("C-c s m" . counsel-notmuch))
2592
2593 (after! notmuch-crypto
2594   (setq notmuch-crypto-process-mime t))
2595
2596 (use-package org-notmuch
2597   :after (:any org notmuch))
2598 #+end_src
2599
2600 * Blogging
2601 ** [[https://ox-hugo.scripter.co][ox-hugo]]
2602
2603 #+begin_src emacs-lisp
2604 (use-package ox-hugo
2605   :after ox)
2606
2607 (use-package ox-hugo-auto-export
2608   :load-path "lib/ox-hugo")
2609 #+end_src
2610
2611 * Post initialization
2612 :PROPERTIES:
2613 :CUSTOM_ID: post-initialization
2614 :END:
2615
2616 Display how long it took to load the init file.
2617
2618 #+begin_src emacs-lisp
2619 (message "Loading %s...done (%.3fs)" user-init-file
2620          (float-time (time-subtract (current-time)
2621                                     amin--before-user-init-time)))
2622 #+end_src
2623
2624 * Footer
2625 :PROPERTIES:
2626 :CUSTOM_ID: footer
2627 :END:
2628
2629 #+begin_src emacs-lisp :comments none
2630 ;;; init.el ends here
2631 #+end_src
2632
2633 * COMMENT Local Variables                                           :ARCHIVE:
2634 # Local Variables:
2635 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
2636 # End: