git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 (require 'borg-nix-shell)
 238 (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c B A" . borg-activate)
 244    ("C-c B a" . borg-assimilate)
 245    ("C-c B b" . borg-build)
 246    ("C-c B c" . borg-clone)))
 247 #+end_src
 248
 249 *** =use-package=
 250
 251 #+begin_quote
 252 A use-package declaration for simplifying your .emacs
 253 #+end_quote
 254
 255 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 256 packages (in our case especially the latter) in a neatly organized way
 257 and without compromising on performance.
 258
 259 #+begin_src emacs-lisp
 260 (require 'use-package)
 261 (if nil  ; set to t when need to debug init
 262     (setq use-package-verbose t
 263           use-package-expand-minimally nil
 264           use-package-compute-statistics t
 265           debug-on-error t)
 266   (setq use-package-verbose nil
 267         use-package-expand-minimally t))
 268 #+end_src
 269
 270 *** Epkg
 271
 272 #+begin_quote
 273 Browse the Emacsmirror package database
 274 #+end_quote
 275
 276 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 277 database, low-level functions for querying the database, and a
 278 =package.el=-like user interface for browsing the available packages.
 279
 280 #+begin_src emacs-lisp
 281 (use-package epkg
 282   :defer t
 283   :bind
 284   (("C-c B d" . epkg-describe-package)
 285    ("C-c B p" . epkg-list-packages)
 286    ("C-c B r" . borg-remove)
 287    ("C-c B u" . epkg-update)))
 288 #+end_src
 289
 290 ** No littering in =~/.emacs.d=
 291
 292 #+begin_quote
 293 Help keeping ~/.emacs.d clean
 294 #+end_quote
 295
 296 By default, even for Emacs' built-in packages, the configuration files
 297 and persistent data are all over the place. Use =no-littering= to help
 298 contain the mess.
 299
 300 #+begin_src emacs-lisp
 301 (use-package no-littering
 302   :demand t
 303   :config
 304   (savehist-mode 1)
 305   (add-to-list 'savehist-additional-variables 'kill-ring)
 306   (save-place-mode 1)
 307   (setq auto-save-file-name-transforms
 308         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 309 #+end_src
 310
 311 ** Custom file (=custom.el=)
 312
 313 I'm not planning on using the custom file much, but even so, I
 314 definitely don't want it mixing with =init.el=. So, here; let's give
 315 it it's own file. While at it, treat themes as safe.
 316
 317 #+begin_src emacs-lisp
 318 (use-package custom
 319   :no-require t
 320   :config
 321   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 322   (when (file-exists-p custom-file)
 323     (load custom-file))
 324   (setf custom-safe-themes t))
 325 #+end_src
 326
 327 ** Better =$PATH= handling
 328
 329 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 330 in my shell.
 331
 332 #+begin_src emacs-lisp
 333 (use-package exec-path-from-shell
 334   :defer 1
 335   :init
 336   (setq exec-path-from-shell-check-startup-files nil)
 337   :config
 338   (exec-path-from-shell-initialize)
 339   ;; while we're at it, let's fix access to our running ssh-agent
 340   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 341   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 342 #+end_src
 343
 344 ** Only one custom theme at a time
 345
 346 #+begin_src emacs-lisp
 347 (defadvice load-theme (before clear-previous-themes activate)
 348   "Clear existing theme settings instead of layering them"
 349   (mapc #'disable-theme custom-enabled-themes))
 350 #+end_src
 351
 352 ** Server
 353
 354 Start server if not already running. Alternatively, can be done by
 355 issuing =emacs --daemon= in the terminal, which can be automated with
 356 a systemd service or using =brew services start emacs= on macOS. I use
 357 Emacs as my window manager (via EXWM), so I always start Emacs on
 358 login; so starting the server from inside Emacs is good enough for me.
 359
 360 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 361
 362 #+begin_src emacs-lisp
 363 (use-package server
 364   :config (or (server-running-p) (server-mode)))
 365 #+end_src
 366
 367 ** Unicode support
 368
 369 Font stack with better unicode support, around =Ubuntu Mono= and
 370 =Hack=.
 371
 372 #+begin_src emacs-lisp
 373 (dolist (ft (fontset-list))
 374   (set-fontset-font
 375    ft
 376    'unicode
 377    (font-spec :name "Ubuntu Mono"))
 378   (set-fontset-font
 379    ft
 380    'unicode
 381    (font-spec :name "DejaVu Sans Mono")
 382    nil
 383    'append)
 384   ;; (set-fontset-font
 385   ;;  ft
 386   ;;  'unicode
 387   ;;  (font-spec
 388   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 389   ;;  nil
 390   ;;  'append)
 391   ;; (set-fontset-font
 392   ;;  ft
 393   ;;  #x2115  ; ℕ
 394   ;;  (font-spec :name "DejaVu Sans Mono")
 395   ;;  nil
 396   ;;  'append)
 397   (set-fontset-font
 398    ft
 399    (cons ?Α ?ω)
 400    (font-spec :name "DejaVu Sans Mono" :size 14)
 401    nil
 402    'prepend))
 403 #+end_src
 404
 405 ** Libraries
 406
 407 #+begin_src emacs-lisp
 408 (require 'cl-lib)
 409 (require 'subr-x)
 410 #+end_src
 411
 412 ** Useful utilities
 413
 414 #+begin_src emacs-lisp
 415 (defun amin-enlist (exp)
 416   "Return EXP wrapped in a list, or as-is if already a list."
 417 (if (listp exp) exp (list exp)))
 418
 419 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 420 (defmacro after! (features &rest body)
 421   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 422 compilation."
 423   (declare (indent defun) (debug t))
 424   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 425                 (dolist (next (amin-enlist features))
 426                   (if (symbolp next)
 427                       (require next nil :no-error)
 428                     (load next :no-message :no-error))))
 429             #'progn
 430           #'with-no-warnings)
 431         (cond ((symbolp features)
 432                `(eval-after-load ',features '(progn ,@body)))
 433               ((and (consp features)
 434                     (memq (car features) '(:or :any)))
 435                `(progn
 436                   ,@(cl-loop for next in (cdr features)
 437                              collect `(after! ,next ,@body))))
 438               ((and (consp features)
 439                     (memq (car features) '(:and :all)))
 440                (dolist (next (cdr features))
 441                  (setq body `(after! ,next ,@body)))
 442                body)
 443               ((listp features)
 444                `(after! (:all ,@features) ,@body)))))
 445 #+end_src
 446
 447 * Core
 448 :PROPERTIES:
 449 :CUSTOM_ID: core
 450 :END:
 451
 452 ** Defaults
 453
 454 *** Time and battery in mode-line
 455
 456 Enable displaying time and battery in the mode-line, since I'm not
 457 using the Xfce panel anymore. Also, I don't need to see the load
 458 average on a regular basis, so disable that.
 459
 460 Note: using =i3status= on sway at the moment, so disabling this.
 461
 462 #+begin_src emacs-lisp :tangle no
 463 (use-package time
 464   :init
 465   (setq display-time-default-load-average nil)
 466   :config
 467   (display-time-mode))
 468
 469 (use-package battery
 470   :config
 471   (display-battery-mode))
 472 #+end_src
 473
 474 *** Smaller fringe
 475
 476 Might want to set the fringe to a smaller value, especially if using
 477 EXWM. I'm fine with the default for now.
 478
 479 #+begin_src emacs-lisp
 480 ;; (fringe-mode '(3 . 1))
 481 (fringe-mode nil)
 482 #+end_src
 483
 484 *** Disable disabled commands
 485
 486 Emacs disables some commands by default that could persumably be
 487 confusing for novice users. Let's disable that.
 488
 489 #+begin_src emacs-lisp
 490 (setq disabled-command-function nil)
 491 #+end_src
 492
 493 *** Kill-ring
 494
 495 Save what I copy into clipboard from other applications into Emacs'
 496 kill-ring, which would allow me to still be able to easily access it
 497 in case I kill (cut or copy) something else inside Emacs before
 498 yanking (pasting) what I'd originally intended to.
 499
 500 #+begin_src emacs-lisp
 501 (setq save-interprogram-paste-before-kill t)
 502 #+end_src
 503
 504 *** Minibuffer
 505
 506 #+begin_src emacs-lisp
 507 (setq enable-recursive-minibuffers t
 508       resize-mini-windows t)
 509 #+end_src
 510
 511 *** Lazy-person-friendly yes/no prompts
 512
 513 Lazy people would prefer to type fewer keystrokes, especially for yes
 514 or no questions. I'm lazy.
 515
 516 #+begin_src emacs-lisp
 517 (defalias 'yes-or-no-p #'y-or-n-p)
 518 #+end_src
 519
 520 *** Startup screen and =*scratch*=
 521
 522 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 523 startup buffer.
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-buffer-choice t)
 527 #+end_src
 528
 529 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 530 need the default hint.
 531
 532 #+begin_src emacs-lisp
 533 (setq initial-scratch-message nil)
 534 #+end_src
 535
 536 Also, let's use Text mode as the major mode, in case I want to
 537 customize it (=*scratch*='s default major mode, Fundamental mode,
 538 can't really be customized).
 539
 540 #+begin_src emacs-lisp
 541 (setq initial-major-mode 'text-mode)
 542 #+end_src
 543
 544 Inhibit the buffer list when more than 2 files are loaded.
 545
 546 #+begin_src emacs-lisp
 547 (setq inhibit-startup-buffer-menu t)
 548 #+end_src
 549
 550 I don't really need to see the startup screen or echo area message
 551 either.
 552
 553 #+begin_src emacs-lisp
 554 (advice-add #'display-startup-echo-area-message :override #'ignore)
 555 (setq inhibit-startup-screen t
 556       inhibit-startup-echo-area-message user-login-name)
 557 #+end_src
 558
 559 *** More useful frame titles
 560
 561 Show either the file name or the buffer name (in case the buffer isn't
 562 visiting a file). Borrowed from Emacs Prelude.
 563
 564 #+begin_src emacs-lisp
 565 (setq frame-title-format
 566       '("" invocation-name " - "
 567         (:eval (if (buffer-file-name)
 568                    (abbreviate-file-name (buffer-file-name))
 569                  "%b"))))
 570 #+end_src
 571
 572 *** Backups
 573
 574 Emacs' default backup settings aren't that great. Let's use more
 575 sensible options. See documentation for the ~make-backup-file~
 576 variable.
 577
 578 #+begin_src emacs-lisp
 579 (setq backup-by-copying t
 580       version-control t)
 581 #+end_src
 582
 583 *** Auto revert
 584
 585 Enable automatic reloading of changed buffers and files.
 586
 587 #+begin_src emacs-lisp
 588 (global-auto-revert-mode 1)
 589 (setq auto-revert-verbose nil
 590       global-auto-revert-non-file-buffers t)
 591 #+end_src
 592
 593 *** Always use space for indentation
 594
 595 #+begin_src emacs-lisp
 596 (setq-default
 597  indent-tabs-mode nil
 598  require-final-newline t
 599  tab-width 4)
 600 #+end_src
 601
 602 *** Winner mode
 603
 604 Enable =winner-mode=.
 605
 606 #+begin_src emacs-lisp
 607 (winner-mode 1)
 608 #+end_src
 609
 610 ** Bindings
 611
 612 #+begin_src emacs-lisp
 613 (bind-keys
 614  ("C-c b B" . ibuffer-list-buffers)
 615  ("C-c b k" . kill-this-buffer)
 616  ("C-c b s" . save-buffer)
 617  ("C-c S"   . save-buffer)
 618  ("C-c o"   . other-window)
 619  ("C-c q q" . save-buffers-kill-terminal))
 620 #+end_src
 621
 622 ** Packages
 623
 624 The packages in this section are absolutely essential to my everyday
 625 workflow, and they play key roles in how I do my computing. They
 626 immensely enhance the Emacs experience for me; both using Emacs, and
 627 customizing it.
 628
 629 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 630
 631 #+begin_src emacs-lisp
 632 (use-package auto-compile
 633   :demand t
 634   :config
 635   (auto-compile-on-load-mode)
 636   (auto-compile-on-save-mode)
 637   (setq auto-compile-display-buffer               nil
 638         auto-compile-mode-line-counter            t
 639         auto-compile-source-recreate-deletes-dest t
 640         auto-compile-toggle-deletes-nonlib-dest   t
 641         auto-compile-update-autoloads             t)
 642   (add-hook 'auto-compile-inhibit-compile-hook
 643             'auto-compile-inhibit-compile-detached-git-head))
 644 #+end_src
 645
 646 *** [[https://orgmode.org/][Org mode]]
 647
 648 #+begin_quote
 649 Org mode is for keeping notes, maintaining TODO lists, planning
 650 projects, and authoring documents with a fast and effective plain-text
 651 system.
 652 #+end_quote
 653
 654 In short, my favourite way of life.
 655
 656 #+begin_src emacs-lisp
 657 (use-package org
 658   :config
 659   (setq org-src-tab-acts-natively t
 660         org-src-preserve-indentation nil
 661         org-edit-src-content-indentation 0)
 662   :hook (org-mode . org-indent-mode))
 663
 664 (use-package org-notmuch
 665   :after (:any org notmuch))
 666 #+end_src
 667
 668 *** [[https://magit.vc/][Magit]]
 669
 670 #+begin_quote
 671 It's Magit! A Git porcelain inside Emacs.
 672 #+end_quote
 673
 674 Not just how I do git, but /the/ way to do git.
 675
 676 #+begin_src emacs-lisp
 677 (use-package magit
 678   :defer t
 679   :bind
 680   (("s-g"   . magit-dispatch-popup)
 681    ("C-x g" . magit-status)
 682    :prefix-map amin--magit-prefix-map
 683    :prefix "C-c g"
 684    ("SPC" . magit-status)
 685    ("s"   . magit-status)
 686    ("S"   . magit-status-prefix)
 687    ("B"   . magit-blame)
 688    ("C"   . magit-clone)
 689    ("f"   . magit-fetch)
 690    ("F"   . magit-pull)
 691    ("P"   . magit-push)
 692    ("p"   . magit-dispatch-popup)
 693    ("c c" . magit-commit)
 694    ("c a" . magit-commit-amend)
 695    ("b b" . magit-checkout)
 696    ("b c" . magit-branch))
 697   :config
 698   (magit-add-section-hook 'magit-status-sections-hook
 699                           'magit-insert-modules
 700                           'magit-insert-stashes
 701                           'append))
 702 #+end_src
 703
 704 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 705
 706 #+begin_quote
 707 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 708 an overview, and more. Oh, man!
 709 #+end_quote
 710
 711 There's no way I could top that, so I won't attempt to.
 712
 713 **** Ivy
 714
 715 #+begin_src emacs-lisp
 716 (use-package ivy
 717   :defer 1
 718   :bind
 719   (("C-c b b" . ivy-switch-buffer)
 720    :map ivy-minibuffer-map
 721    ([escape] . keyboard-escape-quit)
 722    ([S-up]   . ivy-previous-history-element)
 723    ([S-down] . ivy-next-history-element)
 724    ("DEL"    . ivy-backward-delete-char))
 725   :config
 726   (setq ivy-wrap t)
 727   (ivy-mode 1))
 728 #+end_src
 729
 730 **** Swiper
 731
 732 #+begin_src emacs-lisp
 733 (use-package swiper
 734   :bind (([remap isearch-forward]  . swiper)
 735          ([remap isearch-backward] . swiper)))
 736 #+end_src
 737
 738 **** Counsel
 739
 740 #+begin_src emacs-lisp
 741 (use-package counsel
 742   :defer 1
 743   :bind (([remap execute-extended-command] . counsel-M-x)
 744          ([remap find-file]                . counsel-find-file)
 745          ("s-r"                            . counsel-recentf)
 746          ("C-c x"                          . counsel-M-x)
 747          ("C-c f ."                        . counsel-find-file)
 748          ("C-c f r"                        . counsel-recentf)
 749          :map minibuffer-local-map
 750          ("C-r" . counsel-minibuffer-history))
 751   :config
 752   (counsel-mode 1)
 753   (defalias 'locate #'counsel-locate))
 754 #+end_src
 755
 756 *** eshell
 757
 758 #+begin_src emacs-lisp
 759 (use-package eshell
 760   :commands eshell
 761   :config
 762   (eval-when-compile (defvar eshell-prompt-regexp))
 763   (defun amin/eshell-quit-or-delete-char (arg)
 764     (interactive "p")
 765     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 766         (eshell-life-is-too-much)
 767       (delete-char arg)))
 768
 769   (defun amin|eshell-setup ()
 770     (bind-keys :map eshell-mode-map
 771                ("C-d" . amin/eshell-quit-or-delete-char)))
 772
 773   :hook (eshell-mode . amin|eshell-setup))
 774 #+end_src
 775
 776 * Borg's =layer/essentials=
 777
 778 TODO: break this giant source block down into individual org sections.
 779
 780 #+begin_src emacs-lisp
 781 (use-package dash
 782   :config (dash-enable-font-lock))
 783
 784 (use-package diff-hl
 785   :config
 786   (setq diff-hl-draw-borders nil)
 787   (global-diff-hl-mode)
 788   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 789
 790 (use-package dired
 791   :defer t
 792   :config (setq dired-listing-switches "-alh"))
 793
 794 (use-package eldoc
 795   :when (version< "25" emacs-version)
 796   :config (global-eldoc-mode))
 797
 798 (use-package help
 799   :defer t
 800   :config (temp-buffer-resize-mode))
 801
 802 (progn ;    `isearch'
 803   (setq isearch-allow-scroll t))
 804
 805 (use-package lisp-mode
 806   :config
 807   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 808   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 809   (defun indent-spaces-mode ()
 810     (setq indent-tabs-mode nil))
 811   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 812
 813 (use-package man
 814   :defer t
 815   :config (setq Man-width 80))
 816
 817 (use-package paren
 818   :config (show-paren-mode))
 819
 820 (use-package prog-mode
 821   :config (global-prettify-symbols-mode)
 822   (defun indicate-buffer-boundaries-left ()
 823     (setq indicate-buffer-boundaries 'left))
 824   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 825
 826 (use-package recentf
 827   :demand t
 828   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 829
 830 (use-package savehist
 831   :config (savehist-mode))
 832
 833 (use-package saveplace
 834   :when (version< "25" emacs-version)
 835   :config (save-place-mode))
 836
 837 (use-package simple
 838   :config (column-number-mode))
 839
 840 (progn ;    `text-mode'
 841   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 842
 843 (use-package tramp
 844   :defer t
 845   :config
 846   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 847   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 848   (add-to-list 'tramp-default-proxies-alist
 849                (list (regexp-quote (system-name)) nil nil)))
 850
 851 (use-package undo-tree
 852   :bind (("C-?" . undo-tree-undo)
 853          ("M-_" . undo-tree-redo))
 854   :config
 855   (global-undo-tree-mode)
 856   (setq undo-tree-mode-lighter ""
 857         undo-tree-auto-save-history t))
 858 #+end_src
 859
 860 * Editing
 861
 862 ** Company
 863
 864 #+begin_src emacs-lisp
 865 (use-package company
 866   :defer 5
 867   :bind
 868   (:map company-active-map
 869         ([tab] . company-complete-common-or-cycle))
 870   :custom
 871   (company-idle-delay 0.3)
 872   (company-minimum-prefix-length 1)
 873   (company-selection-wrap-around t)
 874   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 875   :config
 876   (global-company-mode t))
 877 #+end_src
 878
 879 * Syntax and spell checking
 880 #+begin_src emacs-lisp
 881 (use-package flycheck
 882   :hook (prog-mode . flycheck-mode)
 883   :config
 884   ;; Use the load-path from running Emacs when checking elisp files
 885   (setq flycheck-emacs-lisp-load-path 'inherit)
 886
 887   ;; Only flycheck when I actually save the buffer
 888   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 889 #+end_src
 890 * Programming modes
 891
 892 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 893
 894 #+begin_src emacs-lisp
 895 (use-package alloy-mode
 896   :config (setq alloy-basic-offset 2))
 897 #+end_src
 898
 899 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 900
 901 #+begin_src emacs-lisp
 902 (use-package proof-site  ; Proof General
 903   :load-path "lib/proof-site/generic/")
 904 #+end_src
 905
 906 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 907
 908 #+begin_src emacs-lisp
 909 (eval-when-compile (defvar lean-mode-map))
 910 (use-package lean-mode
 911   :bind (:map lean-mode-map
 912               ("S-SPC" . company-complete)))
 913 #+end_src
 914
 915 ** Haskell
 916
 917 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 918
 919 #+begin_src emacs-lisp
 920 (use-package haskell-mode
 921   :config
 922   (setq haskell-indentation-layout-offset 4
 923         haskell-indentation-left-offset 4
 924         flycheck-checker 'haskell-hlint
 925         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 926 #+end_src
 927
 928 *** [[https://github.com/jyp/dante][dante]]
 929
 930 #+begin_src emacs-lisp
 931 (use-package dante
 932   :after haskell-mode
 933   :commands dante-mode
 934   :hook (haskell-mode . dante-mode))
 935 #+end_src
 936
 937 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 938
 939 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 940 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 941
 942 #+begin_src emacs-lisp
 943 (use-package hlint-refactor
 944   :bind (:map hlint-refactor-mode-map
 945               ("C-c l b" . hlint-refactor-refactor-buffer)
 946               ("C-c l r" . hlint-refactor-refactor-at-point))
 947   :hook (haskell-mode . hlint-refactor-mode))
 948 #+end_src
 949
 950 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 951
 952 #+begin_src emacs-lisp
 953 (use-package flycheck-haskell)
 954 #+end_src
 955
 956 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 957 :PROPERTIES:
 958 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 959 :END:
 960
 961 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 962 instead.
 963
 964 #+begin_src emacs-lisp :tangle no
 965 ;;; hs-lint.el --- minor mode for HLint code checking
 966
 967 ;; Copyright 2009 (C) Alex Ott
 968 ;;
 969 ;; Author: Alex Ott <alexott@gmail.com>
 970 ;; Keywords: haskell, lint, HLint
 971 ;; Requirements:
 972 ;; Status: distributed under terms of GPL2 or above
 973
 974 ;; Typical message from HLint looks like:
 975 ;;
 976 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 977 ;; Found:
 978 ;;   count1 p l = length (filter p l)
 979 ;; Why not:
 980 ;;   count1 p = length . filter p
 981
 982
 983 (require 'compile)
 984
 985 (defgroup hs-lint nil
 986   "Run HLint as inferior of Emacs, parse error messages."
 987   :group 'tools
 988   :group 'haskell)
 989
 990 (defcustom hs-lint-command "hlint"
 991   "The default hs-lint command for \\[hlint]."
 992   :type 'string
 993   :group 'hs-lint)
 994
 995 (defcustom hs-lint-save-files t
 996   "Save modified files when run HLint or no (ask user)"
 997   :type 'boolean
 998   :group 'hs-lint)
 999
1000 (defcustom hs-lint-replace-with-suggestions nil
1001   "Replace user's code with suggested replacements"
1002   :type 'boolean
1003   :group 'hs-lint)
1004
1005 (defcustom hs-lint-replace-without-ask nil
1006   "Replace user's code with suggested replacements automatically"
1007   :type 'boolean
1008   :group 'hs-lint)
1009
1010 (defun hs-lint-process-setup ()
1011   "Setup compilation variables and buffer for `hlint'."
1012   (run-hooks 'hs-lint-setup-hook))
1013
1014 ;; regex for replace suggestions
1015 ;;
1016 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1017 ;; Found:
1018 ;; \s +\(.*\)
1019 ;; Why not:
1020 ;; \s +\(.*\)
1021
1022 (defvar hs-lint-regex
1023   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1024   "Regex for HLint messages")
1025
1026 (defun make-short-string (str maxlen)
1027   (if (< (length str) maxlen)
1028       str
1029     (concat (substring str 0 (- maxlen 3)) "...")))
1030
1031 (defun hs-lint-replace-suggestions ()
1032   "Perform actual replacement of suggestions"
1033   (goto-char (point-min))
1034   (while (re-search-forward hs-lint-regex nil t)
1035     (let* ((fname (match-string 1))
1036           (fline (string-to-number (match-string 2)))
1037           (old-code (match-string 4))
1038           (new-code (match-string 5))
1039           (msg (concat "Replace '" (make-short-string old-code 30)
1040                        "' with '" (make-short-string new-code 30) "'"))
1041           (bline 0)
1042           (eline 0)
1043           (spos 0)
1044           (new-old-code ""))
1045       (save-excursion
1046         (switch-to-buffer (get-file-buffer fname))
1047         (goto-char (point-min))
1048         (forward-line (1- fline))
1049         (beginning-of-line)
1050         (setf bline (point))
1051         (when (or hs-lint-replace-without-ask
1052                   (yes-or-no-p msg))
1053           (end-of-line)
1054           (setf eline (point))
1055           (beginning-of-line)
1056           (setf old-code (regexp-quote old-code))
1057           (while (string-match "\\\\ " old-code spos)
1058             (setf new-old-code (concat new-old-code
1059                                  (substring old-code spos (match-beginning 0))
1060                                  "\\ *"))
1061             (setf spos (match-end 0)))
1062           (setf new-old-code (concat new-old-code (substring old-code spos)))
1063           (remove-text-properties bline eline '(composition nil))
1064           (when (re-search-forward new-old-code eline t)
1065             (replace-match new-code nil t)))))))
1066
1067 (defun hs-lint-finish-hook (buf msg)
1068   "Function, that is executed at the end of HLint execution"
1069   (if hs-lint-replace-with-suggestions
1070       (hs-lint-replace-suggestions)
1071       (next-error 1 t)))
1072
1073 (define-compilation-mode hs-lint-mode "HLint"
1074   "Mode for check Haskell source code."
1075   (set (make-local-variable 'compilation-process-setup-function)
1076        'hs-lint-process-setup)
1077   (set (make-local-variable 'compilation-disable-input) t)
1078   (set (make-local-variable 'compilation-scroll-output) nil)
1079   (set (make-local-variable 'compilation-finish-functions)
1080        (list 'hs-lint-finish-hook))
1081   )
1082
1083 (defun hs-lint ()
1084   "Run HLint for current buffer with haskell source"
1085   (interactive)
1086   (save-some-buffers hs-lint-save-files)
1087   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1088                      'hs-lint-mode))
1089
1090 (provide 'hs-lint)
1091 ;;; hs-lint.el ends here
1092 #+end_src
1093
1094 #+begin_src emacs-lisp :tangle no
1095 (use-package hs-lint
1096   :load-path "lisp/"
1097   :bind (:map haskell-mode-map
1098               ("C-c l l" . hs-lint)))
1099 #+end_src
1100 * Emacs Enhancements
1101
1102 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1103
1104 #+begin_quote
1105 Emacs package that displays available keybindings in popup
1106 #+end_quote
1107
1108 #+begin_src emacs-lisp
1109 (use-package which-key
1110   :defer 1
1111   :config (which-key-mode))
1112 #+end_src
1113
1114 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1115
1116 #+begin_src emacs-lisp
1117 (use-package doom-modeline
1118   :demand t
1119   :config (setq doom-modeline-height 32)
1120   :hook (after-init . doom-modeline-init))
1121 #+end_src
1122
1123 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1124
1125 #+begin_src emacs-lisp :tangle no
1126 (use-package tao-theme
1127   :demand t
1128   :config (load-theme 'tao-yang t))
1129 #+end_src
1130
1131 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1132
1133 #+begin_src emacs-lisp
1134 (load-theme 'eink t)
1135 #+end_src
1136
1137 ** [[https://github.com/bbatsov/crux][crux]]
1138
1139 #+begin_src emacs-lisp
1140 (use-package crux
1141   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1142          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1143          ("C-c b K" . crux-kill-other-buffers)
1144          ("C-c f c" . crux-copy-file-preserve-attributes)
1145          ("C-c f D" . crux-delete-file-and-buffer)
1146          ("C-c f R" . crux-rename-file-and-buffer)))
1147 #+end_src
1148
1149 ** [[https://github.com/alezost/mwim.el][mwim]]
1150
1151 #+begin_src emacs-lisp
1152 (use-package mwim
1153   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1154          ("C-e"    . mwim-end-of-code-or-line)
1155          ("<home>" . mwim-beginning-of-line-or-code)
1156          ("<end>"  . mwim-end-of-line-or-code)))
1157 #+end_src
1158
1159 ** projectile
1160
1161 #+begin_src emacs-lisp
1162 (use-package projectile
1163   :defer 5
1164   :bind-keymap ("C-c p" . projectile-command-map)
1165   :config
1166   (projectile-mode)
1167
1168   (defun my-projectile-invalidate-cache (&rest _args)
1169     ;; ignore the args to `magit-checkout'
1170     (projectile-invalidate-cache nil))
1171
1172   (eval-after-load 'magit-branch
1173     '(progn
1174        (advice-add 'magit-checkout
1175                    :after #'my-projectile-invalidate-cache)
1176        (advice-add 'magit-branch-and-checkout
1177                    :after #'my-projectile-invalidate-cache))))
1178 #+end_src
1179
1180 ** [[https://github.com/wasamasa/shackle][shackle]]
1181
1182 #+begin_src emacs-lisp
1183 (use-package shackle
1184   :demand t
1185   :commands shackle-mode
1186   :config
1187   (shackle-mode 1)
1188   (setq shackle-rules
1189         '(("*Help*" :align right :select t :size 0.5)
1190           ("\\`\\*helm.*?\\*\\'" :regexp t :align t)
1191           ((compilation-mode "\\`\\*magit-diff: .*?\\'") :regexp t :noselect t)
1192           ((inferior-scheme-mode "*shell*" "*eshell*") :popup t))
1193         shackle-default-rule '(:select t)
1194         shackle-default-size 0.4
1195         shackle-inhibit-window-quit-on-same-windows t))
1196 #+end_src
1197
1198 * Email
1199 ** [[https://notmuchmail.org][notmuch]]
1200
1201 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1202
1203 #+begin_src emacs-lisp
1204 (defvar amin-maildir "~/mail")
1205
1206 (use-package sendmail
1207   ;; :ensure nil
1208   :config
1209   (setq sendmail-program "/usr/bin/msmtp"
1210         ; message-sendmail-extra-arguments '("-v" "-d")
1211         mail-specify-envelope-from t
1212         mail-envelope-from 'header))
1213
1214 (use-package message
1215   ;; :ensure nil
1216   :config
1217   (setq message-kill-buffer-on-exit t
1218         message-send-mail-function 'message-send-mail-with-sendmail
1219         message-sendmail-envelope-from 'header
1220         message-directory "drafts"
1221         message-user-fqdn "aminb.org")
1222   (add-hook 'message-mode-hook
1223             (lambda () (setq fill-column 65
1224                         message-fill-column 65)))
1225   (add-hook 'message-mode-hook
1226             #'flyspell-mode)
1227   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1228   ;; TODO: is there a way to only run this when replying and not composing?
1229   ;; (add-hook 'notmuch-message-mode-hook
1230   ;;           (lambda () (progn
1231   ;;                   (newline)
1232   ;;                   (newline)
1233   ;;                   (forward-line -1)
1234   ;;                   (forward-line -1))))
1235   ;; (add-hook 'message-setup-hook
1236   ;;           #'mml-secure-message-sign-pgpmime)
1237   )
1238
1239 (after! mml-sec
1240   (setq mml-secure-openpgp-encrypt-to-self t
1241         mml-secure-openpgp-sign-with-sender t))
1242
1243 (defun amin/notmuch ()
1244   "Delete other windows, then launch `notmuch'."
1245   (interactive)
1246   (delete-other-windows)
1247   (notmuch))
1248
1249 (use-package notmuch
1250   :commands notmuch
1251   :bind ("C-c m" . amin/notmuch)
1252   :custom (notmuch-always-prompt-for-sender t)
1253   :config
1254   (setq notmuch-hello-sections
1255         '(notmuch-hello-insert-header
1256           notmuch-hello-insert-saved-searches
1257           ;; notmuch-hello-insert-search
1258           notmuch-hello-insert-alltags)
1259         notmuch-search-oldest-first nil
1260         notmuch-show-all-tags-list t
1261         notmuch-message-headers  ; see bug follow-up above
1262         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1263         notmuch-hello-thousands-separator ","
1264         notmuch-fcc-dirs
1265         '(("amin@aminb.org"        . "amin/Sent")
1266           ("amin@gnu.org"          . "gnu/Sent")
1267           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1268           ("mab@gnu.org"           . "gnu/Sent")
1269           ("aminb@gnu.org"         . "gnu/Sent")
1270           (".*"                    . "sent"))
1271         notmuch-search-result-format
1272         '(("date"    . "%12s ")
1273           ("count"   . "%-7s ")
1274           ("authors" . "%-40s ")
1275           ("subject" . "%s ")
1276           ("tags"    . "(%s)"))
1277         notmuch-saved-searches
1278         '((:name "inbox"     :query "tag:inbox"     :key "i")
1279           (:name "unread"    :query "tag:unread"    :key "u")
1280           (:name "latest"    :query "tag:latest"    :key "l")
1281           (:name "encrypted" :query "tag:encrypted" :key "e")
1282           (:name "flagged"   :query "tag:flagged"   :key "f")
1283           (:name "sent"      :query "tag:sent"      :key "s")
1284           (:name "drafts"    :query "tag:draft"     :key "d")
1285           (:name "all mail"  :query "*"             :key "a")))
1286   ;; (add-hook 'visual-fill-column-mode-hook
1287   ;;           (lambda ()
1288   ;;             (when (string= major-mode 'notmuch-message-mode)
1289   ;;               (setq visual-fill-column-width 70))))
1290   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1291   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1292   ;;             :override #'kill-this-buffer)
1293   :bind
1294   (:map notmuch-hello-mode-map
1295         ("u" . (lambda ()
1296                  "Search for `unread'-tagged messages"
1297                  (interactive)
1298                  (notmuch-hello-search "tag:unread")))
1299         ("i" . (lambda ()
1300                  "Search for `inbox'-tagged messages"
1301                  (interactive)
1302                  (notmuch-hello-search "tag:inbox")))
1303         ("l" . (lambda ()
1304                  "Search for `latest'-tagged messages"
1305                  (interactive)
1306                  (notmuch-hello-search "tag:latest")))
1307         ("e" . (lambda ()
1308                  "Search for `encrypted'-tagged messages"
1309                  (interactive)
1310                  (notmuch-hello-search "tag:encrypted"))))
1311   (:map notmuch-search-mode-map
1312         ("k" . (lambda ()
1313                  "Mark message read"
1314                  (interactive)
1315                  (notmuch-search-tag '("-unread"))
1316                  ;; (notmuch-search-archive-thread)
1317                  (notmuch-search-next-thread)))
1318         ("u" . (lambda ()
1319                  "Mark message unread"
1320                  (interactive)
1321                  (notmuch-search-tag '("+unread"))
1322                  (notmuch-search-next-thread)))
1323         ("K" . (lambda ()
1324                  "Mark message deleted"
1325                  (interactive)
1326                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1327                  (notmuch-search-next-thread)))
1328         ("S" . (lambda ()
1329                  "Mark message as spam"
1330                  (interactive)
1331                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1332                  (notmuch-search-next-thread))))
1333   (:map notmuch-tree-mode-map
1334         ("k" . (lambda ()
1335                  "Mark message read"
1336                  (interactive)
1337                  (notmuch-tree-tag '("-unread"))
1338                  ;; (notmuch-tree-archive-thread)
1339                  (notmuch-tree-next-message)))
1340         ("u" . (lambda ()
1341                  "Mark message unread"
1342                  (interactive)
1343                  (notmuch-tree-tag '("+unread"))
1344                  (notmuch-tree-next-message)))
1345         ("K" . (lambda ()
1346                  "Mark message deleted"
1347                  (interactive)
1348                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
1349                  (notmuch-tree-next-message)))
1350         ("S" . (lambda ()
1351                  "Mark message as spam"
1352                  (interactive)
1353                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1354                  (notmuch-tree-next-message)))))
1355
1356 (use-package counsel-notmuch
1357   :bind ("C-c s m" . counsel-notmuch))
1358
1359 (after! notmuch-crypto
1360   (setq notmuch-crypto-process-mime t))
1361
1362 (after! recentf
1363   (add-to-list 'recentf-exclude (expand-file-name amin-maildir)))
1364 #+end_src
1365
1366 ** supercite
1367
1368 #+begin_src emacs-lisp :tangle no
1369 (use-package supercite
1370   :commands sc-cite-original
1371   :init
1372   (add-hook 'mail-citation-hook 'sc-cite-original)
1373
1374   (defun sc-remove-existing-signature ()
1375     (save-excursion
1376       (goto-char (region-beginning))
1377       (when (re-search-forward message-signature-separator (region-end) t)
1378         (delete-region (match-beginning 0) (region-end)))))
1379
1380   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1381
1382   (defun sc-remove-if-not-mailing-list ()
1383     (unless (assoc "list-id" sc-mail-info)
1384       (setq attribution sc-default-attribution
1385             citation (concat sc-citation-delimiter
1386                              sc-citation-separator))))
1387
1388   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1389
1390   :config
1391   (defun sc-fill-if-different (&optional prefix)
1392     "Fill the region bounded by `sc-fill-begin' and point.
1393 Only fill if optional PREFIX is different than
1394 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1395 fill region.  If PREFIX is not supplied, initialize fill
1396 variables.  This is useful for a regi `begin' frame-entry."
1397     (if (not prefix)
1398         (setq sc-fill-line-prefix ""
1399               sc-fill-begin (line-beginning-position))
1400       (if (and sc-auto-fill-region-p
1401                (not (string= prefix sc-fill-line-prefix)))
1402           (let ((fill-prefix sc-fill-line-prefix))
1403             (unless (or (string= fill-prefix "")
1404                         (save-excursion
1405                           (goto-char sc-fill-begin)
1406                           (or (looking-at ">+  +")
1407                               (< (length
1408                                   (buffer-substring (point)
1409                                                     (line-end-position)))
1410                                  65))))
1411               (fill-region sc-fill-begin (line-beginning-position)))
1412             (setq sc-fill-line-prefix prefix
1413                   sc-fill-begin (line-beginning-position)))))
1414 nil))
1415 #+end_src
1416
1417 * Blogging
1418 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1419
1420 #+begin_src emacs-lisp
1421 (use-package ox-hugo
1422   :after ox)
1423 #+end_src
1424
1425 * Post initialization
1426 :PROPERTIES:
1427 :CUSTOM_ID: post-initialization
1428 :END:
1429
1430 Display how long it took to load the init file.
1431
1432 #+begin_src emacs-lisp
1433 (message "Loading %s...done (%.3fs)" user-init-file
1434          (float-time (time-subtract (current-time)
1435                                     amin--before-user-init-time)))
1436 #+end_src
1437
1438 * Footer
1439 :PROPERTIES:
1440 :CUSTOM_ID: footer
1441 :END:
1442
1443 #+begin_src emacs-lisp :comments none
1444 ;;; init.el ends here
1445 #+end_src