git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 ;; (require 'borg-nix-shell)
 238 ;; (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c B A" . borg-activate)
 244    ("C-c B a" . borg-assimilate)
 245    ("C-c B b" . borg-build)
 246    ("C-c B c" . borg-clone)))
 247 #+end_src
 248
 249 *** =use-package=
 250
 251 #+begin_quote
 252 A use-package declaration for simplifying your .emacs
 253 #+end_quote
 254
 255 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 256 packages (in our case especially the latter) in a neatly organized way
 257 and without compromising on performance.
 258
 259 #+begin_src emacs-lisp
 260 (require 'use-package)
 261 (if nil  ; set to t when need to debug init
 262     (setq use-package-verbose t
 263           use-package-expand-minimally nil
 264           use-package-compute-statistics t
 265           debug-on-error t)
 266   (setq use-package-verbose nil
 267         use-package-expand-minimally t))
 268 #+end_src
 269
 270 *** Epkg
 271
 272 #+begin_quote
 273 Browse the Emacsmirror package database
 274 #+end_quote
 275
 276 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 277 database, low-level functions for querying the database, and a
 278 =package.el=-like user interface for browsing the available packages.
 279
 280 #+begin_src emacs-lisp
 281 (use-package epkg
 282   :defer t
 283   :bind
 284   (("C-c B d" . epkg-describe-package)
 285    ("C-c B p" . epkg-list-packages)
 286    ("C-c B r" . borg-remove)
 287    ("C-c B u" . epkg-update)))
 288 #+end_src
 289
 290 ** No littering in =~/.emacs.d=
 291
 292 #+begin_quote
 293 Help keeping ~/.emacs.d clean
 294 #+end_quote
 295
 296 By default, even for Emacs' built-in packages, the configuration files
 297 and persistent data are all over the place. Use =no-littering= to help
 298 contain the mess.
 299
 300 #+begin_src emacs-lisp
 301 (use-package no-littering
 302   :demand t
 303   :config
 304   (savehist-mode 1)
 305   (add-to-list 'savehist-additional-variables 'kill-ring)
 306   (save-place-mode 1)
 307   (setq auto-save-file-name-transforms
 308         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 309 #+end_src
 310
 311 ** Custom file (=custom.el=)
 312
 313 I'm not planning on using the custom file much, but even so, I
 314 definitely don't want it mixing with =init.el=. So, here; let's give
 315 it it's own file. While at it, treat themes as safe.
 316
 317 #+begin_src emacs-lisp
 318 (use-package custom
 319   :no-require t
 320   :config
 321   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 322   (when (file-exists-p custom-file)
 323     (load custom-file))
 324   (setf custom-safe-themes t))
 325 #+end_src
 326
 327 ** Secrets file
 328
 329 #+begin_src emacs-lisp
 330 (load (no-littering-expand-etc-file-name "secrets"))
 331 #+end_src
 332
 333 ** Better =$PATH= handling
 334
 335 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 336 in my shell.
 337
 338 #+begin_src emacs-lisp
 339 (use-package exec-path-from-shell
 340   :defer 1
 341   :init
 342   (setq exec-path-from-shell-check-startup-files nil)
 343   :config
 344   (exec-path-from-shell-initialize)
 345   ;; while we're at it, let's fix access to our running ssh-agent
 346   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 347   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 348 #+end_src
 349
 350 ** Only one custom theme at a time
 351
 352 #+begin_src emacs-lisp
 353 (defadvice load-theme (before clear-previous-themes activate)
 354   "Clear existing theme settings instead of layering them"
 355   (mapc #'disable-theme custom-enabled-themes))
 356 #+end_src
 357
 358 ** Server
 359
 360 Start server if not already running. Alternatively, can be done by
 361 issuing =emacs --daemon= in the terminal, which can be automated with
 362 a systemd service or using =brew services start emacs= on macOS. I use
 363 Emacs as my window manager (via EXWM), so I always start Emacs on
 364 login; so starting the server from inside Emacs is good enough for me.
 365
 366 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 367
 368 #+begin_src emacs-lisp
 369 (use-package server
 370   :defer 1
 371   :config (or (server-running-p) (server-mode)))
 372 #+end_src
 373
 374 ** Unicode support
 375
 376 Font stack with better unicode support, around =Ubuntu Mono= and
 377 =Hack=.
 378
 379 #+begin_src emacs-lisp :tangle no
 380 (dolist (ft (fontset-list))
 381   (set-fontset-font
 382    ft
 383    'unicode
 384    (font-spec :name "Source Code Pro" :size 14))
 385   (set-fontset-font
 386    ft
 387    'unicode
 388    (font-spec :name "DejaVu Sans Mono")
 389    nil
 390    'append)
 391   ;; (set-fontset-font
 392   ;;  ft
 393   ;;  'unicode
 394   ;;  (font-spec
 395   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 396   ;;  nil
 397   ;;  'append)
 398   ;; (set-fontset-font
 399   ;;  ft
 400   ;;  #x2115  ; ℕ
 401   ;;  (font-spec :name "DejaVu Sans Mono")
 402   ;;  nil
 403   ;;  'append)
 404   (set-fontset-font
 405    ft
 406    (cons ?Α ?ω)
 407    (font-spec :name "DejaVu Sans Mono" :size 14)
 408    nil
 409    'prepend))
 410 #+end_src
 411
 412 ** Gentler font resizing
 413
 414 #+begin_src emacs-lisp
 415 (setq text-scale-mode-step 1.05)
 416 #+end_src
 417
 418 ** Libraries
 419
 420 #+begin_src emacs-lisp
 421 (require 'cl-lib)
 422 (require 'subr-x)
 423 #+end_src
 424
 425 ** Useful utilities
 426
 427 #+begin_src emacs-lisp
 428 (defun amin-enlist (exp)
 429   "Return EXP wrapped in a list, or as-is if already a list."
 430 (if (listp exp) exp (list exp)))
 431
 432 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 433 (defmacro after! (features &rest body)
 434   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 435 compilation."
 436   (declare (indent defun) (debug t))
 437   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 438                 (dolist (next (amin-enlist features))
 439                   (if (symbolp next)
 440                       (require next nil :no-error)
 441                     (load next :no-message :no-error))))
 442             #'progn
 443           #'with-no-warnings)
 444         (cond ((symbolp features)
 445                `(eval-after-load ',features '(progn ,@body)))
 446               ((and (consp features)
 447                     (memq (car features) '(:or :any)))
 448                `(progn
 449                   ,@(cl-loop for next in (cdr features)
 450                              collect `(after! ,next ,@body))))
 451               ((and (consp features)
 452                     (memq (car features) '(:and :all)))
 453                (dolist (next (cdr features))
 454                  (setq body `(after! ,next ,@body)))
 455                body)
 456               ((listp features)
 457                `(after! (:all ,@features) ,@body)))))
 458 #+end_src
 459
 460 Convenience macro for =setq='ing multiple variables to the same value:
 461
 462 #+begin_src emacs-lisp
 463 (defmacro setq-every! (value &rest vars)
 464   "Set all the variables from VARS to value VALUE."
 465   (declare (indent defun) (debug t))
 466   `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))
 467 #+end_src
 468
 469 * Core
 470 :PROPERTIES:
 471 :CUSTOM_ID: core
 472 :END:
 473
 474 ** Defaults
 475
 476 *** Time and battery in mode-line
 477
 478 Enable displaying time and battery in the mode-line, since I'm not
 479 using the Xfce panel anymore. Also, I don't need to see the load
 480 average on a regular basis, so disable that.
 481
 482 Note: using =i3status= on sway at the moment, so disabling this.
 483
 484 #+begin_src emacs-lisp :tangle no
 485 (use-package time
 486   :init
 487   (setq display-time-default-load-average nil)
 488   :config
 489   (display-time-mode))
 490
 491 (use-package battery
 492   :config
 493   (display-battery-mode))
 494 #+end_src
 495
 496 *** Smaller fringe
 497
 498 Might want to set the fringe to a smaller value, especially if using
 499 EXWM. I'm fine with the default for now.
 500
 501 #+begin_src emacs-lisp
 502 ;; (fringe-mode '(3 . 1))
 503 (fringe-mode nil)
 504 #+end_src
 505
 506 *** Disable disabled commands
 507
 508 Emacs disables some commands by default that could persumably be
 509 confusing for novice users. Let's disable that.
 510
 511 #+begin_src emacs-lisp
 512 (setq disabled-command-function nil)
 513 #+end_src
 514
 515 *** Kill-ring
 516
 517 Save what I copy into clipboard from other applications into Emacs'
 518 kill-ring, which would allow me to still be able to easily access it
 519 in case I kill (cut or copy) something else inside Emacs before
 520 yanking (pasting) what I'd originally intended to.
 521
 522 #+begin_src emacs-lisp
 523 (setq save-interprogram-paste-before-kill t)
 524 #+end_src
 525
 526 *** Minibuffer
 527
 528 #+begin_src emacs-lisp
 529 (setq enable-recursive-minibuffers t
 530       resize-mini-windows t)
 531 #+end_src
 532
 533 *** Lazy-person-friendly yes/no prompts
 534
 535 Lazy people would prefer to type fewer keystrokes, especially for yes
 536 or no questions. I'm lazy.
 537
 538 #+begin_src emacs-lisp
 539 (defalias 'yes-or-no-p #'y-or-n-p)
 540 #+end_src
 541
 542 *** Startup screen and =*scratch*=
 543
 544 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 545 startup buffer.
 546
 547 #+begin_src emacs-lisp
 548 (setq initial-buffer-choice t)
 549 #+end_src
 550
 551 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 552 need the default hint.
 553
 554 #+begin_src emacs-lisp
 555 (setq initial-scratch-message nil)
 556 #+end_src
 557
 558 Also, let's use Text mode as the major mode, in case I want to
 559 customize it (=*scratch*='s default major mode, Fundamental mode,
 560 can't really be customized).
 561
 562 #+begin_src emacs-lisp
 563 (setq initial-major-mode 'text-mode)
 564 #+end_src
 565
 566 Inhibit the buffer list when more than 2 files are loaded.
 567
 568 #+begin_src emacs-lisp
 569 (setq inhibit-startup-buffer-menu t)
 570 #+end_src
 571
 572 I don't really need to see the startup screen or echo area message
 573 either.
 574
 575 #+begin_src emacs-lisp
 576 (advice-add #'display-startup-echo-area-message :override #'ignore)
 577 (setq inhibit-startup-screen t
 578       inhibit-startup-echo-area-message user-login-name)
 579 #+end_src
 580
 581 *** More useful frame titles
 582
 583 Show either the file name or the buffer name (in case the buffer isn't
 584 visiting a file). Borrowed from Emacs Prelude.
 585
 586 #+begin_src emacs-lisp
 587 (setq frame-title-format
 588       '("" invocation-name " - "
 589         (:eval (if (buffer-file-name)
 590                    (abbreviate-file-name (buffer-file-name))
 591                  "%b"))))
 592 #+end_src
 593
 594 *** Backups
 595
 596 Emacs' default backup settings aren't that great. Let's use more
 597 sensible options. See documentation for the ~make-backup-file~
 598 variable.
 599
 600 #+begin_src emacs-lisp
 601 (setq backup-by-copying t
 602       version-control t
 603       delete-old-versions t)
 604 #+end_src
 605
 606 *** Auto revert
 607
 608 Enable automatic reloading of changed buffers and files.
 609
 610 #+begin_src emacs-lisp
 611 (global-auto-revert-mode 1)
 612 (setq auto-revert-verbose nil
 613       global-auto-revert-non-file-buffers t)
 614 #+end_src
 615
 616 *** Always use space for indentation
 617
 618 #+begin_src emacs-lisp
 619 (setq-default
 620  indent-tabs-mode nil
 621  require-final-newline t
 622  tab-width 4)
 623 #+end_src
 624
 625 *** Winner mode
 626
 627 Enable =winner-mode=.
 628
 629 #+begin_src emacs-lisp
 630 (winner-mode 1)
 631 #+end_src
 632
 633 *** Close =*compilation*= on success
 634
 635 #+begin_src emacs-lisp
 636 (setq compilation-exit-message-function
 637       (lambda (status code msg)
 638         "Close the compilation window if successful."
 639         ;; if M-x compile exits with 0
 640          (when (and (eq status 'exit) (zerop code))
 641            (bury-buffer)
 642            (delete-window (get-buffer-window (get-buffer "*compilation*"))))
 643          ;; return the result of compilation-exit-message-function
 644          (cons msg code)))
 645 #+end_src
 646
 647 ** Bindings
 648
 649 #+begin_src emacs-lisp
 650 (bind-keys
 651  ("C-c b k" . kill-this-buffer)
 652  ("C-c b s" . save-buffer)
 653  ("C-c S"   . save-buffer)
 654  ("C-c o"   . other-window)
 655  ("C-c q q" . save-buffers-kill-terminal)
 656
 657  ("C-c F m" . make-frame-command)
 658  ("C-c F d" . delete-frame)
 659  ("C-c F D" . delete-other-frames)
 660
 661  ("s-c e b" . eval-buffer)
 662  ("s-c e r" . eval-region)
 663
 664  ("s-p"     . beginning-of-buffer)
 665  ("s-n"     . end-of-buffer))
 666 #+end_src
 667
 668 ** Packages
 669
 670 The packages in this section are absolutely essential to my everyday
 671 workflow, and they play key roles in how I do my computing. They
 672 immensely enhance the Emacs experience for me; both using Emacs, and
 673 customizing it.
 674
 675 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 676
 677 #+begin_src emacs-lisp
 678 (use-package auto-compile
 679   :demand t
 680   :config
 681   (auto-compile-on-load-mode)
 682   (auto-compile-on-save-mode)
 683   (setq auto-compile-display-buffer               nil
 684         auto-compile-mode-line-counter            t
 685         auto-compile-source-recreate-deletes-dest t
 686         auto-compile-toggle-deletes-nonlib-dest   t
 687         auto-compile-update-autoloads             t)
 688   (add-hook 'auto-compile-inhibit-compile-hook
 689             'auto-compile-inhibit-compile-detached-git-head))
 690 #+end_src
 691
 692 *** [[https://orgmode.org/][Org mode]]
 693
 694 #+begin_quote
 695 Org mode is for keeping notes, maintaining TODO lists, planning
 696 projects, and authoring documents with a fast and effective plain-text
 697 system.
 698 #+end_quote
 699
 700 In short, my favourite way of life.
 701
 702 #+begin_src emacs-lisp
 703 (use-package org
 704   :defer 3
 705   :config
 706   (setq org-src-tab-acts-natively t
 707         org-src-preserve-indentation nil
 708         org-edit-src-content-indentation 0
 709         org-email-link-description-format "Email %c: %s" ; %.30s
 710         org-log-done 'time)
 711   :bind (:map org-mode-map ("M-L" . org-insert-last-stored-link))
 712   :hook ((org-mode . org-indent-mode)
 713          (org-mode . auto-fill-mode)
 714          (org-mode . flyspell-mode))
 715   :custom
 716   (org-latex-packages-alist '(("" "listings") ("" "color"))))
 717
 718 (use-package ox-latex
 719   :after ox
 720   :config
 721   (setq org-latex-listings 'listings
 722         ;; org-latex-prefer-user-labels t
 723         )
 724   (add-to-list 'org-latex-packages-alist '("" "listings"))
 725   (add-to-list 'org-latex-packages-alist '("" "color"))
 726   (add-to-list 'org-latex-classes
 727                '("IEEEtran" "\\documentclass[11pt]{IEEEtran}"
 728                  ("\\section{%s}" . "\\section*{%s}")
 729                  ("\\subsection{%s}" . "\\subsection*{%s}")
 730                  ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 731                  ("\\paragraph{%s}" . "\\paragraph*{%s}")
 732                  ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 733                t))
 734
 735 (use-package ox-beamer
 736   :after ox)
 737
 738 (use-package orgalist
 739   :after message
 740   :hook (message-mode . orgalist-mode))
 741 #+end_src
 742
 743 **** asynchronous tangle
 744
 745 =amin/async-babel-tangle= is a function closely inspired by [[https://github.com/dieggsy/dotfiles/tree/cc10edf7701958eff1cd94d4081da544d882a28c/emacs.d#dotfiles][dieggsy's
 746 d/async-babel-tangle]] which uses [[https://github.com/jwiegley/emacs-async][async]] to asynchronously tangle an org
 747 file.
 748
 749 #+begin_src emacs-lisp
 750 (after! org
 751   (defvar amin-show-async-tangle-results nil
 752     "Keep *emacs* async buffers around for later inspection.")
 753
 754   (defvar amin-show-async-tangle-time nil
 755     "Show the time spent tangling the file.")
 756
 757   (defvar amin-async-tangle-post-compile "make ti"
 758     "If non-nil, pass to `compile' after successful tangle.")
 759
 760   (defun amin/async-babel-tangle ()
 761     "Tangle org file asynchronously."
 762     (interactive)
 763     (let* ((file-tangle-start-time (current-time))
 764            (file (buffer-file-name))
 765            (file-nodir (file-name-nondirectory file))
 766            (async-quiet-switch "-q"))
 767       (async-start
 768        `(lambda ()
 769           (require 'org)
 770           (org-babel-tangle-file ,file))
 771        (unless amin-show-async-tangle-results
 772          `(lambda (result)
 773             (if result
 774                 (progn
 775                   (message "Tangled %s%s"
 776                            ,file-nodir
 777                            (if amin-show-async-tangle-time
 778                                (format " (%.3fs)"
 779                                        (float-time (time-subtract (current-time)
 780                                                                   ',file-tangle-start-time)))
 781                              ""))
 782                   (when amin-async-tangle-post-compile
 783                     (compile amin-async-tangle-post-compile)))
 784               (message "Tangling %s failed" ,file-nodir))))))))
 785
 786 (add-to-list
 787  'safe-local-variable-values
 788  '(eval add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local))
 789 #+end_src
 790
 791 *** [[https://magit.vc/][Magit]]
 792
 793 #+begin_quote
 794 It's Magit! A Git porcelain inside Emacs.
 795 #+end_quote
 796
 797 Not just how I do git, but /the/ way to do git.
 798
 799 #+begin_src emacs-lisp
 800 (use-package magit
 801   :defer 2
 802   :bind
 803   (("s-g" . magit-status)
 804    :prefix-map amin--magit-prefix-map
 805    :prefix "C-c g"
 806    ("SPC" . magit-status)
 807    ("s"   . magit-status)
 808    ("S"   . magit-status-prefix)
 809    ("B"   . magit-blame-addition)
 810    ("C"   . magit-clone)
 811    ("f"   . magit-fetch-other)
 812    ("F"   . magit-pull-branch)
 813    ("P"   . magit-push-other)
 814    ("p"   . magit-dispatch-popup)
 815    ("c c" . magit-commit-create)
 816    ("c a" . magit-commit-amend)
 817    ("b b" . magit-checkout)
 818    ("b c" . magit-branch-create))
 819   :config
 820   (magit-add-section-hook 'magit-status-sections-hook
 821                           'magit-insert-modules
 822                           'magit-insert-stashes
 823                           'append)
 824   :custom-face (magit-diff-file-heading ((t (:weight normal)))))
 825 #+end_src
 826
 827 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 828
 829 #+begin_quote
 830 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 831 an overview, and more. Oh, man!
 832 #+end_quote
 833
 834 There's no way I could top that, so I won't attempt to.
 835
 836 **** Ivy
 837
 838 #+begin_src emacs-lisp
 839 (use-package ivy
 840   :defer 1
 841   :bind
 842   (("C-c b b" . ivy-switch-buffer)
 843    :map ivy-minibuffer-map
 844    ([escape] . keyboard-escape-quit)
 845    ([S-up]   . ivy-previous-history-element)
 846    ([S-down] . ivy-next-history-element)
 847    ("DEL"    . ivy-backward-delete-char))
 848   :config
 849   (setq ivy-wrap t)
 850   (ivy-mode 1)
 851   :custom-face
 852   (ivy-minibuffer-match-face-2 ((t (:background "#e99ce8" :weight semi-bold))))
 853   (ivy-minibuffer-match-face-3 ((t (:background "#bbbbff" :weight semi-bold))))
 854   (ivy-minibuffer-match-face-4 ((t (:background "#ffbbff" :weight semi-bold)))))
 855 #+end_src
 856
 857 **** Swiper
 858
 859 #+begin_src emacs-lisp
 860 (use-package swiper
 861   :bind (("C-s" . swiper)
 862          ("C-r" . swiper)))
 863 #+end_src
 864
 865 **** Counsel
 866
 867 #+begin_src emacs-lisp
 868 (use-package counsel
 869   :defer 1
 870   :bind (([remap execute-extended-command] . counsel-M-x)
 871          ([remap find-file]                . counsel-find-file)
 872          ("s-r"                            . counsel-recentf)
 873          ("C-c x"                          . counsel-M-x)
 874          ("C-c f ."                        . counsel-find-file)
 875          :map minibuffer-local-map
 876          ("C-r" . counsel-minibuffer-history))
 877   :config
 878   (counsel-mode 1)
 879   (defalias 'locate #'counsel-locate))
 880 #+end_src
 881
 882 *** eshell
 883
 884 #+begin_src emacs-lisp
 885 (use-package eshell
 886   :defer t
 887   :commands eshell
 888   :config
 889   (eval-when-compile (defvar eshell-prompt-regexp))
 890   (defun amin/eshell-quit-or-delete-char (arg)
 891     (interactive "p")
 892     (if (and (eolp) (looking-back eshell-prompt-regexp nil))
 893         (eshell-life-is-too-much)
 894       (delete-char arg)))
 895
 896   (defun amin/eshell-clear ()
 897     (interactive)
 898     (let ((inhibit-read-only t))
 899       (erase-buffer))
 900     (eshell-send-input))
 901
 902   (defun amin|eshell-setup ()
 903     (bind-keys :map eshell-mode-map
 904                ("C-d" . amin/eshell-quit-or-delete-char)
 905                ("C-l" . amin/eshell-clear)))
 906
 907   :hook (eshell-mode . amin|eshell-setup))
 908 #+end_src
 909
 910 *** Ibuffer
 911
 912 #+begin_src emacs-lisp
 913 (use-package ibuffer
 914   :defer t
 915   :bind
 916   (("C-x C-b" . ibuffer-other-window)
 917    ("C-c b B" . ibuffer-other-window)
 918    :map ibuffer-mode-map
 919    ("P"   . ibuffer-backward-filter-group)
 920    ("N"   . ibuffer-forward-filter-group)
 921    ("M-p" . ibuffer-do-print)
 922    ("M-n" . ibuffer-do-shell-command-pipe-replace))
 923   :config
 924   ;; Use human readable Size column instead of original one
 925   (define-ibuffer-column size-h
 926     (:name "Size" :inline t)
 927     (cond
 928      ((> (buffer-size) 1000000) (format "%7.1fM" (/ (buffer-size) 1000000.0)))
 929      ((> (buffer-size) 100000) (format "%7.0fk" (/ (buffer-size) 1000.0)))
 930      ((> (buffer-size) 1000) (format "%7.1fk" (/ (buffer-size) 1000.0)))
 931      (t (format "%8d" (buffer-size)))))
 932   :custom
 933   (ibuffer-saved-filter-groups
 934    '(("default"
 935       ("dired" (mode . dired-mode))
 936       ("org"   (mode . org-mode))
 937       ("web"
 938        (or
 939         (mode . web-mode)
 940         (mode . css-mode)
 941         (mode . scss-mode)
 942         (mode . js2-mode)))
 943       ("shell"
 944        (or
 945         (mode . eshell-mode)
 946         (mode . shell-mode)))
 947       ("notmuch" (name . "\*notmuch\*"))
 948       ("programming"
 949        (or
 950         (mode . python-mode)
 951         (mode . c++-mode)
 952         (mode . emacs-lisp-mode)))
 953       ("emacs"
 954        (or
 955         (name . "^\\*scratch\\*$")
 956         (name . "^\\*Messages\\*$")))
 957       ("slack"
 958        (or
 959         (name . "^\\*Slack*"))))))
 960   (ibuffer-formats
 961    '((mark modified read-only locked " "
 962            (name 18 18 :left :elide)
 963            " "
 964            (size-h 9 -1 :right)
 965            " "
 966            (mode 16 16 :left :elide)
 967            " " filename-and-process)
 968      (mark " "
 969            (name 16 -1)
 970            " " filename)))
 971   :hook (ibuffer . (lambda () (ibuffer-switch-to-saved-filter-groups "default"))))
 972 #+end_src
 973
 974 *** Outline
 975
 976 #+begin_src emacs-lisp
 977 (use-package outline
 978   :defer t
 979   :hook (prog-mode . outline-minor-mode)
 980   :bind
 981   (:map
 982    outline-minor-mode-map
 983    ("<s-tab>"  . outline-toggle-children)
 984    ("M-p"      . outline-previous-visible-heading)
 985    ("M-n"      . outline-next-visible-heading)
 986    :prefix-map amin--outline-prefix-map
 987    :prefix "s-o"
 988    ("TAB" . outline-toggle-children)
 989    ("a"   . outline-hide-body)
 990    ("H"   . outline-hide-body)
 991    ("S"   . outline-show-all)
 992    ("h"   . outline-hide-subtree)
 993    ("s"   . outline-show-subtree)))
 994 #+end_src
 995
 996 * Borg's =layer/essentials=
 997
 998 TODO: break this giant source block down into individual org sections.
 999
1000 #+begin_src emacs-lisp
1001 (use-package dash
1002   :config (dash-enable-font-lock))
1003
1004 (use-package diff-hl
1005   :config
1006   (setq diff-hl-draw-borders nil)
1007   (global-diff-hl-mode)
1008   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
1009
1010 (use-package dired
1011   :defer t
1012   :config (setq dired-listing-switches "-alh"))
1013
1014 (use-package eldoc
1015   :when (version< "25" emacs-version)
1016   :config (global-eldoc-mode))
1017
1018 (use-package help
1019   :defer t
1020   :config (temp-buffer-resize-mode))
1021
1022 (progn ;    `isearch'
1023   (setq isearch-allow-scroll t))
1024
1025 (use-package lisp-mode
1026   :config
1027   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
1028   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
1029   (defun indent-spaces-mode ()
1030     (setq indent-tabs-mode nil))
1031   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
1032
1033 (use-package man
1034   :defer t
1035   :config (setq Man-width 80))
1036
1037 (use-package paren
1038   :config (show-paren-mode))
1039
1040 (use-package prog-mode
1041   :config (global-prettify-symbols-mode)
1042   (defun indicate-buffer-boundaries-left ()
1043     (setq indicate-buffer-boundaries 'left))
1044   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
1045
1046 (use-package recentf
1047   :defer 0.5
1048   :config
1049   (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:")
1050   (setq recentf-max-saved-items 40))
1051
1052 (use-package savehist
1053   :config (savehist-mode))
1054
1055 (use-package saveplace
1056   :when (version< "25" emacs-version)
1057   :config (save-place-mode))
1058
1059 (use-package simple
1060   :config (column-number-mode))
1061
1062 (progn ;    `text-mode'
1063   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
1064
1065 (use-package tramp
1066   :defer t
1067   :config
1068   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
1069   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
1070   (add-to-list 'tramp-default-proxies-alist
1071                (list (regexp-quote (system-name)) nil nil)))
1072
1073 (use-package undo-tree
1074   :bind (("C-?" . undo-tree-undo)
1075          ("M-_" . undo-tree-redo))
1076   :config
1077   (global-undo-tree-mode)
1078   (setq undo-tree-mode-lighter ""
1079         undo-tree-auto-save-history t))
1080 #+end_src
1081
1082 * Editing
1083
1084 ** Company
1085
1086 #+begin_src emacs-lisp
1087 (use-package company
1088   :defer 2
1089   :bind
1090   (:map company-active-map
1091         ([tab]    . company-complete-common-or-cycle)
1092         ([escape] . company-abort))
1093   :custom
1094   (company-idle-delay 0.3)
1095   (company-minimum-prefix-length 1)
1096   (company-selection-wrap-around t)
1097   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
1098   (company-dabbrev-downcase nil)
1099   (company-dabbrev-ignore-case nil)
1100   :config
1101   (global-company-mode t))
1102 #+end_src
1103
1104 * Syntax and spell checking
1105 #+begin_src emacs-lisp
1106 (use-package flycheck
1107   :defer 3
1108   :hook (prog-mode . flycheck-mode)
1109   :bind
1110   (:map flycheck-mode-map
1111         ("M-P" . flycheck-previous-error)
1112         ("M-N" . flycheck-next-error))
1113   :config
1114   ;; Use the load-path from running Emacs when checking elisp files
1115   (setq flycheck-emacs-lisp-load-path 'inherit)
1116
1117   ;; Only flycheck when I actually save the buffer
1118   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
1119
1120 ;; http://endlessparentheses.com/ispell-and-apostrophes.html
1121 (use-package ispell
1122   :defer 3
1123   :config
1124   ;; ’ can be part of a word
1125   (setq ispell-local-dictionary-alist
1126         `((nil "[[:alpha:]]" "[^[:alpha:]]"
1127                "['\x2019]" nil ("-B") nil utf-8)))
1128   ;; don't send ’ to the subprocess
1129   (defun endless/replace-apostrophe (args)
1130     (cons (replace-regexp-in-string
1131            "’" "'" (car args))
1132           (cdr args)))
1133   (advice-add #'ispell-send-string :filter-args
1134               #'endless/replace-apostrophe)
1135
1136   ;; convert ' back to ’ from the subprocess
1137   (defun endless/replace-quote (args)
1138     (if (not (derived-mode-p 'org-mode))
1139         args
1140       (cons (replace-regexp-in-string
1141              "'" "’" (car args))
1142             (cdr args))))
1143   (advice-add #'ispell-parse-output :filter-args
1144               #'endless/replace-quote))
1145 #+end_src
1146 * Programming modes
1147
1148 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
1149
1150 #+begin_src emacs-lisp
1151 (use-package alloy-mode
1152   :defer t
1153   :config (setq alloy-basic-offset 2))
1154 #+end_src
1155
1156 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
1157
1158 #+begin_src emacs-lisp
1159 (use-package proof-site  ; Proof General
1160   :defer t
1161   :load-path "lib/proof-site/generic/")
1162 #+end_src
1163
1164 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
1165
1166 #+begin_src emacs-lisp
1167 (eval-when-compile (defvar lean-mode-map))
1168 (use-package lean-mode
1169   :defer 1
1170   :bind (:map lean-mode-map
1171               ("S-SPC" . company-complete))
1172   :config
1173   (require 'lean-input)
1174   (setq default-input-method "Lean"
1175         lean-input-tweak-all '(lean-input-compose
1176                                (lean-input-prepend "/")
1177                                (lean-input-nonempty))
1178         lean-input-user-translations '(("/" "/")))
1179   (lean-input-setup))
1180   #+end_src
1181
1182 ** Haskell
1183
1184 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1185
1186 #+begin_src emacs-lisp
1187 (use-package haskell-mode
1188   :defer t
1189   :config
1190   (setq haskell-indentation-layout-offset 4
1191         haskell-indentation-left-offset 4
1192         flycheck-checker 'haskell-hlint
1193         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1194 #+end_src
1195
1196 *** [[https://github.com/jyp/dante][dante]]
1197
1198 #+begin_src emacs-lisp
1199 (use-package dante
1200   :after haskell-mode
1201   :commands dante-mode
1202   :hook (haskell-mode . dante-mode))
1203 #+end_src
1204
1205 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1206
1207 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1208 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1209
1210 #+begin_src emacs-lisp
1211 (use-package hlint-refactor
1212   :after haskell-mode
1213   :bind (:map hlint-refactor-mode-map
1214               ("C-c l b" . hlint-refactor-refactor-buffer)
1215               ("C-c l r" . hlint-refactor-refactor-at-point))
1216   :hook (haskell-mode . hlint-refactor-mode))
1217 #+end_src
1218
1219 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1220
1221 #+begin_src emacs-lisp
1222 (use-package flycheck-haskell
1223   :after haskell-mode)
1224 #+end_src
1225
1226 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1227 :PROPERTIES:
1228 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1229 :END:
1230
1231 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1232 instead.
1233
1234 #+begin_src emacs-lisp :tangle no
1235 ;;; hs-lint.el --- minor mode for HLint code checking
1236
1237 ;; Copyright 2009 (C) Alex Ott
1238 ;;
1239 ;; Author: Alex Ott <alexott@gmail.com>
1240 ;; Keywords: haskell, lint, HLint
1241 ;; Requirements:
1242 ;; Status: distributed under terms of GPL2 or above
1243
1244 ;; Typical message from HLint looks like:
1245 ;;
1246 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1247 ;; Found:
1248 ;;   count1 p l = length (filter p l)
1249 ;; Why not:
1250 ;;   count1 p = length . filter p
1251
1252
1253 (require 'compile)
1254
1255 (defgroup hs-lint nil
1256   "Run HLint as inferior of Emacs, parse error messages."
1257   :group 'tools
1258   :group 'haskell)
1259
1260 (defcustom hs-lint-command "hlint"
1261   "The default hs-lint command for \\[hlint]."
1262   :type 'string
1263   :group 'hs-lint)
1264
1265 (defcustom hs-lint-save-files t
1266   "Save modified files when run HLint or no (ask user)"
1267   :type 'boolean
1268   :group 'hs-lint)
1269
1270 (defcustom hs-lint-replace-with-suggestions nil
1271   "Replace user's code with suggested replacements"
1272   :type 'boolean
1273   :group 'hs-lint)
1274
1275 (defcustom hs-lint-replace-without-ask nil
1276   "Replace user's code with suggested replacements automatically"
1277   :type 'boolean
1278   :group 'hs-lint)
1279
1280 (defun hs-lint-process-setup ()
1281   "Setup compilation variables and buffer for `hlint'."
1282   (run-hooks 'hs-lint-setup-hook))
1283
1284 ;; regex for replace suggestions
1285 ;;
1286 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1287 ;; Found:
1288 ;; \s +\(.*\)
1289 ;; Why not:
1290 ;; \s +\(.*\)
1291
1292 (defvar hs-lint-regex
1293   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1294   "Regex for HLint messages")
1295
1296 (defun make-short-string (str maxlen)
1297   (if (< (length str) maxlen)
1298       str
1299     (concat (substring str 0 (- maxlen 3)) "...")))
1300
1301 (defun hs-lint-replace-suggestions ()
1302   "Perform actual replacement of suggestions"
1303   (goto-char (point-min))
1304   (while (re-search-forward hs-lint-regex nil t)
1305     (let* ((fname (match-string 1))
1306           (fline (string-to-number (match-string 2)))
1307           (old-code (match-string 4))
1308           (new-code (match-string 5))
1309           (msg (concat "Replace '" (make-short-string old-code 30)
1310                        "' with '" (make-short-string new-code 30) "'"))
1311           (bline 0)
1312           (eline 0)
1313           (spos 0)
1314           (new-old-code ""))
1315       (save-excursion
1316         (switch-to-buffer (get-file-buffer fname))
1317         (goto-char (point-min))
1318         (forward-line (1- fline))
1319         (beginning-of-line)
1320         (setf bline (point))
1321         (when (or hs-lint-replace-without-ask
1322                   (yes-or-no-p msg))
1323           (end-of-line)
1324           (setf eline (point))
1325           (beginning-of-line)
1326           (setf old-code (regexp-quote old-code))
1327           (while (string-match "\\\\ " old-code spos)
1328             (setf new-old-code (concat new-old-code
1329                                  (substring old-code spos (match-beginning 0))
1330                                  "\\ *"))
1331             (setf spos (match-end 0)))
1332           (setf new-old-code (concat new-old-code (substring old-code spos)))
1333           (remove-text-properties bline eline '(composition nil))
1334           (when (re-search-forward new-old-code eline t)
1335             (replace-match new-code nil t)))))))
1336
1337 (defun hs-lint-finish-hook (buf msg)
1338   "Function, that is executed at the end of HLint execution"
1339   (if hs-lint-replace-with-suggestions
1340       (hs-lint-replace-suggestions)
1341       (next-error 1 t)))
1342
1343 (define-compilation-mode hs-lint-mode "HLint"
1344   "Mode for check Haskell source code."
1345   (set (make-local-variable 'compilation-process-setup-function)
1346        'hs-lint-process-setup)
1347   (set (make-local-variable 'compilation-disable-input) t)
1348   (set (make-local-variable 'compilation-scroll-output) nil)
1349   (set (make-local-variable 'compilation-finish-functions)
1350        (list 'hs-lint-finish-hook))
1351   )
1352
1353 (defun hs-lint ()
1354   "Run HLint for current buffer with haskell source"
1355   (interactive)
1356   (save-some-buffers hs-lint-save-files)
1357   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1358                      'hs-lint-mode))
1359
1360 (provide 'hs-lint)
1361 ;;; hs-lint.el ends here
1362 #+end_src
1363
1364 #+begin_src emacs-lisp :tangle no
1365 (use-package hs-lint
1366   :load-path "lisp/"
1367   :bind (:map haskell-mode-map
1368               ("C-c l l" . hs-lint)))
1369 #+end_src
1370
1371 ** Web dev
1372
1373 *** SGML and HTML
1374
1375 #+begin_src emacs-lisp
1376 (use-package sgml-mode
1377   :defer t
1378   :config
1379   (setq sgml-basic-offset 2))
1380 #+end_src
1381
1382 *** CSS and SCSS
1383
1384 #+begin_src emacs-lisp
1385 (use-package css-mode
1386   :defer t
1387   :config
1388   (setq css-indent-offset 2))
1389 #+end_src
1390
1391 *** Web mode
1392
1393 #+begin_src emacs-lisp
1394 (use-package web-mode
1395   :defer t
1396   :mode "\\.html\\'"
1397   :config
1398   (setq-every! 2
1399     web-mode-code-indent-offset
1400     web-mode-css-indent-offset
1401     web-mode-markup-indent-offset))
1402 #+end_src
1403
1404 *** Emmet mode
1405
1406 #+begin_src emacs-lisp
1407 (use-package emmet-mode
1408   :after (:any web-mode css-mode sgml-mode)
1409   :bind* (("C-)" . emmet-next-edit-point)
1410           ("C-(" . emmet-prev-edit-point))
1411   :config
1412   (unbind-key "C-j" emmet-mode-keymap)
1413   (setq emmet-move-cursor-between-quotes t)
1414   :hook (web-mode css-mode html-mode sgml-mode))
1415 #+end_src
1416
1417 ** Nix
1418
1419 #+begin_src emacs-lisp
1420 (use-package nix-mode
1421   :defer t
1422   :mode "\\.nix\\'")
1423 #+end_src
1424
1425 ** Java
1426
1427 *** meghanada
1428
1429 #+begin_src emacs-lisp :tangle no
1430 (use-package meghanada
1431   :bind
1432   (:map meghanada-mode-map
1433         (("C-M-o" . meghanada-optimize-import)
1434          ("C-M-t" . meghanada-import-all)))
1435   :hook (java-mode . meghanada-mode))
1436 #+end_src
1437
1438 *** lsp-java
1439
1440 #+begin_comment
1441 dependencies:
1442
1443 ace-window
1444 avy
1445 bui
1446 company-lsp
1447 dap-mode
1448 lsp-java
1449 lsp-mode
1450 lsp-ui
1451 pfuture
1452 tree-mode
1453 treemacs
1454 #+end_comment
1455
1456 #+begin_src emacs-lisp :tangle no
1457 (use-package treemacs
1458   :config (setq treemacs-never-persist t))
1459
1460 (use-package yasnippet
1461   :config
1462   ;; (yas-global-mode)
1463   )
1464
1465 (use-package lsp-mode
1466   :init (setq lsp-eldoc-render-all nil
1467               lsp-highlight-symbol-at-point nil)
1468   )
1469
1470 (use-package hydra)
1471
1472 (use-package company-lsp
1473   :after  company
1474   :config
1475   (setq company-lsp-cache-candidates t
1476         company-lsp-async t))
1477
1478 (use-package lsp-ui
1479   :config
1480   (setq lsp-ui-sideline-update-mode 'point))
1481
1482 (use-package lsp-java
1483   :config
1484   (add-hook 'java-mode-hook
1485             (lambda ()
1486               (setq-local company-backends (list 'company-lsp))))
1487
1488   (add-hook 'java-mode-hook 'lsp-java-enable)
1489   (add-hook 'java-mode-hook 'flycheck-mode)
1490   (add-hook 'java-mode-hook 'company-mode)
1491   (add-hook 'java-mode-hook 'lsp-ui-mode))
1492
1493 (use-package dap-mode
1494   :after lsp-mode
1495   :config
1496   (dap-mode t)
1497   (dap-ui-mode t))
1498
1499 (use-package dap-java
1500   :after (lsp-java))
1501
1502 (use-package lsp-java-treemacs
1503   :after (treemacs))
1504 #+end_src
1505
1506 * Emacs Enhancements
1507
1508 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1509
1510 #+begin_quote
1511 Emacs package that displays available keybindings in popup
1512 #+end_quote
1513
1514 #+begin_src emacs-lisp
1515 (use-package which-key
1516   :defer 1
1517   :config (which-key-mode))
1518 #+end_src
1519
1520 ** [[https://github.com/Malabarba/smart-mode-line][smart-mode-line]]
1521
1522 #+begin_src emacs-lisp
1523 (use-package smart-mode-line
1524   :config
1525   (sml/setup)
1526   ;; (sml/apply-theme 'light)
1527   (remove-hook 'display-time-hook 'sml/propertize-time-string))
1528 #+end_src
1529
1530 ** [[https://github.com/bbatsov/crux][crux]]
1531
1532 #+begin_src emacs-lisp
1533 (use-package crux
1534   :defer 1
1535   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1536          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1537          ("C-c b K" . crux-kill-other-buffers)
1538          ("C-c f C" . crux-copy-file-preserve-attributes)
1539          ("C-c f D" . crux-delete-file-and-buffer)
1540          ("C-c f R" . crux-rename-file-and-buffer)
1541          ("C-S-j"   . crux-top-join-line)
1542          ("C-c j"   . crux-top-join-line)))
1543 #+end_src
1544
1545 ** [[https://github.com/alezost/mwim.el][mwim]]
1546
1547 #+begin_src emacs-lisp
1548 (use-package mwim
1549   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1550          ("C-e"    . mwim-end-of-code-or-line)
1551          ("<home>" . mwim-beginning-of-line-or-code)
1552          ("<end>"  . mwim-end-of-line-or-code)))
1553 #+end_src
1554
1555 ** projectile
1556
1557 #+begin_src emacs-lisp
1558 (use-package projectile
1559   :defer 2
1560   :bind-keymap ("C-c p" . projectile-command-map)
1561   :config
1562   (projectile-mode)
1563
1564   (defun my-projectile-invalidate-cache (&rest _args)
1565     ;; ignore the args to `magit-checkout'
1566     (projectile-invalidate-cache nil))
1567
1568   (eval-after-load 'magit-branch
1569     '(progn
1570        (advice-add 'magit-checkout
1571                    :after #'my-projectile-invalidate-cache)
1572        (advice-add 'magit-branch-and-checkout
1573                    :after #'my-projectile-invalidate-cache))))
1574 #+end_src
1575
1576 ** [[https://github.com/Wilfred/helpful][helpful]]
1577
1578 #+begin_src emacs-lisp
1579 (use-package helpful
1580   :defer 1
1581   :bind
1582   (;; ("C-h F"   . helpful-function)
1583    ("C-h f"   . helpful-callable)
1584    ("C-h v"   . helpful-variable)
1585    ("C-h k"   . helpful-key)
1586    ("C-c C-d" . helpful-at-point)
1587    ("C-h C"   . helpful-command)
1588    ("C-h c"   . describe-char)
1589    ("C-h F"   . describe-face)))
1590
1591 (use-package help
1592   :bind
1593   (("C-S-h f" . describe-function)
1594    ("C-S-h v" . describe-variable)
1595    ("C-S-h k" . describe-key)
1596    ("C-S-h C" . describe-coding-system)
1597    ("C-S-h c" . describe-key-briefly))
1598   :config (setq help-window-select t))
1599 #+end_src
1600
1601 ** [[https://github.com/kyagi/shell-pop-el][shell-pop]]
1602
1603 #+begin_src emacs-lisp
1604 (use-package shell-pop
1605   :defer 1
1606   :init
1607   (setq shell-pop-universal-key "C-c e"
1608         shell-pop-shell-type '("eshell" "*eshell*" (lambda nil (eshell)))))
1609 #+end_src
1610
1611 ** [[https://github.com/EricCrosson/unkillable-scratch][unkillable-scratch]]
1612
1613 Make =*scratch*= and =*Messages*= unkillable.
1614
1615 #+begin_src emacs-lisp
1616 (use-package unkillable-scratch
1617   :defer 3
1618   :config
1619   (unkillable-scratch 1)
1620   :custom
1621   (unkillable-buffers '("^\\*scratch\\*$" "^\\*Messages\\*$")))
1622 #+end_src
1623
1624 ** [[https://github.com/davep/boxquote.el][boxquote.el]]
1625
1626 #+begin_example
1627 ,----
1628 | make pretty boxed quotes like this
1629 `----
1630 #+end_example
1631
1632 #+begin_src emacs-lisp
1633 (use-package boxquote
1634   :defer 3
1635   :bind
1636   (:prefix-map amin--boxquote-prefix-map
1637    :prefix "C-c q"
1638    ("b"   . boxquote-buffer)
1639    ("B"   . boxquote-insert-buffer)
1640    ("d"   . boxquote-defun)
1641    ("F"   . boxquote-insert-file)
1642    ("hf"  . boxquote-describe-function)
1643    ("hk"  . boxquote-describe-key)
1644    ("hv"  . boxquote-describe-variable)
1645    ("hw"  . boxquote-where-is)
1646    ("k"   . boxquote-kill)
1647    ("p"   . boxquote-paragraph)
1648    ("q"   . boxquote-boxquote)
1649    ("r"   . boxquote-region)
1650    ("s"   . boxquote-shell-command)
1651    ("t"   . boxquote-text)
1652    ("T"   . boxquote-title)
1653    ("u"   . boxquote-unbox)
1654    ("U"   . boxquote-unbox-region)
1655    ("y"   . boxquote-yank)
1656    ("M-q" . boxquote-fill-paragraph)
1657    ("M-w" . boxquote-kill-ring-save)))
1658 #+end_src
1659
1660 Also see [[https://www.emacswiki.org/emacs/rebox2][rebox2]].
1661
1662 ** [[https://github.com/DarthFennec/highlight-indent-guides][highlight-indent-guides]]
1663
1664 #+begin_src emacs-lisp
1665 (use-package highlight-indent-guides
1666   :defer 3
1667   :hook ((prog-mode . highlight-indent-guides-mode)
1668          ;; (org-mode  . highlight-indent-guides-mode)
1669          )
1670   :config
1671   (setq highlight-indent-guides-character ?\|)
1672   (setq highlight-indent-guides-auto-enabled nil)
1673   (setq highlight-indent-guides-method 'character)
1674   (setq highlight-indent-guides-responsive 'top)
1675   (set-face-foreground 'highlight-indent-guides-character-face "gainsboro")
1676   (set-face-foreground 'highlight-indent-guides-top-character-face "grey40")) ; grey13 is nice too
1677 #+end_src
1678
1679 ** pdf-tools
1680
1681 #+begin_src emacs-lisp
1682 (use-package pdf-tools
1683   :defer t
1684   :magic ("%PDF" . pdf-view-mode)
1685   :config
1686   (setq pdf-view-resize-factor 1.05)
1687   (pdf-tools-install)
1688   :bind
1689   (:map pdf-view-mode-map
1690         ("C-s" . isearch-forward)
1691         ("C-r" . isearch-backward)
1692         ("j"   . pdf-view-next-line-or-next-page)
1693         ("k"   . pdf-view-previous-line-or-previous-page)
1694         ("h"   . image-backward-hscroll)
1695         ("l"   . image-forward-hscroll)))
1696 #+end_src
1697
1698 ** anzu
1699
1700 #+begin_src emacs-lisp
1701 (use-package anzu)
1702 #+end_src
1703
1704 ** typo.el
1705
1706 #+begin_src emacs-lisp
1707 (use-package typo
1708   :defer 2
1709   :config
1710   (typo-global-mode 1)
1711   :hook (text-mode . typo-mode))
1712 #+end_src
1713
1714 ** slack
1715
1716 Hopefully temporary.
1717
1718 #+begin_src emacs-lisp
1719 (use-package slack
1720   :commands (slack-start)
1721   :init
1722   (eval-when-compile                    ; silence the byte-compiler
1723     (defvar url-http-data nil)
1724     (defvar url-http-extra-headers nil)
1725     (defvar url-http-method nil)
1726     (defvar url-callback-function nil)
1727     (defvar url-callback-arguments nil)
1728     (defvar oauth--token-data nil))
1729   (setq slack-buffer-emojify t
1730         slack-prefer-current-team t)
1731   :config
1732   (slack-register-team
1733    :name "uw-apv"
1734    :default t
1735    :client-id uw-apv-client-id
1736    :client-secret uw-apv-client-secret
1737    :token uw-apv-token
1738    :subscribed-channels '(general)
1739    :full-and-display-names t)
1740   (slack-register-team
1741    :name "watform"
1742    :default nil
1743    :client-id watform-client-id
1744    :client-secret watform-client-secret
1745    :token watform-token
1746    :subscribed-channels '(general)
1747    :full-and-display-names t)
1748   (add-to-list 'swiper-font-lock-exclude 'slack-message-buffer-mode t)
1749   :bind
1750   (("C-c s s" . slack-start)
1751    ("C-c s u" . slack-select-unread-rooms)
1752    ("C-c s b" . slack-select-rooms)
1753    ("C-c s t" . slack-change-current-team)
1754    ("C-c s c" . slack-ws-close)
1755    :map slack-mode-map
1756    ("M-p"     . slack-buffer-goto-prev-message)
1757    ("M-n"     . slack-buffer-goto-next-message)
1758    ("C-c e"   . slack-message-edit)
1759    ("C-c k"   . slack-message-delete)
1760    ("C-c C-k" . slack-channel-leave)
1761    ("C-c r a" . slack-message-add-reaction)
1762    ("C-c r r" . slack-message-remove-reaction)
1763    ("C-c r s" . slack-message-show-reaction-users)
1764    ("C-c p l" . slack-room-pins-list)
1765    ("C-c p a" . slack-message-pins-add)
1766    ("C-c p r" . slack-message-pins-remove)
1767    ("@"       . slack-message-embed-mention)
1768    ("#"       . slack-message-embed-channel)))
1769
1770 (use-package alert
1771   :commands (alert)
1772   :init
1773   (setq alert-default-style 'notifier))
1774 #+end_src
1775
1776 * Email
1777
1778 #+begin_src emacs-lisp
1779 (defvar amin-maildir (expand-file-name "~/mail/"))
1780 (after! recentf
1781   (add-to-list 'recentf-exclude amin-maildir))
1782 #+end_src
1783
1784 ** Gnus
1785
1786 #+begin_src emacs-lisp
1787 (setq
1788  amin-gnus-init-file (no-littering-expand-etc-file-name "gnus")
1789  mail-user-agent     'gnus-user-agent
1790  read-mail-command   'gnus)
1791
1792 (use-package gnus
1793   :bind (("s-m" . gnus)
1794          ("s-M" . gnus-unplugged))
1795   :init
1796   (setq
1797    gnus-select-method '(nnnil "")
1798    gnus-secondary-select-methods
1799    '((nnimap "amin"
1800             (nnimap-stream plain)
1801             (nnimap-address "127.0.0.1")
1802             (nnimap-server-port 143)
1803             (nnimap-authenticator plain)
1804             (nnimap-user "amin@aminb.org"))
1805      (nnimap "uwaterloo"
1806              (nnimap-stream plain)
1807              (nnimap-address "127.0.0.1")
1808              (nnimap-server-port 143)
1809              (nnimap-authenticator plain)
1810              (nnimap-user "abandali@uwaterloo.ca")))
1811    gnus-message-archive-group "nnimap:Sent"
1812    gnus-parameters
1813    '(("gnu.*"
1814       (gcc-self . t)))
1815    gnus-large-newsgroup  50
1816    gnus-home-directory   (no-littering-expand-var-file-name "gnus/")
1817    gnus-directory        (concat gnus-home-directory "news/")
1818    message-directory     (concat gnus-home-directory "mail/")
1819    nndraft-directory     (concat gnus-home-directory "drafts/")
1820    gnus-save-newsrc-file nil
1821    gnus-read-newsrc-file nil
1822    gnus-interactive-exit nil
1823    gnus-gcc-mark-as-read t))
1824
1825 (use-package gnus-art
1826   :config
1827   (setq
1828    gnus-visible-headers
1829    (concat gnus-visible-headers "\\|^List-Id:\\|^X-RT-Originator:\\|^User-Agent:")
1830    gnus-sorted-header-list
1831    '("^From:" "^Subject:" "^Summary:" "^Keywords:"
1832      "^Followup-To:" "^To:" "^Cc:" "X-RT-Originator"
1833      "^Newsgroups:" "List-Id:" "^Organization:"
1834      "^User-Agent:" "^Date:")
1835   ;; local-lapsed article dates
1836   ;; from https://www.emacswiki.org/emacs/GnusFormatting#toc11
1837   gnus-article-date-headers '(user-defined)
1838   gnus-article-time-format
1839   (lambda (time)
1840     (let* ((date (format-time-string "%a, %d %b %Y %T %z" time))
1841            (local (article-make-date-line date 'local))
1842            (combined-lapsed (article-make-date-line date
1843                                                     'combined-lapsed))
1844            (lapsed (progn
1845                      (string-match " (.+" combined-lapsed)
1846                      (match-string 0 combined-lapsed))))
1847       (concat local lapsed))))
1848   (bind-keys
1849    :map gnus-article-mode-map
1850    ("r"   . gnus-article-reply-with-original)
1851    ("R"   . gnus-article-wide-reply-with-original)
1852    ("M-L" . org-store-link)))
1853
1854 (use-package gnus-sum
1855   :bind (:map gnus-summary-mode-map
1856               :prefix-map amin--gnus-summary-prefix-map
1857               :prefix "v"
1858               ("r" . gnus-summary-reply)
1859               ("w" . gnus-summary-wide-reply)
1860               ("v" . gnus-summary-show-raw-article))
1861   :config
1862   (bind-keys
1863    :map gnus-summary-mode-map
1864    ("r"   . gnus-summary-reply-with-original)
1865    ("R"   . gnus-summary-wide-reply-with-original)
1866    ("M-L" . org-store-link)))
1867
1868 (use-package gnus-msg
1869   :config
1870   (setq gnus-posting-styles
1871         '((".*"
1872            (address "amin@aminb.org"))
1873           ("gnu.*"
1874            (address "bandali@gnu.org"))
1875           ("nnimap\\+uwaterloo:.*"
1876            (address "abandali@uwaterloo.ca")
1877            (gcc "\"nnimap+uwaterloo:Sent Items\"")))))
1878
1879 (use-package gnus-topic
1880   :hook (gnus-group-mode . gnus-topic-mode))
1881
1882 (use-package gnus-agent
1883   :config
1884   (setq gnus-agent-synchronize-flags 'ask)
1885   :hook (gnus-group-mode . gnus-agent-mode))
1886
1887 (use-package gnus-group
1888   :config
1889   (setq gnus-permanently-visible-groups "\\((INBOX\\|gnu$\\)"))
1890
1891 (use-package mm-decode
1892   :config
1893   (setq mm-discouraged-alternatives '("text/html" "text/richtext")))
1894 #+end_src
1895
1896 ** sendmail
1897
1898 #+begin_src emacs-lisp
1899 (use-package sendmail
1900   :config
1901   (setq sendmail-program "/usr/bin/msmtp"
1902         ;; message-sendmail-extra-arguments '("-v" "-d")
1903         mail-specify-envelope-from t
1904         mail-envelope-from 'header))
1905 #+end_src
1906
1907 ** message
1908
1909 #+begin_src emacs-lisp
1910 (use-package message
1911   :config
1912   (setq message-kill-buffer-on-exit t
1913         message-send-mail-function 'message-send-mail-with-sendmail
1914         message-sendmail-envelope-from 'header
1915         message-dont-reply-to-names
1916         "\\(\\(.*@aminb\\.org\\)\\|\\(\\(aminb?\\|mab\\|bandali\\)@gnu\\.org\\)\\|\\(\\(m\\|a\\(min\\.\\)?\\)bandali@uwaterloo\\.ca\\)\\)"
1917         message-user-fqdn "aminb.org")
1918   :hook (;; (message-setup . mml-secure-message-sign-pgpmime)
1919          (message-mode . flyspell-mode)
1920          (message-mode . (lambda () (setq fill-column 65
1921                                      message-fill-column 65))))
1922   :custom-face
1923   (message-header-subject ((t (:foreground "#111" :weight semi-bold))))
1924   (message-header-to      ((t (:foreground "#111" :weight normal))))
1925   (message-header-cc      ((t (:foreground "#333" :weight normal)))))
1926
1927 (after! mml-sec
1928   (setq mml-secure-openpgp-encrypt-to-self t
1929         mml-secure-openpgp-sign-with-sender t))
1930 #+end_src
1931
1932 ** footnote
1933
1934 Convenient footnotes in =message-mode=.
1935
1936 #+begin_src emacs-lisp
1937 (use-package footnote
1938   :after message
1939   :bind
1940   (:map message-mode-map
1941         :prefix-map amin--footnote-prefix-map
1942         :prefix "C-c f"
1943         ("a" . footnote-add-footnote)
1944         ("b" . footnote-back-to-message)
1945         ("c" . footnote-cycle-style)
1946         ("d" . footnote-delete-footnote)
1947         ("g" . footnote-goto-footnote)
1948         ("r" . footnote-renumber-footnotes)
1949         ("s" . footnote-set-style))
1950   :config
1951   (setq footnote-start-tag ""
1952         footnote-end-tag   ""
1953         footnote-style     'unicode))
1954 #+end_src
1955
1956 ** supercite
1957
1958 #+begin_src emacs-lisp :tangle no
1959 (use-package supercite
1960   :commands sc-cite-original
1961   :init
1962   (add-hook 'mail-citation-hook 'sc-cite-original)
1963
1964   (defun sc-remove-existing-signature ()
1965     (save-excursion
1966       (goto-char (region-beginning))
1967       (when (re-search-forward message-signature-separator (region-end) t)
1968         (delete-region (match-beginning 0) (region-end)))))
1969
1970   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1971
1972   (defun sc-remove-if-not-mailing-list ()
1973     (unless (assoc "list-id" sc-mail-info)
1974       (setq attribution sc-default-attribution
1975             citation (concat sc-citation-delimiter
1976                              sc-citation-separator))))
1977
1978   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1979
1980   :config
1981   (defun sc-fill-if-different (&optional prefix)
1982     "Fill the region bounded by `sc-fill-begin' and point.
1983 Only fill if optional PREFIX is different than
1984 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1985 fill region.  If PREFIX is not supplied, initialize fill
1986 variables.  This is useful for a regi `begin' frame-entry."
1987     (if (not prefix)
1988         (setq sc-fill-line-prefix ""
1989               sc-fill-begin (line-beginning-position))
1990       (if (and sc-auto-fill-region-p
1991                (not (string= prefix sc-fill-line-prefix)))
1992           (let ((fill-prefix sc-fill-line-prefix))
1993             (unless (or (string= fill-prefix "")
1994                         (save-excursion
1995                           (goto-char sc-fill-begin)
1996                           (or (looking-at ">+  +")
1997                               (< (length
1998                                   (buffer-substring (point)
1999                                                     (line-end-position)))
2000                                  65))))
2001               (fill-region sc-fill-begin (line-beginning-position)))
2002             (setq sc-fill-line-prefix prefix
2003                   sc-fill-begin (line-beginning-position)))))
2004 nil))
2005 #+end_src
2006
2007 ** COMMENT gnus-alias                                              :ARCHIVE:
2008
2009 #+begin_src emacs-lisp
2010 (use-package gnus-alias
2011   :commands (gnus-alias-determine-identity
2012              gnus-alias-select-identity)
2013   :bind (:map  message-mode-map
2014                ("s-i" . gnus-alias-select-identity))
2015   :config
2016   (setq
2017    gnus-alias-default-identity "amin"
2018    gnus-alias-identity-alist
2019    '(("amin"
2020       nil   ;; Does not refer to any other identity
2021       "Amin Bandali <amin@aminb.org>"
2022       nil   ;; Organization
2023       nil   ;; extra headers
2024       nil   ;; extra body text
2025       nil)  ;; signature file
2026      ("gnu"
2027       nil
2028       "Amin Bandali <bandali@gnu.org>"
2029       nil
2030       nil
2031       nil
2032       nil)
2033      ("uw"
2034       nil
2035       "Amin Bandali <abandali@uwaterloo.ca>"
2036       nil
2037       (("Gcc" . "\"nnimap+uwaterloo:Sent Items\""))
2038       nil
2039       nil))
2040    gnus-alias-identity-rules
2041    '(("amin" ("Delivered-To" "<amin\\@aminb\\.org" both) "amin")
2042      ("gnu" ("Delivered-To" "<gnu\\@aminb\\.org" both) "gnu")
2043      ("uw" ("any" "<\\(.+\\)\\@uwaterloo\\.ca" both) "uw"))
2044    gnus-alias-override-user-mail-address t)
2045   :hook (message-setup . gnus-alias-determine-identity))
2046 #+end_src
2047
2048 ** COMMENT [[https://notmuchmail.org][notmuch]]                                                 :ARCHIVE:
2049
2050 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
2051
2052 #+begin_src emacs-lisp
2053 (defun amin/notmuch ()
2054   "Delete other windows, then launch `notmuch'."
2055   (interactive
2056    (when (equal current-prefix-arg nil)
2057      (delete-other-windows)))
2058   (notmuch))
2059
2060 (use-package notmuch
2061   :commands notmuch
2062   :bind ("C-c n" . amin/notmuch)
2063   :custom (notmuch-always-prompt-for-sender t)
2064   :config
2065   (setq notmuch-hello-sections
2066         '(notmuch-hello-insert-header
2067           notmuch-hello-insert-saved-searches
2068           ;; notmuch-hello-insert-search
2069           notmuch-hello-insert-alltags)
2070         notmuch-search-oldest-first nil
2071         notmuch-show-all-tags-list t
2072         notmuch-message-headers  ; see bug follow-up above
2073         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
2074         notmuch-hello-thousands-separator ","
2075         notmuch-fcc-dirs
2076         '(("amin@aminb.org"        . "amin/Sent")
2077           ("bandali@gnu.org"       . "gnu/Sent")
2078           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
2079           ("mab@gnu.org"           . "gnu/Sent")
2080           ("amin@gnu.org"          . "gnu/Sent")
2081           ("aminb@gnu.org"         . "gnu/Sent")
2082           (".*"                    . "sent"))
2083         notmuch-search-result-format
2084         '(("date"    . "%12s ")
2085           ("count"   . "%-7s ")
2086           ("authors" . "%-40s ")
2087           ("subject" . "%s ")
2088           ("tags"    . "(%s)"))
2089         notmuch-saved-searches
2090         '((:name "inbox"     :query "tag:inbox"     :key "i")
2091           (:name "unread"    :query "tag:unread"    :key "u")
2092           (:name "latest"    :query "tag:latest"    :key "l")
2093           (:name "encrypted" :query "tag:encrypted" :key "e")
2094           (:name "flagged"   :query "tag:flagged"   :key "f")
2095           (:name "sent"      :query "tag:sent"      :key "s")
2096           (:name "drafts"    :query "tag:draft"     :key "d")
2097           (:name "all mail"  :query "*"             :key "a")))
2098   ;; (add-hook 'visual-fill-column-mode-hook
2099   ;;           (lambda ()
2100   ;;             (when (string= major-mode 'notmuch-message-mode)
2101   ;;               (setq visual-fill-column-width 70))))
2102   ;; (set! :evil-state 'notmuch-message-mode 'insert)
2103   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
2104   ;;             :override #'kill-this-buffer)
2105   :hook (notmuch-message-mode . doom-modeline-set-special-modeline)
2106   :bind
2107   (:map notmuch-hello-mode-map
2108         ("u" . (lambda ()
2109                  "Search for `unread'-tagged messages"
2110                  (interactive)
2111                  (notmuch-hello-search "tag:unread")))
2112         ("i" . (lambda ()
2113                  "Search for `inbox'-tagged messages"
2114                  (interactive)
2115                  (notmuch-hello-search "tag:inbox")))
2116         ("l" . (lambda ()
2117                  "Search for `latest'-tagged messages"
2118                  (interactive)
2119                  (notmuch-hello-search "tag:latest")))
2120         ("e" . (lambda ()
2121                  "Search for `encrypted'-tagged messages"
2122                  (interactive)
2123                  (notmuch-hello-search "tag:encrypted"))))
2124   (:map notmuch-search-mode-map
2125         ("k" . (lambda ()
2126                  "Mark message read"
2127                  (interactive)
2128                  (notmuch-search-tag '("-unread"))
2129                  ;; (notmuch-search-archive-thread)
2130                  (notmuch-search-next-thread)))
2131         ("u" . (lambda ()
2132                  "Mark message unread"
2133                  (interactive)
2134                  (notmuch-search-tag '("+unread"))
2135                  (notmuch-search-next-thread)))
2136         ("K" . (lambda ()
2137                  "Mark message deleted"
2138                  (interactive)
2139                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
2140                  (notmuch-search-next-thread)))
2141         ("S" . (lambda ()
2142                  "Mark message as spam"
2143                  (interactive)
2144                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
2145                  (notmuch-search-next-thread))))
2146   (:map notmuch-tree-mode-map
2147         ("k" . (lambda ()
2148                  "Mark message read"
2149                  (interactive)
2150                  (notmuch-tree-tag '("-unread"))
2151                  ;; (notmuch-tree-archive-thread)
2152                  (notmuch-tree-next-message)))
2153         ("u" . (lambda ()
2154                  "Mark message unread"
2155                  (interactive)
2156                  (notmuch-tree-tag '("+unread"))
2157                  (notmuch-tree-next-message)))
2158         ("K" . (lambda ()
2159                  "Mark message deleted"
2160                  (interactive)
2161                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
2162                  (notmuch-tree-next-message)))
2163         ("S" . (lambda ()
2164                  "Mark message as spam"
2165                  (interactive)
2166                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
2167                  (notmuch-tree-next-message))))
2168   :custom-face
2169   (notmuch-search-unread-face ((t (:weight semi-bold))))
2170   (notmuch-tag-face ((t (:foreground "navy blue" :weight semi-bold)))))
2171
2172 (use-package counsel-notmuch
2173   :bind ("C-c s m" . counsel-notmuch))
2174
2175 (after! notmuch-crypto
2176   (setq notmuch-crypto-process-mime t))
2177
2178 (use-package org-notmuch
2179   :after (:any org notmuch))
2180 #+end_src
2181
2182 * Blogging
2183 ** [[https://ox-hugo.scripter.co][ox-hugo]]
2184
2185 #+begin_src emacs-lisp
2186 (use-package ox-hugo
2187   :after ox)
2188
2189 (use-package ox-hugo-auto-export
2190   :load-path "lib/ox-hugo")
2191 #+end_src
2192
2193 * Post initialization
2194 :PROPERTIES:
2195 :CUSTOM_ID: post-initialization
2196 :END:
2197
2198 Display how long it took to load the init file.
2199
2200 #+begin_src emacs-lisp
2201 (message "Loading %s...done (%.3fs)" user-init-file
2202          (float-time (time-subtract (current-time)
2203                                     amin--before-user-init-time)))
2204 #+end_src
2205
2206 * Footer
2207 :PROPERTIES:
2208 :CUSTOM_ID: footer
2209 :END:
2210
2211 #+begin_src emacs-lisp :comments none
2212 ;;; init.el ends here
2213 #+end_src
2214
2215 * COMMENT Local Variables                                           :ARCHIVE:
2216 # Local Variables:
2217 # eval: (add-hook 'after-save-hook #'amin/async-babel-tangle 'append 'local)
2218 # End: