git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 (with-eval-after-load 'bind-key
 238   (bind-keys
 239    :package borg
 240    ("C-c B A" . borg-activate)
 241    ("C-c B a" . borg-assimilate)
 242    ("C-c B b" . borg-build)
 243    ("C-c B c" . borg-clone)))
 244 #+end_src
 245
 246 *** =use-package=
 247
 248 #+begin_quote
 249 A use-package declaration for simplifying your .emacs
 250 #+end_quote
 251
 252 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 253 packages (in our case especially the latter) in a neatly organized way
 254 and without compromising on performance.
 255
 256 #+begin_src emacs-lisp
 257 (require 'use-package)
 258 (if nil  ; set to t when need to debug init
 259     (setq use-package-verbose t
 260           use-package-expand-minimally nil
 261           use-package-compute-statistics t
 262           debug-on-error t)
 263   (setq use-package-verbose nil
 264         use-package-expand-minimally t))
 265 #+end_src
 266
 267 *** Epkg
 268
 269 #+begin_quote
 270 Browse the Emacsmirror package database
 271 #+end_quote
 272
 273 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 274 database, low-level functions for querying the database, and a
 275 =package.el=-like user interface for browsing the available packages.
 276
 277 #+begin_src emacs-lisp
 278 (use-package epkg
 279   :defer t
 280   :bind
 281   (("C-c B d" . epkg-describe-package)
 282    ("C-c B p" . epkg-list-packages)
 283    ("C-c B r" . borg-remove)
 284    ("C-c B u" . epkg-update)))
 285 #+end_src
 286
 287 ** No littering in =~/.emacs.d=
 288
 289 #+begin_quote
 290 Help keeping ~/.emacs.d clean
 291 #+end_quote
 292
 293 By default, even for Emacs' built-in packages, the configuration files
 294 and persistent data are all over the place. Use =no-littering= to help
 295 contain the mess.
 296
 297 #+begin_src emacs-lisp
 298 (use-package no-littering
 299   :demand t
 300   :config
 301   (savehist-mode 1)
 302   (add-to-list 'savehist-additional-variables 'kill-ring)
 303   (save-place-mode 1)
 304   (setq auto-save-file-name-transforms
 305         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 306 #+end_src
 307
 308 ** Custom file (=custom.el=)
 309
 310 I'm not planning on using the custom file much, but even so, I
 311 definitely don't want it mixing with =init.el=. So, here; let's give
 312 it it's own file. While at it, treat themes as safe.
 313
 314 #+begin_src emacs-lisp
 315 (use-package custom
 316   :no-require t
 317   :config
 318   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 319   (when (file-exists-p custom-file)
 320     (load custom-file))
 321   (setf custom-safe-themes t))
 322 #+end_src
 323
 324 ** Better =$PATH= handling
 325
 326 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 327 in my shell.
 328
 329 #+begin_src emacs-lisp
 330 (use-package exec-path-from-shell
 331   :defer 1
 332   :init
 333   (setq exec-path-from-shell-check-startup-files nil)
 334   :config
 335   (exec-path-from-shell-initialize)
 336   ;; while we're at it, let's fix access to our running ssh-agent
 337   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 338   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 339 #+end_src
 340
 341 ** Only one custom theme at a time
 342
 343 #+begin_src emacs-lisp
 344 (defadvice load-theme (before clear-previous-themes activate)
 345   "Clear existing theme settings instead of layering them"
 346   (mapc #'disable-theme custom-enabled-themes))
 347 #+end_src
 348
 349 ** Server
 350
 351 Start server if not already running. Alternatively, can be done by
 352 issuing =emacs --daemon= in the terminal, which can be automated with
 353 a systemd service or using =brew services start emacs= on macOS. I use
 354 Emacs as my window manager (via EXWM), so I always start Emacs on
 355 login; so starting the server from inside Emacs is good enough for me.
 356
 357 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 358
 359 #+begin_src emacs-lisp
 360 (use-package server
 361   :config (or (server-running-p) (server-mode)))
 362 #+end_src
 363
 364 ** Unicode support
 365
 366 Font stack with better unicode support, around =Ubuntu Mono= and
 367 =Hack=.
 368
 369 #+begin_src emacs-lisp
 370 (dolist (ft (fontset-list))
 371   (set-fontset-font
 372    ft
 373    'unicode
 374    (font-spec :name "Ubuntu Mono"))
 375   (set-fontset-font
 376    ft
 377    'unicode
 378    (font-spec :name "DejaVu Sans Mono")
 379    nil
 380    'append)
 381   ;; (set-fontset-font
 382   ;;  ft
 383   ;;  'unicode
 384   ;;  (font-spec
 385   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 386   ;;  nil
 387   ;;  'append)
 388   ;; (set-fontset-font
 389   ;;  ft
 390   ;;  #x2115  ; ℕ
 391   ;;  (font-spec :name "DejaVu Sans Mono")
 392   ;;  nil
 393   ;;  'append)
 394   (set-fontset-font
 395    ft
 396    (cons ?Α ?ω)
 397    (font-spec :name "DejaVu Sans Mono" :size 14)
 398    nil
 399    'prepend))
 400 #+end_src
 401
 402 ** Libraries
 403
 404 #+begin_src emacs-lisp
 405 (require 'cl-lib)
 406 (require 'subr-x)
 407 #+end_src
 408
 409 ** Useful utilities
 410
 411 #+begin_src emacs-lisp
 412 (defun amin-enlist (exp)
 413   "Return EXP wrapped in a list, or as-is if already a list."
 414 (if (listp exp) exp (list exp)))
 415
 416 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 417 (defmacro after! (features &rest body)
 418   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 419 compilation."
 420   (declare (indent defun) (debug t))
 421   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 422                 (dolist (next (amin-enlist features))
 423                   (if (symbolp next)
 424                       (require next nil :no-error)
 425                     (load next :no-message :no-error))))
 426             #'progn
 427           #'with-no-warnings)
 428         (cond ((symbolp features)
 429                `(eval-after-load ',features '(progn ,@body)))
 430               ((and (consp features)
 431                     (memq (car features) '(:or :any)))
 432                `(progn
 433                   ,@(cl-loop for next in (cdr features)
 434                              collect `(after! ,next ,@body))))
 435               ((and (consp features)
 436                     (memq (car features) '(:and :all)))
 437                (dolist (next (cdr features))
 438                  (setq body `(after! ,next ,@body)))
 439                body)
 440               ((listp features)
 441                `(after! (:all ,@features) ,@body)))))
 442 #+end_src
 443
 444 * Core
 445 :PROPERTIES:
 446 :CUSTOM_ID: core
 447 :END:
 448
 449 ** Defaults
 450
 451 *** Time and battery in mode-line
 452
 453 Enable displaying time and battery in the mode-line, since I'm not
 454 using the Xfce panel anymore. Also, I don't need to see the load
 455 average on a regular basis, so disable that.
 456
 457 Note: using =i3status= on sway at the moment, so disabling this.
 458
 459 #+begin_src emacs-lisp :tangle no
 460 (use-package time
 461   :init
 462   (setq display-time-default-load-average nil)
 463   :config
 464   (display-time-mode))
 465
 466 (use-package battery
 467   :config
 468   (display-battery-mode))
 469 #+end_src
 470
 471 *** Smaller fringe
 472
 473 Might want to set the fringe to a smaller value, especially if using
 474 EXWM. I'm fine with the default for now.
 475
 476 #+begin_src emacs-lisp
 477 ;; (fringe-mode '(3 . 1))
 478 (fringe-mode nil)
 479 #+end_src
 480
 481 *** Disable disabled commands
 482
 483 Emacs disables some commands by default that could persumably be
 484 confusing for novice users. Let's disable that.
 485
 486 #+begin_src emacs-lisp
 487 (setq disabled-command-function nil)
 488 #+end_src
 489
 490 *** Kill-ring
 491
 492 Save what I copy into clipboard from other applications into Emacs'
 493 kill-ring, which would allow me to still be able to easily access it
 494 in case I kill (cut or copy) something else inside Emacs before
 495 yanking (pasting) what I'd originally intended to.
 496
 497 #+begin_src emacs-lisp
 498 (setq save-interprogram-paste-before-kill t)
 499 #+end_src
 500
 501 *** Minibuffer
 502
 503 #+begin_src emacs-lisp
 504 (setq enable-recursive-minibuffers t
 505       resize-mini-windows t)
 506 #+end_src
 507
 508 *** Lazy-person-friendly yes/no prompts
 509
 510 Lazy people would prefer to type fewer keystrokes, especially for yes
 511 or no questions. I'm lazy.
 512
 513 #+begin_src emacs-lisp
 514 (defalias 'yes-or-no-p #'y-or-n-p)
 515 #+end_src
 516
 517 *** Startup screen and =*scratch*=
 518
 519 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 520 startup buffer.
 521
 522 #+begin_src emacs-lisp
 523 (setq initial-buffer-choice t)
 524 #+end_src
 525
 526 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 527 need the default hint.
 528
 529 #+begin_src emacs-lisp
 530 (setq initial-scratch-message nil)
 531 #+end_src
 532
 533 Also, let's use Text mode as the major mode, in case I want to
 534 customize it (=*scratch*='s default major mode, Fundamental mode,
 535 can't really be customized).
 536
 537 #+begin_src emacs-lisp
 538 (setq initial-major-mode 'text-mode)
 539 #+end_src
 540
 541 Inhibit the buffer list when more than 2 files are loaded.
 542
 543 #+begin_src emacs-lisp
 544 (setq inhibit-startup-buffer-menu t)
 545 #+end_src
 546
 547 I don't really need to see the startup screen or echo area message
 548 either.
 549
 550 #+begin_src emacs-lisp
 551 (advice-add #'display-startup-echo-area-message :override #'ignore)
 552 (setq inhibit-startup-screen t
 553       inhibit-startup-echo-area-message user-login-name)
 554 #+end_src
 555
 556 *** More useful frame titles
 557
 558 Show either the file name or the buffer name (in case the buffer isn't
 559 visiting a file). Borrowed from Emacs Prelude.
 560
 561 #+begin_src emacs-lisp
 562 (setq frame-title-format
 563       '("" invocation-name " - "
 564         (:eval (if (buffer-file-name)
 565                    (abbreviate-file-name (buffer-file-name))
 566                  "%b"))))
 567 #+end_src
 568
 569 *** Backups
 570
 571 Emacs' default backup settings aren't that great. Let's use more
 572 sensible options. See documentation for the ~make-backup-file~
 573 variable.
 574
 575 #+begin_src emacs-lisp
 576 (setq backup-by-copying t
 577       version-control t)
 578 #+end_src
 579
 580 *** Auto revert
 581
 582 Enable automatic reloading of changed buffers and files.
 583
 584 #+begin_src emacs-lisp
 585 (global-auto-revert-mode 1)
 586 (setq auto-revert-verbose nil
 587       global-auto-revert-non-file-buffers t)
 588 #+end_src
 589
 590 *** Always use space for indentation
 591
 592 #+begin_src emacs-lisp
 593 (setq-default
 594  indent-tabs-mode nil
 595  require-final-newline t
 596  tab-width 4)
 597 #+end_src
 598
 599 *** Winner mode
 600
 601 Enable =winner-mode=.
 602
 603 #+begin_src emacs-lisp
 604 (winner-mode 1)
 605 #+end_src
 606
 607 ** Bindings
 608
 609 #+begin_src emacs-lisp
 610 (bind-keys
 611  ("C-c b B" . ibuffer-list-buffers)
 612  ("C-c b k" . kill-this-buffer)
 613  ("C-c b s" . save-buffer)
 614  ("C-c S"   . save-buffer)
 615  ("C-c o"   . other-window)
 616  ("C-c q q" . save-buffers-kill-terminal))
 617 #+end_src
 618
 619 ** Packages
 620
 621 The packages in this section are absolutely essential to my everyday
 622 workflow, and they play key roles in how I do my computing. They
 623 immensely enhance the Emacs experience for me; both using Emacs, and
 624 customizing it.
 625
 626 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 627
 628 #+begin_src emacs-lisp
 629 (use-package auto-compile
 630   :demand t
 631   :config
 632   (auto-compile-on-load-mode)
 633   (auto-compile-on-save-mode)
 634   (setq auto-compile-display-buffer               nil
 635         auto-compile-mode-line-counter            t
 636         auto-compile-source-recreate-deletes-dest t
 637         auto-compile-toggle-deletes-nonlib-dest   t
 638         auto-compile-update-autoloads             t)
 639   (add-hook 'auto-compile-inhibit-compile-hook
 640             'auto-compile-inhibit-compile-detached-git-head))
 641 #+end_src
 642
 643 *** [[https://orgmode.org/][Org mode]]
 644
 645 #+begin_quote
 646 Org mode is for keeping notes, maintaining TODO lists, planning
 647 projects, and authoring documents with a fast and effective plain-text
 648 system.
 649 #+end_quote
 650
 651 In short, my favourite way of life.
 652
 653 #+begin_src emacs-lisp
 654 (use-package org
 655   :config
 656   (setq org-src-tab-acts-natively t
 657         org-src-preserve-indentation nil
 658         org-edit-src-content-indentation 0)
 659   :hook (org-mode . org-indent-mode))
 660
 661 (use-package org-notmuch
 662   :after (:any org notmuch))
 663 #+end_src
 664
 665 *** [[https://magit.vc/][Magit]]
 666
 667 #+begin_quote
 668 It's Magit! A Git porcelain inside Emacs.
 669 #+end_quote
 670
 671 Not just how I do git, but /the/ way to do git.
 672
 673 #+begin_src emacs-lisp
 674 (use-package magit
 675   :defer t
 676   :bind
 677   (("s-g"   . magit-dispatch-popup)
 678    ("C-x g" . magit-status)
 679    :prefix-map amin--magit-prefix-map
 680    :prefix "C-c g"
 681    ("SPC" . magit-status)
 682    ("s"   . magit-status)
 683    ("S"   . magit-status-prefix)
 684    ("B"   . magit-blame)
 685    ("C"   . magit-clone)
 686    ("f"   . magit-fetch)
 687    ("F"   . magit-pull)
 688    ("P"   . magit-push)
 689    ("p"   . magit-dispatch-popup)
 690    ("c c" . magit-commit)
 691    ("c a" . magit-commit-amend)
 692    ("b b" . magit-checkout)
 693    ("b c" . magit-branch))
 694   :config
 695   (magit-add-section-hook 'magit-status-sections-hook
 696                           'magit-insert-modules
 697                           'magit-insert-stashes
 698                           'append))
 699 #+end_src
 700
 701 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 702
 703 #+begin_quote
 704 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 705 an overview, and more. Oh, man!
 706 #+end_quote
 707
 708 There's no way I could top that, so I won't attempt to.
 709
 710 **** Ivy
 711
 712 #+begin_src emacs-lisp
 713 (use-package ivy
 714   :defer 1
 715   :bind
 716   (("C-c b b" . ivy-switch-buffer)
 717    :map ivy-minibuffer-map
 718    ([escape] . keyboard-escape-quit)
 719    ([S-up]   . ivy-previous-history-element)
 720    ([S-down] . ivy-next-history-element)
 721    ("DEL"    . ivy-backward-delete-char))
 722   :config
 723   (setq ivy-wrap t)
 724   (ivy-mode 1))
 725 #+end_src
 726
 727 **** Swiper
 728
 729 #+begin_src emacs-lisp
 730 (use-package swiper
 731   :bind (([remap isearch-forward]  . swiper)
 732          ([remap isearch-backward] . swiper)))
 733 #+end_src
 734
 735 **** Counsel
 736
 737 #+begin_src emacs-lisp
 738 (use-package counsel
 739   :defer 1
 740   :bind (([remap execute-extended-command] . counsel-M-x)
 741          ([remap find-file]                . counsel-find-file)
 742          ("s-r"                            . counsel-recentf)
 743          ("C-c x"                          . counsel-M-x)
 744          ("C-c f ."                        . counsel-find-file)
 745          ("C-c f r"                        . counsel-recentf)
 746          :map minibuffer-local-map
 747          ("C-r" . counsel-minibuffer-history))
 748   :config
 749   (counsel-mode 1)
 750   (defalias 'locate #'counsel-locate))
 751 #+end_src
 752
 753 * Borg's =layer/essentials=
 754
 755 TODO: break this giant source block down into individual org sections.
 756
 757 #+begin_src emacs-lisp
 758 (use-package dash
 759   :config (dash-enable-font-lock))
 760
 761 (use-package diff-hl
 762   :config
 763   (setq diff-hl-draw-borders nil)
 764   (global-diff-hl-mode)
 765   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 766
 767 (use-package dired
 768   :defer t
 769   :config (setq dired-listing-switches "-alh"))
 770
 771 (use-package eldoc
 772   :when (version< "25" emacs-version)
 773   :config (global-eldoc-mode))
 774
 775 (use-package help
 776   :defer t
 777   :config (temp-buffer-resize-mode))
 778
 779 (progn ;    `isearch'
 780   (setq isearch-allow-scroll t))
 781
 782 (use-package lisp-mode
 783   :config
 784   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 785   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 786   (defun indent-spaces-mode ()
 787     (setq indent-tabs-mode nil))
 788   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 789
 790 (use-package man
 791   :defer t
 792   :config (setq Man-width 80))
 793
 794 (use-package paren
 795   :config (show-paren-mode))
 796
 797 (use-package prog-mode
 798   :config (global-prettify-symbols-mode)
 799   (defun indicate-buffer-boundaries-left ()
 800     (setq indicate-buffer-boundaries 'left))
 801   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 802
 803 (use-package recentf
 804   :demand t
 805   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 806
 807 (use-package savehist
 808   :config (savehist-mode))
 809
 810 (use-package saveplace
 811   :when (version< "25" emacs-version)
 812   :config (save-place-mode))
 813
 814 (use-package simple
 815   :config (column-number-mode))
 816
 817 (progn ;    `text-mode'
 818   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 819
 820 (use-package tramp
 821   :defer t
 822   :config
 823   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 824   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 825   (add-to-list 'tramp-default-proxies-alist
 826                (list (regexp-quote (system-name)) nil nil)))
 827
 828 (use-package undo-tree
 829   :bind (("C-?" . undo-tree-undo)
 830          ("M-_" . undo-tree-redo))
 831   :config
 832   (global-undo-tree-mode)
 833   (setq undo-tree-mode-lighter ""
 834         undo-tree-auto-save-history t))
 835 #+end_src
 836
 837 * Editing
 838
 839 ** Company
 840
 841 #+begin_src emacs-lisp
 842 (use-package company
 843   :defer 5
 844   :bind
 845   (:map company-active-map
 846         ([tab] . company-complete-common-or-cycle))
 847   :custom
 848   (company-idle-delay 0.3)
 849   (company-minimum-prefix-length 1)
 850   (company-selection-wrap-around t)
 851   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 852   :config
 853   (global-company-mode t))
 854 #+end_src
 855
 856 * Syntax and spell checking
 857 #+begin_src emacs-lisp
 858 (use-package flycheck
 859   :hook (prog-mode . flycheck-mode)
 860   :config
 861   ;; Use the load-path from running Emacs when checking elisp files
 862   (setq flycheck-emacs-lisp-load-path 'inherit)
 863
 864   ;; Only flycheck when I actually save the buffer
 865   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 866 #+end_src
 867 * Programming modes
 868
 869 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 870
 871 #+begin_src emacs-lisp
 872 (use-package alloy-mode
 873   :config (setq alloy-basic-offset 2))
 874 #+end_src
 875
 876 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 877
 878 #+begin_src emacs-lisp
 879 (use-package proof-site  ; Proof General
 880   :load-path "lib/proof-site/generic/")
 881 #+end_src
 882
 883 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 884
 885 #+begin_src emacs-lisp
 886 (eval-when-compile (defvar lean-mode-map))
 887 (use-package lean-mode
 888   :bind (:map lean-mode-map
 889               ("S-SPC" . company-complete)))
 890 #+end_src
 891
 892 ** Haskell
 893
 894 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 895
 896 #+begin_src emacs-lisp
 897 (use-package haskell-mode
 898   :config
 899   (setq haskell-indentation-layout-offset 4
 900         haskell-indentation-left-offset 4
 901         flycheck-checker 'haskell-hlint
 902         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 903 #+end_src
 904
 905 *** [[https://github.com/jyp/dante][dante]]
 906
 907 #+begin_src emacs-lisp
 908 (use-package dante
 909   :after haskell-mode
 910   :commands dante-mode
 911   :hook (haskell-mode . dante-mode))
 912 #+end_src
 913
 914 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 915
 916 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 917 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 918
 919 #+begin_src emacs-lisp
 920 (use-package hlint-refactor
 921   :bind (:map hlint-refactor-mode-map
 922               ("C-c l b" . hlint-refactor-refactor-buffer)
 923               ("C-c l r" . hlint-refactor-refactor-at-point))
 924   :hook (haskell-mode . hlint-refactor-mode))
 925 #+end_src
 926
 927 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 928
 929 #+begin_src emacs-lisp
 930 (use-package flycheck-haskell)
 931 #+end_src
 932
 933 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 934 :PROPERTIES:
 935 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 936 :END:
 937
 938 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 939 instead.
 940
 941 #+begin_src emacs-lisp :tangle no
 942 ;;; hs-lint.el --- minor mode for HLint code checking
 943
 944 ;; Copyright 2009 (C) Alex Ott
 945 ;;
 946 ;; Author: Alex Ott <alexott@gmail.com>
 947 ;; Keywords: haskell, lint, HLint
 948 ;; Requirements:
 949 ;; Status: distributed under terms of GPL2 or above
 950
 951 ;; Typical message from HLint looks like:
 952 ;;
 953 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 954 ;; Found:
 955 ;;   count1 p l = length (filter p l)
 956 ;; Why not:
 957 ;;   count1 p = length . filter p
 958
 959
 960 (require 'compile)
 961
 962 (defgroup hs-lint nil
 963   "Run HLint as inferior of Emacs, parse error messages."
 964   :group 'tools
 965   :group 'haskell)
 966
 967 (defcustom hs-lint-command "hlint"
 968   "The default hs-lint command for \\[hlint]."
 969   :type 'string
 970   :group 'hs-lint)
 971
 972 (defcustom hs-lint-save-files t
 973   "Save modified files when run HLint or no (ask user)"
 974   :type 'boolean
 975   :group 'hs-lint)
 976
 977 (defcustom hs-lint-replace-with-suggestions nil
 978   "Replace user's code with suggested replacements"
 979   :type 'boolean
 980   :group 'hs-lint)
 981
 982 (defcustom hs-lint-replace-without-ask nil
 983   "Replace user's code with suggested replacements automatically"
 984   :type 'boolean
 985   :group 'hs-lint)
 986
 987 (defun hs-lint-process-setup ()
 988   "Setup compilation variables and buffer for `hlint'."
 989   (run-hooks 'hs-lint-setup-hook))
 990
 991 ;; regex for replace suggestions
 992 ;;
 993 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 994 ;; Found:
 995 ;; \s +\(.*\)
 996 ;; Why not:
 997 ;; \s +\(.*\)
 998
 999 (defvar hs-lint-regex
1000   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1001   "Regex for HLint messages")
1002
1003 (defun make-short-string (str maxlen)
1004   (if (< (length str) maxlen)
1005       str
1006     (concat (substring str 0 (- maxlen 3)) "...")))
1007
1008 (defun hs-lint-replace-suggestions ()
1009   "Perform actual replacement of suggestions"
1010   (goto-char (point-min))
1011   (while (re-search-forward hs-lint-regex nil t)
1012     (let* ((fname (match-string 1))
1013           (fline (string-to-number (match-string 2)))
1014           (old-code (match-string 4))
1015           (new-code (match-string 5))
1016           (msg (concat "Replace '" (make-short-string old-code 30)
1017                        "' with '" (make-short-string new-code 30) "'"))
1018           (bline 0)
1019           (eline 0)
1020           (spos 0)
1021           (new-old-code ""))
1022       (save-excursion
1023         (switch-to-buffer (get-file-buffer fname))
1024         (goto-char (point-min))
1025         (forward-line (1- fline))
1026         (beginning-of-line)
1027         (setf bline (point))
1028         (when (or hs-lint-replace-without-ask
1029                   (yes-or-no-p msg))
1030           (end-of-line)
1031           (setf eline (point))
1032           (beginning-of-line)
1033           (setf old-code (regexp-quote old-code))
1034           (while (string-match "\\\\ " old-code spos)
1035             (setf new-old-code (concat new-old-code
1036                                  (substring old-code spos (match-beginning 0))
1037                                  "\\ *"))
1038             (setf spos (match-end 0)))
1039           (setf new-old-code (concat new-old-code (substring old-code spos)))
1040           (remove-text-properties bline eline '(composition nil))
1041           (when (re-search-forward new-old-code eline t)
1042             (replace-match new-code nil t)))))))
1043
1044 (defun hs-lint-finish-hook (buf msg)
1045   "Function, that is executed at the end of HLint execution"
1046   (if hs-lint-replace-with-suggestions
1047       (hs-lint-replace-suggestions)
1048       (next-error 1 t)))
1049
1050 (define-compilation-mode hs-lint-mode "HLint"
1051   "Mode for check Haskell source code."
1052   (set (make-local-variable 'compilation-process-setup-function)
1053        'hs-lint-process-setup)
1054   (set (make-local-variable 'compilation-disable-input) t)
1055   (set (make-local-variable 'compilation-scroll-output) nil)
1056   (set (make-local-variable 'compilation-finish-functions)
1057        (list 'hs-lint-finish-hook))
1058   )
1059
1060 (defun hs-lint ()
1061   "Run HLint for current buffer with haskell source"
1062   (interactive)
1063   (save-some-buffers hs-lint-save-files)
1064   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1065                      'hs-lint-mode))
1066
1067 (provide 'hs-lint)
1068 ;;; hs-lint.el ends here
1069 #+end_src
1070
1071 #+begin_src emacs-lisp :tangle no
1072 (use-package hs-lint
1073   :load-path "lisp/"
1074   :bind (:map haskell-mode-map
1075               ("C-c l l" . hs-lint)))
1076 #+end_src
1077 * Emacs Enhancements
1078
1079 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1080
1081 #+begin_quote
1082 Emacs package that displays available keybindings in popup
1083 #+end_quote
1084
1085 #+begin_src emacs-lisp
1086 (use-package which-key
1087   :defer 1
1088   :config (which-key-mode))
1089 #+end_src
1090
1091 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1092
1093 #+begin_src emacs-lisp
1094 (use-package doom-modeline
1095   :demand t
1096   :config (setq doom-modeline-height 32)
1097   :hook (after-init . doom-modeline-init))
1098 #+end_src
1099
1100 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1101
1102 #+begin_src emacs-lisp :tangle no
1103 (use-package tao-theme
1104   :demand t
1105   :config (load-theme 'tao-yang t))
1106 #+end_src
1107
1108 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1109
1110 #+begin_src emacs-lisp
1111 (load-theme 'eink t)
1112 #+end_src
1113
1114 ** [[https://github.com/bbatsov/crux][crux]]
1115
1116 #+begin_src emacs-lisp
1117 (use-package crux
1118   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1119          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1120          ("C-c b K" . crux-kill-other-buffers)
1121          ("C-c f c" . crux-copy-file-preserve-attributes)
1122          ("C-c f D" . crux-delete-file-and-buffer)
1123          ("C-c f R" . crux-rename-file-and-buffer)))
1124 #+end_src
1125
1126 ** [[https://github.com/alezost/mwim.el][mwim]]
1127
1128 #+begin_src emacs-lisp
1129 (use-package mwim
1130   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1131          ("C-e"    . mwim-end-of-code-or-line)
1132          ("<home>" . mwim-beginning-of-line-or-code)
1133          ("<end>"  . mwim-end-of-line-or-code)))
1134 #+end_src
1135
1136 ** projectile
1137
1138 #+begin_src emacs-lisp
1139 (use-package projectile
1140   :defer 5
1141   :bind-keymap ("C-c p" . projectile-command-map)
1142   :config
1143   (projectile-mode)
1144
1145   (defun my-projectile-invalidate-cache (&rest _args)
1146     ;; ignore the args to `magit-checkout'
1147     (projectile-invalidate-cache nil))
1148
1149   (eval-after-load 'magit-branch
1150     '(progn
1151        (advice-add 'magit-checkout
1152                    :after #'my-projectile-invalidate-cache)
1153        (advice-add 'magit-branch-and-checkout
1154                    :after #'my-projectile-invalidate-cache))))
1155 #+end_src
1156
1157 * Email
1158 ** [[https://notmuchmail.org][notmuch]]
1159
1160 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1161
1162 #+begin_src emacs-lisp
1163 (defvar amin-maildir "~/mail")
1164
1165 (use-package sendmail
1166   ;; :ensure nil
1167   :config
1168   (setq sendmail-program "/usr/bin/msmtp"
1169         ; message-sendmail-extra-arguments '("-v" "-d")
1170         mail-specify-envelope-from t
1171         mail-envelope-from 'header))
1172
1173 (use-package message
1174   ;; :ensure nil
1175   :config
1176   (setq message-kill-buffer-on-exit t
1177         message-send-mail-function 'message-send-mail-with-sendmail
1178         message-sendmail-envelope-from 'header
1179         message-directory "drafts"
1180         message-user-fqdn "aminb.org")
1181   (add-hook 'message-mode-hook
1182             (lambda () (setq fill-column 65
1183                         message-fill-column 65)))
1184   (add-hook 'message-mode-hook
1185             #'flyspell-mode)
1186   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1187   ;; TODO: is there a way to only run this when replying and not composing?
1188   ;; (add-hook 'notmuch-message-mode-hook
1189   ;;           (lambda () (progn
1190   ;;                   (newline)
1191   ;;                   (newline)
1192   ;;                   (forward-line -1)
1193   ;;                   (forward-line -1))))
1194   ;; (add-hook 'message-setup-hook
1195   ;;           #'mml-secure-message-sign-pgpmime)
1196   )
1197
1198 (after! mml-sec
1199   (setq mml-secure-openpgp-encrypt-to-self t
1200         mml-secure-openpgp-sign-with-sender t))
1201
1202 (defun amin/notmuch ()
1203   "Delete other windows, then launch `notmuch'."
1204   (interactive)
1205   (delete-other-windows)
1206   (notmuch))
1207
1208 (use-package notmuch
1209   :commands notmuch
1210   :bind ("C-c m" . amin/notmuch)
1211   :custom (notmuch-always-prompt-for-sender t)
1212   :config
1213   (setq notmuch-hello-sections
1214         '(notmuch-hello-insert-header
1215           notmuch-hello-insert-saved-searches
1216           ;; notmuch-hello-insert-search
1217           notmuch-hello-insert-alltags)
1218         notmuch-search-oldest-first nil
1219         notmuch-show-all-tags-list t
1220         notmuch-message-headers  ; see bug follow-up above
1221         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1222         notmuch-hello-thousands-separator ","
1223         notmuch-fcc-dirs
1224         '(("amin@aminb.org"        . "amin/Sent")
1225           ("amin@gnu.org"          . "gnu/Sent")
1226           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1227           ("mab@gnu.org"           . "gnu/Sent")
1228           ("aminb@gnu.org"         . "gnu/Sent")
1229           (".*"                    . "sent"))
1230         notmuch-search-result-format
1231         '(("date"    . "%12s ")
1232           ("count"   . "%-7s ")
1233           ("authors" . "%-40s ")
1234           ("subject" . "%s ")
1235           ("tags"    . "(%s)"))
1236         notmuch-saved-searches
1237         '((:name "inbox"     :query "tag:inbox"     :key "i")
1238           (:name "unread"    :query "tag:unread"    :key "u")
1239           (:name "latest"    :query "tag:latest"    :key "l")
1240           (:name "encrypted" :query "tag:encrypted" :key "e")
1241           (:name "flagged"   :query "tag:flagged"   :key "f")
1242           (:name "sent"      :query "tag:sent"      :key "s")
1243           (:name "drafts"    :query "tag:draft"     :key "d")
1244           (:name "all mail"  :query "*"             :key "a")))
1245   ;; (add-hook 'visual-fill-column-mode-hook
1246   ;;           (lambda ()
1247   ;;             (when (string= major-mode 'notmuch-message-mode)
1248   ;;               (setq visual-fill-column-width 70))))
1249   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1250   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1251   ;;             :override #'kill-this-buffer)
1252   :bind
1253   (:map notmuch-hello-mode-map
1254         ("u" . (lambda ()
1255                  "Search for `unread'-tagged messages"
1256                  (interactive)
1257                  (notmuch-hello-search "tag:unread")))
1258         ("i" . (lambda ()
1259                  "Search for `inbox'-tagged messages"
1260                  (interactive)
1261                  (notmuch-hello-search "tag:inbox")))
1262         ("l" . (lambda ()
1263                  "Search for `latest'-tagged messages"
1264                  (interactive)
1265                  (notmuch-hello-search "tag:latest")))
1266         ("e" . (lambda ()
1267                  "Search for `encrypted'-tagged messages"
1268                  (interactive)
1269                  (notmuch-hello-search "tag:encrypted"))))
1270   (:map notmuch-search-mode-map
1271         ("k" . (lambda ()
1272                  "Mark message read"
1273                  (interactive)
1274                  (notmuch-search-tag '("-unread"))
1275                  ;; (notmuch-search-archive-thread)
1276                  (notmuch-search-next-thread)))
1277         ("u" . (lambda ()
1278                  "Mark message unread"
1279                  (interactive)
1280                  (notmuch-search-tag '("+unread"))
1281                  (notmuch-search-next-thread)))
1282         ("K" . (lambda ()
1283                  "Mark message deleted"
1284                  (interactive)
1285                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1286                  (notmuch-search-next-thread)))
1287         ("S" . (lambda ()
1288                  "Mark message as spam"
1289                  (interactive)
1290                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1291                  (notmuch-search-next-thread))))
1292   (:map notmuch-tree-mode-map
1293         ("k" . (lambda ()
1294                  "Mark message read"
1295                  (interactive)
1296                  (notmuch-tree-tag '("-unread"))
1297                  ;; (notmuch-tree-archive-thread)
1298                  (notmuch-tree-next-message)))
1299         ("u" . (lambda ()
1300                  "Mark message unread"
1301                  (interactive)
1302                  (notmuch-tree-tag '("+unread"))
1303                  (notmuch-tree-next-message)))
1304         ("K" . (lambda ()
1305                  "Mark message deleted"
1306                  (interactive)
1307                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
1308                  (notmuch-tree-next-message)))
1309         ("S" . (lambda ()
1310                  "Mark message as spam"
1311                  (interactive)
1312                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1313                  (notmuch-tree-next-message)))))
1314
1315 (use-package counsel-notmuch
1316   :bind ("C-c s m" . counsel-notmuch))
1317
1318 (after! notmuch-crypto
1319   (setq notmuch-crypto-process-mime t))
1320
1321 (after! recentf
1322   (add-to-list 'recentf-exclude (expand-file-name amin-maildir)))
1323 #+end_src
1324
1325 ** supercite
1326
1327 #+begin_src emacs-lisp :tangle no
1328 (use-package supercite
1329   :commands sc-cite-original
1330   :init
1331   (add-hook 'mail-citation-hook 'sc-cite-original)
1332
1333   (defun sc-remove-existing-signature ()
1334     (save-excursion
1335       (goto-char (region-beginning))
1336       (when (re-search-forward message-signature-separator (region-end) t)
1337         (delete-region (match-beginning 0) (region-end)))))
1338
1339   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1340
1341   (defun sc-remove-if-not-mailing-list ()
1342     (unless (assoc "list-id" sc-mail-info)
1343       (setq attribution sc-default-attribution
1344             citation (concat sc-citation-delimiter
1345                              sc-citation-separator))))
1346
1347   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1348
1349   :config
1350   (defun sc-fill-if-different (&optional prefix)
1351     "Fill the region bounded by `sc-fill-begin' and point.
1352 Only fill if optional PREFIX is different than
1353 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1354 fill region.  If PREFIX is not supplied, initialize fill
1355 variables.  This is useful for a regi `begin' frame-entry."
1356     (if (not prefix)
1357         (setq sc-fill-line-prefix ""
1358               sc-fill-begin (line-beginning-position))
1359       (if (and sc-auto-fill-region-p
1360                (not (string= prefix sc-fill-line-prefix)))
1361           (let ((fill-prefix sc-fill-line-prefix))
1362             (unless (or (string= fill-prefix "")
1363                         (save-excursion
1364                           (goto-char sc-fill-begin)
1365                           (or (looking-at ">+  +")
1366                               (< (length
1367                                   (buffer-substring (point)
1368                                                     (line-end-position)))
1369                                  65))))
1370               (fill-region sc-fill-begin (line-beginning-position)))
1371             (setq sc-fill-line-prefix prefix
1372                   sc-fill-begin (line-beginning-position)))))
1373 nil))
1374 #+end_src
1375
1376 * Blogging
1377 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1378
1379 #+begin_src emacs-lisp
1380 (use-package ox-hugo
1381   :after ox)
1382 #+end_src
1383
1384 * Post initialization
1385 :PROPERTIES:
1386 :CUSTOM_ID: post-initialization
1387 :END:
1388
1389 Display how long it took to load the init file.
1390
1391 #+begin_src emacs-lisp
1392 (message "Loading %s...done (%.3fs)" user-init-file
1393          (float-time (time-subtract (current-time)
1394                                     amin--before-user-init-time)))
1395 #+end_src
1396
1397 * Footer
1398 :PROPERTIES:
1399 :CUSTOM_ID: footer
1400 :END:
1401
1402 #+begin_src emacs-lisp :comments none
1403 ;;; init.el ends here
1404 #+end_src