git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 Note: using =i3status= on sway at the moment, so disabling this.
 446
 447 #+begin_src emacs-lisp :tangle no
 448 (use-package time
 449   :ensure nil
 450   :init
 451   (setq display-time-default-load-average nil)
 452   :config
 453   (display-time-mode))
 454
 455 (use-package battery
 456   :ensure nil
 457   :config
 458   (display-battery-mode))
 459 #+end_src
 460
 461 *** Smaller fringe
 462
 463 Might want to set the fringe to a smaller value, especially if using
 464 EXWM. I'm fine with the default for now.
 465
 466 #+begin_src emacs-lisp
 467 ;; (fringe-mode '(3 . 1))
 468 (fringe-mode nil)
 469 #+end_src
 470
 471 *** Disable disabled commands
 472
 473 Emacs disables some commands by default that could persumably be
 474 confusing for novice users. Let's disable that.
 475
 476 #+begin_src emacs-lisp
 477 (setq disabled-command-function nil)
 478 #+end_src
 479
 480 *** Kill-ring
 481
 482 Save what I copy into clipboard from other applications into Emacs'
 483 kill-ring, which would allow me to still be able to easily access it
 484 in case I kill (cut or copy) something else inside Emacs before
 485 yanking (pasting) what I'd originally intended to.
 486
 487 #+begin_src emacs-lisp
 488 (setq save-interprogram-paste-before-kill t)
 489 #+end_src
 490
 491 *** Minibuffer
 492
 493 #+begin_src emacs-lisp
 494 (setq enable-recursive-minibuffers t
 495       resize-mini-windows t)
 496 #+end_src
 497
 498 *** Lazy-person-friendly yes/no prompts
 499
 500 Lazy people would prefer to type fewer keystrokes, especially for yes
 501 or no questions. I'm lazy.
 502
 503 #+begin_src emacs-lisp
 504 (defalias 'yes-or-no-p #'y-or-n-p)
 505 #+end_src
 506
 507 *** Startup screen and =*scratch*=
 508
 509 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 510 startup buffer.
 511
 512 #+begin_src emacs-lisp
 513 (setq initial-buffer-choice t)
 514 #+end_src
 515
 516 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 517 need the default hint.
 518
 519 #+begin_src emacs-lisp
 520 (setq initial-scratch-message nil)
 521 #+end_src
 522
 523 Also, let's use Text mode as the major mode, in case I want to
 524 customize it (=*scratch*='s default major mode, Fundamental mode,
 525 can't really be customized).
 526
 527 #+begin_src emacs-lisp
 528 (setq initial-major-mode 'text-mode)
 529 #+end_src
 530
 531 Inhibit the buffer list when more than 2 files are loaded.
 532
 533 #+begin_src emacs-lisp
 534 (setq inhibit-startup-buffer-menu t)
 535 #+end_src
 536
 537 I don't really need to see the startup screen or echo area message
 538 either.
 539
 540 #+begin_src emacs-lisp
 541 (advice-add #'display-startup-echo-area-message :override #'ignore)
 542 (setq inhibit-startup-screen t
 543       inhibit-startup-echo-area-message user-login-name)
 544 #+end_src
 545
 546 *** More useful frame titles
 547
 548 Show either the file name or the buffer name (in case the buffer isn't
 549 visiting a file). Borrowed from Emacs Prelude.
 550
 551 #+begin_src emacs-lisp
 552 (setq frame-title-format
 553       '("" invocation-name " - "
 554         (:eval (if (buffer-file-name)
 555                    (abbreviate-file-name (buffer-file-name))
 556                  "%b"))))
 557 #+end_src
 558
 559 *** Backups
 560
 561 Emacs' default backup settings aren't that great. Let's use more
 562 sensible options. See documentation for the ~make-backup-file~
 563 variable.
 564
 565 #+begin_src emacs-lisp
 566 (setq backup-by-copying t
 567       version-control t)
 568 #+end_src
 569
 570 *** Auto revert
 571
 572 Enable automatic reloading of changed buffers and files.
 573
 574 #+begin_src emacs-lisp
 575 (global-auto-revert-mode 1)
 576 (setq auto-revert-verbose nil
 577       global-auto-revert-non-file-buffers t)
 578 #+end_src
 579
 580 *** Always use space for indentation
 581
 582 #+begin_src emacs-lisp
 583 (setq-default
 584  indent-tabs-mode nil
 585  require-final-newline t
 586  tab-width 4)
 587 #+end_src
 588
 589 ** Packages
 590
 591 The packages in this section are absolutely essential to my everyday
 592 workflow, and they play key roles in how I do my computing. They
 593 immensely enhance the Emacs experience for me; both using Emacs, and
 594 customizing it.
 595
 596 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 597
 598 #+begin_src emacs-lisp
 599 (use-package auto-compile
 600   :demand t
 601   :config
 602   (auto-compile-on-load-mode)
 603   (auto-compile-on-save-mode)
 604   (setq auto-compile-display-buffer               nil
 605         auto-compile-mode-line-counter            t
 606         auto-compile-source-recreate-deletes-dest t
 607         auto-compile-toggle-deletes-nonlib-dest   t
 608         auto-compile-update-autoloads             t)
 609   (add-hook 'auto-compile-inhibit-compile-hook
 610             'auto-compile-inhibit-compile-detached-git-head))
 611 #+end_src
 612
 613 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 614
 615 #+begin_quote
 616 Roll your own modal mode
 617 #+end_quote
 618
 619 #+begin_src emacs-lisp
 620 (use-package ryo-modal
 621   :commands ryo-modal-mode
 622   :bind ("M-m" . ryo-modal-mode)
 623   :after which-key
 624   :config
 625   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 626   (ryo-modal-keys
 627    ("," ryo-modal-repeat)
 628    ("b" backward-char)
 629    ("n" next-line)
 630    ("p" previous-line)
 631    ("f" forward-char)
 632    ("/" undo)
 633    ("i" ryo-modal-mode)
 634    ("l" recenter-top-bottom)
 635    ("v" scroll-up-command)
 636    ("V" scroll-down-command)
 637    ("x" delete-forward-char)
 638    ("SPC" (("b" (("b" ibuffer-list-buffers)
 639                  ("k" kill-this-buffer)
 640                  ("o" other-window)
 641                  ("s" save-buffer)))
 642            ("B" (("A" borg-activate)
 643                  ("a" borg-assimilate)
 644                  ("b" borg-build)
 645                  ("c" borg-clone)
 646                  ("r" borg-remove)))
 647            ("h" (("c" describe-char)
 648                  ("f" describe-function)
 649                  ("F" describe-face)
 650                  ("i" info)
 651                  ("k" describe-key)
 652                  ("l" view-lossage)
 653                  ("v" describe-variable)))
 654            ("q" (("q" save-buffers-kill-terminal)))))
 655    ("d" (("w" kill-word)
 656          ("b" backward-kill-word)))
 657    ("c w" kill-word :exit t))
 658
 659   (ryo-modal-keys
 660    ;; First argyment to ryo-modal-keys may be a list of keywords.
 661    ;; These keywords will be applied to all keybindings.
 662    (:norepeat t)
 663    ("0" "M-0")
 664    ("1" "M-1")
 665    ("2" "M-2")
 666    ("3" "M-3")
 667    ("4" "M-4")
 668    ("5" "M-5")
 669    ("6" "M-6")
 670    ("7" "M-7")
 671    ("8" "M-8")
 672    ("9" "M-9"))
 673   :hook ((text-mode . ryo-modal-mode)
 674          (prog-mode . ryo-modal-mode)))
 675 #+end_src
 676
 677 *** [[https://orgmode.org/][Org mode]]
 678
 679 #+begin_quote
 680 Org mode is for keeping notes, maintaining TODO lists, planning
 681 projects, and authoring documents with a fast and effective plain-text
 682 system.
 683 #+end_quote
 684
 685 In short, my favourite way of life.
 686
 687 #+begin_src emacs-lisp
 688 (use-package org
 689   :ryo ("SPC b t" org-babel-tangle)
 690   :config
 691   (setq org-src-tab-acts-natively t
 692         org-src-preserve-indentation nil
 693         org-edit-src-content-indentation 0
 694         org-html-divs '((preamble  "header" "preamble")
 695                         (content   "main"   "content")
 696                         (postamble "footer" "postamble"))
 697         org-html-doctype "html5"
 698         org-html-html5-fancy t
 699         org-html-postamble nil)
 700   :hook (org-mode . org-indent-mode))
 701 (use-package htmlize
 702   :after org)
 703 (use-package org-notmuch
 704   :after (:any org notmuch))
 705 #+end_src
 706
 707 *** [[https://magit.vc/][Magit]]
 708
 709 #+begin_quote
 710 It's Magit! A Git porcelain inside Emacs.
 711 #+end_quote
 712
 713 Not just how I do git, but /the/ way to do git.
 714
 715 #+begin_src emacs-lisp
 716 (use-package magit
 717   :ryo ("SPC" (("g s" magit-status)))
 718   :defer t
 719   :bind (("s-g"     . magit-status)
 720          ("C-x g"   . magit-status)
 721          ("C-x M-g" . magit-dispatch-popup))
 722   :config
 723   (magit-add-section-hook 'magit-status-sections-hook
 724                           'magit-insert-modules
 725                           'magit-insert-stashes
 726                           'append))
 727 #+end_src
 728
 729 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 730
 731 #+begin_quote
 732 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 733 an overview, and more. Oh, man!
 734 #+end_quote
 735
 736 There's no way I could top that, so I won't attempt to.
 737
 738 **** Ivy
 739
 740 #+begin_src emacs-lisp
 741 (use-package ivy
 742   :defer 1
 743   :bind
 744   (:map ivy-minibuffer-map
 745         ([escape] . keyboard-escape-quit)
 746         ;; ("C-j"    . ivy-next-line)
 747         ;; ("C-k"    . ivy-previous-line)
 748         ([S-up]   . ivy-previous-history-element)
 749         ([S-down] . ivy-next-history-element)
 750         ("DEL"    . ivy-backward-delete-char))
 751   :ryo ("SPC ," ivy-switch-buffer)
 752   :config
 753   (setq ivy-wrap t)
 754   (ivy-mode 1))
 755 #+end_src
 756
 757 **** Swiper
 758
 759 #+begin_src emacs-lisp
 760 (use-package swiper
 761   :ryo
 762   ("SPC /" swiper)
 763   ("s" swiper)
 764   :bind (([remap isearch-forward]  . swiper)
 765          ([remap isearch-backward] . swiper)))
 766 #+end_src
 767
 768 **** Counsel
 769
 770 #+begin_src emacs-lisp
 771 (use-package counsel
 772   :defer 1
 773   :ryo
 774   ("SPC" (("f r" counsel-recentf)
 775           ("SPC" counsel-M-x)
 776           ("."   counsel-find-file)))
 777   :bind (([remap execute-extended-command] . counsel-M-x)
 778          ([remap find-file] . counsel-find-file)
 779          ("s-r"     . counsel-recentf)
 780          :map minibuffer-local-map
 781          ("C-r" . counsel-minibuffer-history))
 782   :config
 783   (counsel-mode 1)
 784   (defalias 'locate #'counsel-locate))
 785 #+end_src
 786
 787 * Borg's =layer/essentials=
 788
 789 TODO: break this giant source block down into individual org sections.
 790
 791 #+begin_src emacs-lisp
 792 (use-package dash
 793   :config (dash-enable-font-lock))
 794
 795 (use-package diff-hl
 796   :config
 797   (setq diff-hl-draw-borders nil)
 798   (global-diff-hl-mode)
 799   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 800
 801 (use-package dired
 802   :defer t
 803   :config (setq dired-listing-switches "-alh"))
 804
 805 (use-package eldoc
 806   :when (version< "25" emacs-version)
 807   :config (global-eldoc-mode))
 808
 809 (use-package help
 810   :defer t
 811   :config (temp-buffer-resize-mode))
 812
 813 (progn ;    `isearch'
 814   (setq isearch-allow-scroll t))
 815
 816 (use-package lisp-mode
 817   :config
 818   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 819   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 820   (defun indent-spaces-mode ()
 821     (setq indent-tabs-mode nil))
 822   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 823
 824 (use-package man
 825   :defer t
 826   :config (setq Man-width 80))
 827
 828 (use-package paren
 829   :config (show-paren-mode))
 830
 831 (use-package prog-mode
 832   :config (global-prettify-symbols-mode)
 833   (defun indicate-buffer-boundaries-left ()
 834     (setq indicate-buffer-boundaries 'left))
 835   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 836
 837 (use-package recentf
 838   :demand t
 839   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 840
 841 (use-package savehist
 842   :config (savehist-mode))
 843
 844 (use-package saveplace
 845   :when (version< "25" emacs-version)
 846   :config (save-place-mode))
 847
 848 (use-package simple
 849   :config (column-number-mode))
 850
 851 (progn ;    `text-mode'
 852   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 853
 854 (use-package tramp
 855   :defer t
 856   :config
 857   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 858   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 859   (add-to-list 'tramp-default-proxies-alist
 860                (list (regexp-quote (system-name)) nil nil)))
 861
 862 (use-package undo-tree
 863   :ryo
 864   ("?" undo-tree-undo)
 865   ("_" undo-tree-redo)
 866   :bind (("C-?" . undo-tree-undo)
 867          ("M-_" . undo-tree-redo))
 868   :config
 869   (global-undo-tree-mode)
 870   (setq undo-tree-mode-lighter ""
 871         undo-tree-auto-save-history t))
 872 #+end_src
 873
 874 * Editing
 875
 876 ** Company
 877
 878 #+begin_src emacs-lisp
 879 (use-package company
 880   :defer 5
 881   :bind
 882   (:map company-active-map
 883         ([tab] . company-complete-common-or-cycle))
 884   :custom
 885   (company-idle-delay 0.3)
 886   (company-minimum-prefix-length 1)
 887   (company-selection-wrap-around t)
 888   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 889   :config
 890   (global-company-mode t))
 891 #+end_src
 892
 893 * Syntax and spell checking
 894 #+begin_src emacs-lisp
 895 (use-package flycheck
 896   :hook (prog-mode . flycheck-mode)
 897   :config
 898   ;; Use the load-path from running Emacs when checking elisp files
 899   (setq flycheck-emacs-lisp-load-path 'inherit)
 900
 901   ;; Only flycheck when I actually save the buffer
 902   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 903 #+end_src
 904 * Programming modes
 905
 906 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 907
 908 #+begin_src emacs-lisp
 909 (use-package alloy-mode
 910   :config (setq alloy-basic-offset 2))
 911 #+end_src
 912
 913 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 914
 915 #+begin_src emacs-lisp
 916 (use-package proof-site  ; Proof General
 917   :load-path "lib/proof-site/generic/")
 918 #+end_src
 919
 920 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 921
 922 #+begin_src emacs-lisp
 923 (use-package lean-mode
 924   :bind (:map lean-mode-map
 925               ("S-SPC" . company-complete)))
 926 #+end_src
 927
 928 ** Haskell
 929
 930 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 931
 932 #+begin_src emacs-lisp
 933 (use-package haskell-mode
 934   :config
 935   (setq haskell-indentation-layout-offset 4
 936         haskell-indentation-left-offset 4
 937         flycheck-checker 'haskell-hlint
 938         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 939 #+end_src
 940
 941 *** [[https://github.com/jyp/dante][dante]]
 942
 943 #+begin_src emacs-lisp
 944 (use-package dante
 945   :after haskell-mode
 946   :commands dante-mode
 947   :hook (haskell-mode . dante-mode))
 948 #+end_src
 949
 950 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 951
 952 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 953 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 954
 955 #+begin_src emacs-lisp
 956 (use-package hlint-refactor
 957   :bind (:map hlint-refactor-mode-map
 958               ("C-c l b" . hlint-refactor-refactor-buffer)
 959               ("C-c l r" . hlint-refactor-refactor-at-point))
 960   :hook (haskell-mode . hlint-refactor-mode))
 961 #+end_src
 962
 963 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 964
 965 #+begin_src emacs-lisp
 966 (use-package flycheck-haskell)
 967 #+end_src
 968
 969 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 970 :PROPERTIES:
 971 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 972 :END:
 973
 974 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 975 instead.
 976
 977 #+begin_src emacs-lisp :tangle no
 978 ;;; hs-lint.el --- minor mode for HLint code checking
 979
 980 ;; Copyright 2009 (C) Alex Ott
 981 ;;
 982 ;; Author: Alex Ott <alexott@gmail.com>
 983 ;; Keywords: haskell, lint, HLint
 984 ;; Requirements:
 985 ;; Status: distributed under terms of GPL2 or above
 986
 987 ;; Typical message from HLint looks like:
 988 ;;
 989 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 990 ;; Found:
 991 ;;   count1 p l = length (filter p l)
 992 ;; Why not:
 993 ;;   count1 p = length . filter p
 994
 995
 996 (require 'compile)
 997
 998 (defgroup hs-lint nil
 999   "Run HLint as inferior of Emacs, parse error messages."
1000   :group 'tools
1001   :group 'haskell)
1002
1003 (defcustom hs-lint-command "hlint"
1004   "The default hs-lint command for \\[hlint]."
1005   :type 'string
1006   :group 'hs-lint)
1007
1008 (defcustom hs-lint-save-files t
1009   "Save modified files when run HLint or no (ask user)"
1010   :type 'boolean
1011   :group 'hs-lint)
1012
1013 (defcustom hs-lint-replace-with-suggestions nil
1014   "Replace user's code with suggested replacements"
1015   :type 'boolean
1016   :group 'hs-lint)
1017
1018 (defcustom hs-lint-replace-without-ask nil
1019   "Replace user's code with suggested replacements automatically"
1020   :type 'boolean
1021   :group 'hs-lint)
1022
1023 (defun hs-lint-process-setup ()
1024   "Setup compilation variables and buffer for `hlint'."
1025   (run-hooks 'hs-lint-setup-hook))
1026
1027 ;; regex for replace suggestions
1028 ;;
1029 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1030 ;; Found:
1031 ;; \s +\(.*\)
1032 ;; Why not:
1033 ;; \s +\(.*\)
1034
1035 (defvar hs-lint-regex
1036   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1037   "Regex for HLint messages")
1038
1039 (defun make-short-string (str maxlen)
1040   (if (< (length str) maxlen)
1041       str
1042     (concat (substring str 0 (- maxlen 3)) "...")))
1043
1044 (defun hs-lint-replace-suggestions ()
1045   "Perform actual replacement of suggestions"
1046   (goto-char (point-min))
1047   (while (re-search-forward hs-lint-regex nil t)
1048     (let* ((fname (match-string 1))
1049           (fline (string-to-number (match-string 2)))
1050           (old-code (match-string 4))
1051           (new-code (match-string 5))
1052           (msg (concat "Replace '" (make-short-string old-code 30)
1053                        "' with '" (make-short-string new-code 30) "'"))
1054           (bline 0)
1055           (eline 0)
1056           (spos 0)
1057           (new-old-code ""))
1058       (save-excursion
1059         (switch-to-buffer (get-file-buffer fname))
1060         (goto-char (point-min))
1061         (forward-line (1- fline))
1062         (beginning-of-line)
1063         (setf bline (point))
1064         (when (or hs-lint-replace-without-ask
1065                   (yes-or-no-p msg))
1066           (end-of-line)
1067           (setf eline (point))
1068           (beginning-of-line)
1069           (setf old-code (regexp-quote old-code))
1070           (while (string-match "\\\\ " old-code spos)
1071             (setf new-old-code (concat new-old-code
1072                                  (substring old-code spos (match-beginning 0))
1073                                  "\\ *"))
1074             (setf spos (match-end 0)))
1075           (setf new-old-code (concat new-old-code (substring old-code spos)))
1076           (remove-text-properties bline eline '(composition nil))
1077           (when (re-search-forward new-old-code eline t)
1078             (replace-match new-code nil t)))))))
1079
1080 (defun hs-lint-finish-hook (buf msg)
1081   "Function, that is executed at the end of HLint execution"
1082   (if hs-lint-replace-with-suggestions
1083       (hs-lint-replace-suggestions)
1084       (next-error 1 t)))
1085
1086 (define-compilation-mode hs-lint-mode "HLint"
1087   "Mode for check Haskell source code."
1088   (set (make-local-variable 'compilation-process-setup-function)
1089        'hs-lint-process-setup)
1090   (set (make-local-variable 'compilation-disable-input) t)
1091   (set (make-local-variable 'compilation-scroll-output) nil)
1092   (set (make-local-variable 'compilation-finish-functions)
1093        (list 'hs-lint-finish-hook))
1094   )
1095
1096 (defun hs-lint ()
1097   "Run HLint for current buffer with haskell source"
1098   (interactive)
1099   (save-some-buffers hs-lint-save-files)
1100   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1101                      'hs-lint-mode))
1102
1103 (provide 'hs-lint)
1104 ;;; hs-lint.el ends here
1105 #+end_src
1106
1107 #+begin_src emacs-lisp :tangle no
1108 (use-package hs-lint
1109   :load-path "lisp/"
1110   :bind (:map haskell-mode-map
1111               ("C-c l l" . hs-lint)))
1112 #+end_src
1113 * Emacs Enhancements
1114
1115 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1116
1117 #+begin_quote
1118 Emacs package that displays available keybindings in popup
1119 #+end_quote
1120
1121 #+begin_src emacs-lisp
1122 (use-package which-key
1123   :defer 1
1124   :config (which-key-mode))
1125 #+end_src
1126
1127 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1128
1129 #+begin_src emacs-lisp
1130 (use-package doom-modeline
1131   :demand t
1132   :config (setq doom-modeline-height 32)
1133   :hook (after-init . doom-modeline-init))
1134 #+end_src
1135
1136 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1137
1138 #+begin_src emacs-lisp :tangle no
1139 (use-package tao-theme
1140   :demand t
1141   :config (load-theme 'tao-yang t))
1142 #+end_src
1143
1144 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1145
1146 #+begin_src emacs-lisp
1147 (load-theme 'eink t)
1148 #+end_src
1149
1150 ** [[https://github.com/bbatsov/crux][crux]]
1151
1152 #+begin_src emacs-lisp
1153 (use-package crux
1154   :bind (("C-c d"    . crux-duplicate-current-line-or-region)
1155          ("C-c M-d"  . crux-duplicate-and-comment-current-line-or-region))
1156   :ryo
1157   ("o" crux-smart-open-line :exit t)
1158   ("O" crux-smart-open-line-above :exit t)
1159   ("SPC b K" crux-kill-other-buffers)
1160   ("d d" crux-kill-whole-line)
1161   ("c c" crux-kill-whole-line :then '(crux-smart-open-line-above) :exit t)
1162   ("SPC f" (("c" crux-copy-file-preserve-attributes)
1163             ("D" crux-delete-file-and-buffer)
1164             ("R" crux-rename-file-and-buffer))))
1165 #+end_src
1166
1167 ** [[https://github.com/alezost/mwim.el][mwim]]
1168
1169 #+begin_src emacs-lisp
1170 (use-package mwim
1171   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1172          ("C-e"    . mwim-end-of-code-or-line)
1173          ("<home>" . mwim-beginning-of-line-or-code)
1174          ("<end>"  . mwim-end-of-line-or-code))
1175   :ryo
1176   ("a" mwim-beginning-of-code-or-line)
1177   ("e" mwim-end-of-code-or-line))
1178 #+end_src
1179
1180 ** [[https://www.emacswiki.org/emacs/KeyChord][key-chord]]
1181
1182 #+begin_src emacs-lisp
1183 (use-package key-chord
1184   :demand t
1185   :config
1186   (key-chord-mode 1)
1187   (key-chord-define-global "jk" 'ryo-modal-mode)
1188   (setq key-chord-one-key-delay 0 ; i don't need one-key chords for now
1189         key-chord-two-keys-delay 0.005))
1190 #+end_src
1191
1192 * Email
1193 ** [[https://notmuchmail.org][notmuch]]
1194
1195 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1196
1197 #+begin_src emacs-lisp
1198 (defun ab/notmuch ()
1199   "Delete other windows, then launch `notmuch'."
1200   (interactive)
1201   (require 'notmuch)
1202   (delete-other-windows)
1203   (notmuch))
1204
1205 ;; (map!
1206 ;;  :leader
1207 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1208 ;;  (:desc "search" :prefix "/"
1209 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1210 #+end_src
1211
1212 #+begin_src emacs-lisp
1213 (defvar ab-maildir "~/mail")
1214
1215 (use-package sendmail
1216   ;; :ensure nil
1217   :config
1218   (setq sendmail-program "/usr/bin/msmtp"
1219         ; message-sendmail-extra-arguments '("-v" "-d")
1220         mail-specify-envelope-from t
1221         mail-envelope-from 'header))
1222
1223 (use-package message
1224   ;; :ensure nil
1225   :config
1226   (setq message-kill-buffer-on-exit t
1227         message-send-mail-function 'message-send-mail-with-sendmail
1228         message-sendmail-envelope-from 'header
1229         message-directory "drafts"
1230         message-user-fqdn "aminb.org")
1231   (add-hook 'message-mode-hook
1232             (lambda () (setq fill-column 65
1233                         message-fill-column 65)))
1234   (add-hook 'message-mode-hook
1235             #'flyspell-mode)
1236   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1237   ;; TODO: is there a way to only run this when replying and not composing?
1238   ;; (add-hook 'notmuch-message-mode-hook
1239   ;;           (lambda () (progn
1240   ;;                   (newline)
1241   ;;                   (newline)
1242   ;;                   (forward-line -1)
1243   ;;                   (forward-line -1))))
1244   ;; (add-hook 'message-setup-hook
1245   ;;           #'mml-secure-message-sign-pgpmime)
1246   )
1247
1248 (after! mml-sec
1249   (setq mml-secure-openpgp-encrypt-to-self t
1250         mml-secure-openpgp-sign-with-sender t))
1251
1252 (use-package notmuch
1253   :ryo ("SPC m" ab/notmuch)
1254   :config
1255   (setq notmuch-hello-sections
1256         '(notmuch-hello-insert-header
1257           notmuch-hello-insert-saved-searches
1258           ;; notmuch-hello-insert-search
1259           notmuch-hello-insert-alltags)
1260         notmuch-search-oldest-first nil
1261         notmuch-show-all-tags-list t
1262         notmuch-message-headers  ; see bug follow-up above
1263         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1264         notmuch-hello-thousands-separator ","
1265         notmuch-fcc-dirs
1266         '(("amin@aminb.org"            . "amin/Sent")
1267           ("amin@gnu.org"              . "gnu/Sent")
1268           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1269           ("mab@gnu.org"               . "gnu/Sent")
1270           ("aminb@gnu.org"             . "gnu/Sent")
1271           (".*"                        . "sent"))
1272         notmuch-search-result-format
1273         '(("date" . "%12s ")
1274           ("count" . "%-7s ")
1275           ("authors" . "%-40s ")
1276           ("subject" . "%s ")
1277           ("tags" . "(%s)")))
1278   ;; (add-hook 'visual-fill-column-mode-hook
1279   ;;           (lambda ()
1280   ;;             (when (string= major-mode 'notmuch-message-mode)
1281   ;;               (setq visual-fill-column-width 70))))
1282   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1283   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1284   ;;             :override #'kill-this-buffer)
1285   :bind
1286   (:map notmuch-hello-mode-map
1287         ("g" . notmuch-poll-and-refresh-this-buffer)
1288         ("i" . (lambda ()
1289                  "Search for `inbox' tagged messages"
1290                  (interactive)
1291                  (notmuch-hello-search "tag:inbox")))
1292         ("u" . (lambda ()
1293                  "Search for `unread' tagged messages"
1294                  (interactive)
1295                  (notmuch-hello-search "tag:unread")))
1296         ("l" . (lambda ()
1297                  "Search for `latest tagged messages"
1298                  (interactive)
1299                  (notmuch-hello-search "tag:latest")))
1300         ("M" . (lambda ()
1301                  "Compose new mail and prompt for sender"
1302                  (interactive)
1303                  (let ((current-prefix-arg t))
1304                    (call-interactively #'notmuch-mua-new-mail)))))
1305   (:map notmuch-search-mode-map
1306         ("g" . notmuch-poll-and-refresh-this-buffer)
1307         ("k" . (lambda ()
1308                  "Mark message read"
1309                  (interactive)
1310                  (notmuch-search-tag '("-unread"))
1311                  ;; (notmuch-search-archive-thread)
1312                  (notmuch-search-next-thread)))
1313         ("u" . (lambda ()
1314                  "Mark message unread"
1315                  (interactive)
1316                  (notmuch-search-tag '("+unread"))
1317                  (notmuch-search-next-thread)))
1318         ("K" . (lambda ()
1319                  "Mark message deleted"
1320                  (interactive)
1321                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1322                  (notmuch-search-archive-thread)))
1323         ("S" . (lambda ()
1324                  "Mark message as spam"
1325                  (interactive)
1326                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1327                  (notmuch-search-archive-thread))))
1328   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1329         ("S" . (lambda ()
1330                  "Mark message as spam"
1331                  (interactive)
1332                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1333                  (notmuch-tree-archive-thread))))
1334 )
1335
1336 ;; (use-package counsel-notmuch
1337 ;;   :commands counsel-notmuch)
1338
1339 (after! notmuch-crypto
1340   (setq notmuch-crypto-process-mime t))
1341
1342 ;; (after! evil
1343 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1344 ;;         '((notmuch-hello-mode . emacs)
1345 ;;           (notmuch-search-mode . emacs)
1346 ;;           (notmuch-tree-mode . emacs))))
1347
1348 (after! recentf
1349   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1350 #+end_src
1351
1352 ** supercite
1353
1354 #+begin_src emacs-lisp :tangle no
1355 (use-package supercite
1356   :commands sc-cite-original
1357   :init
1358   (add-hook 'mail-citation-hook 'sc-cite-original)
1359
1360   (defun sc-remove-existing-signature ()
1361     (save-excursion
1362       (goto-char (region-beginning))
1363       (when (re-search-forward message-signature-separator (region-end) t)
1364         (delete-region (match-beginning 0) (region-end)))))
1365
1366   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1367
1368   (defun sc-remove-if-not-mailing-list ()
1369     (unless (assoc "list-id" sc-mail-info)
1370       (setq attribution sc-default-attribution
1371             citation (concat sc-citation-delimiter
1372                              sc-citation-separator))))
1373
1374   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1375
1376   :config
1377   (defun sc-fill-if-different (&optional prefix)
1378     "Fill the region bounded by `sc-fill-begin' and point.
1379 Only fill if optional PREFIX is different than
1380 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1381 fill region.  If PREFIX is not supplied, initialize fill
1382 variables.  This is useful for a regi `begin' frame-entry."
1383     (if (not prefix)
1384         (setq sc-fill-line-prefix ""
1385               sc-fill-begin (line-beginning-position))
1386       (if (and sc-auto-fill-region-p
1387                (not (string= prefix sc-fill-line-prefix)))
1388           (let ((fill-prefix sc-fill-line-prefix))
1389             (unless (or (string= fill-prefix "")
1390                         (save-excursion
1391                           (goto-char sc-fill-begin)
1392                           (or (looking-at ">+  +")
1393                               (< (length
1394                                   (buffer-substring (point)
1395                                                     (line-end-position)))
1396                                  65))))
1397               (fill-region sc-fill-begin (line-beginning-position)))
1398             (setq sc-fill-line-prefix prefix
1399                   sc-fill-begin (line-beginning-position)))))
1400 nil))
1401 #+end_src
1402
1403 * Blogging
1404 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1405
1406 #+begin_src emacs-lisp
1407 (use-package ox-hugo
1408   :after ox)
1409 #+end_src
1410
1411 * Post initialization
1412 :PROPERTIES:
1413 :CUSTOM_ID: post-initialization
1414 :END:
1415
1416 Display how long it took to load the init file.
1417
1418 #+begin_src emacs-lisp
1419 (message "Loading %s...done (%.3fs)" user-init-file
1420          (float-time (time-subtract (current-time)
1421                                     ab--before-user-init-time)))
1422 #+end_src
1423
1424 * Footer
1425 :PROPERTIES:
1426 :CUSTOM_ID: footer
1427 :END:
1428
1429 #+begin_src emacs-lisp :comments none
1430 ;;; init.el ends here
1431 #+end_src