git.shemshak.org - ~bandali/configs/blob - init.org

   1 #+title: =aminb='s Literate Emacs Configuration
   2 #+author: Amin Bandali
   3 #+babel: :cache yes
   4 #+property: header-args :tangle yes
   5
   6 * About
   7 :PROPERTIES:
   8 :CUSTOM_ID: about
   9 :END:
  10
  11 This org file is my literate configuration for GNU Emacs, and is
  12 tangled to [[./init.el][init.el]]. Packages are installed and managed using
  13 [[https://github.com/emacscollective/borg][Borg]]. Over the years, I've taken inspiration from configurations of
  14 many different people. Some of the configurations that I can remember
  15 off the top of my head are:
  16
  17 - [[https://github.com/dieggsy/dotfiles][dieggsy/dotfiles]]: literate Emacs and dotfiles configuration, uses
  18   straight.el for managing packages
  19 - [[https://github.com/dakra/dmacs][dakra/dmacs]]: literate Emacs configuration, using Borg for managing
  20   packages
  21 - [[http://pages.sachachua.com/.emacs.d/Sacha.html][Sacha Chua's literate Emacs configuration]]
  22 - [[https://github.com/dakrone/eos][dakrone/eos]]
  23 - Ryan Rix's [[http://doc.rix.si/cce/cce.html][Complete Computing Environment]] ([[http://doc.rix.si/projects/fsem.html][about cce]])
  24 - [[https://github.com/jwiegley/dot-emacs][jwiegley/dot-emacs]]: nix-based configuration
  25 - [[https://github.com/wasamasa/dotemacs][wasamasa/dotemacs]]
  26 - [[https://github.com/hlissner/doom-emacs][Doom Emacs]]
  27
  28 I'd like to have a fully reproducible Emacs setup (part of the reason
  29 why I store my configuration in this repository) but unfortunately out
  30 of the box, that's not achievable with =package.el=, not currently
  31 anyway. So, I've opted to use Borg. For what it's worth, I briefly
  32 experimented with [[https://github.com/raxod502/straight.el][straight.el]], but found that it added about 2 seconds
  33 to my init time; which is unacceptable for me: I use Emacs as my
  34 window manager (via EXWM) and coming from bspwm, I'm too used to
  35 having fast startup times.
  36
  37 ** Installation
  38
  39 To use this config for your Emacs, first you need to clone this repo,
  40 then bootstrap Borg, tell Borg to retrieve package submodules, and
  41 byte-compiled the packages. Something along these lines should work:
  42
  43 #+begin_src sh :tangle no
  44 git clone https://github.com/aminb/dotfiles ~/.emacs.d
  45 cd ~/.emacs.d
  46 make bootstrap-borg
  47 make bootstrap
  48 make build
  49 #+end_src
  50
  51 * Contents                                                   :toc_1:noexport:
  52
  53 - [[#about][About]]
  54 - [[#header][Header]]
  55 - [[#initial-setup][Initial setup]]
  56 - [[#core][Core]]
  57 - [[#post-initialization][Post initialization]]
  58 - [[#footer][Footer]]
  59
  60 * Header
  61 :PROPERTIES:
  62 :CUSTOM_ID: header
  63 :END:
  64
  65 ** First line
  66
  67 #+begin_src emacs-lisp :comments none
  68 ;;; init.el --- Amin Bandali's Emacs config -*- lexical-binding: t ; eval: (view-mode 1)-*-
  69 #+end_src
  70
  71 Enable =view-mode=, which both makes the file read-only (as a reminder
  72 that =init.el= is an auto-generated file, not supposed to be edited),
  73 and provides some convenient key bindings for browsing through the
  74 file.
  75
  76 ** License
  77
  78 #+begin_src emacs-lisp :comments none
  79 ;; Copyright (C) 2018  Amin Bandali <amin@aminb.org>
  80
  81 ;; This program is free software: you can redistribute it and/or modify
  82 ;; it under the terms of the GNU General Public License as published by
  83 ;; the Free Software Foundation, either version 3 of the License, or
  84 ;; (at your option) any later version.
  85
  86 ;; This program is distributed in the hope that it will be useful,
  87 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  88 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  89 ;; GNU General Public License for more details.
  90
  91 ;; You should have received a copy of the GNU General Public License
  92 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
  93 #+end_src
  94
  95 ** Commentary
  96
  97 #+begin_src emacs-lisp :comments none
  98 ;;; Commentary:
  99
 100 ;; Emacs configuration of Amin Bandali, computer scientist and functional
 101 ;; programmer.
 102
 103 ;; THIS FILE IS AUTO-GENERATED FROM `init.org'.
 104 #+end_src
 105
 106 ** Naming conventions
 107
 108 The conventions below were inspired by [[https://github.com/hlissner/doom-emacs][Doom]]'s conventions, found
 109 [[https://github.com/hlissner/doom-emacs/blob/5dacbb7cb1c6ac246a9ccd15e6c4290def67757c/core/core.el#L3-L17][here]]. Naturally, I use my initials, =ab=, instead of =doom=.
 110
 111 #+begin_src emacs-lisp :comments none
 112 ;; Naming conventions:
 113 ;;
 114 ;;   ab-...   public variables or non-interactive functions
 115 ;;   ab--...  private anything (non-interactive), not safe for direct use
 116 ;;   ab/...   an interactive function; safe for M-x or keybinding
 117 ;;   ab:...   an evil operator, motion, or command
 118 ;;   ab|...   a hook function
 119 ;;   ab*...   an advising function
 120 ;;   ab@...   a hydra command
 121 ;;   ...!     a macro
 122 #+end_src
 123
 124 * Initial setup
 125 :PROPERTIES:
 126 :CUSTOM_ID: initial-setup
 127 :END:
 128
 129 #+begin_src emacs-lisp :comments none
 130 ;;; Code:
 131 #+end_src
 132
 133 ** Emacs initialization
 134
 135 I'd like to do a couple of measurements of Emacs' startup time. First,
 136 let's see how long Emacs takes to start up, before even loading
 137 =init.el=, i.e. =user-init-file=:
 138
 139 #+begin_src emacs-lisp
 140 (defvar ab--before-user-init-time (current-time)
 141   "Value of `current-time' when Emacs begins loading `user-init-file'.")
 142 (message "Loading Emacs...done (%.3fs)"
 143          (float-time (time-subtract ab--before-user-init-time
 144                                     before-init-time)))
 145 #+end_src
 146
 147 Also, temporarily increase ~gc-cons-threshhold~ and
 148 ~gc-cons-percentage~ during startup to reduce garbage collection
 149 frequency. Clearing the ~file-name-handler-alist~ seems to help reduce
 150 startup time as well.
 151
 152 #+begin_src emacs-lisp
 153 (defvar ab--gc-cons-threshold gc-cons-threshold)
 154 (defvar ab--gc-cons-percentage gc-cons-percentage)
 155 (defvar ab--file-name-handler-alist file-name-handler-alist)
 156 (setq gc-cons-threshold (* 400 1024 1024)  ; 400 MiB
 157       gc-cons-percentage 0.6
 158       file-name-handler-alist nil
 159       ;; sidesteps a bug when profiling with esup
 160       esup-child-profile-require-level 0)
 161 #+end_src
 162
 163 Of course, we'd like to set them back to their defaults once we're
 164 done initializing.
 165
 166 #+begin_src emacs-lisp
 167 (add-hook
 168  'after-init-hook
 169  (lambda ()
 170    (setq gc-cons-threshold ab--gc-cons-threshold
 171          gc-cons-percentage ab--gc-cons-percentage
 172          file-name-handler-alist ab--file-name-handler-alist)))
 173 #+end_src
 174
 175 Increase the number of lines kept in message logs (the =*Messages*=
 176 buffer).
 177
 178 #+begin_src emacs-lisp
 179 (setq message-log-max 20000)
 180 #+end_src
 181
 182 Optionally, we could suppress some byte compiler warnings like below,
 183 but for now I've decided to keep them enabled. See documentation for
 184 ~byte-compile-warnings~ for more details.
 185
 186 #+begin_src emacs-lisp
 187 ;; (setq byte-compile-warnings
 188 ;;       '(not free-vars unresolved noruntime lexical make-local))
 189 #+end_src
 190
 191 ** whoami
 192
 193 #+begin_src emacs-lisp
 194 (setq user-full-name "Amin Bandali"
 195       user-mail-address "amin@aminb.org")
 196 #+end_src
 197
 198 ** Package management
 199
 200 *** No =package.el=
 201
 202 I can do all my package management things with Borg, and don't need
 203 Emacs' built-in =package.el=. Emacs 27 lets us disable =package.el= in
 204 the =early-init-file= (see [[https://git.savannah.gnu.org/cgit/emacs.git/commit/?id=24acb31c04b4048b85311d794e600ecd7ce60d3b][here]]).
 205
 206 #+begin_src emacs-lisp :tangle early-init.el
 207 (setq package-enable-at-startup nil)
 208 #+end_src
 209
 210 But since Emacs 27 isn't out yet (Emacs 26 is just around the corner
 211 right now), and even when released it'll be long before most distros
 212 ship in their repos, I'll still put the old workaround with the
 213 commented call to ~package-initialize~ here anyway.
 214
 215 #+begin_src emacs-lisp
 216 (setq package-enable-at-startup nil)
 217 ;; (package-initialize)
 218 #+end_src
 219
 220 *** Borg
 221
 222 #+begin_quote
 223 Assimilate Emacs packages as Git submodules
 224 #+end_quote
 225
 226 [[https://github.com/emacscollective/borg][Borg]] is at the heart of package management of my Emacs setup. In
 227 short, it creates a git submodule in =lib/= for each package, which
 228 can then be managed with the help of Magit or other tools.
 229
 230 #+begin_src emacs-lisp
 231 (setq user-init-file (or load-file-name buffer-file-name)
 232       user-emacs-directory (file-name-directory user-init-file))
 233 (add-to-list 'load-path
 234              (expand-file-name "lib/borg" user-emacs-directory))
 235 (require 'borg)
 236 (borg-initialize)
 237 #+end_src
 238
 239 *** =use-package=
 240
 241 #+begin_quote
 242 A use-package declaration for simplifying your .emacs
 243 #+end_quote
 244
 245 [[https://github.com/jwiegley/use-package][use-package]] is an awesome utility for managing and configuring
 246 packages (in our case especially the latter) in a neatly organized way
 247 and without compromising on performance.
 248
 249 #+begin_src emacs-lisp
 250 (require 'use-package)
 251 (if nil  ; set to t when need to debug init
 252     (setq use-package-verbose t
 253           use-package-expand-minimally nil
 254           use-package-compute-statistics t
 255           debug-on-error t)
 256   (setq use-package-verbose nil
 257         use-package-expand-minimally t))
 258 #+end_src
 259
 260 *** Epkg
 261
 262 #+begin_quote
 263 Browse the Emacsmirror package database
 264 #+end_quote
 265
 266 Epkg provides access to a local copy of the [[https://emacsmirror.net][Emacsmirror]] package
 267 database, low-level functions for querying the database, and a
 268 =package.el=-like user interface for browsing the available packages.
 269
 270 #+begin_src emacs-lisp
 271 (use-package epkg
 272   :defer t)
 273 #+end_src
 274
 275 ** No littering in =~/.emacs.d=
 276
 277 #+begin_quote
 278 Help keeping ~/.emacs.d clean
 279 #+end_quote
 280
 281 By default, even for Emacs' built-in packages, the configuration files
 282 and persistent data are all over the place. Use =no-littering= to help
 283 contain the mess.
 284
 285 #+begin_src emacs-lisp
 286 (use-package no-littering
 287   :demand t
 288   :config
 289   (savehist-mode 1)
 290   (add-to-list 'savehist-additional-variables 'kill-ring)
 291   (save-place-mode 1)
 292   (setq auto-save-file-name-transforms
 293         `((".*" ,(no-littering-expand-var-file-name "auto-save/") t))))
 294 #+end_src
 295
 296 ** Custom file (=custom.el=)
 297
 298 I'm not planning on using the custom file much, but even so, I
 299 definitely don't want it mixing with =init.el=. So, here; let's give
 300 it it's own file. While at it, treat themes as safe.
 301
 302 #+begin_src emacs-lisp
 303 (use-package custom
 304   :no-require t
 305   :config
 306   (setq custom-file (no-littering-expand-etc-file-name "custom.el"))
 307   (when (file-exists-p custom-file)
 308     (load custom-file))
 309   (setf custom-safe-themes t))
 310 #+end_src
 311
 312 ** Better =$PATH= handling
 313
 314 Let's use [[https://github.com/purcell/exec-path-from-shell][exec-path-from-shell]] to make Emacs use the =$PATH= as set up
 315 in my shell.
 316
 317 #+begin_src emacs-lisp
 318 (use-package exec-path-from-shell
 319   :defer 1
 320   :init
 321   (setq exec-path-from-shell-check-startup-files nil)
 322   :config
 323   (exec-path-from-shell-initialize)
 324   ;; while we're at it, let's fix access to our running ssh-agent
 325   (exec-path-from-shell-copy-env "SSH_AGENT_PID")
 326   (exec-path-from-shell-copy-env "SSH_AUTH_SOCK"))
 327 #+end_src
 328
 329 ** Only one custom theme at a time
 330
 331 #+begin_src emacs-lisp
 332 (defadvice load-theme (before clear-previous-themes activate)
 333   "Clear existing theme settings instead of layering them"
 334   (mapc #'disable-theme custom-enabled-themes))
 335 #+end_src
 336
 337 ** Server
 338
 339 Start server if not already running. Alternatively, can be done by
 340 issuing =emacs --daemon= in the terminal, which can be automated with
 341 a systemd service or using =brew services start emacs= on macOS. I use
 342 Emacs as my window manager (via EXWM), so I always start Emacs on
 343 login; so starting the server from inside Emacs is good enough for me.
 344
 345 See [[https://www.gnu.org/software/emacs/manual/html_node/emacs/Emacs-Server.html#Emacs-Server][Using Emacs as a Server]].
 346
 347 #+begin_src emacs-lisp
 348 (use-package server
 349   :config (or (server-running-p) (server-mode)))
 350 #+end_src
 351
 352 ** Unicode support
 353
 354 Font stack with better unicode support, around =Ubuntu Mono= and
 355 =Hack=.
 356
 357 #+begin_src emacs-lisp
 358 (dolist (ft (fontset-list))
 359   (set-fontset-font
 360    ft
 361    'unicode
 362    (font-spec :name "Ubuntu Mono"))
 363   (set-fontset-font
 364    ft
 365    'unicode
 366    (font-spec :name "DejaVu Sans Mono")
 367    nil
 368    'append)
 369   ;; (set-fontset-font
 370   ;;  ft
 371   ;;  'unicode
 372   ;;  (font-spec
 373   ;;   :name "Symbola monospacified for DejaVu Sans Mono")
 374   ;;  nil
 375   ;;  'append)
 376   ;; (set-fontset-font
 377   ;;  ft
 378   ;;  #x2115  ; ℕ
 379   ;;  (font-spec :name "DejaVu Sans Mono")
 380   ;;  nil
 381   ;;  'append)
 382   (set-fontset-font
 383    ft
 384    (cons ?Α ?ω)
 385    (font-spec :name "DejaVu Sans Mono" :size 14)
 386    nil
 387    'prepend))
 388 #+end_src
 389
 390 ** Libraries
 391
 392 #+begin_src emacs-lisp
 393 (require 'cl-lib)
 394 (require 'subr-x)
 395 #+end_src
 396
 397 ** Useful utilities
 398
 399 #+begin_src emacs-lisp
 400 (defun ab-enlist (exp)
 401   "Return EXP wrapped in a list, or as-is if already a list."
 402 (if (listp exp) exp (list exp)))
 403
 404 ; from https://github.com/hlissner/doom-emacs/commit/589108fdb270f24a98ba6209f6955fe41530b3ef
 405 (defmacro after! (features &rest body)
 406   "A smart wrapper around `with-eval-after-load'. Supresses warnings during
 407 compilation."
 408   (declare (indent defun) (debug t))
 409   (list (if (or (not (bound-and-true-p byte-compile-current-file))
 410                 (dolist (next (ab-enlist features))
 411                   (if (symbolp next)
 412                       (require next nil :no-error)
 413                     (load next :no-message :no-error))))
 414             #'progn
 415           #'with-no-warnings)
 416         (cond ((symbolp features)
 417                `(eval-after-load ',features '(progn ,@body)))
 418               ((and (consp features)
 419                     (memq (car features) '(:or :any)))
 420                `(progn
 421                   ,@(cl-loop for next in (cdr features)
 422                              collect `(after! ,next ,@body))))
 423               ((and (consp features)
 424                     (memq (car features) '(:and :all)))
 425                (dolist (next (cdr features))
 426                  (setq body `(after! ,next ,@body)))
 427                body)
 428               ((listp features)
 429                `(after! (:all ,@features) ,@body)))))
 430 #+end_src
 431
 432 * Core
 433 :PROPERTIES:
 434 :CUSTOM_ID: core
 435 :END:
 436
 437 ** Defaults
 438
 439 *** Time and battery in mode-line
 440
 441 Enable displaying time and battery in the mode-line, since I'm not
 442 using the Xfce panel anymore. Also, I don't need to see the load
 443 average on a regular basis, so disable that.
 444
 445 #+begin_src emacs-lisp
 446 (use-package time
 447   :ensure nil
 448   :init
 449   (setq display-time-default-load-average nil)
 450   :config
 451   (display-time-mode))
 452
 453 (use-package battery
 454   :ensure nil
 455   :config
 456   (display-battery-mode))
 457 #+end_src
 458
 459 *** Smaller fringe
 460
 461 Might want to set the fringe to a smaller value, especially if using
 462 EXWM. I'm fine with the default for now.
 463
 464 #+begin_src emacs-lisp
 465 ;; (fringe-mode '(3 . 1))
 466 (fringe-mode nil)
 467 #+end_src
 468
 469 *** Disable disabled commands
 470
 471 Emacs disables some commands by default that could persumably be
 472 confusing for novice users. Let's disable that.
 473
 474 #+begin_src emacs-lisp
 475 (setq disabled-command-function nil)
 476 #+end_src
 477
 478 *** Kill-ring
 479
 480 Save what I copy into clipboard from other applications into Emacs'
 481 kill-ring, which would allow me to still be able to easily access it
 482 in case I kill (cut or copy) something else inside Emacs before
 483 yanking (pasting) what I'd originally intended to.
 484
 485 #+begin_src emacs-lisp
 486 (setq save-interprogram-paste-before-kill t)
 487 #+end_src
 488
 489 *** Minibuffer
 490
 491 #+begin_src emacs-lisp
 492 (setq enable-recursive-minibuffers t
 493       resize-mini-windows t)
 494 #+end_src
 495
 496 *** Lazy-person-friendly yes/no prompts
 497
 498 Lazy people would prefer to type fewer keystrokes, especially for yes
 499 or no questions. I'm lazy.
 500
 501 #+begin_src emacs-lisp
 502 (defalias 'yes-or-no-p #'y-or-n-p)
 503 #+end_src
 504
 505 *** Startup screen and =*scratch*=
 506
 507 Firstly, let Emacs know that I'd like to have =*scratch*= as my
 508 startup buffer.
 509
 510 #+begin_src emacs-lisp
 511 (setq initial-buffer-choice t)
 512 #+end_src
 513
 514 Now let's customize the =*scratch*= buffer a bit. First off, I don't
 515 need the default hint.
 516
 517 #+begin_src emacs-lisp
 518 (setq initial-scratch-message nil)
 519 #+end_src
 520
 521 Also, let's use Text mode as the major mode, in case I want to
 522 customize it (=*scratch*='s default major mode, Fundamental mode,
 523 can't really be customized).
 524
 525 #+begin_src emacs-lisp
 526 (setq initial-major-mode 'text-mode)
 527 #+end_src
 528
 529 Inhibit the buffer list when more than 2 files are loaded.
 530
 531 #+begin_src emacs-lisp
 532 (setq inhibit-startup-buffer-menu t)
 533 #+end_src
 534
 535 I don't really need to see the startup screen or echo area message
 536 either.
 537
 538 #+begin_src emacs-lisp
 539 (advice-add #'display-startup-echo-area-message :override #'ignore)
 540 (setq inhibit-startup-screen t
 541       inhibit-startup-echo-area-message user-login-name)
 542 #+end_src
 543
 544 *** More useful frame titles
 545
 546 Show either the file name or the buffer name (in case the buffer isn't
 547 visiting a file). Borrowed from Emacs Prelude.
 548
 549 #+begin_src emacs-lisp
 550 (setq frame-title-format
 551       '("" invocation-name " - "
 552         (:eval (if (buffer-file-name)
 553                    (abbreviate-file-name (buffer-file-name))
 554                  "%b"))))
 555 #+end_src
 556
 557 *** Backups
 558
 559 Emacs' default backup settings aren't that great. Let's use more
 560 sensible options. See documentation for the ~make-backup-file~
 561 variable.
 562
 563 #+begin_src emacs-lisp
 564 (setq backup-by-copying t
 565       version-control t)
 566 #+end_src
 567
 568 *** Auto revert
 569
 570 Enable automatic reloading of changed buffers and files.
 571
 572 #+begin_src emacs-lisp
 573 (global-auto-revert-mode 1)
 574 (setq auto-revert-verbose nil
 575       global-auto-revert-non-file-buffers t)
 576 #+end_src
 577
 578 *** Always use space for indentation
 579
 580 #+begin_src emacs-lisp
 581 (setq-default
 582  indent-tabs-mode nil
 583  require-final-newline t
 584  tab-width 4)
 585 #+end_src
 586
 587 ** Packages
 588
 589 The packages in this section are absolutely essential to my everyday
 590 workflow, and they play key roles in how I do my computing. They
 591 immensely enhance the Emacs experience for me; both using Emacs, and
 592 customizing it.
 593
 594 *** [[https://github.com/emacscollective/auto-compile][auto-compile]]
 595
 596 #+begin_src emacs-lisp
 597 (use-package auto-compile
 598   :demand t
 599   :config
 600   (auto-compile-on-load-mode)
 601   (auto-compile-on-save-mode)
 602   (setq auto-compile-display-buffer               nil
 603         auto-compile-mode-line-counter            t
 604         auto-compile-source-recreate-deletes-dest t
 605         auto-compile-toggle-deletes-nonlib-dest   t
 606         auto-compile-update-autoloads             t)
 607   (add-hook 'auto-compile-inhibit-compile-hook
 608             'auto-compile-inhibit-compile-detached-git-head))
 609 #+end_src
 610
 611 *** [[https://github.com/Kungsgeten/ryo-modal][ryo-modal]]
 612
 613 #+begin_quote
 614 Roll your own modal mode
 615 #+end_quote
 616
 617 #+begin_src emacs-lisp
 618 (use-package ryo-modal
 619   :commands ryo-modal-mode
 620   :bind ("M-m" . ryo-modal-mode)
 621   :after which-key
 622   :config
 623   (push '((nil . "ryo:.*:") . (nil . "")) which-key-replacement-alist)
 624   (ryo-modal-keys
 625    ("," ryo-modal-repeat)
 626    ("b" backward-char)
 627    ("n" next-line)
 628    ("p" previous-line)
 629    ("f" forward-char)
 630    ("/" undo)
 631    ("i" ryo-modal-mode)
 632    ("l" recenter-top-bottom)
 633    ("v" scroll-up-command)
 634    ("V" scroll-down-command)
 635    ("x" delete-forward-char)
 636    ("SPC" (("b" (("b" ibuffer-list-buffers)
 637                  ("k" kill-this-buffer)
 638                  ("o" other-window)
 639                  ("s" save-buffer)))
 640            ("B" (("A" borg-activate)
 641                  ("a" borg-assimilate)
 642                  ("b" borg-build)
 643                  ("c" borg-clone)
 644                  ("r" borg-remove)))
 645            ("h" (("c" describe-char)
 646                  ("f" describe-function)
 647                  ("F" describe-face)
 648                  ("i" info)
 649                  ("k" describe-key)
 650                  ("l" view-lossage)
 651                  ("v" describe-variable)))
 652            ("q" (("q" save-buffers-kill-terminal)))))
 653    ("d" (("w" kill-word)
 654          ("b" backward-kill-word)))
 655    ("c w" kill-word :exit t))
 656
 657   (ryo-modal-keys
 658    ;; First argyment to ryo-modal-keys may be a list of keywords.
 659    ;; These keywords will be applied to all keybindings.
 660    (:norepeat t)
 661    ("0" "M-0")
 662    ("1" "M-1")
 663    ("2" "M-2")
 664    ("3" "M-3")
 665    ("4" "M-4")
 666    ("5" "M-5")
 667    ("6" "M-6")
 668    ("7" "M-7")
 669    ("8" "M-8")
 670    ("9" "M-9"))
 671   :hook ((text-mode . ryo-modal-mode)
 672          (prog-mode . ryo-modal-mode)))
 673 #+end_src
 674
 675 *** [[https://orgmode.org/][Org mode]]
 676
 677 #+begin_quote
 678 Org mode is for keeping notes, maintaining TODO lists, planning
 679 projects, and authoring documents with a fast and effective plain-text
 680 system.
 681 #+end_quote
 682
 683 In short, my favourite way of life.
 684
 685 #+begin_src emacs-lisp
 686 (use-package org
 687   :ryo ("SPC b t" org-babel-tangle)
 688   :config
 689   (setq org-src-tab-acts-natively t
 690         org-src-preserve-indentation nil
 691         org-edit-src-content-indentation 0
 692         org-html-divs '((preamble  "header" "preamble")
 693                         (content   "main"   "content")
 694                         (postamble "footer" "postamble"))
 695         org-html-doctype "html5"
 696         org-html-html5-fancy t
 697         org-html-postamble nil)
 698   :hook (org-mode . org-indent-mode))
 699 (use-package htmlize
 700   :after org)
 701 (use-package org-notmuch
 702   :after (:any org notmuch))
 703 #+end_src
 704
 705 *** [[https://magit.vc/][Magit]]
 706
 707 #+begin_quote
 708 It's Magit! A Git porcelain inside Emacs.
 709 #+end_quote
 710
 711 Not just how I do git, but /the/ way to do git.
 712
 713 #+begin_src emacs-lisp
 714 (use-package magit
 715   :ryo ("SPC" (("g s" magit-status)))
 716   :defer t
 717   :bind (("s-g"     . magit-status)
 718          ("C-x g"   . magit-status)
 719          ("C-x M-g" . magit-dispatch-popup))
 720   :config
 721   (magit-add-section-hook 'magit-status-sections-hook
 722                           'magit-insert-modules
 723                           'magit-insert-stashes
 724                           'append))
 725 #+end_src
 726
 727 *** [[https://github.com/abo-abo/swiper][Ivy]] (and friends)
 728
 729 #+begin_quote
 730 Ivy - a generic completion frontend for Emacs, Swiper - isearch with
 731 an overview, and more. Oh, man!
 732 #+end_quote
 733
 734 There's no way I could top that, so I won't attempt to.
 735
 736 **** Ivy
 737
 738 #+begin_src emacs-lisp
 739 (use-package ivy
 740   :defer 1
 741   :bind
 742   (:map ivy-minibuffer-map
 743         ([escape] . keyboard-escape-quit)
 744         ;; ("C-j"    . ivy-next-line)
 745         ;; ("C-k"    . ivy-previous-line)
 746         ([S-up]   . ivy-previous-history-element)
 747         ([S-down] . ivy-next-history-element)
 748         ("DEL"    . ivy-backward-delete-char))
 749   :ryo ("SPC ," ivy-switch-buffer)
 750   :config
 751   (setq ivy-wrap t)
 752   (ivy-mode 1))
 753 #+end_src
 754
 755 **** Swiper
 756
 757 #+begin_src emacs-lisp
 758 (use-package swiper
 759   :ryo
 760   ("SPC /" swiper)
 761   ("s" swiper)
 762   :bind (([remap isearch-forward]  . swiper)
 763          ([remap isearch-backward] . swiper)))
 764 #+end_src
 765
 766 **** Counsel
 767
 768 #+begin_src emacs-lisp
 769 (use-package counsel
 770   :defer 1
 771   :ryo
 772   ("SPC" (("f r" counsel-recentf)
 773           ("SPC" counsel-M-x)
 774           ("."   counsel-find-file)))
 775   :bind (([remap execute-extended-command] . counsel-M-x)
 776          ([remap find-file] . counsel-find-file)
 777          ("s-r"     . counsel-recentf)
 778          :map minibuffer-local-map
 779          ("C-r" . counsel-minibuffer-history))
 780   :config
 781   (counsel-mode 1)
 782   (defalias 'locate #'counsel-locate))
 783 #+end_src
 784
 785 * Borg's =layer/essentials=
 786
 787 TODO: break this giant source block down into individual org sections.
 788
 789 #+begin_src emacs-lisp
 790 (use-package dash
 791   :config (dash-enable-font-lock))
 792
 793 (use-package diff-hl
 794   :config
 795   (setq diff-hl-draw-borders nil)
 796   (global-diff-hl-mode)
 797   (add-hook 'magit-post-refresh-hook 'diff-hl-magit-post-refresh t))
 798
 799 (use-package dired
 800   :defer t
 801   :config (setq dired-listing-switches "-alh"))
 802
 803 (use-package eldoc
 804   :when (version< "25" emacs-version)
 805   :config (global-eldoc-mode))
 806
 807 (use-package help
 808   :defer t
 809   :config (temp-buffer-resize-mode))
 810
 811 (progn ;    `isearch'
 812   (setq isearch-allow-scroll t))
 813
 814 (use-package lisp-mode
 815   :config
 816   (add-hook 'emacs-lisp-mode-hook 'outline-minor-mode)
 817   (add-hook 'emacs-lisp-mode-hook 'reveal-mode)
 818   (defun indent-spaces-mode ()
 819     (setq indent-tabs-mode nil))
 820   (add-hook 'lisp-interaction-mode-hook #'indent-spaces-mode))
 821
 822 (use-package man
 823   :defer t
 824   :config (setq Man-width 80))
 825
 826 (use-package paren
 827   :config (show-paren-mode))
 828
 829 (use-package prog-mode
 830   :config (global-prettify-symbols-mode)
 831   (defun indicate-buffer-boundaries-left ()
 832     (setq indicate-buffer-boundaries 'left))
 833   (add-hook 'prog-mode-hook #'indicate-buffer-boundaries-left))
 834
 835 (use-package recentf
 836   :demand t
 837   :config (add-to-list 'recentf-exclude "^/\\(?:ssh\\|su\\|sudo\\)?:"))
 838
 839 (use-package savehist
 840   :config (savehist-mode))
 841
 842 (use-package saveplace
 843   :when (version< "25" emacs-version)
 844   :config (save-place-mode))
 845
 846 (use-package simple
 847   :config (column-number-mode))
 848
 849 (progn ;    `text-mode'
 850   (add-hook 'text-mode-hook #'indicate-buffer-boundaries-left))
 851
 852 (use-package tramp
 853   :defer t
 854   :config
 855   (add-to-list 'tramp-default-proxies-alist '(nil "\\`root\\'" "/ssh:%h:"))
 856   (add-to-list 'tramp-default-proxies-alist '("localhost" nil nil))
 857   (add-to-list 'tramp-default-proxies-alist
 858                (list (regexp-quote (system-name)) nil nil)))
 859
 860 (use-package undo-tree
 861   :ryo
 862   ("?" undo-tree-undo)
 863   ("_" undo-tree-redo)
 864   :bind (("C-?" . undo-tree-undo)
 865          ("M-_" . undo-tree-redo))
 866   :config
 867   (global-undo-tree-mode)
 868   (setq undo-tree-mode-lighter ""
 869         undo-tree-auto-save-history t))
 870 #+end_src
 871
 872 * Editing
 873
 874 ** Company
 875
 876 #+begin_src emacs-lisp
 877 (use-package company
 878   :defer 5
 879   :bind
 880   (:map company-active-map
 881         ([tab] . company-complete-common-or-cycle))
 882   :custom
 883   (company-idle-delay 0.3)
 884   (company-minimum-prefix-length 1)
 885   (company-selection-wrap-around t)
 886   (company-dabbrev-char-regexp "\\sw\\|\\s_\\|[-_]")
 887   :config
 888   (global-company-mode t))
 889 #+end_src
 890
 891 * Syntax and spell checking
 892 #+begin_src emacs-lisp
 893 (use-package flycheck
 894   :hook (prog-mode . flycheck-mode)
 895   :config
 896   ;; Use the load-path from running Emacs when checking elisp files
 897   (setq flycheck-emacs-lisp-load-path 'inherit)
 898
 899   ;; Only flycheck when I actually save the buffer
 900   (setq flycheck-check-syntax-automatically '(mode-enabled save)))
 901 #+end_src
 902 * Programming modes
 903
 904 ** [[http://alloytools.org][Alloy]] (with [[https://github.com/dwwmmn/alloy-mode][alloy-mode]])
 905
 906 #+begin_src emacs-lisp
 907 (use-package alloy-mode
 908   :config (setq alloy-basic-offset 2))
 909 #+end_src
 910
 911 ** [[https://coq.inria.fr][Coq]] (with [[https://github.com/ProofGeneral/PG][Proof General]])
 912
 913 #+begin_src emacs-lisp
 914 (use-package proof-site  ; Proof General
 915   :load-path "lib/proof-site/generic/")
 916 #+end_src
 917
 918 ** [[https://leanprover.github.io][Lean]] (with [[https://github.com/leanprover/lean-mode][lean-mode]])
 919
 920 #+begin_src emacs-lisp
 921 (use-package lean-mode
 922   :bind (:map lean-mode-map
 923               ("S-SPC" . company-complete)))
 924 #+end_src
 925
 926 ** Haskell
 927
 928 *** [[https://github.com/haskell/haskell-mode][haskell-mode]]
 929
 930 #+begin_src emacs-lisp
 931 (use-package haskell-mode
 932   :config
 933   (setq haskell-indentation-layout-offset 4
 934         haskell-indentation-left-offset 4
 935         flycheck-checker 'haskell-hlint
 936         flycheck-disabled-checkers '(haskell-stack-ghc haskell-ghc)))
 937 #+end_src
 938
 939 *** [[https://github.com/jyp/dante][dante]]
 940
 941 #+begin_src emacs-lisp
 942 (use-package dante
 943   :after haskell-mode
 944   :commands dante-mode
 945   :hook (haskell-mode . dante-mode))
 946 #+end_src
 947
 948 *** [[https://github.com/mpickering/hlint-refactor-mode][hlint-refactor]]
 949
 950 Emacs bindings for [[https://github.com/ndmitchell/hlint][hlint]]'s refactor option. This requires the refact
 951 executable from [[https://github.com/mpickering/apply-refact][apply-refact]].
 952
 953 #+begin_src emacs-lisp
 954 (use-package hlint-refactor
 955   :bind (:map hlint-refactor-mode-map
 956               ("C-c l b" . hlint-refactor-refactor-buffer)
 957               ("C-c l r" . hlint-refactor-refactor-at-point))
 958   :hook (haskell-mode . hlint-refactor-mode))
 959 #+end_src
 960
 961 *** [[https://github.com/flycheck/flycheck-haskell][flycheck-haskell]]
 962
 963 #+begin_src emacs-lisp
 964 (use-package flycheck-haskell)
 965 #+end_src
 966
 967 *** [[https://github.com/ndmitchell/hlint/blob/20e116a043f2073c57b17b24ae6364b5e433ba7e/data/hs-lint.el][hs-lint.el]]
 968 :PROPERTIES:
 969 :header-args+: :tangle lisp/hs-lint.el :mkdirp yes
 970 :END:
 971
 972 Currently using =flycheck-haskell= with the =haskell-hlint= checker
 973 instead.
 974
 975 #+begin_src emacs-lisp :tangle no
 976 ;;; hs-lint.el --- minor mode for HLint code checking
 977
 978 ;; Copyright 2009 (C) Alex Ott
 979 ;;
 980 ;; Author: Alex Ott <alexott@gmail.com>
 981 ;; Keywords: haskell, lint, HLint
 982 ;; Requirements:
 983 ;; Status: distributed under terms of GPL2 or above
 984
 985 ;; Typical message from HLint looks like:
 986 ;;
 987 ;; /Users/ott/projects/lang-exp/haskell/test.hs:52:1: Eta reduce
 988 ;; Found:
 989 ;;   count1 p l = length (filter p l)
 990 ;; Why not:
 991 ;;   count1 p = length . filter p
 992
 993
 994 (require 'compile)
 995
 996 (defgroup hs-lint nil
 997   "Run HLint as inferior of Emacs, parse error messages."
 998   :group 'tools
 999   :group 'haskell)
1000
1001 (defcustom hs-lint-command "hlint"
1002   "The default hs-lint command for \\[hlint]."
1003   :type 'string
1004   :group 'hs-lint)
1005
1006 (defcustom hs-lint-save-files t
1007   "Save modified files when run HLint or no (ask user)"
1008   :type 'boolean
1009   :group 'hs-lint)
1010
1011 (defcustom hs-lint-replace-with-suggestions nil
1012   "Replace user's code with suggested replacements"
1013   :type 'boolean
1014   :group 'hs-lint)
1015
1016 (defcustom hs-lint-replace-without-ask nil
1017   "Replace user's code with suggested replacements automatically"
1018   :type 'boolean
1019   :group 'hs-lint)
1020
1021 (defun hs-lint-process-setup ()
1022   "Setup compilation variables and buffer for `hlint'."
1023   (run-hooks 'hs-lint-setup-hook))
1024
1025 ;; regex for replace suggestions
1026 ;;
1027 ;; ^\(.*?\):\([0-9]+\):\([0-9]+\): .*
1028 ;; Found:
1029 ;; \s +\(.*\)
1030 ;; Why not:
1031 ;; \s +\(.*\)
1032
1033 (defvar hs-lint-regex
1034   "^\\(.*?\\):\\([0-9]+\\):\\([0-9]+\\): .*[\n\C-m]Found:[\n\C-m]\\s +\\(.*\\)[\n\C-m]Why not:[\n\C-m]\\s +\\(.*\\)[\n\C-m]"
1035   "Regex for HLint messages")
1036
1037 (defun make-short-string (str maxlen)
1038   (if (< (length str) maxlen)
1039       str
1040     (concat (substring str 0 (- maxlen 3)) "...")))
1041
1042 (defun hs-lint-replace-suggestions ()
1043   "Perform actual replacement of suggestions"
1044   (goto-char (point-min))
1045   (while (re-search-forward hs-lint-regex nil t)
1046     (let* ((fname (match-string 1))
1047           (fline (string-to-number (match-string 2)))
1048           (old-code (match-string 4))
1049           (new-code (match-string 5))
1050           (msg (concat "Replace '" (make-short-string old-code 30)
1051                        "' with '" (make-short-string new-code 30) "'"))
1052           (bline 0)
1053           (eline 0)
1054           (spos 0)
1055           (new-old-code ""))
1056       (save-excursion
1057         (switch-to-buffer (get-file-buffer fname))
1058         (goto-char (point-min))
1059         (forward-line (1- fline))
1060         (beginning-of-line)
1061         (setf bline (point))
1062         (when (or hs-lint-replace-without-ask
1063                   (yes-or-no-p msg))
1064           (end-of-line)
1065           (setf eline (point))
1066           (beginning-of-line)
1067           (setf old-code (regexp-quote old-code))
1068           (while (string-match "\\\\ " old-code spos)
1069             (setf new-old-code (concat new-old-code
1070                                  (substring old-code spos (match-beginning 0))
1071                                  "\\ *"))
1072             (setf spos (match-end 0)))
1073           (setf new-old-code (concat new-old-code (substring old-code spos)))
1074           (remove-text-properties bline eline '(composition nil))
1075           (when (re-search-forward new-old-code eline t)
1076             (replace-match new-code nil t)))))))
1077
1078 (defun hs-lint-finish-hook (buf msg)
1079   "Function, that is executed at the end of HLint execution"
1080   (if hs-lint-replace-with-suggestions
1081       (hs-lint-replace-suggestions)
1082       (next-error 1 t)))
1083
1084 (define-compilation-mode hs-lint-mode "HLint"
1085   "Mode for check Haskell source code."
1086   (set (make-local-variable 'compilation-process-setup-function)
1087        'hs-lint-process-setup)
1088   (set (make-local-variable 'compilation-disable-input) t)
1089   (set (make-local-variable 'compilation-scroll-output) nil)
1090   (set (make-local-variable 'compilation-finish-functions)
1091        (list 'hs-lint-finish-hook))
1092   )
1093
1094 (defun hs-lint ()
1095   "Run HLint for current buffer with haskell source"
1096   (interactive)
1097   (save-some-buffers hs-lint-save-files)
1098   (compilation-start (concat hs-lint-command " \"" buffer-file-name "\"")
1099                      'hs-lint-mode))
1100
1101 (provide 'hs-lint)
1102 ;;; hs-lint.el ends here
1103 #+end_src
1104
1105 #+begin_src emacs-lisp :tangle no
1106 (use-package hs-lint
1107   :load-path "lisp/"
1108   :bind (:map haskell-mode-map
1109               ("C-c l l" . hs-lint)))
1110 #+end_src
1111 * Emacs Enhancements
1112
1113 ** [[https://github.com/justbur/emacs-which-key][which-key]]
1114
1115 #+begin_quote
1116 Emacs package that displays available keybindings in popup
1117 #+end_quote
1118
1119 #+begin_src emacs-lisp
1120 (use-package which-key
1121   :defer 1
1122   :config (which-key-mode))
1123 #+end_src
1124
1125 ** [[https://github.com/seagle0128/doom-modeline][doom-modeline]]
1126
1127 #+begin_src emacs-lisp
1128 (use-package doom-modeline
1129   :demand t
1130   :config (setq doom-modeline-height 32)
1131   :hook (after-init . doom-modeline-init))
1132 #+end_src
1133
1134 ** [[https://github.com/11111000000/tao-theme-emacs][tao-theme]]
1135
1136 #+begin_src emacs-lisp :tangle no
1137 (use-package tao-theme
1138   :demand t
1139   :config (load-theme 'tao-yang t))
1140 #+end_src
1141
1142 ** [[https://github.com/maio/eink-emacs][eink-theme]]
1143
1144 #+begin_src emacs-lisp
1145 (load-theme 'eink t)
1146 #+end_src
1147
1148 ** [[https://github.com/bbatsov/crux][crux]]
1149
1150 #+begin_src emacs-lisp
1151 (use-package crux
1152   :bind (("C-c d"    . crux-duplicate-current-line-or-region)
1153          ("C-c M-d"  . crux-duplicate-and-comment-current-line-or-region))
1154   :ryo
1155   ("o" crux-smart-open-line :exit t)
1156   ("O" crux-smart-open-line-above :exit t)
1157   ("SPC b K" crux-kill-other-buffers)
1158   ("d d" crux-kill-whole-line)
1159   ("c c" crux-kill-whole-line :then '(crux-smart-open-line-above) :exit t)
1160   ("SPC f" (("c" crux-copy-file-preserve-attributes)
1161             ("D" crux-delete-file-and-buffer)
1162             ("R" crux-rename-file-and-buffer))))
1163 #+end_src
1164
1165 ** [[https://github.com/alezost/mwim.el][mwim]]
1166
1167 #+begin_src emacs-lisp
1168 (use-package mwim
1169   :bind (("C-a"    . mwim-beginning-of-code-or-line)
1170          ("C-e"    . mwim-end-of-code-or-line)
1171          ("<home>" . mwim-beginning-of-line-or-code)
1172          ("<end>"  . mwim-end-of-line-or-code))
1173   :ryo
1174   ("a" mwim-beginning-of-code-or-line)
1175   ("e" mwim-end-of-code-or-line))
1176 #+end_src
1177
1178 ** [[https://www.emacswiki.org/emacs/KeyChord][key-chord]]
1179
1180 #+begin_src emacs-lisp
1181 (use-package key-chord
1182   :demand t
1183   :config
1184   (key-chord-mode 1)
1185   (key-chord-define-global "jk" 'ryo-modal-mode)
1186   (setq key-chord-one-key-delay 0 ; i don't need one-key chords for now
1187         key-chord-two-keys-delay 0.005))
1188 #+end_src
1189
1190 * Email
1191 ** [[https://notmuchmail.org][notmuch]]
1192
1193 See [[notmuch:id:87muuqsvci.fsf@fencepost.gnu.org][bug follow-up]].
1194
1195 #+begin_src emacs-lisp
1196 (defun ab/notmuch ()
1197   "Delete other windows, then launch `notmuch'."
1198   (interactive)
1199   (require 'notmuch)
1200   (delete-other-windows)
1201   (notmuch))
1202
1203 ;; (map!
1204 ;;  :leader
1205 ;;  :desc "notmuch" :n "m" #'ab/notmuch
1206 ;;  (:desc "search" :prefix "/"
1207 ;;    :desc "notmuch" :n "m" #'counsel-notmuch))
1208 #+end_src
1209
1210 #+begin_src emacs-lisp
1211 (defvar ab-maildir "~/mail")
1212
1213 (use-package sendmail
1214   ;; :ensure nil
1215   :config
1216   (setq sendmail-program "/usr/bin/msmtp"
1217         ; message-sendmail-extra-arguments '("-v" "-d")
1218         mail-specify-envelope-from t
1219         mail-envelope-from 'header))
1220
1221 (use-package message
1222   ;; :ensure nil
1223   :config
1224   (setq message-kill-buffer-on-exit t
1225         message-send-mail-function 'message-send-mail-with-sendmail
1226         message-sendmail-envelope-from 'header
1227         message-directory "drafts"
1228         message-user-fqdn "aminb.org")
1229   (add-hook 'message-mode-hook
1230             (lambda () (setq fill-column 65
1231                         message-fill-column 65)))
1232   (add-hook 'message-mode-hook
1233             #'flyspell-mode)
1234   ;; (add-hook 'notmuch-message-mode-hook #'+doom-modeline|set-special-modeline)
1235   ;; TODO: is there a way to only run this when replying and not composing?
1236   ;; (add-hook 'notmuch-message-mode-hook
1237   ;;           (lambda () (progn
1238   ;;                   (newline)
1239   ;;                   (newline)
1240   ;;                   (forward-line -1)
1241   ;;                   (forward-line -1))))
1242   ;; (add-hook 'message-setup-hook
1243   ;;           #'mml-secure-message-sign-pgpmime)
1244   )
1245
1246 (after! mml-sec
1247   (setq mml-secure-openpgp-encrypt-to-self t
1248         mml-secure-openpgp-sign-with-sender t))
1249
1250 (use-package notmuch
1251   :ryo ("SPC m" ab/notmuch)
1252   :config
1253   (setq notmuch-hello-sections
1254         '(notmuch-hello-insert-header
1255           notmuch-hello-insert-saved-searches
1256           ;; notmuch-hello-insert-search
1257           notmuch-hello-insert-alltags)
1258         notmuch-search-oldest-first nil
1259         notmuch-show-all-tags-list t
1260         notmuch-message-headers  ; see bug follow-up above
1261         '("Subject" "To" "Cc" "Date" "List-Id" "X-RT-Originator")
1262         notmuch-hello-thousands-separator ","
1263         notmuch-fcc-dirs
1264         '(("amin@aminb.org"            . "amin/Sent")
1265           ("abandali@uwaterloo.ca"     . "\"uwaterloo/Sent Items\"")
1266           ("mab@gnu.org"               . "gnu/Sent")
1267           ("aminb@gnu.org"             . "gnu/Sent")
1268           (".*"                        . "sent"))
1269         notmuch-search-result-format
1270         '(("date" . "%12s ")
1271           ("count" . "%-7s ")
1272           ("authors" . "%-40s ")
1273           ("subject" . "%s ")
1274           ("tags" . "(%s)")))
1275   ;; (add-hook 'visual-fill-column-mode-hook
1276   ;;           (lambda ()
1277   ;;             (when (string= major-mode 'notmuch-message-mode)
1278   ;;               (setq visual-fill-column-width 70))))
1279   ;; (set! :evil-state 'notmuch-message-mode 'insert)
1280   ;; (advice-add #'notmuch-bury-or-kill-this-buffer
1281   ;;             :override #'kill-this-buffer)
1282   :bind
1283   (:map notmuch-hello-mode-map
1284         ("g" . notmuch-poll-and-refresh-this-buffer)
1285         ("i" . (lambda ()
1286                  "Search for `inbox' tagged messages"
1287                  (interactive)
1288                  (notmuch-hello-search "tag:inbox")))
1289         ("u" . (lambda ()
1290                  "Search for `unread' tagged messages"
1291                  (interactive)
1292                  (notmuch-hello-search "tag:unread")))
1293         ("l" . (lambda ()
1294                  "Search for `latest tagged messages"
1295                  (interactive)
1296                  (notmuch-hello-search "tag:latest")))
1297         ("M" . (lambda ()
1298                  "Compose new mail and prompt for sender"
1299                  (interactive)
1300                  (let ((current-prefix-arg t))
1301                    (call-interactively #'notmuch-mua-new-mail)))))
1302   (:map notmuch-search-mode-map
1303         ("g" . notmuch-poll-and-refresh-this-buffer)
1304         ("k" . (lambda ()
1305                  "Mark message read"
1306                  (interactive)
1307                  (notmuch-search-tag '("-unread"))
1308                  ;; (notmuch-search-archive-thread)
1309                  (notmuch-search-next-thread)))
1310         ("u" . (lambda ()
1311                  "Mark message unread"
1312                  (interactive)
1313                  (notmuch-search-tag '("+unread"))
1314                  (notmuch-search-next-thread)))
1315         ("K" . (lambda ()
1316                  "Mark message deleted"
1317                  (interactive)
1318                  (notmuch-search-tag '("-unread" "-inbox" "+deleted"))
1319                  (notmuch-search-archive-thread)))
1320         ("S" . (lambda ()
1321                  "Mark message as spam"
1322                  (interactive)
1323                  (notmuch-search-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1324                  (notmuch-search-archive-thread))))
1325   (:map notmuch-tree-mode-map  ; TODO: additional bindings
1326         ("S" . (lambda ()
1327                  "Mark message as spam"
1328                  (interactive)
1329                  (notmuch-tree-tag '("-unread" "-inbox" "-webmasters" "+spam"))
1330                  (notmuch-tree-archive-thread))))
1331 )
1332
1333 ;; (use-package counsel-notmuch
1334 ;;   :commands counsel-notmuch)
1335
1336 (after! notmuch-crypto
1337   (setq notmuch-crypto-process-mime t))
1338
1339 ;; (after! evil
1340 ;;   (mapc (lambda (str) (evil-set-initial-state (car str) (cdr str)))
1341 ;;         '((notmuch-hello-mode . emacs)
1342 ;;           (notmuch-search-mode . emacs)
1343 ;;           (notmuch-tree-mode . emacs))))
1344
1345 (after! recentf
1346   (add-to-list 'recentf-exclude (expand-file-name ab-maildir)))
1347 #+end_src
1348
1349 ** supercite
1350
1351 #+begin_src emacs-lisp :tangle no
1352 (use-package supercite
1353   :commands sc-cite-original
1354   :init
1355   (add-hook 'mail-citation-hook 'sc-cite-original)
1356
1357   (defun sc-remove-existing-signature ()
1358     (save-excursion
1359       (goto-char (region-beginning))
1360       (when (re-search-forward message-signature-separator (region-end) t)
1361         (delete-region (match-beginning 0) (region-end)))))
1362
1363   (add-hook 'mail-citation-hook 'sc-remove-existing-signature)
1364
1365   (defun sc-remove-if-not-mailing-list ()
1366     (unless (assoc "list-id" sc-mail-info)
1367       (setq attribution sc-default-attribution
1368             citation (concat sc-citation-delimiter
1369                              sc-citation-separator))))
1370
1371   (add-hook 'sc-attribs-postselect-hook 'sc-remove-if-not-mailing-list)
1372
1373   :config
1374   (defun sc-fill-if-different (&optional prefix)
1375     "Fill the region bounded by `sc-fill-begin' and point.
1376 Only fill if optional PREFIX is different than
1377 `sc-fill-line-prefix'.  If `sc-auto-fill-region-p' is nil, do not
1378 fill region.  If PREFIX is not supplied, initialize fill
1379 variables.  This is useful for a regi `begin' frame-entry."
1380     (if (not prefix)
1381         (setq sc-fill-line-prefix ""
1382               sc-fill-begin (line-beginning-position))
1383       (if (and sc-auto-fill-region-p
1384                (not (string= prefix sc-fill-line-prefix)))
1385           (let ((fill-prefix sc-fill-line-prefix))
1386             (unless (or (string= fill-prefix "")
1387                         (save-excursion
1388                           (goto-char sc-fill-begin)
1389                           (or (looking-at ">+  +")
1390                               (< (length
1391                                   (buffer-substring (point)
1392                                                     (line-end-position)))
1393                                  65))))
1394               (fill-region sc-fill-begin (line-beginning-position)))
1395             (setq sc-fill-line-prefix prefix
1396                   sc-fill-begin (line-beginning-position)))))
1397 nil))
1398 #+end_src
1399
1400 * Blogging
1401 ** [[https://ox-hugo.scripter.co][ox-hugo]]
1402
1403 #+begin_src emacs-lisp
1404 (use-package ox-hugo
1405   :after ox)
1406 #+end_src
1407
1408 * Post initialization
1409 :PROPERTIES:
1410 :CUSTOM_ID: post-initialization
1411 :END:
1412
1413 Display how long it took to load the init file.
1414
1415 #+begin_src emacs-lisp
1416 (message "Loading %s...done (%.3fs)" user-init-file
1417          (float-time (time-subtract (current-time)
1418                                     ab--before-user-init-time)))
1419 #+end_src
1420
1421 * Footer
1422 :PROPERTIES:
1423 :CUSTOM_ID: footer
1424 :END:
1425
1426 #+begin_src emacs-lisp :comments none
1427 ;;; init.el ends here
1428 #+end_src