git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s, found [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]].
 109
 110 #+begin_src emacs-lisp :comments none
 111 ;; Naming conventions:
 112 ;;
 113 ;;   amin-...   public variables or non-interactive functions
 114 ;;   amin--...  private anything (non-interactive), not safe for direct use
 115 ;;   amin/...   an interactive function; safe for M-x or keybinding
 116 ;;   amin:...   an evil operator, motion, or command
 117 ;;   amin|...   a hook function
 118 ;;   amin*...   an advising function
 119 ;;   amin@...   a hydra command
 120 ;;   ...!       a macro
 121 #+end_src
 122
 123 * Initial setup
 124 :PROPERTIES:
 125 :CUSTOM_ID: initial-setup
 126 :END:
 127
 128 #+begin_src emacs-lisp :comments none
 129 ;;; Code:
 130 #+end_src
 131
 132 ** Emacs initialization
 133
 134 I'd like to do a couple of measurements of Emacs' startup time. First,
 135 let's see how long Emacs takes to start up, before even loading
 136 =init.el=, i.e. =user-init-file=:
 137
 138 #+begin_src emacs-lisp
 139 (defvar amin--before-user-init-time (current-time)
 140   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 141 (message "Loading Emacs...done (%.3fs)"
 142          (float-time (time-subtract amin--before-user-init-time
 143                                     before-init-time)))
 144 #+end_src
 145
 146 Also, temporarily increase ~gc-cons-threshhold~ and
 147 ~gc-cons-percentage~ during startup to reduce garbage collection
 148 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 149 startup time as well.
 150
 151 #+begin_src emacs-lisp
 152 (defvar amin--gc-cons-threshold gc-cons-threshold)
 153 (defvar amin--gc-cons-percentage gc-cons-percentage)
 154 (defvar amin--file-name-handler-alist file-name-handler-alist)
 155 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 156       gc-cons-percentage 0.6
 157       file-name-handler-alist nil
 158       ;; sidesteps a bug when profiling with esup
 159       esup-child-profile-require-level 0)
 160 #+end_src
 161
 162 Of course, we'd like to set them back to their defaults once we're
 163 done initializing.
 164
 165 #+begin_src emacs-lisp
 166 (add-hook
 167  'after-init-hook
 168  (lambda ()
 169    (setq gc-cons-threshold amin--gc-cons-threshold
 170          gc-cons-percentage amin--gc-cons-percentage
 171          file-name-handler-alist amin--file-name-handler-alist)))
 172 #+end_src
 173
 174 Increase the number of lines kept in message logs (the =*Messages*=
 175 buffer).
 176
 177 #+begin_src emacs-lisp
 178 (setq message-log-max 20000)
 179 #+end_src
 180
 181 Optionally, we could suppress some byte compiler warnings like below,
 182 but for now I've decided to keep them enabled. See documentation for
 183 ~byte-compile-warnings~ for more details.
 184
 185 #+begin_src emacs-lisp
 186 ;; (setq byte-compile-warnings
 187 ;;       '(not free-vars unresolved noruntime lexical make-local))
 188 #+end_src
 189
 190 ** whoami
 191
 192 #+begin_src emacs-lisp
 193 (setq user-full-name "Amin Bandali"
 194       user-mail-address "amin@aminb.org")
 195 #+end_src
 196
 197 ** Package management
 198
 199 *** No =package.el=
 200
 201 I can do all my package management things with Borg, and don't need
 202 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 203 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 204
 205 #+begin_src emacs-lisp :tangle early-init.el
 206 (setq package-enable-at-startup nil)
 207 #+end_src
 208
 209 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 210 right now), and even when released it'll be long before most distros
 211 ship in their repos, I'll still put the old workaround with the
 212 commented call to ~package-initialize~ here anyway.
 213
 214 #+begin_src emacs-lisp
 215 (setq package-enable-at-startup nil)
 216 ;; (package-initialize)
 217 #+end_src
 218
 219 *** Borg
 220
 221 #+begin_quote
 222 Assimilate Emacs packages as Git submodules
 223 #+end_quote
 224
 225 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 226 short, it creates a git submodule in =lib/= for each package, which
 227 can then be managed with the help of Magit or other tools.
 228
 229 #+begin_src emacs-lisp
 230 (setq user-init-file (or load-file-name buffer-file-name)
 231       user-emacs-directory (file-name-directory user-init-file))
 232 (add-to-list 'load-path
 233              (expand-file-name "lib/borg" user-emacs-directory))
 234 (require 'borg)
 235 (borg-initialize)
 236 #+end_src
 237
 238 *** =use-package=
 239
 240 #+begin_quote
 241 A use-package declaration for simplifying your .emacs
 242 #+end_quote
 243
 244 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 245 packages (in our case especially the latter) in a neatly organized way
 246 and without compromising on performance.
 247
 248 #+begin_src emacs-lisp
 249 (require 'use-package)
 250 (if nil  ; set to t when need to debug init
 251     (setq use-package-verbose t
 252           use-package-expand-minimally nil
 253           use-package-compute-statistics t
 254           debug-on-error t)
 255   (setq use-package-verbose nil
 256         use-package-expand-minimally t))
 257 #+end_src
 258
 259 *** Epkg
 260
 261 #+begin_quote
 262 Browse the Emacsmirror package database
 263 #+end_quote
 264
 265 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 266 database, low-level functions for querying the database, and a
 267 =package.el=-like user interface for browsing the available packages.
 268
 269 #+begin_src emacs-lisp
 270 (use-package epkg
 271   :defer t)
 272 #+end_src
 273
 274 ** No littering in =~/.emacs.d=
 275
 276 #+begin_quote
 277 Help keeping ~/.emacs.d clean
 278 #+end_quote
 279
 280 By default, even for Emacs' built-in packages, the configuration files
 281 and persistent data are all over the place. Use =no-littering= to help
 282 contain the mess.
 283
 284 #+begin_src emacs-lisp
 285 (use-package no-littering
 286   :demand t
 287   :config
 288   (savehist-mode 1)
 289   (add-to-list 'savehist-additional-variables 'kill-ring)
 290   (save-place-mode 1)
 291   (setq auto-save-file-name-transforms
 292         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 293 #+end_src
 294
 295 ** Custom file (=custom.el=)
 296
 297 I'm not planning on using the custom file much, but even so, I
 298 definitely don't want it mixing with =init.el=. So, here; let's give
 299 it it's own file. While at it, treat themes as safe.
 300
 301 #+begin_src emacs-lisp
 302 (use-package custom
 303   :no-require t
 304   :config
 305   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 306   (when (file-exists-p custom-file)
 307     (load custom-file))
 308   (setf custom-safe-themes t))
 309 #+end_src
 310
 311 ** Better =$PATH= handling
 312
 313 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 314 in my shell.
 315
 316 #+begin_src emacs-lisp
 317 (use-package exec-path-from-shell
 318   :defer 1
 319   :init
 320   (setq exec-path-from-shell-check-startup-files nil)
 321   :config
 322   (exec-path-from-shell-initialize)
 323   ;; while we're at it, let's fix access to our running ssh-agent
 324   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 325   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 326 #+end_src
 327
 328 ** Only one custom theme at a time
 329
 330 #+begin_src emacs-lisp
 331 (defadvice load-theme (before clear-previous-themes activate)
 332   "Clear existing theme settings instead of layering them"
 333   (mapc #'disable-theme custom-enabled-themes))
 334 #+end_src
 335
 336 ** Server
 337
 338 Start server if not already running. Alternatively, can be done by
 339 issuing =emacs --daemon= in the terminal, which can be automated with
 340 a systemd service or using =brew services start emacs= on macOS. I use
 341 Emacs as my window manager (via EXWM), so I always start Emacs on
 342 login; so starting the server from inside Emacs is good enough for me.
 343
 344 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 345
 346 #+begin_src emacs-lisp
 347 (use-package server
 348   :config (or (server-running-p) (server-mode)))
 349 #+end_src
 350
 351 ** Unicode support
 352
 353 Font stack with better unicode support, around =Ubuntu Mono= and
 354 =Hack=.
 355
 356 #+begin_src emacs-lisp
 357 (dolist (ft (fontset-list))
 358   (set-fontset-font
 359    ft
 360    'unicode
 361    (font-spec :name "Ubuntu Mono"))
 362   (set-fontset-font
 363    ft
 364    'unicode
 365    (font-spec :name "DejaVu Sans Mono")
 366    nil
 367    'append)
 368   ;; (set-fontset-font
 369   ;;  ft
 370   ;;  'unicode
 371   ;;  (font-spec
 372   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 373   ;;  nil
 374   ;;  'append)
 375   ;; (set-fontset-font
 376   ;;  ft
 377   ;;  #x2115  ; ℕ
 378   ;;  (font-spec :name "DejaVu Sans Mono")
 379   ;;  nil
 380   ;;  'append)
 381   (set-fontset-font
 382    ft
 383    (cons ?Α ?ω)
 384    (font-spec :name "DejaVu Sans Mono" :size 14)
 385    nil
 386    'prepend))
 387 #+end_src
 388
 389 ** Libraries
 390
 391 #+begin_src emacs-lisp
 392 (require 'cl-lib)
 393 (require 'subr-x)
 394 #+end_src
 395
 396 ** Useful utilities
 397
 398 #+begin_src emacs-lisp
 399 (defun amin-enlist (exp)
 400   "Return EXP wrapped in a list, or as-is if already a list."
 401 (if (listp exp) exp (list exp)))
 402
 403 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 404 (defmacro after! (features &rest body)
 405   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 406 compilation."
 407   (declare (indent defun) (debug t))
 408   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 409                 (dolist (next (amin-enlist features))
 410                   (if (symbolp next)
 411                       (require next nil :no-error)
 412                     (load next :no-message :no-error))))
 413             #'progn
 414           #'with-no-warnings)
 415         (cond ((symbolp features)
 416                `(eval-after-load ',features '(progn ,@body)))
 417               ((and (consp features)
 418                     (memq (car features) '(:or :any)))
 419                `(progn
 420                   ,@(cl-loop for next in (cdr features)
 421                              collect `(after! ,next ,@body))))
 422               ((and (consp features)
 423                     (memq (car features) '(:and :all)))
 424                (dolist (next (cdr features))
 425                  (setq body `(after! ,next ,@body)))
 426                body)
 427               ((listp features)
 428                `(after! (:all ,@features) ,@body)))))
 429 #+end_src
 430
 431 * Core
 432 :PROPERTIES:
 433 :CUSTOM_ID: core
 434 :END:
 435
 436 ** Defaults
 437
 438 *** Time and battery in mode-line
 439
 440 Enable displaying time and battery in the mode-line, since I'm not
 441 using the Xfce panel anymore. Also, I don't need to see the load
 442 average on a regular basis, so disable that.
 443
 444 Note: using =i3status= on sway at the moment, so disabling this.
 445
 446 #+begin_src emacs-lisp :tangle no
 447 (use-package time
 448   :ensure nil
 449   :init
 450   (setq display-time-default-load-average nil)
 451   :config
 452   (display-time-mode))
 453
 454 (use-package battery
 455   :ensure nil
 456   :config
 457   (display-battery-mode))
 458 #+end_src
 459
 460 *** Smaller fringe
 461
 462 Might want to set the fringe to a smaller value, especially if using
 463 EXWM. I'm fine with the default for now.
 464
 465 #+begin_src emacs-lisp
 466 ;; (fringe-mode '(3 . 1))
 467 (fringe-mode nil)
 468 #+end_src
 469
 470 *** Disable disabled commands
 471
 472 Emacs disables some commands by default that could persumably be
 473 confusing for novice users. Let's disable that.
 474
 475 #+begin_src emacs-lisp
 476 (setq disabled-command-function nil)
 477 #+end_src
 478
 479 *** Kill-ring
 480
 481 Save what I copy into clipboard from other applications into Emacs'
 482 kill-ring, which would allow me to still be able to easily access it
 483 in case I kill (cut or copy) something else inside Emacs before
 484 yanking (pasting) what I'd originally intended to.
 485
 486 #+begin_src emacs-lisp
 487 (setq save-interprogram-paste-before-kill t)
 488 #+end_src
 489
 490 *** Minibuffer
 491
 492 #+begin_src emacs-lisp
 493 (setq enable-recursive-minibuffers t
 494       resize-mini-windows t)
 495 #+end_src
 496
 497 *** Lazy-person-friendly yes/no prompts
 498
 499 Lazy people would prefer to type fewer keystrokes, especially for yes
 500 or no questions. I'm lazy.
 501
 502 #+begin_src emacs-lisp
 503 (defalias 'yes-or-no-p #'y-or-n-p)
 504 #+end_src
 505
 506 *** Startup screen and =*scratch*=
 507
 508 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 509 startup buffer.
 510
 511 #+begin_src emacs-lisp
 512 (setq initial-buffer-choice t)
 513 #+end_src
 514
 515 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 516 need the default hint.
 517
 518 #+begin_src emacs-lisp
 519 (setq initial-scratch-message nil)
 520 #+end_src
 521
 522 Also, let's use Text mode as the major mode, in case I want to
 523 customize it (=*scratch*='s default major mode, Fundamental mode,
 524 can't really be customized).
 525
 526 #+begin_src emacs-lisp
 527 (setq initial-major-mode 'text-mode)
 528 #+end_src
 529
 530 Inhibit the buffer list when more than 2 files are loaded.
 531
 532 #+begin_src emacs-lisp
 533 (setq inhibit-startup-buffer-menu t)
 534 #+end_src
 535
 536 I don't really need to see the startup screen or echo area message
 537 either.
 538
 539 #+begin_src emacs-lisp
 540 (advice-add #'display-startup-echo-area-message :override #'ignore)
 541 (setq inhibit-startup-screen t
 542       inhibit-startup-echo-area-message user-login-name)
 543 #+end_src
 544
 545 *** More useful frame titles
 546
 547 Show either the file name or the buffer name (in case the buffer isn't
 548 visiting a file). Borrowed from Emacs Prelude.
 549
 550 #+begin_src emacs-lisp
 551 (setq frame-title-format
 552       '("" invocation-name " - "
 553         (:eval (if (buffer-file-name)
 554                    (abbreviate-file-name (buffer-file-name))
 555                  "%b"))))
 556 #+end_src
 557
 558 *** Backups
 559
 560 Emacs' default backup settings aren't that great. Let's use more
 561 sensible options. See documentation for the ~make-backup-file~
 562 variable.
 563
 564 #+begin_src emacs-lisp
 565 (setq backup-by-copying t
 566       version-control t)
 567 #+end_src
 568
 569 *** Auto revert
 570
 571 Enable automatic reloading of changed buffers and files.
 572
 573 #+begin_src emacs-lisp
 574 (global-auto-revert-mode 1)
 575 (setq auto-revert-verbose nil
 576       global-auto-revert-non-file-buffers t)
 577 #+end_src
 578
 579 *** Always use space for indentation
 580
 581 #+begin_src emacs-lisp
 582 (setq-default
 583  indent-tabs-mode nil
 584  require-final-newline t
 585  tab-width 4)
 586 #+end_src
 587
 588 ** Packages
 589
 590 The packages in this section are absolutely essential to my everyday
 591 workflow, and they play key roles in how I do my computing. They
 592 immensely enhance the Emacs experience for me; both using Emacs, and
 593 customizing it.
 594
 595 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 596
 597 #+begin_src emacs-lisp
 598 (use-package auto-compile
 599   :demand t
 600   :config
 601   (auto-compile-on-load-mode)
 602   (auto-compile-on-save-mode)
 603   (setq auto-compile-display-buffer               nil
 604         auto-compile-mode-line-counter            t
 605         auto-compile-source-recreate-deletes-dest t
 606         auto-compile-toggle-deletes-nonlib-dest   t
 607         auto-compile-update-autoloads             t)
 608   (add-hook 'auto-compile-inhibit-compile-hook
 609             'auto-compile-inhibit-compile-detached-git-head))
 610 #+end_src
 611
 612 *** [[https://github.com/noctuid/general.el][general]]
 613
 614  #+begin_src emacs-lisp
 615 (use-package general
 616   :demand t
 617   :config
 618   (general-evil-setup t)
 619
 620   (general-override-mode)
 621
 622   (general-create-definer
 623     amin--mode-leader-keys
 624     :keymaps 'override
 625     :states '(emacs normal visual motion insert)
 626     :non-normal-prefix "C-,"
 627     :prefix ",")
 628
 629   (general-create-definer
 630     amin--leader-keys
 631     :keymaps 'override
 632     :states '(emacs normal visual motion insert)
 633     :non-normal-prefix "M-m"
 634     :prefix "SPC"))
 635 #+end_src
 636
 637 *** evil
 638
 639 #+begin_src emacs-lisp
 640 (use-package evil
 641   :demand t
 642   :hook (view-mode . evil-motion-state)
 643   :init
 644   (setq evil-want-integration nil)
 645   :config (evil-mode 1)
 646   (general-swap-key nil '(normal motion) ";" ":")
 647   (setq evil-want-visual-char-semi-exclusive t))
 648 #+end_src
 649
 650 #+begin_src emacs-lisp
 651 (use-package evil-collection
 652   :after evil
 653   :config
 654   (evil-collection-init))
 655 #+end_src
 656
 657 #+begin_src emacs-lisp
 658 (use-package evil-escape
 659   :demand t
 660   :init
 661   (setq evil-escape-excluded-states '(normal visual multiedit emacs motion)
 662         evil-escape-excluded-major-modes '(neotree-mode)
 663         evil-escape-key-sequence "jk"
 664         evil-escape-delay 0.25)
 665   :general
 666   (:states '(insert replace visual operator)
 667     "C-g" #'evil-escape)
 668    :config
 669   (evil-escape-mode 1)
 670   ;; no `evil-escape' in minibuffer
 671   (push #'minibufferp evil-escape-inhibit-functions))
 672 #+end_src
 673
 674 #+begin_src emacs-lisp
 675 (use-package evil-magit
 676   :after magit
 677   :config
 678   (evil-set-initial-state 'git-commit-mode 'insert))
 679 #+end_src
 680
 681 #+begin_src emacs-lisp
 682 (use-package evil-org
 683   :hook (org-mode . evil-org-mode)
 684   :general
 685   (nvmap evil-org-mode-map
 686     "TAB" 'org-cycle
 687     "S-TAB" 'org-cycle)
 688   :config
 689   (evil-org-set-key-theme)
 690   (require 'evil-org-agenda)
 691   (evil-org-agenda-set-keys)
 692   (nmap evil-org-mode-map
 693     [backtab] 'org-shifttab)
 694   (after! org-src
 695     (define-key org-src-mode-map [remap evil-write] 'org-edit-src-save)
 696     (define-key org-src-mode-map [remap evil-save-and-close]
 697       (lambda () (interactive)
 698         (org-edit-src-save)
 699         (org-edit-src-exit)))
 700     (define-key org-src-mode-map [remap evil-save-modified-and-close]
 701       (lambda () (interactive)
 702         (org-edit-src-save)
 703         (org-edit-src-exit)))))
 704 #+end_src
 705
 706 #+begin_src emacs-lisp
 707 (amin--leader-keys
 708  "/"  '(:ignore t :wk "search")
 709
 710  "B"  '(:ignore t :wk "Borg")
 711  "BA" 'borg-activate
 712  "Ba" 'borg-assimilate
 713  "Bb" 'borg-build
 714  "Bc" 'borg-clone
 715  "Bd" 'epkg-describe-package
 716  "Bp" 'epkg-list-packages
 717  "Br" 'borg-remove
 718  "Bu" 'epkg-update
 719
 720  "b"  '(:ignore t :wk "buffers")
 721  "bb" 'ibuffer-list-buffers
 722  "bk" 'kill-this-buffer
 723  "bs" 'save-buffer
 724
 725  "f"  '(:ignore t :wk "files")
 726
 727  "h"  '(:ignore t :wk "help")
 728  "hc" 'describe-char
 729  "hf" 'describe-function
 730  "hF" 'describe-face
 731  "hi" 'info
 732  "hk" 'describe-key
 733  "hl" 'view-lossage
 734  "hv" 'describe-variable
 735
 736  "o" 'other-window
 737
 738  "w"  '(:ignore t :wk "window")
 739  "wo" 'other-window
 740
 741  "q"  '(:ignore t :wk "quit")
 742  "qq" 'save-buffers-kill-terminal)
 743 #+end_src
 744
 745 *** [[https://orgmode.org/][Org mode]]
 746
 747 #+begin_quote
 748 Org mode is for keeping notes, maintaining TODO lists, planning
 749 projects, and authoring documents with a fast and effective plain-text
 750 system.
 751 #+end_quote
 752
 753 In short, my favourite way of life.
 754
 755 #+begin_src emacs-lisp
 756 (use-package org
 757   :general
 758   (amin--leader-keys "bt" 'org-babel-tangle)
 759   (amin--leader-keys org-mode-map "i" 'org-edit-special)
 760   :config
 761   (setq org-src-tab-acts-natively t
 762         org-src-preserve-indentation nil
 763         org-edit-src-content-indentation 0)
 764   :hook (org-mode . org-indent-mode))
 765
 766 (use-package org-notmuch
 767   :after (:any org notmuch))
 768 #+end_src
 769
 770 *** [[https://magit.vc/][Magit]]
 771
 772 #+begin_quote
 773 It's Magit! A Git porcelain inside Emacs.
 774 #+end_quote
 775
 776 Not just how I do git, but /the/ way to do git.
 777
 778 #+begin_src emacs-lisp
 779 (use-package magit
 780   :general
 781   (amin--leader-keys
 782    "g"     '(:ignore t :wk "magit")
 783    "g SPC" 'magit-status
 784    "gs"    'magit-status
 785    "gS"    'magit-status-prefix
 786    "gB"    'magit-blame
 787    "gC"    'magit-clone
 788    "gf"    'magit-fetch
 789    "gF"    'magit-pull
 790    "gP"    'magit-push
 791    "gcc"   'magit-commit
 792    "gca"   'magit-commit-amend
 793    "gbb"   'magit-checkout
 794    "gbc"   'magit-branch)
 795   :defer t
 796   :bind (("s-g"     . magit-status)
 797          ("C-x g"   . magit-status)
 798          ("C-x M-g" . magit-dispatch-popup))
 799   :config
 800   (magit-add-section-hook 'magit-status-sections-hook
 801                           'magit-insert-modules
 802                           'magit-insert-stashes
 803                           'append))
 804 #+end_src
 805
 806 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 807
 808 #+begin_quote
 809 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 810 an overview, and more. Oh, man!
 811 #+end_quote
 812
 813 There's no way I could top that, so I won't attempt to.
 814
 815 **** Ivy
 816
 817 #+begin_src emacs-lisp
 818 (use-package ivy
 819   :defer 1
 820   :bind
 821   (:map ivy-minibuffer-map
 822         ([escape] . keyboard-escape-quit)
 823         ;; ("C-j"    . ivy-next-line)
 824         ;; ("C-k"    . ivy-previous-line)
 825         ([S-up]   . ivy-previous-history-element)
 826         ([S-down] . ivy-next-history-element)
 827         ("DEL"    . ivy-backward-delete-char))
 828   :general (amin--leader-keys "," 'ivy-switch-buffer)
 829   :config
 830   (setq ivy-wrap t)
 831   (ivy-mode 1))
 832 #+end_src
 833
 834 **** Swiper
 835
 836 #+begin_src emacs-lisp
 837 (use-package swiper
 838   :general (:states '(normal motion) "/" 'swiper)
 839   (amin--leader-keys "//" 'swiper)
 840   :bind (([remap isearch-forward]  . swiper)
 841          ([remap isearch-backward] . swiper)))
 842 #+end_src
 843
 844 **** Counsel
 845
 846 #+begin_src emacs-lisp
 847 (use-package counsel
 848   :defer 1
 849   :general
 850   (amin--leader-keys
 851    "fr" 'counsel-recentf
 852    "SPC" 'counsel-M-x
 853    "."   'counsel-find-file)
 854   :bind (([remap execute-extended-command] . counsel-M-x)
 855          ([remap find-file] . counsel-find-file)
 856          ("s-r"     . counsel-recentf)
 857          :map minibuffer-local-map
 858          ("C-r" . counsel-minibuffer-history))
 859   :config
 860   (counsel-mode 1)
 861   (defalias 'locate #'counsel-locate))
 862 #+end_src
 863
 864 * Borg's =layer/essentials=
 865
 866 TODO: break this giant source block down into individual org sections.
 867
 868 #+begin_src emacs-lisp
 869 (use-package dash
 870   :config (dash-enable-font-lock))
 871
 872 (use-package diff-hl
 873   :config
 874   (setq diff-hl-draw-borders nil)
 875   (global-diff-hl-mode)
 876   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 877
 878 (use-package dired
 879   :defer t
 880   :config (setq dired-listing-switches "-alh"))
 881
 882 (use-package eldoc
 883   :when (version< "25" emacs-version)
 884   :config (global-eldoc-mode))
 885
 886 (use-package help
 887   :defer t
 888   :config (temp-buffer-resize-mode))
 889
 890 (progn ;    `isearch'
 891   (setq isearch-allow-scroll t))
 892
 893 (use-package lisp-mode
 894   :config
 895   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 896   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 897   (defun indent-spaces-mode ()
 898     (setq indent-tabs-mode nil))
 899   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 900
 901 (use-package man
 902   :defer t
 903   :config (setq Man-width 80))
 904
 905 (use-package paren
 906   :config (show-paren-mode))
 907
 908 (use-package prog-mode
 909   :config (global-prettify-symbols-mode)
 910   (defun indicate-buffer-boundaries-left ()
 911     (setq indicate-buffer-boundaries 'left))
 912   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 913
 914 (use-package recentf
 915   :demand t
 916   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 917
 918 (use-package savehist
 919   :config (savehist-mode))
 920
 921 (use-package saveplace
 922   :when (version< "25" emacs-version)
 923   :config (save-place-mode))
 924
 925 (use-package simple
 926   :config (column-number-mode))
 927
 928 (progn ;    `text-mode'
 929   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 930
 931 (use-package tramp
 932   :defer t
 933   :config
 934   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 935   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 936   (add-to-list 'tramp-default-proxies-alist
 937                (list (regexp-quote (system-name)) nil nil)))
 938
 939 (use-package undo-tree
 940   :bind (("C-?" . undo-tree-undo)
 941          ("M-_" . undo-tree-redo))
 942   :config
 943   (global-undo-tree-mode)
 944   (setq undo-tree-mode-lighter ""
 945         undo-tree-auto-save-history t))
 946 #+end_src
 947
 948 * Editing
 949
 950 ** Company
 951
 952 #+begin_src emacs-lisp
 953 (use-package company
 954   :defer 5
 955   :bind
 956   (:map company-active-map
 957         ([tab] . company-complete-common-or-cycle))
 958   :custom
 959   (company-idle-delay 0.3)
 960   (company-minimum-prefix-length 1)
 961   (company-selection-wrap-around t)
 962   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 963   :config
 964   (global-company-mode t))
 965 #+end_src
 966
 967 * Syntax and spell checking
 968 #+begin_src emacs-lisp
 969 (use-package flycheck
 970   :hook (prog-mode . flycheck-mode)
 971   :config
 972   ;; Use the load-path from running Emacs when checking elisp files
 973   (setq flycheck-emacs-lisp-load-path 'inherit)
 974
 975   ;; Only flycheck when I actually save the buffer
 976   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 977 #+end_src
 978 * Programming modes
 979
 980 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 981
 982 #+begin_src emacs-lisp
 983 (use-package alloy-mode
 984   :config (setq alloy-basic-offset 2))
 985 #+end_src
 986
 987 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 988
 989 #+begin_src emacs-lisp
 990 (use-package proof-site  ; Proof General
 991   :load-path "lib/proof-site/generic/")
 992 #+end_src
 993
 994 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 995
 996 #+begin_src emacs-lisp
 997 (use-package lean-mode
 998   :bind (:map lean-mode-map
 999               ("S-SPC" . company-complete)))
1000 #+end_src
1001
1002 ** Haskell
1003
1004 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
1005
1006 #+begin_src emacs-lisp
1007 (use-package haskell-mode
1008   :config
1009   (setq haskell-indentation-layout-offset 4
1010         haskell-indentation-left-offset 4
1011         flycheck-checker 'haskell-hlint
1012         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
1013 #+end_src
1014
1015 *** [[https://github.com/jyp/dante][dante]]
1016
1017 #+begin_src emacs-lisp
1018 (use-package dante
1019   :after haskell-mode
1020   :commands dante-mode
1021   :hook (haskell-mode . dante-mode))
1022 #+end_src
1023
1024 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
1025
1026 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
1027 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
1028
1029 #+begin_src emacs-lisp
1030 (use-package hlint-refactor
1031   :bind (:map hlint-refactor-mode-map
1032               ("C-c l b" . hlint-refactor-refactor-buffer)
1033               ("C-c l r" . hlint-refactor-refactor-at-point))
1034   :hook (haskell-mode . hlint-refactor-mode))
1035 #+end_src
1036
1037 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
1038
1039 #+begin_src emacs-lisp
1040 (use-package flycheck-haskell)
1041 #+end_src
1042
1043 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
1044 :PROPERTIES:
1045 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
1046 :END:
1047
1048 Currently using =flycheck-haskell= with the =haskell-hlint= checker
1049 instead.
1050
1051 #+begin_src emacs-lisp :tangle no
1052 ;;; hs-lint.el --- minor mode for HLint code checking
1053
1054 ;; Copyright 2009 (C) Alex Ott
1055 ;;
1056 ;; Author: Alex Ott <alexott@gmail.com>
1057 ;; Keywords: haskell, lint, HLint
1058 ;; Requirements:
1059 ;; Status: distributed under terms of GPL2 or above
1060
1061 ;; Typical message from HLint looks like:
1062 ;;
1063 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
1064 ;; Found:
1065 ;;   count1 p l = length (filter p l)
1066 ;; Why not:
1067 ;;   count1 p = length . filter p
1068
1069
1070 (require 'compile)
1071
1072 (defgroup hs-lint nil
1073   "Run HLint as inferior of Emacs, parse error messages."
1074   :group 'tools
1075   :group 'haskell)
1076
1077 (defcustom hs-lint-command "hlint"
1078   "The default hs-lint command for \\[hlint]."
1079   :type 'string
1080   :group 'hs-lint)
1081
1082 (defcustom hs-lint-save-files t
1083   "Save modified files when run HLint or no (ask user)"
1084   :type 'boolean
1085   :group 'hs-lint)
1086
1087 (defcustom hs-lint-replace-with-suggestions nil
1088   "Replace user's code with suggested replacements"
1089   :type 'boolean
1090   :group 'hs-lint)
1091
1092 (defcustom hs-lint-replace-without-ask nil
1093   "Replace user's code with suggested replacements automatically"
1094   :type 'boolean
1095   :group 'hs-lint)
1096
1097 (defun hs-lint-process-setup ()
1098   "Setup compilation variables and buffer for `hlint'."
1099   (run-hooks 'hs-lint-setup-hook))
1100
1101 ;; regex for replace suggestions
1102 ;;
1103 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1104 ;; Found:
1105 ;; \s +\(.*\)
1106 ;; Why not:
1107 ;; \s +\(.*\)
1108
1109 (defvar hs-lint-regex
1110   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1111   "Regex for HLint messages")
1112
1113 (defun make-short-string (str maxlen)
1114   (if (< (length str) maxlen)
1115       str
1116     (concat (substring str 0 (- maxlen 3)) "...")))
1117
1118 (defun hs-lint-replace-suggestions ()
1119   "Perform actual replacement of suggestions"
1120   (goto-char (point-min))
1121   (while (re-search-forward hs-lint-regex nil t)
1122     (let* ((fname (match-string 1))
1123           (fline (string-to-number (match-string 2)))
1124           (old-code (match-string 4))
1125           (new-code (match-string 5))
1126           (msg (concat "Replace '" (make-short-string old-code 30)
1127                        "' with '" (make-short-string new-code 30) "'"))
1128           (bline 0)
1129           (eline 0)
1130           (spos 0)
1131           (new-old-code ""))
1132       (save-excursion
1133         (switch-to-buffer (get-file-buffer fname))
1134         (goto-char (point-min))
1135         (forward-line (1- fline))
1136         (beginning-of-line)
1137         (setf bline (point))
1138         (when (or hs-lint-replace-without-ask
1139                   (yes-or-no-p msg))
1140           (end-of-line)
1141           (setf eline (point))
1142           (beginning-of-line)
1143           (setf old-code (regexp-quote old-code))
1144           (while (string-match "\\\\ " old-code spos)
1145             (setf new-old-code (concat new-old-code
1146                                  (substring old-code spos (match-beginning 0))
1147                                  "\\ *"))
1148             (setf spos (match-end 0)))
1149           (setf new-old-code (concat new-old-code (substring old-code spos)))
1150           (remove-text-properties bline eline '(composition nil))
1151           (when (re-search-forward new-old-code eline t)
1152             (replace-match new-code nil t)))))))
1153
1154 (defun hs-lint-finish-hook (buf msg)
1155   "Function, that is executed at the end of HLint execution"
1156   (if hs-lint-replace-with-suggestions
1157       (hs-lint-replace-suggestions)
1158       (next-error 1 t)))
1159
1160 (define-compilation-mode hs-lint-mode "HLint"
1161   "Mode for check Haskell source code."
1162   (set (make-local-variable 'compilation-process-setup-function)
1163        'hs-lint-process-setup)
1164   (set (make-local-variable 'compilation-disable-input) t)
1165   (set (make-local-variable 'compilation-scroll-output) nil)
1166   (set (make-local-variable 'compilation-finish-functions)
1167        (list 'hs-lint-finish-hook))
1168   )
1169
1170 (defun hs-lint ()
1171   "Run HLint for current buffer with haskell source"
1172   (interactive)
1173   (save-some-buffers hs-lint-save-files)
1174   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1175                      'hs-lint-mode))
1176
1177 (provide 'hs-lint)
1178 ;;; hs-lint.el ends here
1179 #+end_src
1180
1181 #+begin_src emacs-lisp :tangle no
1182 (use-package hs-lint
1183   :load-path "lisp/"
1184   :bind (:map haskell-mode-map
1185               ("C-c l l" . hs-lint)))
1186 #+end_src
1187 * Emacs Enhancements
1188
1189 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1190
1191 #+begin_quote
1192 Emacs package that displays available keybindings in popup
1193 #+end_quote
1194
1195 #+begin_src emacs-lisp
1196 (use-package which-key
1197   :defer 1
1198   :config (which-key-mode))
1199 #+end_src
1200
1201 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1202
1203 #+begin_src emacs-lisp
1204 (use-package doom-modeline
1205   :demand t
1206   :config (setq doom-modeline-height 32)
1207   :hook (after-init . doom-modeline-init))
1208 #+end_src
1209
1210 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1211
1212 #+begin_src emacs-lisp :tangle no
1213 (use-package tao-theme
1214   :demand t
1215   :config (load-theme 'tao-yang t))
1216 #+end_src
1217
1218 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1219
1220 #+begin_src emacs-lisp
1221 (load-theme 'eink t)
1222 #+end_src
1223
1224 ** [[https://github.com/bbatsov/crux][crux]]
1225
1226 #+begin_src emacs-lisp
1227 (use-package crux
1228   :bind (("C-c d"    . crux-duplicate-current-line-or-region)
1229          ("C-c M-d"  . crux-duplicate-and-comment-current-line-or-region))
1230   :general
1231   (amin--leader-keys
1232    "bK" 'crux-kill-other-buffers
1233    "fc" 'crux-copy-file-preserve-attributes
1234    "fD" 'crux-delete-file-and-buffer
1235    "fR" 'crux-rename-file-and-buffer))
1236 #+end_src
1237
1238 ** [[https://github.com/alezost/mwim.el][mwim]]
1239
1240 #+begin_src emacs-lisp
1241 (use-package mwim
1242   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1243          ("C-e"    . mwim-end-of-code-or-line)
1244          ("<home>" . mwim-beginning-of-line-or-code)
1245          ("<end>"  . mwim-end-of-line-or-code))
1246   :general (:states '(normal visual)
1247     "0" 'mwim-beginning-of-code-or-line
1248     "$" 'mwim-end-of-code-or-line))
1249 #+end_src
1250
1251 * Email
1252 ** [[https://notmuchmail.org][notmuch]]
1253
1254 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1255
1256 #+begin_src emacs-lisp
1257 (defvar amin-maildir "~/mail")
1258
1259 (use-package sendmail
1260   ;; :ensure nil
1261   :config
1262   (setq sendmail-program "/usr/bin/msmtp"
1263         ; message-sendmail-extra-arguments '("-v" "-d")
1264         mail-specify-envelope-from t
1265         mail-envelope-from 'header))
1266
1267 (use-package message
1268   ;; :ensure nil
1269   :config
1270   (setq message-kill-buffer-on-exit t
1271         message-send-mail-function 'message-send-mail-with-sendmail
1272         message-sendmail-envelope-from 'header
1273         message-directory "drafts"
1274         message-user-fqdn "aminb.org")
1275   (add-hook 'message-mode-hook
1276             (lambda () (setq fill-column 65
1277                         message-fill-column 65)))
1278   (add-hook 'message-mode-hook
1279             #'flyspell-mode)
1280   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1281   ;; TODO: is there a way to only run this when replying and not composing?
1282   ;; (add-hook 'notmuch-message-mode-hook
1283   ;;           (lambda () (progn
1284   ;;                   (newline)
1285   ;;                   (newline)
1286   ;;                   (forward-line -1)
1287   ;;                   (forward-line -1))))
1288   ;; (add-hook 'message-setup-hook
1289   ;;           #'mml-secure-message-sign-pgpmime)
1290   )
1291
1292 (after! mml-sec
1293   (setq mml-secure-openpgp-encrypt-to-self t
1294         mml-secure-openpgp-sign-with-sender t))
1295
1296 (defun amin/notmuch ()
1297   "Delete other windows, then launch `notmuch'."
1298   (interactive)
1299   (delete-other-windows)
1300   (notmuch))
1301
1302 (use-package notmuch
1303   :general (amin--leader-keys "m" 'amin/notmuch)
1304   :commands notmuch
1305   :config
1306   (setq notmuch-hello-sections
1307         '(notmuch-hello-insert-header
1308           notmuch-hello-insert-saved-searches
1309           ;; notmuch-hello-insert-search
1310           notmuch-hello-insert-alltags)
1311         notmuch-search-oldest-first nil
1312         notmuch-show-all-tags-list t
1313         notmuch-message-headers  ; see bug follow-up above
1314         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1315         notmuch-hello-thousands-separator ","
1316         notmuch-fcc-dirs
1317         '(("amin@aminb.org"            . "amin/Sent")
1318           ("amin@gnu.org"              . "gnu/Sent")
1319           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1320           ("mab@gnu.org"               . "gnu/Sent")
1321           ("aminb@gnu.org"             . "gnu/Sent")
1322           (".*"                        . "sent"))
1323         notmuch-search-result-format
1324         '(("date" . "%12s ")
1325           ("count" . "%-7s ")
1326           ("authors" . "%-40s ")
1327           ("subject" . "%s ")
1328           ("tags" . "(%s)")))
1329   ;; (add-hook 'visual-fill-column-mode-hook
1330   ;;           (lambda ()
1331   ;;             (when (string= major-mode 'notmuch-message-mode)
1332   ;;               (setq visual-fill-column-width 70))))
1333   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1334   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1335   ;;             :override #'kill-this-buffer)
1336   :bind
1337   (:map notmuch-hello-mode-map
1338         ("g" . notmuch-poll-and-refresh-this-buffer)
1339         ("u" . (lambda ()
1340                  "Search for `unread' tagged messages"
1341                  (interactive)
1342                  (notmuch-hello-search "tag:unread")))
1343         ("i" . (lambda ()
1344                  "Search for `inbox' tagged messages"
1345                  (interactive)
1346                  (notmuch-hello-search "tag:inbox")))
1347         ("l" . (lambda ()
1348                  "Search for `latest' tagged messages"
1349                  (interactive)
1350                  (notmuch-hello-search "tag:latest")))
1351         ("e" . (lambda ()
1352                  "Search for `encrypted' tagged messages"
1353                  (interactive)
1354                  (notmuch-hello-search "tag:encrypted")))
1355         ("M" . (lambda ()
1356                  "Compose new mail and prompt for sender"
1357                  (interactive)
1358                  (let ((current-prefix-arg t))
1359                    (call-interactively #'notmuch-mua-new-mail)))))
1360   (:map notmuch-search-mode-map
1361         ("g" . notmuch-poll-and-refresh-this-buffer)
1362         ("k" . (lambda ()
1363                  "Mark message read"
1364                  (interactive)
1365                  (notmuch-search-tag '("-unread"))
1366                  ;; (notmuch-search-archive-thread)
1367                  (notmuch-search-next-thread)))
1368         ("u" . (lambda ()
1369                  "Mark message unread"
1370                  (interactive)
1371                  (notmuch-search-tag '("+unread"))
1372                  (notmuch-search-next-thread)))
1373         ("K" . (lambda ()
1374                  "Mark message deleted"
1375                  (interactive)
1376                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1377                  (notmuch-search-archive-thread)))
1378         ("S" . (lambda ()
1379                  "Mark message as spam"
1380                  (interactive)
1381                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1382                  (notmuch-search-archive-thread))))
1383   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1384         ("S" . (lambda ()
1385                  "Mark message as spam"
1386                  (interactive)
1387                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1388                  (notmuch-tree-archive-thread))))
1389 )
1390
1391 (use-package counsel-notmuch
1392   :general (amin--leader-keys "/m" 'counsel-notmuch))
1393
1394 (after! notmuch-crypto
1395   (setq notmuch-crypto-process-mime t))
1396
1397 ;; (after! evil
1398 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1399 ;;         '((notmuch-hello-mode . emacs)
1400 ;;           (notmuch-search-mode . emacs)
1401 ;;           (notmuch-tree-mode . emacs))))
1402
1403 (after! recentf
1404   (add-to-list 'recentf-exclude (expand-file-name amin-maildir)))
1405 #+end_src
1406
1407 ** supercite
1408
1409 #+begin_src emacs-lisp :tangle no
1410 (use-package supercite
1411   :commands sc-cite-original
1412   :init
1413   (add-hook 'mail-citation-hook 'sc-cite-original)
1414
1415   (defun sc-remove-existing-signature ()
1416     (save-excursion
1417       (goto-char (region-beginning))
1418       (when (re-search-forward message-signature-separator (region-end) t)
1419         (delete-region (match-beginning 0) (region-end)))))
1420
1421   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1422
1423   (defun sc-remove-if-not-mailing-list ()
1424     (unless (assoc "list-id" sc-mail-info)
1425       (setq attribution sc-default-attribution
1426             citation (concat sc-citation-delimiter
1427                              sc-citation-separator))))
1428
1429   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1430
1431   :config
1432   (defun sc-fill-if-different (&optional prefix)
1433     "Fill the region bounded by `sc-fill-begin' and point.
1434 Only fill if optional PREFIX is different than
1435 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1436 fill region.  If PREFIX is not supplied, initialize fill
1437 variables.  This is useful for a regi `begin' frame-entry."
1438     (if (not prefix)
1439         (setq sc-fill-line-prefix ""
1440               sc-fill-begin (line-beginning-position))
1441       (if (and sc-auto-fill-region-p
1442                (not (string= prefix sc-fill-line-prefix)))
1443           (let ((fill-prefix sc-fill-line-prefix))
1444             (unless (or (string= fill-prefix "")
1445                         (save-excursion
1446                           (goto-char sc-fill-begin)
1447                           (or (looking-at ">+  +")
1448                               (< (length
1449                                   (buffer-substring (point)
1450                                                     (line-end-position)))
1451                                  65))))
1452               (fill-region sc-fill-begin (line-beginning-position)))
1453             (setq sc-fill-line-prefix prefix
1454                   sc-fill-begin (line-beginning-position)))))
1455 nil))
1456 #+end_src
1457
1458 * Blogging
1459 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1460
1461 #+begin_src emacs-lisp
1462 (use-package ox-hugo
1463   :after ox)
1464 #+end_src
1465
1466 * Post initialization
1467 :PROPERTIES:
1468 :CUSTOM_ID: post-initialization
1469 :END:
1470
1471 Display how long it took to load the init file.
1472
1473 #+begin_src emacs-lisp
1474 (message "Loading %s...done (%.3fs)" user-init-file
1475          (float-time (time-subtract (current-time)
1476                                     amin--before-user-init-time)))
1477 #+end_src
1478
1479 * Footer
1480 :PROPERTIES:
1481 :CUSTOM_ID: footer
1482 :END:
1483
1484 #+begin_src emacs-lisp :comments none
1485 ;;; init.el ends here
1486 #+end_src