git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 ;; (require 'borg-nix-shell)
 238 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c b A" . borg-activate)
 244    ("C-c b a" . borg-assimilate)
 245    ("C-c b b" . borg-build)
 246    ("C-c b c" . borg-clone)
 247    ("C-c b m" . borg-insert-update-message)
 248    ("C-c b r" . borg-remove)))
 249 #+end_src
 250
 251 *** =use-package=
 252
 253 #+begin_quote
 254 A use-package declaration for simplifying your .emacs
 255 #+end_quote
 256
 257 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 258 packages (in our case especially the latter) in a neatly organized way
 259 and without compromising on performance.
 260
 261 #+begin_src emacs-lisp
 262 (require 'use-package)
 263 (if nil  ; set to t when need to debug init
 264     (setq use-package-verbose t
 265           use-package-expand-minimally nil
 266           use-package-compute-statistics t
 267           debug-on-error t)
 268   (setq use-package-verbose nil
 269         use-package-expand-minimally t))
 270 #+end_src
 271
 272 *** Epkg
 273
 274 #+begin_quote
 275 Browse the Emacsmirror package database
 276 #+end_quote
 277
 278 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 279 database, low-level functions for querying the database, and a
 280 =package.el=-like user interface for browsing the available packages.
 281
 282 #+begin_src emacs-lisp
 283 (use-package epkg
 284   :defer t
 285   :bind
 286   (("C-c b d" . epkg-describe-package)
 287    ("C-c b p" . epkg-list-packages)
 288    ("C-c b u" . epkg-update)))
 289 #+end_src
 290
 291 ** No littering in =~/.emacs.d=
 292
 293 #+begin_quote
 294 Help keeping ~/.emacs.d clean
 295 #+end_quote
 296
 297 By default, even for Emacs' built-in packages, the configuration files
 298 and persistent data are all over the place. Use =no-littering= to help
 299 contain the mess.
 300
 301 #+begin_src emacs-lisp
 302 (use-package no-littering
 303   :demand t
 304   :config
 305   (savehist-mode 1)
 306   (add-to-list 'savehist-additional-variables 'kill-ring)
 307   (save-place-mode 1)
 308   (setq auto-save-file-name-transforms
 309         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 310 #+end_src
 311
 312 ** Custom file (=custom.el=)
 313
 314 I'm not planning on using the custom file much, but even so, I
 315 definitely don't want it mixing with =init.el=. So, here; let's give
 316 it it's own file. While at it, treat themes as safe.
 317
 318 #+begin_src emacs-lisp
 319 (use-package custom
 320   :no-require t
 321   :config
 322   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 323   (when (file-exists-p custom-file)
 324     (load custom-file))
 325   (setf custom-safe-themes t))
 326 #+end_src
 327
 328 ** Secrets file
 329
 330 #+begin_src emacs-lisp
 331 (load (no-littering-expand-etc-file-name "secrets"))
 332 #+end_src
 333
 334 ** Better =$PATH= handling
 335
 336 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 337 in my shell.
 338
 339 #+begin_src emacs-lisp
 340 (use-package exec-path-from-shell
 341   :defer 1
 342   :init
 343   (setq exec-path-from-shell-check-startup-files nil)
 344   :config
 345   (exec-path-from-shell-initialize)
 346   ;; while we're at it, let's fix access to our running ssh-agent
 347   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 348   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 349 #+end_src
 350
 351 ** COMMENT Only one custom theme at a time
 352
 353 #+begin_src emacs-lisp
 354 (defadvice load-theme (before clear-previous-themes activate)
 355   "Clear existing theme settings instead of layering them"
 356   (mapc #'disable-theme custom-enabled-themes))
 357 #+end_src
 358
 359 ** Server
 360
 361 Start server if not already running. Alternatively, can be done by
 362 issuing =emacs --daemon= in the terminal, which can be automated with
 363 a systemd service or using =brew services start emacs= on macOS. I use
 364 Emacs as my window manager (via EXWM), so I always start Emacs on
 365 login; so starting the server from inside Emacs is good enough for me.
 366
 367 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 368
 369 #+begin_src emacs-lisp
 370 (use-package server
 371   :defer 1
 372   :config (or (server-running-p) (server-mode)))
 373 #+end_src
 374
 375 ** COMMENT Unicode support
 376
 377 Font stack with better unicode support, around =Ubuntu Mono= and
 378 =Hack=.
 379
 380 #+begin_src emacs-lisp :tangle no
 381 (dolist (ft (fontset-list))
 382   (set-fontset-font
 383    ft
 384    'unicode
 385    (font-spec :name "Source Code Pro" :size 14))
 386   (set-fontset-font
 387    ft
 388    'unicode
 389    (font-spec :name "DejaVu Sans Mono")
 390    nil
 391    'append)
 392   ;; (set-fontset-font
 393   ;;  ft
 394   ;;  'unicode
 395   ;;  (font-spec
 396   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 397   ;;  nil
 398   ;;  'append)
 399   ;; (set-fontset-font
 400   ;;  ft
 401   ;;  #x2115  ; ℕ
 402   ;;  (font-spec :name "DejaVu Sans Mono")
 403   ;;  nil
 404   ;;  'append)
 405   (set-fontset-font
 406    ft
 407    (cons ?Α ?ω)
 408    (font-spec :name "DejaVu Sans Mono" :size 14)
 409    nil
 410    'prepend))
 411 #+end_src
 412
 413 ** Gentler font resizing
 414
 415 #+begin_src emacs-lisp
 416 (setq text-scale-mode-step 1.05)
 417 #+end_src
 418
 419 ** Libraries
 420
 421 #+begin_src emacs-lisp
 422 (require 'cl-lib)
 423 (require 'subr-x)
 424 #+end_src
 425
 426 ** Useful utilities
 427
 428 #+begin_src emacs-lisp
 429 (defun amin-enlist (exp)
 430   "Return EXP wrapped in a list, or as-is if already a list."
 431 (if (listp exp) exp (list exp)))
 432
 433 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 434 (defmacro after! (features &rest body)
 435   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 436 compilation."
 437   (declare (indent defun) (debug t))
 438   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 439                 (dolist (next (amin-enlist features))
 440                   (if (symbolp next)
 441                       (require next nil :no-error)
 442                     (load next :no-message :no-error))))
 443             #'progn
 444           #'with-no-warnings)
 445         (cond ((symbolp features)
 446                `(eval-after-load ',features '(progn ,@body)))
 447               ((and (consp features)
 448                     (memq (car features) '(:or :any)))
 449                `(progn
 450                   ,@(cl-loop for next in (cdr features)
 451                              collect `(after! ,next ,@body))))
 452               ((and (consp features)
 453                     (memq (car features) '(:and :all)))
 454                (dolist (next (cdr features))
 455                  (setq body `(after! ,next ,@body)))
 456                body)
 457               ((listp features)
 458                `(after! (:all ,@features) ,@body)))))
 459 #+end_src
 460
 461 Convenience macro for =setq='ing multiple variables to the same value:
 462
 463 #+begin_src emacs-lisp
 464 (defmacro setq-every! (value &rest vars)
 465   "Set all the variables from VARS to value VALUE."
 466   (declare (indent defun) (debug t))
 467   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 468 #+end_src
 469
 470 * Core
 471 :PROPERTIES:
 472 :CUSTOM_ID: core
 473 :END:
 474
 475 ** Defaults
 476
 477 *** Time and battery in mode-line
 478
 479 Enable displaying time and battery in the mode-line, since I'm not
 480 using the Xfce panel anymore. Also, I don't need to see the load
 481 average on a regular basis, so disable that.
 482
 483 Note: using =i3status= on sway at the moment, so disabling this.
 484
 485 #+begin_src emacs-lisp :tangle no
 486 (use-package time
 487   :init
 488   (setq display-time-default-load-average nil)
 489   :config
 490   (display-time-mode))
 491
 492 (use-package battery
 493   :config
 494   (display-battery-mode))
 495 #+end_src
 496
 497 *** Smaller fringe
 498
 499 Might want to set the fringe to a smaller value, especially if using
 500 EXWM. I'm fine with the default for now.
 501
 502 #+begin_src emacs-lisp
 503 ;; (fringe-mode '(3 . 1))
 504 (fringe-mode nil)
 505 #+end_src
 506
 507 *** Disable disabled commands
 508
 509 Emacs disables some commands by default that could persumably be
 510 confusing for novice users. Let's disable that.
 511
 512 #+begin_src emacs-lisp
 513 (setq disabled-command-function nil)
 514 #+end_src
 515
 516 *** Kill-ring
 517
 518 Save what I copy into clipboard from other applications into Emacs'
 519 kill-ring, which would allow me to still be able to easily access it
 520 in case I kill (cut or copy) something else inside Emacs before
 521 yanking (pasting) what I'd originally intended to.
 522
 523 #+begin_src emacs-lisp
 524 (setq save-interprogram-paste-before-kill t)
 525 #+end_src
 526
 527 *** Minibuffer
 528
 529 #+begin_src emacs-lisp
 530 (setq enable-recursive-minibuffers t
 531       resize-mini-windows t)
 532 #+end_src
 533
 534 *** Lazy-person-friendly yes/no prompts
 535
 536 Lazy people would prefer to type fewer keystrokes, especially for yes
 537 or no questions. I'm lazy.
 538
 539 #+begin_src emacs-lisp
 540 (defalias 'yes-or-no-p #'y-or-n-p)
 541 #+end_src
 542
 543 *** Startup screen and =*scratch*=
 544
 545 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 546 startup buffer.
 547
 548 #+begin_src emacs-lisp
 549 (setq initial-buffer-choice t)
 550 #+end_src
 551
 552 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 553 need the default hint.
 554
 555 #+begin_src emacs-lisp
 556 (setq initial-scratch-message nil)
 557 #+end_src
 558
 559 Also, let's use Text mode as the major mode, in case I want to
 560 customize it (=*scratch*='s default major mode, Fundamental mode,
 561 can't really be customized).
 562
 563 #+begin_src emacs-lisp
 564 (setq initial-major-mode 'text-mode)
 565 #+end_src
 566
 567 Inhibit the buffer list when more than 2 files are loaded.
 568
 569 #+begin_src emacs-lisp
 570 (setq inhibit-startup-buffer-menu t)
 571 #+end_src
 572
 573 I don't really need to see the startup screen or echo area message
 574 either.
 575
 576 #+begin_src emacs-lisp
 577 (advice-add #'display-startup-echo-area-message :override #'ignore)
 578 (setq inhibit-startup-screen t
 579       inhibit-startup-echo-area-message user-login-name)
 580 #+end_src
 581
 582 *** More useful frame titles
 583
 584 Show either the file name or the buffer name (in case the buffer isn't
 585 visiting a file). Borrowed from Emacs Prelude.
 586
 587 #+begin_src emacs-lisp
 588 (setq frame-title-format
 589       '("" invocation-name " - "
 590         (:eval (if (buffer-file-name)
 591                    (abbreviate-file-name (buffer-file-name))
 592                  "%b"))))
 593 #+end_src
 594
 595 *** Backups
 596
 597 Emacs' default backup settings aren't that great. Let's use more
 598 sensible options. See documentation for the ~make-backup-file~
 599 variable.
 600
 601 #+begin_src emacs-lisp
 602 (setq backup-by-copying t
 603       version-control t
 604       delete-old-versions t)
 605 #+end_src
 606
 607 *** Auto revert
 608
 609 Enable automatic reloading of changed buffers and files.
 610
 611 #+begin_src emacs-lisp
 612 (global-auto-revert-mode 1)
 613 (setq auto-revert-verbose nil
 614       global-auto-revert-non-file-buffers nil)
 615 #+end_src
 616
 617 *** Always use space for indentation
 618
 619 #+begin_src emacs-lisp
 620 (setq-default
 621  indent-tabs-mode nil
 622  require-final-newline t
 623  tab-width 4)
 624 #+end_src
 625
 626 *** Winner mode
 627
 628 Enable =winner-mode=.
 629
 630 #+begin_src emacs-lisp
 631 (winner-mode 1)
 632 #+end_src
 633
 634 *** Close =*compilation*= on success
 635
 636 #+begin_src emacs-lisp
 637 (setq compilation-exit-message-function
 638       (lambda (status code msg)
 639         "Close the compilation window if successful."
 640         ;; if M-x compile exits with 0
 641          (when (and (eq status 'exit) (zerop code))
 642            (bury-buffer)
 643            (delete-window (get-buffer-window (get-buffer "*compilation*"))))
 644          ;; return the result of compilation-exit-message-function
 645          (cons msg code)))
 646 #+end_src
 647
 648 *** Search for non-ASCII characters
 649
 650 I’d like non-ASCII characters such as ‘’“”«»‹›áⓐ𝒶 to be selected when
 651 I search for their ASCII counterpart.  Shoutout to [[http://endlessparentheses.com/new-in-emacs-25-1-easily-search-non-ascii-characters.html][endlessparentheses]]
 652 for this.
 653
 654 #+begin_src emacs-lisp
 655 (setq search-default-mode #'char-fold-to-regexp)
 656
 657 ;; uncomment to extend this behaviour to query-replace
 658 ;; (setq replace-char-fold t)
 659 #+end_src
 660
 661 ** Bindings
 662
 663 #+begin_src emacs-lisp
 664 (bind-keys
 665  ("s-c e b" . eval-buffer)
 666  ("s-c e r" . eval-region)
 667
 668  ("s-p"     . beginning-of-buffer)
 669  ("s-n"     . end-of-buffer))
 670 #+end_src
 671
 672 ** Packages
 673
 674 The packages in this section are absolutely essential to my everyday
 675 workflow, and they play key roles in how I do my computing. They
 676 immensely enhance the Emacs experience for me; both using Emacs, and
 677 customizing it.
 678
 679 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 680
 681 #+begin_src emacs-lisp
 682 (use-package auto-compile
 683   :demand t
 684   :config
 685   (auto-compile-on-load-mode)
 686   (auto-compile-on-save-mode)
 687   (setq auto-compile-display-buffer               nil
 688         auto-compile-mode-line-counter            t
 689         auto-compile-source-recreate-deletes-dest t
 690         auto-compile-toggle-deletes-nonlib-dest   t
 691         auto-compile-update-autoloads             t)
 692   (add-hook 'auto-compile-inhibit-compile-hook
 693             'auto-compile-inhibit-compile-detached-git-head))
 694 #+end_src
 695
 696 *** [[https://github.com/noctuid/general.el][general]]
 697
 698 #+begin_src emacs-lisp
 699 (use-package general
 700   :demand t
 701   :config
 702   (general-evil-setup t)
 703   (general-override-mode)
 704
 705   (general-create-definer
 706    amin--leader-keys
 707    :keymaps 'override
 708    :states '(emacs normal visual motion insert)
 709    :non-normal-prefix "M-m"
 710    :prefix "SPC"))
 711 #+end_src
 712
 713 *** [[https://github.com/emacs-evil/evil][evil]]
 714
 715 #+begin_src emacs-lisp
 716 (use-package evil
 717   :demand t
 718   ;; :hook (org-src-mode . evil-motion-state)
 719   :config
 720   (evil-mode 1)
 721   (general-swap-key nil '(normal motion) ";" ":")
 722
 723   (setq evil-want-visual-char-semi-exclusive t)
 724
 725   ;; custom mode state mappings
 726   (dolist (mspair '((ebdb-mode    . emacs)
 727                     (helpful-mode . motion)
 728                     (view-mode    . motion)))
 729     (evil-set-initial-state (car mspair) (cdr mspair)))
 730
 731   ;; fix tab and indentation in src blocks inside org-mode buffer
 732   ;; also see https://git.sr.ht/~bandali/dotfiles/commit/0e2ffd584aafdd4cf256bcdf2473f01c3aaaed55
 733   (unbind-key "TAB" evil-motion-state-map)
 734
 735   (unbind-key "C-d" evil-insert-state-map)
 736   (unbind-key "C-v" evil-insert-state-map)
 737   (unbind-key "C-y" evil-insert-state-map)
 738   (unbind-key "C-a" evil-insert-state-map)
 739   (unbind-key "C-e" evil-insert-state-map)
 740   (unbind-key "C-p" evil-insert-state-map)
 741   (unbind-key "C-n" evil-insert-state-map)
 742   (unbind-key "C-k" evil-insert-state-map)
 743   (bind-keys
 744     :map evil-insert-state-map
 745     ("C-k"   . kill-line)
 746     ("C-S-k" . evil-insert-digraph)
 747     :map evil-motion-state-map
 748     ([down-mouse-1] . nil)))
 749 #+end_src
 750
 751 #+begin_src emacs-lisp
 752 (use-package evil-escape
 753   :after evil
 754   :init
 755   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 756         evil-escape-excluded-major-modes '(neotree-mode)
 757         evil-escape-key-sequence "jk"
 758         evil-escape-delay 0.25)
 759   ;; :general
 760   ;; (:states '(insert replace visual operator)
 761   ;;          "C-g" #'evil-escape)
 762   :config
 763   (evil-escape-mode 1)
 764   ;; no `evil-escape' in minibuffer
 765   (push #'minibufferp evil-escape-inhibit-functions))
 766 #+end_src
 767
 768 #+begin_src emacs-lisp
 769 (use-package evil-nerd-commenter
 770   :after evil
 771   :general
 772   (nmap
 773     "gc" 'evilnc-comment-operator
 774     "gy" 'evilnc-copy-and-comment-lines))
 775 #+end_src
 776
 777 #+begin_src emacs-lisp
 778 (use-package evil-surround
 779   :after evil
 780   :general
 781   (omap
 782     "s" 'evil-surround-edit
 783     "S" 'evil-Surround-edit)
 784   (vmap
 785     "S" 'evil-surround-region
 786     "gS" 'evil-Surround-region))
 787 #+end_src
 788
 789 #+begin_src emacs-lisp
 790 (amin--leader-keys
 791   "/"   '(:ignore t :wk "search")
 792
 793   "a"   '(:ignore t :wk "apps")
 794   "a i" 'ielm
 795
 796   "b"   '(:ignore t :wk "buffers")
 797   "b k" 'kill-this-buffer
 798   "b s" 'save-buffer
 799
 800   "e"   '(:ignore t :wk "eval")
 801   "e b" 'eval-buffer
 802   "e r" 'eval-region
 803
 804   "f"   '(:ignore t :wk "files")
 805
 806   "F"   '(:ignore t :wk "frames")
 807   "F m" 'make-frame-command
 808   "F d" 'delete-frame
 809   "F D" 'delete-other-frames
 810
 811   "h"   '(:ignore t :wk "help(ful)")
 812   "h c" 'describe-char
 813   "h f" 'describe-function
 814   "h F" 'describe-face
 815   "h H" 'view-hello-file
 816   "h i" 'info
 817   "h k" 'describe-key
 818   "h l" 'view-lossage
 819   "h v" 'describe-variable
 820
 821   "o"   'other-window
 822
 823   "w"   '(:ignore t :wk "window")
 824   "w o" 'other-window
 825   "w 0" 'delete-window
 826   "w 1" 'delete-other-windows
 827   "w 2" 'split-window-below
 828   "w 3" 'split-window-right
 829   "w u" 'winner-undo
 830   "w r" 'winner-redo
 831
 832   "q"   '(:ignore t :wk "quit")
 833   "q q" 'save-buffers-kill-terminal)
 834 #+end_src
 835
 836 *** [[https://orgmode.org/][Org mode]]
 837
 838 #+begin_quote
 839 Org mode is for keeping notes, maintaining TODO lists, planning
 840 projects, and authoring documents with a fast and effective plain-text
 841 system.
 842 #+end_quote
 843
 844 In short, my favourite way of life.
 845
 846 #+begin_src emacs-lisp
 847 (use-package org
 848   :defer 3
 849   :general
 850   (amin--leader-keys
 851     :states 'normal
 852     :keymaps 'org-mode-map
 853     "'" 'org-edit-special)
 854   (amin--leader-keys
 855     :definer 'minor-mode
 856     :states 'normal
 857     :keymaps 'org-src-mode
 858     "'" 'org-edit-src-exit
 859     "k" 'org-edit-src-abort)
 860   (general-define-key
 861    :definer 'minor-mode
 862    :states 'normal
 863    :keymaps 'org-src-mode
 864    "q" 'org-edit-src-exit)
 865   :config
 866   (setq org-src-tab-acts-natively t
 867         org-src-preserve-indentation nil
 868         org-edit-src-content-indentation 0
 869         org-email-link-description-format "Email %c: %s" ; %.30s
 870         org-log-done 'time)
 871   (add-to-list 'org-structure-template-alist '("L" . "src emacs-lisp") t)
 872   (after! org-src
 873     (define-key org-src-mode-map [remap evil-write] 'org-edit-src-save)
 874     (define-key org-src-mode-map [remap evil-save-and-close]
 875       (lambda () (interactive)
 876         (org-edit-src-save)
 877         (org-edit-src-exit)))
 878     (define-key org-src-mode-map [remap evil-save-modified-and-close]
 879       (lambda () (interactive)
 880         (org-edit-src-save)
 881         (org-edit-src-exit)))
 882     (define-key org-src-mode-map [remap evil-quit] 'org-edit-src-abort))
 883   :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
 884   :hook ((org-mode . org-indent-mode)
 885          (org-mode . auto-fill-mode)
 886          (org-mode . flyspell-mode))
 887   :custom
 888   (org-latex-packages-alist '(("" "listings") ("" "color"))))
 889
 890 (use-package ox-latex
 891   :after ox
 892   :config
 893   (setq org-latex-listings 'listings
 894         ;; org-latex-prefer-user-labels t
 895         )
 896   (add-to-list 'org-latex-packages-alist '("" "listings"))
 897   (add-to-list 'org-latex-packages-alist '("" "color"))
 898   (add-to-list 'org-latex-classes
 899                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 900                  ("\\section{%s}" . "\\section*{%s}")
 901                  ("\\subsection{%s}" . "\\subsection*{%s}")
 902                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 903                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 904                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 905                t))
 906
 907 (use-package ox-beamer
 908   :after ox)
 909
 910 (use-package ob-tangle
 911   :general
 912   (amin--leader-keys
 913     :states 'normal
 914     :keymaps 'org-mode-map
 915     "b t" 'org-babel-tangle))
 916
 917 (use-package orgalist
 918   :after message
 919   :hook (message-mode . orgalist-mode))
 920 #+end_src
 921
 922 **** asynchronous tangle
 923
 924 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 925 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 926 file.
 927
 928 #+begin_src emacs-lisp
 929 (after! org
 930   (defvar amin-show-async-tangle-results nil
 931     "Keep *emacs* async buffers around for later inspection.")
 932
 933   (defvar amin-show-async-tangle-time nil
 934     "Show the time spent tangling the file.")
 935
 936   (defvar amin-async-tangle-post-compile "make ti"
 937     "If non-nil, pass to `compile' after successful tangle.")
 938
 939   (defun amin/async-babel-tangle ()
 940     "Tangle org file asynchronously."
 941     (interactive)
 942     (let* ((file-tangle-start-time (current-time))
 943            (file (buffer-file-name))
 944            (file-nodir (file-name-nondirectory file))
 945            (async-quiet-switch "-q"))
 946       (async-start
 947        `(lambda ()
 948           (require 'org)
 949           (org-babel-tangle-file ,file))
 950        (unless amin-show-async-tangle-results
 951          `(lambda (result)
 952             (if result
 953                 (progn
 954                   (message "Tangled %s%s"
 955                            ,file-nodir
 956                            (if amin-show-async-tangle-time
 957                                (format " (%.3fs)"
 958                                        (float-time (time-subtract (current-time)
 959                                                                   ',file-tangle-start-time)))
 960                              ""))
 961                   (when amin-async-tangle-post-compile
 962                     (compile amin-async-tangle-post-compile)))
 963               (message "Tangling %s failed" ,file-nodir))))))))
 964
 965 (add-to-list
 966  'safe-local-variable-values
 967  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 968 #+end_src
 969
 970 *** [[https://magit.vc/][Magit]]
 971
 972 #+begin_quote
 973 It's Magit! A Git porcelain inside Emacs.
 974 #+end_quote
 975
 976 Not just how I do git, but /the/ way to do git.
 977
 978 #+begin_src emacs-lisp
 979 (use-package magit
 980   :defer 2
 981   :general (amin--leader-keys "g s" 'magit-status)
 982   :bind ("s-g" . magit-status)
 983   :config
 984   (magit-add-section-hook 'magit-status-sections-hook
 985                           'magit-insert-modules
 986                           'magit-insert-stashes
 987                           'append)
 988   (setq
 989    magit-repository-directories '(("~/.emacs.d/" . 0)
 990                                   ("~/src/git/" . 1)))
 991   (nconc magit-section-initial-visibility-alist
 992          '(([unpulled status] . show)
 993            ([unpushed status] . show)))
 994   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 995 #+end_src
 996
 997 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 998
 999 #+begin_quote
1000 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
1001 an overview, and more. Oh, man!
1002 #+end_quote
1003
1004 There's no way I could top that, so I won't attempt to.
1005
1006 **** Ivy
1007
1008 #+begin_src emacs-lisp
1009 (use-package ivy
1010   :defer 1
1011   :general (amin--leader-keys "," 'ivy-switch-buffer)
1012   :bind
1013   (:map ivy-minibuffer-map
1014    ([escape] . keyboard-escape-quit)
1015    ([S-up]   . ivy-previous-history-element)
1016    ([S-down] . ivy-next-history-element)
1017    ("DEL"    . ivy-backward-delete-char))
1018   :config
1019   (setq ivy-wrap t)
1020   (ivy-mode 1)
1021   :custom-face
1022   (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
1023   (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
1024   (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold)))))
1025 #+end_src
1026
1027 **** Swiper
1028
1029 #+begin_src emacs-lisp
1030 (use-package swiper
1031   :general (:states '(normal motion) "/" 'swiper)
1032   :bind (("C-s" . swiper)
1033          ("C-r" . swiper)))
1034 #+end_src
1035
1036 **** Counsel
1037
1038 #+begin_src emacs-lisp
1039 (use-package counsel
1040   :defer 1
1041   :general
1042   (amin--leader-keys
1043     "r" 'counsel-recentf
1044     "SPC" 'counsel-M-x
1045     "."   'counsel-find-file)
1046   :bind (([remap execute-extended-command] . counsel-M-x)
1047          ([remap find-file]                . counsel-find-file)
1048          ("s-r"                            . counsel-recentf)
1049          ("C-c x"                          . counsel-M-x)
1050          ("C-c f ."                        . counsel-find-file)
1051          :map minibuffer-local-map
1052          ("C-r" . counsel-minibuffer-history))
1053   :config
1054   (counsel-mode 1)
1055   (defalias 'locate #'counsel-locate))
1056 #+end_src
1057
1058 *** eshell
1059
1060 #+begin_src emacs-lisp
1061 (use-package eshell
1062   :defer 1
1063   :commands eshell
1064   :config
1065   (eval-when-compile (defvar eshell-prompt-regexp))
1066   (defun amin/eshell-quit-or-delete-char (arg)
1067     (interactive "p")
1068     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
1069         (eshell-life-is-too-much)
1070       (delete-char arg)))
1071
1072   (defun amin/eshell-clear ()
1073     (interactive)
1074     (let ((inhibit-read-only t))
1075       (erase-buffer))
1076     (eshell-send-input))
1077
1078   (defun amin|eshell-setup ()
1079     (bind-keys :map eshell-mode-map
1080                ("C-d" . amin/eshell-quit-or-delete-char)
1081                ("C-l" . amin/eshell-clear)))
1082
1083   :hook (eshell-mode . amin|eshell-setup))
1084 #+end_src
1085
1086 *** Ibuffer
1087
1088 #+begin_src emacs-lisp
1089 (use-package ibuffer
1090   :defer t
1091   :general (amin--leader-keys "b b" 'ibuffer-other-window)
1092   :bind
1093   (("C-x C-b" . ibuffer-other-window)
1094    :map ibuffer-mode-map
1095    ("P"   . ibuffer-backward-filter-group)
1096    ("N"   . ibuffer-forward-filter-group)
1097    ("M-p" . ibuffer-do-print)
1098    ("M-n" . ibuffer-do-shell-command-pipe-replace))
1099   :config
1100   ;; Use human readable Size column instead of original one
1101   (define-ibuffer-column size-h
1102     (:name "Size" :inline t)
1103     (cond
1104      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
1105      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
1106      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
1107      (t (format "%8d" (buffer-size)))))
1108   :custom
1109   (ibuffer-saved-filter-groups
1110    '(("default"
1111       ("dired" (mode . dired-mode))
1112       ("org"   (mode . org-mode))
1113       ("web"
1114        (or
1115         (mode . web-mode)
1116         (mode . css-mode)
1117         (mode . scss-mode)
1118         (mode . js2-mode)))
1119       ("shell"
1120        (or
1121         (mode . eshell-mode)
1122         (mode . shell-mode)))
1123       ("notmuch" (name . "\*notmuch\*"))
1124       ("programming"
1125        (or
1126         (mode . python-mode)
1127         (mode . c++-mode)
1128         (mode . emacs-lisp-mode)))
1129       ("emacs"
1130        (or
1131         (name . "^\\*scratch\\*$")
1132         (name . "^\\*Messages\\*$")))
1133       ("slack"
1134        (or
1135         (name . "^\\*Slack*"))))))
1136   (ibuffer-formats
1137    '((mark modified read-only locked " "
1138            (name 18 18 :left :elide)
1139            " "
1140            (size-h 9 -1 :right)
1141            " "
1142            (mode 16 16 :left :elide)
1143            " " filename-and-process)
1144      (mark " "
1145            (name 16 -1)
1146            " " filename)))
1147   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
1148 #+end_src
1149
1150 *** Outline
1151
1152 #+begin_src emacs-lisp
1153 (use-package outline
1154   :defer t
1155   :hook (prog-mode . outline-minor-mode)
1156   :bind
1157   (:map
1158    outline-minor-mode-map
1159    ("<s-tab>"  . outline-toggle-children)
1160    ("M-p"      . outline-previous-visible-heading)
1161    ("M-n"      . outline-next-visible-heading)
1162    :prefix-map amin--outline-prefix-map
1163    :prefix "s-o"
1164    ("TAB" . outline-toggle-children)
1165    ("a"   . outline-hide-body)
1166    ("H"   . outline-hide-body)
1167    ("S"   . outline-show-all)
1168    ("h"   . outline-hide-subtree)
1169    ("s"   . outline-show-subtree)))
1170 #+end_src
1171
1172 * Borg's =layer/essentials=
1173
1174 TODO: break this giant source block down into individual org sections.
1175
1176 #+begin_src emacs-lisp
1177 (use-package dash
1178   :config (dash-enable-font-lock))
1179
1180 (use-package diff-hl
1181   :config
1182   (setq diff-hl-draw-borders nil)
1183   (global-diff-hl-mode)
1184   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
1185
1186 (use-package dired
1187   :defer t
1188   :config (setq dired-listing-switches "-alh"))
1189
1190 (use-package eldoc
1191   :when (version< "25" emacs-version)
1192   :config (global-eldoc-mode))
1193
1194 (use-package help
1195   :defer t
1196   :config
1197   (temp-buffer-resize-mode)
1198   (setq help-window-select t))
1199
1200 (progn ;    `isearch'
1201   (setq isearch-allow-scroll t))
1202
1203 (use-package lisp-mode
1204   :config
1205   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1206   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1207   (defun indent-spaces-mode ()
1208     (setq indent-tabs-mode nil))
1209   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1210
1211 (use-package man
1212   :defer t
1213   :config (setq Man-width 80))
1214
1215 (use-package paren
1216   :config (show-paren-mode))
1217
1218 (use-package prog-mode
1219   :config (global-prettify-symbols-mode)
1220   (defun indicate-buffer-boundaries-left ()
1221     (setq indicate-buffer-boundaries 'left))
1222   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1223
1224 (use-package recentf
1225   :defer 0.5
1226   :config
1227   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1228   (setq recentf-max-saved-items 40))
1229
1230 (use-package savehist
1231   :config (savehist-mode))
1232
1233 (use-package saveplace
1234   :when (version< "25" emacs-version)
1235   :config (save-place-mode))
1236
1237 (use-package simple
1238   :config (column-number-mode))
1239
1240 (progn ;    `text-mode'
1241   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1242
1243 (use-package tramp
1244   :defer t
1245   :config
1246   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1247   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1248   (add-to-list 'tramp-default-proxies-alist
1249                (list (regexp-quote (system-name)) nil nil)))
1250
1251 (use-package undo-tree
1252   :config
1253   (global-undo-tree-mode -1))
1254   ;; :bind (("C-?" . undo-tree-undo)
1255   ;;        ("M-_" . undo-tree-redo))
1256   ;; :config
1257   ;; (global-undo-tree-mode)
1258   ;; (setq undo-tree-mode-lighter ""
1259   ;;       undo-tree-auto-save-history t))
1260 #+end_src
1261
1262 * Editing
1263
1264 ** Company
1265
1266 #+begin_src emacs-lisp
1267 (use-package company
1268   :defer 2
1269   :bind
1270   (:map company-active-map
1271         ([tab]    . company-complete-common-or-cycle)
1272         ([escape] . company-abort))
1273   :custom
1274   (company-idle-delay 0.3)
1275   (company-minimum-prefix-length 1)
1276   (company-selection-wrap-around t)
1277   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1278   (company-dabbrev-downcase nil)
1279   (company-dabbrev-ignore-case nil)
1280   :config
1281   (global-company-mode t))
1282 #+end_src
1283
1284 * Syntax and spell checking
1285 #+begin_src emacs-lisp
1286 (use-package flycheck
1287   :defer 3
1288   :hook (prog-mode . flycheck-mode)
1289   :bind
1290   (:map flycheck-mode-map
1291         ("M-P" . flycheck-previous-error)
1292         ("M-N" . flycheck-next-error))
1293   :config
1294   ;; Use the load-path from running Emacs when checking elisp files
1295   (setq flycheck-emacs-lisp-load-path 'inherit)
1296
1297   ;; Only flycheck when I actually save the buffer
1298   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1299
1300 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1301 (use-package ispell
1302   :defer 3
1303   :config
1304   ;; ’ can be part of a word
1305   (setq ispell-local-dictionary-alist
1306         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1307                "['\x2019]" nil ("-B") nil utf-8)))
1308   ;; don't send ’ to the subprocess
1309   (defun endless/replace-apostrophe (args)
1310     (cons (replace-regexp-in-string
1311            "’" "'" (car args))
1312           (cdr args)))
1313   (advice-add #'ispell-send-string :filter-args
1314               #'endless/replace-apostrophe)
1315
1316   ;; convert ' back to ’ from the subprocess
1317   (defun endless/replace-quote (args)
1318     (if (not (derived-mode-p 'org-mode))
1319         args
1320       (cons (replace-regexp-in-string
1321              "'" "’" (car args))
1322             (cdr args))))
1323   (advice-add #'ispell-parse-output :filter-args
1324               #'endless/replace-quote))
1325 #+end_src
1326 * Programming modes
1327
1328 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1329
1330 #+begin_src emacs-lisp
1331 (use-package alloy-mode
1332   :defer t
1333   :config (setq alloy-basic-offset 2))
1334 #+end_src
1335
1336 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1337
1338 #+begin_src emacs-lisp
1339 (use-package proof-site  ; Proof General
1340   :defer t
1341   :load-path "lib/proof-site/generic/")
1342 #+end_src
1343
1344 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1345
1346 #+begin_src emacs-lisp
1347 (eval-when-compile (defvar lean-mode-map))
1348 (use-package lean-mode
1349   :defer 1
1350   :bind (:map lean-mode-map
1351               ("S-SPC" . company-complete))
1352   :config
1353   (require 'lean-input)
1354   (setq default-input-method "Lean"
1355         lean-input-tweak-all '(lean-input-compose
1356                                (lean-input-prepend "/")
1357                                (lean-input-nonempty))
1358         lean-input-user-translations '(("/" "/")))
1359   (lean-input-setup))
1360   #+end_src
1361
1362 ** Haskell
1363
1364 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1365
1366 #+begin_src emacs-lisp
1367 (use-package haskell-mode
1368   :defer t
1369   :config
1370   (setq haskell-indentation-layout-offset 4
1371         haskell-indentation-left-offset 4
1372         flycheck-checker 'haskell-hlint
1373         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1374 #+end_src
1375
1376 *** [[https://github.com/jyp/dante][dante]]
1377
1378 #+begin_src emacs-lisp
1379 (use-package dante
1380   :after haskell-mode
1381   :commands dante-mode
1382   :hook (haskell-mode . dante-mode))
1383 #+end_src
1384
1385 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1386
1387 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1388 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1389
1390 #+begin_src emacs-lisp
1391 (use-package hlint-refactor
1392   :after haskell-mode
1393   :bind (:map hlint-refactor-mode-map
1394               ("C-c l b" . hlint-refactor-refactor-buffer)
1395               ("C-c l r" . hlint-refactor-refactor-at-point))
1396   :hook (haskell-mode . hlint-refactor-mode))
1397 #+end_src
1398
1399 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1400
1401 #+begin_src emacs-lisp
1402 (use-package flycheck-haskell
1403   :after haskell-mode)
1404 #+end_src
1405
1406 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1407 :PROPERTIES:
1408 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1409 :END:
1410
1411 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1412 instead.
1413
1414 #+begin_src emacs-lisp :tangle no
1415 ;;; hs-lint.el --- minor mode for HLint code checking
1416
1417 ;; Copyright 2009 (C) Alex Ott
1418 ;;
1419 ;; Author: Alex Ott <alexott@gmail.com>
1420 ;; Keywords: haskell, lint, HLint
1421 ;; Requirements:
1422 ;; Status: distributed under terms of GPL2 or above
1423
1424 ;; Typical message from HLint looks like:
1425 ;;
1426 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1427 ;; Found:
1428 ;;   count1 p l = length (filter p l)
1429 ;; Why not:
1430 ;;   count1 p = length . filter p
1431
1432
1433 (require 'compile)
1434
1435 (defgroup hs-lint nil
1436   "Run HLint as inferior of Emacs, parse error messages."
1437   :group 'tools
1438   :group 'haskell)
1439
1440 (defcustom hs-lint-command "hlint"
1441   "The default hs-lint command for \\[hlint]."
1442   :type 'string
1443   :group 'hs-lint)
1444
1445 (defcustom hs-lint-save-files t
1446   "Save modified files when run HLint or no (ask user)"
1447   :type 'boolean
1448   :group 'hs-lint)
1449
1450 (defcustom hs-lint-replace-with-suggestions nil
1451   "Replace user's code with suggested replacements"
1452   :type 'boolean
1453   :group 'hs-lint)
1454
1455 (defcustom hs-lint-replace-without-ask nil
1456   "Replace user's code with suggested replacements automatically"
1457   :type 'boolean
1458   :group 'hs-lint)
1459
1460 (defun hs-lint-process-setup ()
1461   "Setup compilation variables and buffer for `hlint'."
1462   (run-hooks 'hs-lint-setup-hook))
1463
1464 ;; regex for replace suggestions
1465 ;;
1466 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1467 ;; Found:
1468 ;; \s +\(.*\)
1469 ;; Why not:
1470 ;; \s +\(.*\)
1471
1472 (defvar hs-lint-regex
1473   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1474   "Regex for HLint messages")
1475
1476 (defun make-short-string (str maxlen)
1477   (if (< (length str) maxlen)
1478       str
1479     (concat (substring str 0 (- maxlen 3)) "...")))
1480
1481 (defun hs-lint-replace-suggestions ()
1482   "Perform actual replacement of suggestions"
1483   (goto-char (point-min))
1484   (while (re-search-forward hs-lint-regex nil t)
1485     (let* ((fname (match-string 1))
1486           (fline (string-to-number (match-string 2)))
1487           (old-code (match-string 4))
1488           (new-code (match-string 5))
1489           (msg (concat "Replace '" (make-short-string old-code 30)
1490                        "' with '" (make-short-string new-code 30) "'"))
1491           (bline 0)
1492           (eline 0)
1493           (spos 0)
1494           (new-old-code ""))
1495       (save-excursion
1496         (switch-to-buffer (get-file-buffer fname))
1497         (goto-char (point-min))
1498         (forward-line (1- fline))
1499         (beginning-of-line)
1500         (setf bline (point))
1501         (when (or hs-lint-replace-without-ask
1502                   (yes-or-no-p msg))
1503           (end-of-line)
1504           (setf eline (point))
1505           (beginning-of-line)
1506           (setf old-code (regexp-quote old-code))
1507           (while (string-match "\\\\ " old-code spos)
1508             (setf new-old-code (concat new-old-code
1509                                  (substring old-code spos (match-beginning 0))
1510                                  "\\ *"))
1511             (setf spos (match-end 0)))
1512           (setf new-old-code (concat new-old-code (substring old-code spos)))
1513           (remove-text-properties bline eline '(composition nil))
1514           (when (re-search-forward new-old-code eline t)
1515             (replace-match new-code nil t)))))))
1516
1517 (defun hs-lint-finish-hook (buf msg)
1518   "Function, that is executed at the end of HLint execution"
1519   (if hs-lint-replace-with-suggestions
1520       (hs-lint-replace-suggestions)
1521       (next-error 1 t)))
1522
1523 (define-compilation-mode hs-lint-mode "HLint"
1524   "Mode for check Haskell source code."
1525   (set (make-local-variable 'compilation-process-setup-function)
1526        'hs-lint-process-setup)
1527   (set (make-local-variable 'compilation-disable-input) t)
1528   (set (make-local-variable 'compilation-scroll-output) nil)
1529   (set (make-local-variable 'compilation-finish-functions)
1530        (list 'hs-lint-finish-hook))
1531   )
1532
1533 (defun hs-lint ()
1534   "Run HLint for current buffer with haskell source"
1535   (interactive)
1536   (save-some-buffers hs-lint-save-files)
1537   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1538                      'hs-lint-mode))
1539
1540 (provide 'hs-lint)
1541 ;;; hs-lint.el ends here
1542 #+end_src
1543
1544 #+begin_src emacs-lisp :tangle no
1545 (use-package hs-lint
1546   :load-path "lisp/"
1547   :bind (:map haskell-mode-map
1548               ("C-c l l" . hs-lint)))
1549 #+end_src
1550
1551 ** Web dev
1552
1553 *** SGML and HTML
1554
1555 #+begin_src emacs-lisp
1556 (use-package sgml-mode
1557   :defer t
1558   :config
1559   (setq sgml-basic-offset 2))
1560 #+end_src
1561
1562 *** CSS and SCSS
1563
1564 #+begin_src emacs-lisp
1565 (use-package css-mode
1566   :defer t
1567   :config
1568   (setq css-indent-offset 2))
1569 #+end_src
1570
1571 *** Web mode
1572
1573 #+begin_src emacs-lisp
1574 (use-package web-mode
1575   :defer t
1576   :mode "\\.html\\'"
1577   :config
1578   (setq-every! 2
1579     web-mode-code-indent-offset
1580     web-mode-css-indent-offset
1581     web-mode-markup-indent-offset))
1582 #+end_src
1583
1584 *** Emmet mode
1585
1586 #+begin_src emacs-lisp
1587 (use-package emmet-mode
1588   :after (:any web-mode css-mode sgml-mode)
1589   :bind* (("C-)" . emmet-next-edit-point)
1590           ("C-(" . emmet-prev-edit-point))
1591   :config
1592   (unbind-key "C-j" emmet-mode-keymap)
1593   (setq emmet-move-cursor-between-quotes t)
1594   :hook (web-mode css-mode html-mode sgml-mode))
1595 #+end_src
1596
1597 ** Nix
1598
1599 #+begin_src emacs-lisp
1600 (use-package nix-mode
1601   :defer t
1602   :mode "\\.nix\\'")
1603 #+end_src
1604
1605 ** Java
1606
1607 *** meghanada
1608
1609 #+begin_src emacs-lisp :tangle no
1610 (use-package meghanada
1611   :bind
1612   (:map meghanada-mode-map
1613         (("C-M-o" . meghanada-optimize-import)
1614          ("C-M-t" . meghanada-import-all)))
1615   :hook (java-mode . meghanada-mode))
1616 #+end_src
1617
1618 *** lsp-java
1619
1620 #+begin_comment
1621 dependencies:
1622
1623 ace-window
1624 avy
1625 bui
1626 company-lsp
1627 dap-mode
1628 lsp-java
1629 lsp-mode
1630 lsp-ui
1631 pfuture
1632 tree-mode
1633 treemacs
1634 #+end_comment
1635
1636 #+begin_src emacs-lisp :tangle no
1637 (use-package treemacs
1638   :config (setq treemacs-never-persist t))
1639
1640 (use-package yasnippet
1641   :config
1642   ;; (yas-global-mode)
1643   )
1644
1645 (use-package lsp-mode
1646   :init (setq lsp-eldoc-render-all nil
1647               lsp-highlight-symbol-at-point nil)
1648   )
1649
1650 (use-package hydra)
1651
1652 (use-package company-lsp
1653   :after  company
1654   :config
1655   (setq company-lsp-cache-candidates t
1656         company-lsp-async t))
1657
1658 (use-package lsp-ui
1659   :config
1660   (setq lsp-ui-sideline-update-mode 'point))
1661
1662 (use-package lsp-java
1663   :config
1664   (add-hook 'java-mode-hook
1665             (lambda ()
1666               (setq-local company-backends (list 'company-lsp))))
1667
1668   (add-hook 'java-mode-hook 'lsp-java-enable)
1669   (add-hook 'java-mode-hook 'flycheck-mode)
1670   (add-hook 'java-mode-hook 'company-mode)
1671   (add-hook 'java-mode-hook 'lsp-ui-mode))
1672
1673 (use-package dap-mode
1674   :after lsp-mode
1675   :config
1676   (dap-mode t)
1677   (dap-ui-mode t))
1678
1679 (use-package dap-java
1680   :after (lsp-java))
1681
1682 (use-package lsp-java-treemacs
1683   :after (treemacs))
1684 #+end_src
1685
1686 * Emacs Enhancements
1687
1688 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1689
1690 #+begin_quote
1691 Emacs package that displays available keybindings in popup
1692 #+end_quote
1693
1694 #+begin_src emacs-lisp
1695 (use-package which-key
1696   :defer 1
1697   :config (which-key-mode))
1698 #+end_src
1699
1700 ** theme
1701
1702 #+begin_src emacs-lisp
1703 (add-to-list 'custom-theme-load-path "~/.emacs.d/lisp")
1704 (load-theme 'tangomod t)
1705 #+end_src
1706
1707 ** [[https://github.com/Malabarba/smart-mode-line][smart-mode-line]]
1708
1709 #+begin_src emacs-lisp
1710 (use-package smart-mode-line
1711   :config
1712   (sml/setup)
1713   (sml/apply-theme 'light)
1714   (remove-hook 'display-time-hook 'sml/propertize-time-string))
1715 #+end_src
1716
1717 ** theme helper functions
1718
1719 #+begin_src emacs-lisp
1720 (defun amin/light ()
1721   "Load light theme(s)."
1722   (interactive)
1723   (progn
1724     (mapc #'disable-theme custom-enabled-themes)
1725     (load-theme 'tangomod t)
1726     (sml/apply-theme 'light)))
1727
1728 (defun amin/dark ()
1729   "Load dark theme(s)."
1730   (interactive)
1731   (progn
1732     (mapc #'disable-theme custom-enabled-themes)
1733     (load-theme 'tangomod-dark t)
1734     (sml/apply-theme 'dark)))
1735
1736 (amin--leader-keys
1737   "t"   '(:ignore t :wk "theme")
1738   "t d" 'amin/dark
1739   "t l" 'amin/light)
1740 #+end_src
1741
1742 ** [[https://github.com/bbatsov/crux][crux]]
1743
1744 #+begin_src emacs-lisp
1745 (use-package crux
1746   :defer 1
1747   :general
1748   (amin--leader-keys
1749     "b K" 'crux-kill-other-buffers
1750     "c d" 'crux-duplicate-current-line-or-region
1751     "c D" 'crux-duplicate-and-comment-current-line-or-region
1752     "f c" 'crux-copy-file-preserve-attributes
1753     "f d" 'crux-delete-file-and-buffer
1754     "f r" 'crux-rename-file-and-buffer)
1755   :bind (("C-c d" . crux-duplicate-current-line-or-region)
1756          ("C-c D" . crux-duplicate-and-comment-current-line-or-region)
1757          ("C-S-j" . crux-top-join-line)
1758          ("C-c j" . crux-top-join-line)))
1759 #+end_src
1760
1761 ** [[https://github.com/alezost/mwim.el][mwim]]
1762
1763 #+begin_src emacs-lisp
1764 (use-package mwim
1765   :general
1766   (:states '(normal visual)
1767            "0" 'mwim-beginning-of-code-or-line
1768            "$" 'mwim-end-of-code-or-line)
1769   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1770          ("C-e"    . mwim-end-of-code-or-line)
1771          ("<home>" . mwim-beginning-of-line-or-code)
1772          ("<end>"  . mwim-end-of-line-or-code)))
1773 #+end_src
1774
1775 ** projectile
1776
1777 #+begin_src emacs-lisp
1778 (use-package projectile
1779   :defer 2
1780   :bind-keymap ("C-c p" . projectile-command-map)
1781   :config
1782   (projectile-mode)
1783
1784   (defun my-projectile-invalidate-cache (&rest _args)
1785     ;; ignore the args to `magit-checkout'
1786     (projectile-invalidate-cache nil))
1787
1788   (eval-after-load 'magit-branch
1789     '(progn
1790        (advice-add 'magit-checkout
1791                    :after #'my-projectile-invalidate-cache)
1792        (advice-add 'magit-branch-and-checkout
1793                    :after #'my-projectile-invalidate-cache))))
1794 #+end_src
1795
1796 ** [[https://github.com/Wilfred/helpful][helpful]]
1797
1798 #+begin_src emacs-lisp
1799 (use-package helpful
1800   :defer 1
1801   :general
1802   (amin--leader-keys
1803     "h h"   '(:ignore t :wk "helpful")
1804     "h h c" 'helpful-command
1805     "h h f" 'helpful-callable           ; helpful-function
1806     "h h v" 'helpful-variable
1807     "h h k" 'helpful-key
1808     "h h p" 'helpful-at-point))
1809 #+end_src
1810
1811 ** [[https://github.com/knu/shell-toggle.el][shell-toggle]]
1812
1813 #+begin_src emacs-lisp
1814 (use-package shell-toggle
1815   :after eshell
1816   :general (amin--leader-keys "a s" 'amin/shell-toggle)
1817   :bind ("C-c e" . amin/shell-toggle)
1818   :config
1819   (defun amin/shell-toggle (make-cd)
1820     "Toggle between the shell buffer and whatever buffer you are editing.
1821 With a prefix argument MAKE-CD also insert a \"cd DIR\" command
1822 into the shell, where DIR is the directory of the current buffer.
1823
1824 When called in the shell buffer returns you to the buffer you were editing
1825 before calling this the first time.
1826
1827 Options: `shell-toggle-goto-eob'"
1828     (interactive "P")
1829     ;; Try to decide on one of three possibilities:
1830     ;; If not in shell-buffer, switch to it.
1831     ;; If in shell-buffer, return to state before going to the shell-buffer
1832     (if (eq (current-buffer) shell-toggle-shell-buffer)
1833         (shell-toggle-buffer-return-from-shell)
1834       (progn
1835         (shell-toggle-buffer-goto-shell make-cd)
1836         (if shell-toggle-full-screen-window-only (delete-other-windows)))))
1837
1838   ;; override to split horizontally instead
1839   (defun shell-toggle-buffer-switch-to-other-window ()
1840     "Switch to other window.
1841 If the current window is the only window in the current frame,
1842 create a new window and switch to it.
1843
1844 \(This is less intrusive to the current window configuration than
1845 `switch-buffer-other-window')"
1846     (let ((this-window (selected-window)))
1847       (other-window 1)
1848       ;; If we did not switch window then we only have one window and need to
1849       ;; create a new one.
1850       (if (eq this-window (selected-window))
1851               (progn
1852                 (split-window-horizontally)
1853             (other-window 1)))))
1854
1855   :custom
1856   (shell-toggle-launch-shell 'shell-toggle-eshell))
1857 #+end_src
1858
1859 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1860
1861 Make =*scratch*= and =*Messages*= unkillable.
1862
1863 #+begin_src emacs-lisp
1864 (use-package unkillable-scratch
1865   :defer 3
1866   :config
1867   (unkillable-scratch 1)
1868   :custom
1869   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1870 #+end_src
1871
1872 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1873
1874 #+begin_example
1875 ,----
1876 | make pretty boxed quotes like this
1877 `----
1878 #+end_example
1879
1880 #+begin_src emacs-lisp
1881 (use-package boxquote
1882   :defer 3
1883   :bind
1884   (:prefix-map amin--boxquote-prefix-map
1885    :prefix "C-c q"
1886    ("b"   . boxquote-buffer)
1887    ("B"   . boxquote-insert-buffer)
1888    ("d"   . boxquote-defun)
1889    ("F"   . boxquote-insert-file)
1890    ("hf"  . boxquote-describe-function)
1891    ("hk"  . boxquote-describe-key)
1892    ("hv"  . boxquote-describe-variable)
1893    ("hw"  . boxquote-where-is)
1894    ("k"   . boxquote-kill)
1895    ("p"   . boxquote-paragraph)
1896    ("q"   . boxquote-boxquote)
1897    ("r"   . boxquote-region)
1898    ("s"   . boxquote-shell-command)
1899    ("t"   . boxquote-text)
1900    ("T"   . boxquote-title)
1901    ("u"   . boxquote-unbox)
1902    ("U"   . boxquote-unbox-region)
1903    ("y"   . boxquote-yank)
1904    ("M-q" . boxquote-fill-paragraph)
1905    ("M-w" . boxquote-kill-ring-save)))
1906 #+end_src
1907
1908 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1909
1910 ** COMMENT [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]                                 :ARCHIVE:
1911
1912 #+begin_src emacs-lisp
1913 (use-package highlight-indent-guides
1914   :defer 3
1915   :hook ((prog-mode . highlight-indent-guides-mode)
1916          ;; (org-mode  . highlight-indent-guides-mode)
1917          )
1918   :config
1919   (setq highlight-indent-guides-character ?\|)
1920   (setq highlight-indent-guides-auto-enabled nil)
1921   (setq highlight-indent-guides-method 'character)
1922   (setq highlight-indent-guides-responsive 'top)
1923   (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
1924   (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
1925 #+end_src
1926
1927 ** pdf-tools
1928
1929 #+begin_src emacs-lisp
1930 (use-package pdf-tools
1931   :defer t
1932   :magic ("%PDF" . pdf-view-mode)
1933   :config
1934   (setq pdf-view-resize-factor 1.05)
1935   (pdf-tools-install)
1936   :bind
1937   (:map pdf-view-mode-map
1938         ("C-s" . isearch-forward)
1939         ("C-r" . isearch-backward)
1940         ("j"   . pdf-view-next-line-or-next-page)
1941         ("k"   . pdf-view-previous-line-or-previous-page)
1942         ("h"   . image-backward-hscroll)
1943         ("l"   . image-forward-hscroll)))
1944 #+end_src
1945
1946 ** anzu
1947
1948 #+begin_src emacs-lisp
1949 (use-package anzu)
1950 #+end_src
1951
1952 ** typo.el
1953
1954 #+begin_src emacs-lisp
1955 (use-package typo
1956   :defer 2
1957   :config
1958   (typo-global-mode 1)
1959   :hook (text-mode . typo-mode))
1960 #+end_src
1961
1962 ** slack
1963
1964 Hopefully temporary.
1965
1966 #+begin_src emacs-lisp
1967 (use-package slack
1968   :commands (slack-start)
1969   :init
1970   (eval-when-compile                    ; silence the byte-compiler
1971     (defvar url-http-data nil)
1972     (defvar url-http-extra-headers nil)
1973     (defvar url-http-method nil)
1974     (defvar url-callback-function nil)
1975     (defvar url-callback-arguments nil)
1976     (defvar oauth--token-data nil))
1977   (setq slack-buffer-emojify t
1978         slack-prefer-current-team t)
1979   :config
1980   (slack-register-team
1981    :name "uw-apv"
1982    :default t
1983    :client-id uw-apv-client-id
1984    :client-secret uw-apv-client-secret
1985    :token uw-apv-token
1986    :subscribed-channels '(general)
1987    :full-and-display-names t)
1988   (slack-register-team
1989    :name "watform"
1990    :default nil
1991    :client-id watform-client-id
1992    :client-secret watform-client-secret
1993    :token watform-token
1994    :subscribed-channels '(general)
1995    :full-and-display-names t)
1996   (add-to-list 'swiper-font-lock-exclude 'slack-message-buffer-mode t)
1997   (setq lui-time-stamp-format "[%Y-%m-%d %H:%M:%S]"
1998         lui-time-stamp-only-when-changed-p t
1999         lui-time-stamp-position 'right)
2000   :bind
2001   (("C-c s s" . slack-start)
2002    ("C-c s u" . slack-select-unread-rooms)
2003    ("C-c s b" . slack-select-rooms)
2004    ("C-c s t" . slack-change-current-team)
2005    ("C-c s c" . slack-ws-close)
2006    :map slack-mode-map
2007    ("M-p"     . slack-buffer-goto-prev-message)
2008    ("M-n"     . slack-buffer-goto-next-message)
2009    ("C-c e"   . slack-message-edit)
2010    ("C-c k"   . slack-message-delete)
2011    ("C-c C-k" . slack-channel-leave)
2012    ("C-c r a" . slack-message-add-reaction)
2013    ("C-c r r" . slack-message-remove-reaction)
2014    ("C-c r s" . slack-message-show-reaction-users)
2015    ("C-c p l" . slack-room-pins-list)
2016    ("C-c p a" . slack-message-pins-add)
2017    ("C-c p r" . slack-message-pins-remove)
2018    ("@"       . slack-message-embed-mention)
2019    ("#"       . slack-message-embed-channel)))
2020
2021 (use-package alert
2022   :commands (alert)
2023   :init
2024   (setq alert-default-style 'notifier))
2025 #+end_src
2026
2027 ** hl-todo
2028
2029 #+begin_src emacs-lisp
2030 (use-package hl-todo
2031   :defer 4
2032   :config
2033   (global-hl-todo-mode))
2034 #+end_src
2035
2036 ** shrink-path
2037
2038 #+begin_src emacs-lisp
2039 (use-package shrink-path
2040   :after eshell
2041   :config
2042   (setq eshell-prompt-regexp "\\(.*\n\\)*λ "
2043         eshell-prompt-function #'+eshell/prompt)
2044
2045   (defun +eshell/prompt ()
2046     (let ((base/dir (shrink-path-prompt default-directory)))
2047       (concat (propertize (car base/dir)
2048                           'face 'font-lock-comment-face)
2049               (propertize (cdr base/dir)
2050                           'face 'font-lock-constant-face)
2051               (propertize (+eshell--current-git-branch)
2052                           'face 'font-lock-function-name-face)
2053               "\n"
2054               (propertize "λ" 'face 'eshell-prompt-face)
2055               ;; needed for the input text to not have prompt face
2056               (propertize " " 'face 'default))))
2057
2058   (defun +eshell--current-git-branch ()
2059     (let ((branch (car (loop for match in (split-string (shell-command-to-string "git branch") "\n")
2060                              when (string-match "^\*" match)
2061                              collect match))))
2062       (if (not (eq branch nil))
2063           (concat " " (substring branch 2))
2064         ""))))
2065 #+end_src
2066
2067 ** magithub
2068
2069 For when I /have to/ use GH.
2070
2071 #+begin_src emacs-lisp
2072 (use-package magithub
2073   :after magit
2074   :config
2075   (magithub-feature-autoinject t)
2076   (setq magithub-clone-default-directory "~/src/git"))
2077 #+end_src
2078
2079 ** [[https://github.com/peterwvj/eshell-up][eshell-up]]
2080
2081 #+begin_src emacs-lisp
2082 (use-package eshell-up
2083   :after eshell)
2084 #+end_src
2085
2086 * Email
2087
2088 #+begin_src emacs-lisp
2089 (defvar amin-maildir (expand-file-name "~/mail/"))
2090 (after! recentf
2091   (add-to-list 'recentf-exclude amin-maildir))
2092 #+end_src
2093
2094 ** Gnus
2095
2096 #+begin_src emacs-lisp
2097 (setq
2098  amin-gnus-init-file (no-littering-expand-etc-file-name "gnus")
2099  mail-user-agent     'gnus-user-agent
2100  read-mail-command   'gnus)
2101
2102 (use-package gnus
2103   :general
2104   (amin--leader-keys
2105     "m" 'gnus
2106     "M" 'gnus-unplugged)
2107   :bind (("s-m" . gnus)
2108          ("s-M" . gnus-unplugged))
2109   :init
2110   (setq
2111    gnus-select-method '(nnnil "")
2112    gnus-secondary-select-methods
2113    '((nnimap "amin"
2114             (nnimap-stream plain)
2115             (nnimap-address "127.0.0.1")
2116             (nnimap-server-port 143)
2117             (nnimap-authenticator plain)
2118             (nnimap-user "amin@aminb.org"))
2119      (nnimap "uwaterloo"
2120              (nnimap-stream plain)
2121              (nnimap-address "127.0.0.1")
2122              (nnimap-server-port 143)
2123              (nnimap-authenticator plain)
2124              (nnimap-user "abandali@uwaterloo.ca")))
2125    gnus-message-archive-group "nnimap+amin:Sent"
2126    gnus-parameters
2127    '(("gnu.*"
2128       (gcc-self . t)))
2129    gnus-large-newsgroup  50
2130    gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
2131    gnus-directory        (concat gnus-home-directory "news/")
2132    message-directory     (concat gnus-home-directory "mail/")
2133    nndraft-directory     (concat gnus-home-directory "drafts/")
2134    gnus-save-newsrc-file nil
2135    gnus-read-newsrc-file nil
2136    gnus-interactive-exit nil
2137    gnus-gcc-mark-as-read t))
2138
2139 (use-package gnus-art
2140   :config
2141   (setq
2142    gnus-visible-headers
2143    (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
2144    gnus-sorted-header-list
2145    '("^From:" "^Subject:" "^Summary:" "^Keywords:"
2146      "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
2147      "^Newsgroups:" "List-Id:" "^Organization:"
2148      "^User-Agent:" "^Date:")
2149   ;; local-lapsed article dates
2150   ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
2151   gnus-article-date-headers '(user-defined)
2152   gnus-article-time-format
2153   (lambda (time)
2154     (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
2155            (local (article-make-date-line date 'local))
2156            (combined-lapsed (article-make-date-line date
2157                                                     'combined-lapsed))
2158            (lapsed (progn
2159                      (string-match " (.+" combined-lapsed)
2160                      (match-string 0 combined-lapsed))))
2161       (concat local lapsed))))
2162   (bind-keys
2163    :map gnus-article-mode-map
2164    ("r"   . gnus-article-reply-with-original)
2165    ("R"   . gnus-article-wide-reply-with-original)
2166    ("M-L" . org-store-link)))
2167
2168 (use-package gnus-sum
2169   :bind (:map gnus-summary-mode-map
2170               :prefix-map amin--gnus-summary-prefix-map
2171               :prefix "v"
2172               ("r" . gnus-summary-reply)
2173               ("w" . gnus-summary-wide-reply)
2174               ("v" . gnus-summary-show-raw-article))
2175   :config
2176   (bind-keys
2177    :map gnus-summary-mode-map
2178    ("r"   . gnus-summary-reply-with-original)
2179    ("R"   . gnus-summary-wide-reply-with-original)
2180    ("M-L" . org-store-link)))
2181
2182 (use-package gnus-msg
2183   :config
2184   (setq gnus-posting-styles
2185         '((".*"
2186            (address "amin@aminb.org")
2187            (body "\nBest,\namin\n"))
2188           ("gnu.*"
2189            (address "bandali@gnu.org"))
2190           ((header "subject" "ThankCRM")
2191            (to "webmasters-comment@gnu.org"))
2192           ("nnimap\\+uwaterloo:.*"
2193            (address "abandali@uwaterloo.ca")
2194            (gcc "\"nnimap+uwaterloo:Sent Items\"")))))
2195
2196 (use-package gnus-topic
2197   :hook (gnus-group-mode . gnus-topic-mode))
2198
2199 (use-package gnus-agent
2200   :config
2201   (setq gnus-agent-synchronize-flags 'ask)
2202   :hook (gnus-group-mode . gnus-agent-mode))
2203
2204 (use-package gnus-group
2205   :config
2206   (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))
2207
2208 (use-package mm-decode
2209   :config
2210   (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
2211 #+end_src
2212
2213 ** sendmail
2214
2215 #+begin_src emacs-lisp
2216 (use-package sendmail
2217   :config
2218   (setq sendmail-program "/usr/bin/msmtp"
2219         ;; message-sendmail-extra-arguments '("-v" "-d")
2220         mail-specify-envelope-from t
2221         mail-envelope-from 'header))
2222 #+end_src
2223
2224 ** message
2225
2226 #+begin_src emacs-lisp
2227 (use-package message
2228   :config
2229   (defconst message-cite-style-bandali
2230     '((message-cite-function  'message-cite-original)
2231       (message-citation-line-function  'message-insert-formatted-citation-line)
2232       (message-cite-reply-position 'traditional)
2233       (message-yank-prefix  "> ")
2234       (message-yank-cited-prefix  ">")
2235       (message-yank-empty-prefix  ">")
2236       (message-citation-line-format "Hi %F,\n\nOn %Y-%m-%d %l:%M %p, %N wrote:"))
2237     "Citation style based on Mozilla Thunderbird's. Use with message-cite-style.")
2238   (setq message-cite-style 'message-cite-style-bandali
2239         message-kill-buffer-on-exit t
2240         message-send-mail-function 'message-send-mail-with-sendmail
2241         message-sendmail-envelope-from 'header
2242         message-dont-reply-to-names
2243         "\\(\\(.*@aminb\\.org\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
2244         message-user-fqdn "aminb.org")
2245   :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
2246          (message-mode . flyspell-mode)
2247          (message-mode . (lambda () (setq fill-column 65
2248                                      message-fill-column 65))))
2249   :custom-face
2250   (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
2251   (message-header-to      ((t (:foreground "#111" :weight normal))))
2252   (message-header-cc      ((t (:foreground "#333" :weight normal)))))
2253
2254 (after! mml-sec
2255   (setq mml-secure-openpgp-encrypt-to-self t
2256         mml-secure-openpgp-sign-with-sender t))
2257 #+end_src
2258
2259 ** footnote
2260
2261 Convenient footnotes in =message-mode=.
2262
2263 #+begin_src emacs-lisp
2264 (use-package footnote
2265   :after message
2266   :bind
2267   (:map message-mode-map
2268         :prefix-map amin--footnote-prefix-map
2269         :prefix "C-c f"
2270         ("a" . footnote-add-footnote)
2271         ("b" . footnote-back-to-message)
2272         ("c" . footnote-cycle-style)
2273         ("d" . footnote-delete-footnote)
2274         ("g" . footnote-goto-footnote)
2275         ("r" . footnote-renumber-footnotes)
2276         ("s" . footnote-set-style))
2277   :config
2278   (setq footnote-start-tag ""
2279         footnote-end-tag   ""
2280         footnote-style     'unicode))
2281 #+end_src
2282
2283 ** COMMENT supercite
2284
2285 #+begin_src emacs-lisp
2286 (use-package supercite
2287   :after message
2288   :init
2289   (setq sc-nested-citation-p t
2290         ;; sc-cite-blank-lines-p t
2291         sc-citation-leader ""
2292         sc-reference-tag-string ""
2293         sc-preferred-header-style 5     ; (sc-header-author-writes)
2294         sc-auto-fill-region-p nil
2295         sc-confirm-always-p nil)
2296   :config
2297   ;;   (defun amin--sc-header-on-wrote ()
2298   ;;     "\"On <date>, <sc-author> wrote:\" unless:
2299   ;; 1. the \"sc-author\" field cannot be found, in which case nothing is inserted;
2300   ;; 2. the \"date\" field is missing in which case only the from part is printed."
2301   ;;     (let ((sc-mumble "")
2302   ;;          (whofrom (sc-whofrom)))
2303   ;;       (if whofrom
2304   ;;          (insert sc-reference-tag-string
2305   ;;                      (sc-hdr "On " (sc-mail-field "date") ", ")
2306   ;;                      (sc-hdr "" (sc-mail-field "sc-author")) " wrote:\n"))))
2307   ;;   (defun amin--sc-header ()
2308   ;;     "Hi <firstname>,\n\n <from> writes:"
2309   ;;     (let ((sc-mumble "")
2310   ;;          (whofrom (sc-whofrom)))
2311   ;;       (if whofrom
2312   ;;          (insert (sc-hdr "Hi " (sc-mail-field "sc-firstname") ",\n\n")
2313   ;;                   sc-reference-tag-string
2314   ;;                      whofrom
2315   ;;                      " writes:\n"))))
2316   ;; (add-to-list 'sc-rewrite-header-list '(amin--sc-header) t)
2317   ;; (add-to-list 'sc-rewrite-header-list '(amin--sc-header-on-wrote) t)
2318   ;; (setq sc-preferred-header-style (1- (length sc-rewrite-header-list)))
2319   (add-hook 'mail-citation-hook 'sc-cite-original))
2320 #+end_src
2321
2322 ** ebdb
2323
2324 #+begin_src emacs-lisp
2325 (use-package ebdb
2326   :defer 1
2327   :bind (:map gnus-group-mode-map ("e" . ebdb))
2328   :config
2329   (setq ebdb-sources (no-littering-expand-var-file-name "ebdb")))
2330
2331 (use-package ebdb-com
2332   :after ebdb)
2333
2334 (use-package ebdb-complete
2335   :after ebdb
2336   :config
2337   (ebdb-complete-enable))
2338
2339 (use-package ebdb-gnus
2340   :after ebdb)
2341
2342 (use-package ebdb-message
2343   :after ebdb)
2344
2345 ;; (use-package ebdb-vcard
2346 ;;   :after ebdb)
2347 #+end_src
2348
2349 ** COMMENT bbdb
2350
2351 #+begin_comment
2352 [submodule "bbdb"]
2353         path = lib/bbdb
2354         url = https://git.savannah.nongnu.org/git/bbdb.git
2355         load-path = lisp/elisp
2356         info-path = doc
2357         build-step = ./autogen.sh
2358         build-step = ./configure --with-lispdir=elisp
2359         build-step = make
2360         build-step = make install
2361 #+end_comment
2362
2363 #+begin_src emacs-lisp
2364 (use-package bbdb
2365   :init
2366   (bbdb-mua-auto-update-init 'message)
2367   (setq bbdb-mua-auto-update-p 'query)
2368   (add-hook 'gnus-startup-hook 'bbdb-insinuate-gnus))
2369 #+end_src
2370
2371 ** COMMENT message-x
2372
2373 #+begin_src emacs-lisp
2374 (use-package message-x
2375   :custom
2376   (message-x-completion-alist
2377    (quote
2378     (("\\([rR]esent-\\|[rR]eply-\\)?[tT]o:\\|[bB]?[cC][cC]:" . gnus-harvest-find-address)
2379      ((if
2380           (boundp
2381            (quote message-newgroups-header-regexp))
2382           message-newgroups-header-regexp message-newsgroups-header-regexp)
2383       . message-expand-group)))))
2384 #+end_src
2385
2386 ** COMMENT gnus-harvest
2387
2388 #+begin_src emacs-lisp
2389 (use-package gnus-harvest
2390   :commands gnus-harvest-install
2391   :demand t
2392   :config
2393   (if (featurep 'message-x)
2394       (gnus-harvest-install 'message-x)
2395     (gnus-harvest-install)))
2396 #+end_src
2397
2398 ** COMMENT gnus-alias                                              :ARCHIVE:
2399
2400 #+begin_src emacs-lisp
2401 (use-package gnus-alias
2402   :commands (gnus-alias-determine-identity
2403              gnus-alias-select-identity)
2404   :bind (:map  message-mode-map
2405                ("s-i" . gnus-alias-select-identity))
2406   :config
2407   (setq
2408    gnus-alias-default-identity "amin"
2409    gnus-alias-identity-alist
2410    '(("amin"
2411       nil   ;; Does not refer to any other identity
2412       "Amin Bandali <amin@aminb.org>"
2413       nil   ;; Organization
2414       nil   ;; extra headers
2415       nil   ;; extra body text
2416       nil)  ;; signature file
2417      ("gnu"
2418       nil
2419       "Amin Bandali <bandali@gnu.org>"
2420       nil
2421       nil
2422       nil
2423       nil)
2424      ("uw"
2425       nil
2426       "Amin Bandali <abandali@uwaterloo.ca>"
2427       nil
2428       (("Gcc" . "\"nnimap+uwaterloo:Sent Items\""))
2429       nil
2430       nil))
2431    gnus-alias-identity-rules
2432    '(("amin" ("Delivered-To" "<amin\\@aminb\\.org" both) "amin")
2433      ("gnu" ("Delivered-To" "<gnu\\@aminb\\.org" both) "gnu")
2434      ("uw" ("any" "<\\(.+\\)\\@uwaterloo\\.ca" both) "uw"))
2435    gnus-alias-override-user-mail-address t)
2436   :hook (message-setup . gnus-alias-determine-identity))
2437 #+end_src
2438
2439 ** COMMENT [[https://notmuchmail.org][notmuch]]                                                 :ARCHIVE:
2440
2441 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
2442
2443 #+begin_src emacs-lisp
2444 (defun amin/notmuch ()
2445   "Delete other windows, then launch `notmuch'."
2446   (interactive
2447    (when (equal current-prefix-arg nil)
2448      (delete-other-windows)))
2449   (notmuch))
2450
2451 (use-package notmuch
2452   :commands notmuch
2453   :bind ("C-c n" . amin/notmuch)
2454   :custom (notmuch-always-prompt-for-sender t)
2455   :config
2456   (setq notmuch-hello-sections
2457         '(notmuch-hello-insert-header
2458           notmuch-hello-insert-saved-searches
2459           ;; notmuch-hello-insert-search
2460           notmuch-hello-insert-alltags)
2461         notmuch-search-oldest-first nil
2462         notmuch-show-all-tags-list t
2463         notmuch-message-headers  ; see bug follow-up above
2464         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
2465         notmuch-hello-thousands-separator ","
2466         notmuch-fcc-dirs
2467         '(("amin@aminb.org"        . "amin/Sent")
2468           ("bandali@gnu.org"       . "gnu/Sent")
2469           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
2470           ("mab@gnu.org"           . "gnu/Sent")
2471           ("amin@gnu.org"          . "gnu/Sent")
2472           ("aminb@gnu.org"         . "gnu/Sent")
2473           (".*"                    . "sent"))
2474         notmuch-search-result-format
2475         '(("date"    . "%12s ")
2476           ("count"   . "%-7s ")
2477           ("authors" . "%-40s ")
2478           ("subject" . "%s ")
2479           ("tags"    . "(%s)"))
2480         notmuch-saved-searches
2481         '((:name "inbox"     :query "tag:inbox"     :key "i")
2482           (:name "unread"    :query "tag:unread"    :key "u")
2483           (:name "latest"    :query "tag:latest"    :key "l")
2484           (:name "encrypted" :query "tag:encrypted" :key "e")
2485           (:name "flagged"   :query "tag:flagged"   :key "f")
2486           (:name "sent"      :query "tag:sent"      :key "s")
2487           (:name "drafts"    :query "tag:draft"     :key "d")
2488           (:name "all mail"  :query "*"             :key "a")))
2489   ;; (add-hook 'visual-fill-column-mode-hook
2490   ;;           (lambda ()
2491   ;;             (when (string= major-mode 'notmuch-message-mode)
2492   ;;               (setq visual-fill-column-width 70))))
2493   ;; (set! :evil-state 'notmuch-message-mode 'insert)
2494   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
2495   ;;             :override #'kill-this-buffer)
2496   :hook (notmuch-message-mode . doom-modeline-set-special-modeline)
2497   :bind
2498   (:map notmuch-hello-mode-map
2499         ("u" . (lambda ()
2500                  "Search for `unread'-tagged messages"
2501                  (interactive)
2502                  (notmuch-hello-search "tag:unread")))
2503         ("i" . (lambda ()
2504                  "Search for `inbox'-tagged messages"
2505                  (interactive)
2506                  (notmuch-hello-search "tag:inbox")))
2507         ("l" . (lambda ()
2508                  "Search for `latest'-tagged messages"
2509                  (interactive)
2510                  (notmuch-hello-search "tag:latest")))
2511         ("e" . (lambda ()
2512                  "Search for `encrypted'-tagged messages"
2513                  (interactive)
2514                  (notmuch-hello-search "tag:encrypted"))))
2515   (:map notmuch-search-mode-map
2516         ("k" . (lambda ()
2517                  "Mark message read"
2518                  (interactive)
2519                  (notmuch-search-tag '("-unread"))
2520                  ;; (notmuch-search-archive-thread)
2521                  (notmuch-search-next-thread)))
2522         ("u" . (lambda ()
2523                  "Mark message unread"
2524                  (interactive)
2525                  (notmuch-search-tag '("+unread"))
2526                  (notmuch-search-next-thread)))
2527         ("K" . (lambda ()
2528                  "Mark message deleted"
2529                  (interactive)
2530                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
2531                  (notmuch-search-next-thread)))
2532         ("S" . (lambda ()
2533                  "Mark message as spam"
2534                  (interactive)
2535                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
2536                  (notmuch-search-next-thread))))
2537   (:map notmuch-tree-mode-map
2538         ("k" . (lambda ()
2539                  "Mark message read"
2540                  (interactive)
2541                  (notmuch-tree-tag '("-unread"))
2542                  ;; (notmuch-tree-archive-thread)
2543                  (notmuch-tree-next-message)))
2544         ("u" . (lambda ()
2545                  "Mark message unread"
2546                  (interactive)
2547                  (notmuch-tree-tag '("+unread"))
2548                  (notmuch-tree-next-message)))
2549         ("K" . (lambda ()
2550                  "Mark message deleted"
2551                  (interactive)
2552                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
2553                  (notmuch-tree-next-message)))
2554         ("S" . (lambda ()
2555                  "Mark message as spam"
2556                  (interactive)
2557                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
2558                  (notmuch-tree-next-message))))
2559   :custom-face
2560   (notmuch-search-unread-face ((t (:weight semi-bold))))
2561   (notmuch-tag-face ((t (:foreground "navy blue" :weight semi-bold)))))
2562
2563 (use-package counsel-notmuch
2564   :bind ("C-c s m" . counsel-notmuch))
2565
2566 (after! notmuch-crypto
2567   (setq notmuch-crypto-process-mime t))
2568
2569 (use-package org-notmuch
2570   :after (:any org notmuch))
2571 #+end_src
2572
2573 * Blogging
2574 ** [[https://ox-hugo.scripter.co][ox-hugo]]
2575
2576 #+begin_src emacs-lisp
2577 (use-package ox-hugo
2578   :after ox)
2579
2580 (use-package ox-hugo-auto-export
2581   :load-path "lib/ox-hugo")
2582 #+end_src
2583
2584 * Post initialization
2585 :PROPERTIES:
2586 :CUSTOM_ID: post-initialization
2587 :END:
2588
2589 Display how long it took to load the init file.
2590
2591 #+begin_src emacs-lisp
2592 (message "Loading %s...done (%.3fs)" user-init-file
2593          (float-time (time-subtract (current-time)
2594                                     amin--before-user-init-time)))
2595 #+end_src
2596
2597 * Footer
2598 :PROPERTIES:
2599 :CUSTOM_ID: footer
2600 :END:
2601
2602 #+begin_src emacs-lisp :comments none
2603 ;;; init.el ends here
2604 #+end_src
2605
2606 * COMMENT Local Variables                                           :ARCHIVE:
2607 # Local Variables:
2608 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
2609 # End: