git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236
 237 (require 'borg-nix-shell)
 238 (setq borg-build-shell-command 'borg-nix-shell-build-command)
 239
 240 (with-eval-after-load 'bind-key
 241   (bind-keys
 242    :package borg
 243    ("C-c B A" . borg-activate)
 244    ("C-c B a" . borg-assimilate)
 245    ("C-c B b" . borg-build)
 246    ("C-c B c" . borg-clone)))
 247 #+end_src
 248
 249 *** =use-package=
 250
 251 #+begin_quote
 252 A use-package declaration for simplifying your .emacs
 253 #+end_quote
 254
 255 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 256 packages (in our case especially the latter) in a neatly organized way
 257 and without compromising on performance.
 258
 259 #+begin_src emacs-lisp
 260 (require 'use-package)
 261 (if nil  ; set to t when need to debug init
 262     (setq use-package-verbose t
 263           use-package-expand-minimally nil
 264           use-package-compute-statistics t
 265           debug-on-error t)
 266   (setq use-package-verbose nil
 267         use-package-expand-minimally t))
 268 #+end_src
 269
 270 *** Epkg
 271
 272 #+begin_quote
 273 Browse the Emacsmirror package database
 274 #+end_quote
 275
 276 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 277 database, low-level functions for querying the database, and a
 278 =package.el=-like user interface for browsing the available packages.
 279
 280 #+begin_src emacs-lisp
 281 (use-package epkg
 282   :defer t
 283   :bind
 284   (("C-c B d" . epkg-describe-package)
 285    ("C-c B p" . epkg-list-packages)
 286    ("C-c B r" . borg-remove)
 287    ("C-c B u" . epkg-update)))
 288 #+end_src
 289
 290 ** No littering in =~/.emacs.d=
 291
 292 #+begin_quote
 293 Help keeping ~/.emacs.d clean
 294 #+end_quote
 295
 296 By default, even for Emacs' built-in packages, the configuration files
 297 and persistent data are all over the place. Use =no-littering= to help
 298 contain the mess.
 299
 300 #+begin_src emacs-lisp
 301 (use-package no-littering
 302   :demand t
 303   :config
 304   (savehist-mode 1)
 305   (add-to-list 'savehist-additional-variables 'kill-ring)
 306   (save-place-mode 1)
 307   (setq auto-save-file-name-transforms
 308         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 309 #+end_src
 310
 311 ** Custom file (=custom.el=)
 312
 313 I'm not planning on using the custom file much, but even so, I
 314 definitely don't want it mixing with =init.el=. So, here; let's give
 315 it it's own file. While at it, treat themes as safe.
 316
 317 #+begin_src emacs-lisp
 318 (use-package custom
 319   :no-require t
 320   :config
 321   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 322   (when (file-exists-p custom-file)
 323     (load custom-file))
 324   (setf custom-safe-themes t))
 325 #+end_src
 326
 327 ** Better =$PATH= handling
 328
 329 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 330 in my shell.
 331
 332 #+begin_src emacs-lisp
 333 (use-package exec-path-from-shell
 334   :defer 1
 335   :init
 336   (setq exec-path-from-shell-check-startup-files nil)
 337   :config
 338   (exec-path-from-shell-initialize)
 339   ;; while we're at it, let's fix access to our running ssh-agent
 340   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 341   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 342 #+end_src
 343
 344 ** Only one custom theme at a time
 345
 346 #+begin_src emacs-lisp
 347 (defadvice load-theme (before clear-previous-themes activate)
 348   "Clear existing theme settings instead of layering them"
 349   (mapc #'disable-theme custom-enabled-themes))
 350 #+end_src
 351
 352 ** Server
 353
 354 Start server if not already running. Alternatively, can be done by
 355 issuing =emacs --daemon= in the terminal, which can be automated with
 356 a systemd service or using =brew services start emacs= on macOS. I use
 357 Emacs as my window manager (via EXWM), so I always start Emacs on
 358 login; so starting the server from inside Emacs is good enough for me.
 359
 360 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 361
 362 #+begin_src emacs-lisp
 363 (use-package server
 364   :config (or (server-running-p) (server-mode)))
 365 #+end_src
 366
 367 ** Unicode support
 368
 369 Font stack with better unicode support, around =Ubuntu Mono= and
 370 =Hack=.
 371
 372 #+begin_src emacs-lisp
 373 (dolist (ft (fontset-list))
 374   (set-fontset-font
 375    ft
 376    'unicode
 377    (font-spec :name "Ubuntu Mono"))
 378   (set-fontset-font
 379    ft
 380    'unicode
 381    (font-spec :name "DejaVu Sans Mono")
 382    nil
 383    'append)
 384   ;; (set-fontset-font
 385   ;;  ft
 386   ;;  'unicode
 387   ;;  (font-spec
 388   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 389   ;;  nil
 390   ;;  'append)
 391   ;; (set-fontset-font
 392   ;;  ft
 393   ;;  #x2115  ; ℕ
 394   ;;  (font-spec :name "DejaVu Sans Mono")
 395   ;;  nil
 396   ;;  'append)
 397   (set-fontset-font
 398    ft
 399    (cons ?Α ?ω)
 400    (font-spec :name "DejaVu Sans Mono" :size 14)
 401    nil
 402    'prepend))
 403 #+end_src
 404
 405 ** Libraries
 406
 407 #+begin_src emacs-lisp
 408 (require 'cl-lib)
 409 (require 'subr-x)
 410 #+end_src
 411
 412 ** Useful utilities
 413
 414 #+begin_src emacs-lisp
 415 (defun amin-enlist (exp)
 416   "Return EXP wrapped in a list, or as-is if already a list."
 417 (if (listp exp) exp (list exp)))
 418
 419 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 420 (defmacro after! (features &rest body)
 421   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 422 compilation."
 423   (declare (indent defun) (debug t))
 424   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 425                 (dolist (next (amin-enlist features))
 426                   (if (symbolp next)
 427                       (require next nil :no-error)
 428                     (load next :no-message :no-error))))
 429             #'progn
 430           #'with-no-warnings)
 431         (cond ((symbolp features)
 432                `(eval-after-load ',features '(progn ,@body)))
 433               ((and (consp features)
 434                     (memq (car features) '(:or :any)))
 435                `(progn
 436                   ,@(cl-loop for next in (cdr features)
 437                              collect `(after! ,next ,@body))))
 438               ((and (consp features)
 439                     (memq (car features) '(:and :all)))
 440                (dolist (next (cdr features))
 441                  (setq body `(after! ,next ,@body)))
 442                body)
 443               ((listp features)
 444                `(after! (:all ,@features) ,@body)))))
 445 #+end_src
 446
 447 * Core
 448 :PROPERTIES:
 449 :CUSTOM_ID: core
 450 :END:
 451
 452 ** Defaults
 453
 454 *** Time and battery in mode-line
 455
 456 Enable displaying time and battery in the mode-line, since I'm not
 457 using the Xfce panel anymore. Also, I don't need to see the load
 458 average on a regular basis, so disable that.
 459
 460 Note: using =i3status= on sway at the moment, so disabling this.
 461
 462 #+begin_src emacs-lisp :tangle no
 463 (use-package time
 464   :init
 465   (setq display-time-default-load-average nil)
 466   :config
 467   (display-time-mode))
 468
 469 (use-package battery
 470   :config
 471   (display-battery-mode))
 472 #+end_src
 473
 474 *** Smaller fringe
 475
 476 Might want to set the fringe to a smaller value, especially if using
 477 EXWM. I'm fine with the default for now.
 478
 479 #+begin_src emacs-lisp
 480 ;; (fringe-mode '(3 . 1))
 481 (fringe-mode nil)
 482 #+end_src
 483
 484 *** Disable disabled commands
 485
 486 Emacs disables some commands by default that could persumably be
 487 confusing for novice users. Let's disable that.
 488
 489 #+begin_src emacs-lisp
 490 (setq disabled-command-function nil)
 491 #+end_src
 492
 493 *** Kill-ring
 494
 495 Save what I copy into clipboard from other applications into Emacs'
 496 kill-ring, which would allow me to still be able to easily access it
 497 in case I kill (cut or copy) something else inside Emacs before
 498 yanking (pasting) what I'd originally intended to.
 499
 500 #+begin_src emacs-lisp
 501 (setq save-interprogram-paste-before-kill t)
 502 #+end_src
 503
 504 *** Minibuffer
 505
 506 #+begin_src emacs-lisp
 507 (setq enable-recursive-minibuffers t
 508       resize-mini-windows t)
 509 #+end_src
 510
 511 *** Lazy-person-friendly yes/no prompts
 512
 513 Lazy people would prefer to type fewer keystrokes, especially for yes
 514 or no questions. I'm lazy.
 515
 516 #+begin_src emacs-lisp
 517 (defalias 'yes-or-no-p #'y-or-n-p)
 518 #+end_src
 519
 520 *** Startup screen and =*scratch*=
 521
 522 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 523 startup buffer.
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-buffer-choice t)
 527 #+end_src
 528
 529 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 530 need the default hint.
 531
 532 #+begin_src emacs-lisp
 533 (setq initial-scratch-message nil)
 534 #+end_src
 535
 536 Also, let's use Text mode as the major mode, in case I want to
 537 customize it (=*scratch*='s default major mode, Fundamental mode,
 538 can't really be customized).
 539
 540 #+begin_src emacs-lisp
 541 (setq initial-major-mode 'text-mode)
 542 #+end_src
 543
 544 Inhibit the buffer list when more than 2 files are loaded.
 545
 546 #+begin_src emacs-lisp
 547 (setq inhibit-startup-buffer-menu t)
 548 #+end_src
 549
 550 I don't really need to see the startup screen or echo area message
 551 either.
 552
 553 #+begin_src emacs-lisp
 554 (advice-add #'display-startup-echo-area-message :override #'ignore)
 555 (setq inhibit-startup-screen t
 556       inhibit-startup-echo-area-message user-login-name)
 557 #+end_src
 558
 559 *** More useful frame titles
 560
 561 Show either the file name or the buffer name (in case the buffer isn't
 562 visiting a file). Borrowed from Emacs Prelude.
 563
 564 #+begin_src emacs-lisp
 565 (setq frame-title-format
 566       '("" invocation-name " - "
 567         (:eval (if (buffer-file-name)
 568                    (abbreviate-file-name (buffer-file-name))
 569                  "%b"))))
 570 #+end_src
 571
 572 *** Backups
 573
 574 Emacs' default backup settings aren't that great. Let's use more
 575 sensible options. See documentation for the ~make-backup-file~
 576 variable.
 577
 578 #+begin_src emacs-lisp
 579 (setq backup-by-copying t
 580       version-control t)
 581 #+end_src
 582
 583 *** Auto revert
 584
 585 Enable automatic reloading of changed buffers and files.
 586
 587 #+begin_src emacs-lisp
 588 (global-auto-revert-mode 1)
 589 (setq auto-revert-verbose nil
 590       global-auto-revert-non-file-buffers t)
 591 #+end_src
 592
 593 *** Always use space for indentation
 594
 595 #+begin_src emacs-lisp
 596 (setq-default
 597  indent-tabs-mode nil
 598  require-final-newline t
 599  tab-width 4)
 600 #+end_src
 601
 602 *** Winner mode
 603
 604 Enable =winner-mode=.
 605
 606 #+begin_src emacs-lisp
 607 (winner-mode 1)
 608 #+end_src
 609
 610 ** Bindings
 611
 612 #+begin_src emacs-lisp
 613 (bind-keys
 614  ("C-c b B" . ibuffer-list-buffers)
 615  ("C-c b k" . kill-this-buffer)
 616  ("C-c b s" . save-buffer)
 617  ("C-c S"   . save-buffer)
 618  ("C-c o"   . other-window)
 619  ("C-c q q" . save-buffers-kill-terminal))
 620 #+end_src
 621
 622 ** Packages
 623
 624 The packages in this section are absolutely essential to my everyday
 625 workflow, and they play key roles in how I do my computing. They
 626 immensely enhance the Emacs experience for me; both using Emacs, and
 627 customizing it.
 628
 629 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 630
 631 #+begin_src emacs-lisp
 632 (use-package auto-compile
 633   :demand t
 634   :config
 635   (auto-compile-on-load-mode)
 636   (auto-compile-on-save-mode)
 637   (setq auto-compile-display-buffer               nil
 638         auto-compile-mode-line-counter            t
 639         auto-compile-source-recreate-deletes-dest t
 640         auto-compile-toggle-deletes-nonlib-dest   t
 641         auto-compile-update-autoloads             t)
 642   (add-hook 'auto-compile-inhibit-compile-hook
 643             'auto-compile-inhibit-compile-detached-git-head))
 644 #+end_src
 645
 646 *** [[https://orgmode.org/][Org mode]]
 647
 648 #+begin_quote
 649 Org mode is for keeping notes, maintaining TODO lists, planning
 650 projects, and authoring documents with a fast and effective plain-text
 651 system.
 652 #+end_quote
 653
 654 In short, my favourite way of life.
 655
 656 #+begin_src emacs-lisp
 657 (use-package org
 658   :config
 659   (setq org-src-tab-acts-natively t
 660         org-src-preserve-indentation nil
 661         org-edit-src-content-indentation 0)
 662   :hook (org-mode . org-indent-mode))
 663
 664 (use-package org-notmuch
 665   :after (:any org notmuch))
 666 #+end_src
 667
 668 *** [[https://magit.vc/][Magit]]
 669
 670 #+begin_quote
 671 It's Magit! A Git porcelain inside Emacs.
 672 #+end_quote
 673
 674 Not just how I do git, but /the/ way to do git.
 675
 676 #+begin_src emacs-lisp
 677 (use-package magit
 678   :defer t
 679   :bind
 680   (("s-g"   . magit-dispatch-popup)
 681    ("C-x g" . magit-status)
 682    :prefix-map amin--magit-prefix-map
 683    :prefix "C-c g"
 684    ("SPC" . magit-status)
 685    ("s"   . magit-status)
 686    ("S"   . magit-status-prefix)
 687    ("B"   . magit-blame)
 688    ("C"   . magit-clone)
 689    ("f"   . magit-fetch)
 690    ("F"   . magit-pull)
 691    ("P"   . magit-push)
 692    ("p"   . magit-dispatch-popup)
 693    ("c c" . magit-commit)
 694    ("c a" . magit-commit-amend)
 695    ("b b" . magit-checkout)
 696    ("b c" . magit-branch))
 697   :config
 698   (magit-add-section-hook 'magit-status-sections-hook
 699                           'magit-insert-modules
 700                           'magit-insert-stashes
 701                           'append))
 702 #+end_src
 703
 704 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 705
 706 #+begin_quote
 707 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 708 an overview, and more. Oh, man!
 709 #+end_quote
 710
 711 There's no way I could top that, so I won't attempt to.
 712
 713 **** Ivy
 714
 715 #+begin_src emacs-lisp
 716 (use-package ivy
 717   :defer 1
 718   :bind
 719   (("C-c b b" . ivy-switch-buffer)
 720    :map ivy-minibuffer-map
 721    ([escape] . keyboard-escape-quit)
 722    ([S-up]   . ivy-previous-history-element)
 723    ([S-down] . ivy-next-history-element)
 724    ("DEL"    . ivy-backward-delete-char))
 725   :config
 726   (setq ivy-wrap t)
 727   (ivy-mode 1))
 728 #+end_src
 729
 730 **** Swiper
 731
 732 #+begin_src emacs-lisp
 733 (use-package swiper
 734   :bind (([remap isearch-forward]  . swiper)
 735          ([remap isearch-backward] . swiper)))
 736 #+end_src
 737
 738 **** Counsel
 739
 740 #+begin_src emacs-lisp
 741 (use-package counsel
 742   :defer 1
 743   :bind (([remap execute-extended-command] . counsel-M-x)
 744          ([remap find-file]                . counsel-find-file)
 745          ("s-r"                            . counsel-recentf)
 746          ("C-c x"                          . counsel-M-x)
 747          ("C-c f ."                        . counsel-find-file)
 748          ("C-c f r"                        . counsel-recentf)
 749          :map minibuffer-local-map
 750          ("C-r" . counsel-minibuffer-history))
 751   :config
 752   (counsel-mode 1)
 753   (defalias 'locate #'counsel-locate))
 754 #+end_src
 755
 756 * Borg's =layer/essentials=
 757
 758 TODO: break this giant source block down into individual org sections.
 759
 760 #+begin_src emacs-lisp
 761 (use-package dash
 762   :config (dash-enable-font-lock))
 763
 764 (use-package diff-hl
 765   :config
 766   (setq diff-hl-draw-borders nil)
 767   (global-diff-hl-mode)
 768   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 769
 770 (use-package dired
 771   :defer t
 772   :config (setq dired-listing-switches "-alh"))
 773
 774 (use-package eldoc
 775   :when (version< "25" emacs-version)
 776   :config (global-eldoc-mode))
 777
 778 (use-package help
 779   :defer t
 780   :config (temp-buffer-resize-mode))
 781
 782 (progn ;    `isearch'
 783   (setq isearch-allow-scroll t))
 784
 785 (use-package lisp-mode
 786   :config
 787   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 788   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 789   (defun indent-spaces-mode ()
 790     (setq indent-tabs-mode nil))
 791   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 792
 793 (use-package man
 794   :defer t
 795   :config (setq Man-width 80))
 796
 797 (use-package paren
 798   :config (show-paren-mode))
 799
 800 (use-package prog-mode
 801   :config (global-prettify-symbols-mode)
 802   (defun indicate-buffer-boundaries-left ()
 803     (setq indicate-buffer-boundaries 'left))
 804   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 805
 806 (use-package recentf
 807   :demand t
 808   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 809
 810 (use-package savehist
 811   :config (savehist-mode))
 812
 813 (use-package saveplace
 814   :when (version< "25" emacs-version)
 815   :config (save-place-mode))
 816
 817 (use-package simple
 818   :config (column-number-mode))
 819
 820 (progn ;    `text-mode'
 821   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 822
 823 (use-package tramp
 824   :defer t
 825   :config
 826   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 827   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 828   (add-to-list 'tramp-default-proxies-alist
 829                (list (regexp-quote (system-name)) nil nil)))
 830
 831 (use-package undo-tree
 832   :bind (("C-?" . undo-tree-undo)
 833          ("M-_" . undo-tree-redo))
 834   :config
 835   (global-undo-tree-mode)
 836   (setq undo-tree-mode-lighter ""
 837         undo-tree-auto-save-history t))
 838 #+end_src
 839
 840 * Editing
 841
 842 ** Company
 843
 844 #+begin_src emacs-lisp
 845 (use-package company
 846   :defer 5
 847   :bind
 848   (:map company-active-map
 849         ([tab] . company-complete-common-or-cycle))
 850   :custom
 851   (company-idle-delay 0.3)
 852   (company-minimum-prefix-length 1)
 853   (company-selection-wrap-around t)
 854   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 855   :config
 856   (global-company-mode t))
 857 #+end_src
 858
 859 * Syntax and spell checking
 860 #+begin_src emacs-lisp
 861 (use-package flycheck
 862   :hook (prog-mode . flycheck-mode)
 863   :config
 864   ;; Use the load-path from running Emacs when checking elisp files
 865   (setq flycheck-emacs-lisp-load-path 'inherit)
 866
 867   ;; Only flycheck when I actually save the buffer
 868   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 869 #+end_src
 870 * Programming modes
 871
 872 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 873
 874 #+begin_src emacs-lisp
 875 (use-package alloy-mode
 876   :config (setq alloy-basic-offset 2))
 877 #+end_src
 878
 879 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 880
 881 #+begin_src emacs-lisp
 882 (use-package proof-site  ; Proof General
 883   :load-path "lib/proof-site/generic/")
 884 #+end_src
 885
 886 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 887
 888 #+begin_src emacs-lisp
 889 (eval-when-compile (defvar lean-mode-map))
 890 (use-package lean-mode
 891   :bind (:map lean-mode-map
 892               ("S-SPC" . company-complete)))
 893 #+end_src
 894
 895 ** Haskell
 896
 897 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 898
 899 #+begin_src emacs-lisp
 900 (use-package haskell-mode
 901   :config
 902   (setq haskell-indentation-layout-offset 4
 903         haskell-indentation-left-offset 4
 904         flycheck-checker 'haskell-hlint
 905         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 906 #+end_src
 907
 908 *** [[https://github.com/jyp/dante][dante]]
 909
 910 #+begin_src emacs-lisp
 911 (use-package dante
 912   :after haskell-mode
 913   :commands dante-mode
 914   :hook (haskell-mode . dante-mode))
 915 #+end_src
 916
 917 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 918
 919 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 920 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 921
 922 #+begin_src emacs-lisp
 923 (use-package hlint-refactor
 924   :bind (:map hlint-refactor-mode-map
 925               ("C-c l b" . hlint-refactor-refactor-buffer)
 926               ("C-c l r" . hlint-refactor-refactor-at-point))
 927   :hook (haskell-mode . hlint-refactor-mode))
 928 #+end_src
 929
 930 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 931
 932 #+begin_src emacs-lisp
 933 (use-package flycheck-haskell)
 934 #+end_src
 935
 936 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 937 :PROPERTIES:
 938 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 939 :END:
 940
 941 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 942 instead.
 943
 944 #+begin_src emacs-lisp :tangle no
 945 ;;; hs-lint.el --- minor mode for HLint code checking
 946
 947 ;; Copyright 2009 (C) Alex Ott
 948 ;;
 949 ;; Author: Alex Ott <alexott@gmail.com>
 950 ;; Keywords: haskell, lint, HLint
 951 ;; Requirements:
 952 ;; Status: distributed under terms of GPL2 or above
 953
 954 ;; Typical message from HLint looks like:
 955 ;;
 956 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 957 ;; Found:
 958 ;;   count1 p l = length (filter p l)
 959 ;; Why not:
 960 ;;   count1 p = length . filter p
 961
 962
 963 (require 'compile)
 964
 965 (defgroup hs-lint nil
 966   "Run HLint as inferior of Emacs, parse error messages."
 967   :group 'tools
 968   :group 'haskell)
 969
 970 (defcustom hs-lint-command "hlint"
 971   "The default hs-lint command for \\[hlint]."
 972   :type 'string
 973   :group 'hs-lint)
 974
 975 (defcustom hs-lint-save-files t
 976   "Save modified files when run HLint or no (ask user)"
 977   :type 'boolean
 978   :group 'hs-lint)
 979
 980 (defcustom hs-lint-replace-with-suggestions nil
 981   "Replace user's code with suggested replacements"
 982   :type 'boolean
 983   :group 'hs-lint)
 984
 985 (defcustom hs-lint-replace-without-ask nil
 986   "Replace user's code with suggested replacements automatically"
 987   :type 'boolean
 988   :group 'hs-lint)
 989
 990 (defun hs-lint-process-setup ()
 991   "Setup compilation variables and buffer for `hlint'."
 992   (run-hooks 'hs-lint-setup-hook))
 993
 994 ;; regex for replace suggestions
 995 ;;
 996 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
 997 ;; Found:
 998 ;; \s +\(.*\)
 999 ;; Why not:
1000 ;; \s +\(.*\)
1001
1002 (defvar hs-lint-regex
1003   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1004   "Regex for HLint messages")
1005
1006 (defun make-short-string (str maxlen)
1007   (if (< (length str) maxlen)
1008       str
1009     (concat (substring str 0 (- maxlen 3)) "...")))
1010
1011 (defun hs-lint-replace-suggestions ()
1012   "Perform actual replacement of suggestions"
1013   (goto-char (point-min))
1014   (while (re-search-forward hs-lint-regex nil t)
1015     (let* ((fname (match-string 1))
1016           (fline (string-to-number (match-string 2)))
1017           (old-code (match-string 4))
1018           (new-code (match-string 5))
1019           (msg (concat "Replace '" (make-short-string old-code 30)
1020                        "' with '" (make-short-string new-code 30) "'"))
1021           (bline 0)
1022           (eline 0)
1023           (spos 0)
1024           (new-old-code ""))
1025       (save-excursion
1026         (switch-to-buffer (get-file-buffer fname))
1027         (goto-char (point-min))
1028         (forward-line (1- fline))
1029         (beginning-of-line)
1030         (setf bline (point))
1031         (when (or hs-lint-replace-without-ask
1032                   (yes-or-no-p msg))
1033           (end-of-line)
1034           (setf eline (point))
1035           (beginning-of-line)
1036           (setf old-code (regexp-quote old-code))
1037           (while (string-match "\\\\ " old-code spos)
1038             (setf new-old-code (concat new-old-code
1039                                  (substring old-code spos (match-beginning 0))
1040                                  "\\ *"))
1041             (setf spos (match-end 0)))
1042           (setf new-old-code (concat new-old-code (substring old-code spos)))
1043           (remove-text-properties bline eline '(composition nil))
1044           (when (re-search-forward new-old-code eline t)
1045             (replace-match new-code nil t)))))))
1046
1047 (defun hs-lint-finish-hook (buf msg)
1048   "Function, that is executed at the end of HLint execution"
1049   (if hs-lint-replace-with-suggestions
1050       (hs-lint-replace-suggestions)
1051       (next-error 1 t)))
1052
1053 (define-compilation-mode hs-lint-mode "HLint"
1054   "Mode for check Haskell source code."
1055   (set (make-local-variable 'compilation-process-setup-function)
1056        'hs-lint-process-setup)
1057   (set (make-local-variable 'compilation-disable-input) t)
1058   (set (make-local-variable 'compilation-scroll-output) nil)
1059   (set (make-local-variable 'compilation-finish-functions)
1060        (list 'hs-lint-finish-hook))
1061   )
1062
1063 (defun hs-lint ()
1064   "Run HLint for current buffer with haskell source"
1065   (interactive)
1066   (save-some-buffers hs-lint-save-files)
1067   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1068                      'hs-lint-mode))
1069
1070 (provide 'hs-lint)
1071 ;;; hs-lint.el ends here
1072 #+end_src
1073
1074 #+begin_src emacs-lisp :tangle no
1075 (use-package hs-lint
1076   :load-path "lisp/"
1077   :bind (:map haskell-mode-map
1078               ("C-c l l" . hs-lint)))
1079 #+end_src
1080 * Emacs Enhancements
1081
1082 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1083
1084 #+begin_quote
1085 Emacs package that displays available keybindings in popup
1086 #+end_quote
1087
1088 #+begin_src emacs-lisp
1089 (use-package which-key
1090   :defer 1
1091   :config (which-key-mode))
1092 #+end_src
1093
1094 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1095
1096 #+begin_src emacs-lisp
1097 (use-package doom-modeline
1098   :demand t
1099   :config (setq doom-modeline-height 32)
1100   :hook (after-init . doom-modeline-init))
1101 #+end_src
1102
1103 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1104
1105 #+begin_src emacs-lisp :tangle no
1106 (use-package tao-theme
1107   :demand t
1108   :config (load-theme 'tao-yang t))
1109 #+end_src
1110
1111 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1112
1113 #+begin_src emacs-lisp
1114 (load-theme 'eink t)
1115 #+end_src
1116
1117 ** [[https://github.com/bbatsov/crux][crux]]
1118
1119 #+begin_src emacs-lisp
1120 (use-package crux
1121   :bind (("C-c d"   . crux-duplicate-current-line-or-region)
1122          ("C-c M-d" . crux-duplicate-and-comment-current-line-or-region)
1123          ("C-c b K" . crux-kill-other-buffers)
1124          ("C-c f c" . crux-copy-file-preserve-attributes)
1125          ("C-c f D" . crux-delete-file-and-buffer)
1126          ("C-c f R" . crux-rename-file-and-buffer)))
1127 #+end_src
1128
1129 ** [[https://github.com/alezost/mwim.el][mwim]]
1130
1131 #+begin_src emacs-lisp
1132 (use-package mwim
1133   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1134          ("C-e"    . mwim-end-of-code-or-line)
1135          ("<home>" . mwim-beginning-of-line-or-code)
1136          ("<end>"  . mwim-end-of-line-or-code)))
1137 #+end_src
1138
1139 ** projectile
1140
1141 #+begin_src emacs-lisp
1142 (use-package projectile
1143   :defer 5
1144   :bind-keymap ("C-c p" . projectile-command-map)
1145   :config
1146   (projectile-mode)
1147
1148   (defun my-projectile-invalidate-cache (&rest _args)
1149     ;; ignore the args to `magit-checkout'
1150     (projectile-invalidate-cache nil))
1151
1152   (eval-after-load 'magit-branch
1153     '(progn
1154        (advice-add 'magit-checkout
1155                    :after #'my-projectile-invalidate-cache)
1156        (advice-add 'magit-branch-and-checkout
1157                    :after #'my-projectile-invalidate-cache))))
1158 #+end_src
1159
1160 * Email
1161 ** [[https://notmuchmail.org][notmuch]]
1162
1163 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1164
1165 #+begin_src emacs-lisp
1166 (defvar amin-maildir "~/mail")
1167
1168 (use-package sendmail
1169   ;; :ensure nil
1170   :config
1171   (setq sendmail-program "/usr/bin/msmtp"
1172         ; message-sendmail-extra-arguments '("-v" "-d")
1173         mail-specify-envelope-from t
1174         mail-envelope-from 'header))
1175
1176 (use-package message
1177   ;; :ensure nil
1178   :config
1179   (setq message-kill-buffer-on-exit t
1180         message-send-mail-function 'message-send-mail-with-sendmail
1181         message-sendmail-envelope-from 'header
1182         message-directory "drafts"
1183         message-user-fqdn "aminb.org")
1184   (add-hook 'message-mode-hook
1185             (lambda () (setq fill-column 65
1186                         message-fill-column 65)))
1187   (add-hook 'message-mode-hook
1188             #'flyspell-mode)
1189   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1190   ;; TODO: is there a way to only run this when replying and not composing?
1191   ;; (add-hook 'notmuch-message-mode-hook
1192   ;;           (lambda () (progn
1193   ;;                   (newline)
1194   ;;                   (newline)
1195   ;;                   (forward-line -1)
1196   ;;                   (forward-line -1))))
1197   ;; (add-hook 'message-setup-hook
1198   ;;           #'mml-secure-message-sign-pgpmime)
1199   )
1200
1201 (after! mml-sec
1202   (setq mml-secure-openpgp-encrypt-to-self t
1203         mml-secure-openpgp-sign-with-sender t))
1204
1205 (defun amin/notmuch ()
1206   "Delete other windows, then launch `notmuch'."
1207   (interactive)
1208   (delete-other-windows)
1209   (notmuch))
1210
1211 (use-package notmuch
1212   :commands notmuch
1213   :bind ("C-c m" . amin/notmuch)
1214   :custom (notmuch-always-prompt-for-sender t)
1215   :config
1216   (setq notmuch-hello-sections
1217         '(notmuch-hello-insert-header
1218           notmuch-hello-insert-saved-searches
1219           ;; notmuch-hello-insert-search
1220           notmuch-hello-insert-alltags)
1221         notmuch-search-oldest-first nil
1222         notmuch-show-all-tags-list t
1223         notmuch-message-headers  ; see bug follow-up above
1224         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1225         notmuch-hello-thousands-separator ","
1226         notmuch-fcc-dirs
1227         '(("amin@aminb.org"        . "amin/Sent")
1228           ("amin@gnu.org"          . "gnu/Sent")
1229           ("abandali@uwaterloo.ca" . "\"uwaterloo/Sent Items\"")
1230           ("mab@gnu.org"           . "gnu/Sent")
1231           ("aminb@gnu.org"         . "gnu/Sent")
1232           (".*"                    . "sent"))
1233         notmuch-search-result-format
1234         '(("date"    . "%12s ")
1235           ("count"   . "%-7s ")
1236           ("authors" . "%-40s ")
1237           ("subject" . "%s ")
1238           ("tags"    . "(%s)"))
1239         notmuch-saved-searches
1240         '((:name "inbox"     :query "tag:inbox"     :key "i")
1241           (:name "unread"    :query "tag:unread"    :key "u")
1242           (:name "latest"    :query "tag:latest"    :key "l")
1243           (:name "encrypted" :query "tag:encrypted" :key "e")
1244           (:name "flagged"   :query "tag:flagged"   :key "f")
1245           (:name "sent"      :query "tag:sent"      :key "s")
1246           (:name "drafts"    :query "tag:draft"     :key "d")
1247           (:name "all mail"  :query "*"             :key "a")))
1248   ;; (add-hook 'visual-fill-column-mode-hook
1249   ;;           (lambda ()
1250   ;;             (when (string= major-mode 'notmuch-message-mode)
1251   ;;               (setq visual-fill-column-width 70))))
1252   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1253   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1254   ;;             :override #'kill-this-buffer)
1255   :bind
1256   (:map notmuch-hello-mode-map
1257         ("u" . (lambda ()
1258                  "Search for `unread'-tagged messages"
1259                  (interactive)
1260                  (notmuch-hello-search "tag:unread")))
1261         ("i" . (lambda ()
1262                  "Search for `inbox'-tagged messages"
1263                  (interactive)
1264                  (notmuch-hello-search "tag:inbox")))
1265         ("l" . (lambda ()
1266                  "Search for `latest'-tagged messages"
1267                  (interactive)
1268                  (notmuch-hello-search "tag:latest")))
1269         ("e" . (lambda ()
1270                  "Search for `encrypted'-tagged messages"
1271                  (interactive)
1272                  (notmuch-hello-search "tag:encrypted"))))
1273   (:map notmuch-search-mode-map
1274         ("k" . (lambda ()
1275                  "Mark message read"
1276                  (interactive)
1277                  (notmuch-search-tag '("-unread"))
1278                  ;; (notmuch-search-archive-thread)
1279                  (notmuch-search-next-thread)))
1280         ("u" . (lambda ()
1281                  "Mark message unread"
1282                  (interactive)
1283                  (notmuch-search-tag '("+unread"))
1284                  (notmuch-search-next-thread)))
1285         ("K" . (lambda ()
1286                  "Mark message deleted"
1287                  (interactive)
1288                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1289                  (notmuch-search-next-thread)))
1290         ("S" . (lambda ()
1291                  "Mark message as spam"
1292                  (interactive)
1293                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1294                  (notmuch-search-next-thread))))
1295   (:map notmuch-tree-mode-map
1296         ("k" . (lambda ()
1297                  "Mark message read"
1298                  (interactive)
1299                  (notmuch-tree-tag '("-unread"))
1300                  ;; (notmuch-tree-archive-thread)
1301                  (notmuch-tree-next-message)))
1302         ("u" . (lambda ()
1303                  "Mark message unread"
1304                  (interactive)
1305                  (notmuch-tree-tag '("+unread"))
1306                  (notmuch-tree-next-message)))
1307         ("K" . (lambda ()
1308                  "Mark message deleted"
1309                  (interactive)
1310                  (notmuch-tree-tag '("-unread" "-inbox" "+deleted"))
1311                  (notmuch-tree-next-message)))
1312         ("S" . (lambda ()
1313                  "Mark message as spam"
1314                  (interactive)
1315                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1316                  (notmuch-tree-next-message)))))
1317
1318 (use-package counsel-notmuch
1319   :bind ("C-c s m" . counsel-notmuch))
1320
1321 (after! notmuch-crypto
1322   (setq notmuch-crypto-process-mime t))
1323
1324 (after! recentf
1325   (add-to-list 'recentf-exclude (expand-file-name amin-maildir)))
1326 #+end_src
1327
1328 ** supercite
1329
1330 #+begin_src emacs-lisp :tangle no
1331 (use-package supercite
1332   :commands sc-cite-original
1333   :init
1334   (add-hook 'mail-citation-hook 'sc-cite-original)
1335
1336   (defun sc-remove-existing-signature ()
1337     (save-excursion
1338       (goto-char (region-beginning))
1339       (when (re-search-forward message-signature-separator (region-end) t)
1340         (delete-region (match-beginning 0) (region-end)))))
1341
1342   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1343
1344   (defun sc-remove-if-not-mailing-list ()
1345     (unless (assoc "list-id" sc-mail-info)
1346       (setq attribution sc-default-attribution
1347             citation (concat sc-citation-delimiter
1348                              sc-citation-separator))))
1349
1350   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1351
1352   :config
1353   (defun sc-fill-if-different (&optional prefix)
1354     "Fill the region bounded by `sc-fill-begin' and point.
1355 Only fill if optional PREFIX is different than
1356 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1357 fill region.  If PREFIX is not supplied, initialize fill
1358 variables.  This is useful for a regi `begin' frame-entry."
1359     (if (not prefix)
1360         (setq sc-fill-line-prefix ""
1361               sc-fill-begin (line-beginning-position))
1362       (if (and sc-auto-fill-region-p
1363                (not (string= prefix sc-fill-line-prefix)))
1364           (let ((fill-prefix sc-fill-line-prefix))
1365             (unless (or (string= fill-prefix "")
1366                         (save-excursion
1367                           (goto-char sc-fill-begin)
1368                           (or (looking-at ">+  +")
1369                               (< (length
1370                                   (buffer-substring (point)
1371                                                     (line-end-position)))
1372                                  65))))
1373               (fill-region sc-fill-begin (line-beginning-position)))
1374             (setq sc-fill-line-prefix prefix
1375                   sc-fill-begin (line-beginning-position)))))
1376 nil))
1377 #+end_src
1378
1379 * Blogging
1380 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1381
1382 #+begin_src emacs-lisp
1383 (use-package ox-hugo
1384   :after ox)
1385 #+end_src
1386
1387 * Post initialization
1388 :PROPERTIES:
1389 :CUSTOM_ID: post-initialization
1390 :END:
1391
1392 Display how long it took to load the init file.
1393
1394 #+begin_src emacs-lisp
1395 (message "Loading %s...done (%.3fs)" user-init-file
1396          (float-time (time-subtract (current-time)
1397                                     amin--before-user-init-time)))
1398 #+end_src
1399
1400 * Footer
1401 :PROPERTIES:
1402 :CUSTOM_ID: footer
1403 :END:
1404
1405 #+begin_src emacs-lisp :comments none
1406 ;;; init.el ends here
1407 #+end_src